File:  [gforth] / gforth / stuff.fs
Revision 1.21: download - view: text, annotated - select for diffs
Mon Aug 12 16:39:34 2002 UTC (21 years, 7 months ago) by anton
Branches: MAIN
CVS tags: HEAD
added str= and string-prefix?

    1: \ miscelleneous words
    2: 
    3: \ Copyright (C) 1996,1997,1998,2000 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: require glocals.fs
   22: 
   23: ' require alias needs ( ... "name" -- ... ) \ gforth
   24: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
   25: \ needs is an F-PC name. we will probably switch to 'needs' in the future
   26: 
   27: \ a little more compiler security
   28: 
   29: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
   30: AUser CSP
   31: 
   32: : !CSP ( -- )
   33:     sp@ csp ! ;
   34: 
   35: : ?CSP ( -- )
   36:     sp@ csp @ <> -22 and throw ;
   37: 
   38: \ DMIN and DMAX
   39: 
   40: : dmin ( d1 d2 -- d ) \ double d-min
   41:     2over 2over d> IF  2swap  THEN 2drop ;
   42: 
   43: 
   44: : dmax ( d1 d2 -- d ) \ double d-max
   45:     2over 2over d< IF  2swap  THEN 2drop ;
   46: 
   47: \ shell commands
   48: 
   49: 0 Value $? ( -- n ) \ gforth dollar-question
   50: \G @code{Value} -- the exit status returned by the most recently executed
   51: \G @code{system} command.
   52: 
   53: : system ( c-addr u -- ) \ gforth
   54: \G Pass the string specified by @var{c-addr u} to the host operating system
   55: \G for execution in a sub-shell.
   56:     (system) throw TO $? ;
   57: 
   58: : sh ( "..." -- ) \ gforth
   59: \G Parse a string and use @code{system} to pass it to the host
   60: \G operating system for execution in a sub-shell.
   61:     '# parse cr system ;
   62: 
   63: \ stuff
   64: 
   65: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
   66:     \G equivalent to @code{] literal}
   67:     ] postpone literal ;
   68: 
   69: : in-dictionary? ( x -- f )
   70:     forthstart dictionary-end within ;
   71: 
   72: : in-return-stack? ( addr -- f )
   73:     rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
   74: 
   75: \ const-does>
   76: 
   77: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
   78:     \ compile u literals, starting with the bottommost one
   79:     ?dup-if
   80: 	swap >r 1- compile-literals
   81: 	r> POSTPONE literal
   82:     endif ;
   83: 
   84: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
   85:     \ compile u fliterals, starting with the bottommost one
   86:     ?dup-if
   87: 	{ F: r } 1- compile-fliterals
   88: 	r POSTPONE fliteral
   89:     endif ;
   90: 
   91: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
   92:     \ define a colon definition "name" containing w*uw r*ur as
   93:     \ literals and a call to target.
   94:     { uw ur target }
   95:     header docol: cfa, \ start colon def without stack junk
   96:     ur compile-fliterals uw compile-literals
   97:     target compile, POSTPONE exit reveal ;
   98: 
   99: : const-does> ( run-time: w*uw r*ur uw ur "name" -- )
  100:     \G Defines @var{name} and returns.@sp 0
  101:     \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
  102:     \G code following the @code{const-does>}.
  103:     here >r 0 POSTPONE literal
  104:     POSTPONE (const-does>)
  105:     POSTPONE ;
  106:     noname : POSTPONE rdrop
  107:     lastxt r> cell+ ! \ patch the literal
  108: ; immediate
  109: 
  110: \ !! rewrite slurp-file using slurp-fid
  111: : slurp-file ( c-addr1 u1 -- c-addr2 u2 )
  112:     \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
  113:     r/o bin open-file throw >r
  114:     r@ file-size throw abort" file too large"
  115:     dup allocate throw swap
  116:     2dup r@ read-file throw over <> abort" could not read whole file"
  117:     r> close-file throw ;
  118: 
  119: : slurp-fid { fid -- addr u }
  120:     \G @var{addr u} is the content of the file @var{fid}
  121:     0 0 begin ( awhole uwhole )
  122: 	dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
  123: 	rot r@ fid read-file throw ( awhole uwhole uread R: unew )
  124: 	r> 2dup =
  125:     while ( awhole uwhole uread unew )
  126: 	2drop
  127:     repeat
  128:     - + dup >r resize throw r> ;
  129: 
  130: : str= ( c-addr1 u1 c-addr2 u2 -- f )
  131:     compare 0= ;
  132: 
  133: : string-prefix? ( c-addr1 u1 c-addr2 u2 -- f )
  134:     \G Is @var{c-addr2 u2} a prefix of @var{c-addr1 u1}?
  135:     tuck 2>r min 2r> compare 0= ;

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>