File:  [gforth] / gforth / stuff.fs
Revision 1.65: download - view: text, annotated - select for diffs
Thu Dec 31 15:32:35 2009 UTC (14 years, 2 months ago) by anton
Branches: MAIN
CVS tags: HEAD
updated copyright years

    1: \ miscelleneous words
    2: 
    3: \ Copyright (C) 1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: require glocals.fs
   21: 
   22: ' require alias needs ( ... "name" -- ... ) \ gforth
   23: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
   24: \ needs is an F-PC name. we will probably switch to 'needs' in the future
   25: 
   26: \ a little more compiler security
   27: 
   28: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
   29: AUser CSP
   30: 
   31: : !CSP ( -- )
   32:     sp@ csp ! ;
   33: 
   34: : ?CSP ( -- )
   35:     sp@ csp @ <> -22 and throw ;
   36: 
   37: \ DMIN and DMAX
   38: 
   39: : dmin ( d1 d2 -- d ) \ double d-min
   40:     2over 2over d> IF  2swap  THEN 2drop ;
   41: 
   42: 
   43: : dmax ( d1 d2 -- d ) \ double d-max
   44:     2over 2over d< IF  2swap  THEN 2drop ;
   45: 
   46: \ shell commands
   47: 
   48: 0 Value $? ( -- n ) \ gforth dollar-question
   49: \G @code{Value} -- the exit status returned by the most recently executed
   50: \G @code{system} command.
   51: 
   52: : system ( c-addr u -- ) \ gforth
   53: \G Pass the string specified by @var{c-addr u} to the host operating
   54: \G system for execution in a sub-shell.  The value of the environment
   55: \G variable @code{GFORTHSYSTEMPREFIX} (or its default value) is
   56: \G prepended to the string (mainly to support using @code{command.com}
   57: \G as shell in Windows instead of whatever shell Cygwin uses by
   58: \G default; @pxref{Environment variables}).
   59:     (system) throw TO $? ;
   60: 
   61: : sh ( "..." -- ) \ gforth
   62: \G Parse a string and use @code{system} to pass it to the host
   63: \G operating system for execution in a sub-shell.
   64:     '# parse cr system ;
   65: 
   66: \ stuff
   67: 
   68: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
   69:     \G equivalent to @code{] literal}
   70:     ] postpone literal ;
   71: 
   72: [ifundef] in-dictionary?
   73: : in-dictionary? ( x -- f )
   74:     forthstart dictionary-end within ;
   75: [endif]
   76: 
   77: : in-return-stack? ( addr -- f )
   78:     rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
   79: 
   80: \ const-does>
   81: 
   82: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
   83:     \ compile u literals, starting with the bottommost one
   84:     ?dup-if
   85: 	swap >r 1- compile-literals
   86: 	r> POSTPONE literal
   87:     endif ;
   88: 
   89: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
   90:     \ compile u fliterals, starting with the bottommost one
   91:     ?dup-if
   92: 	{ F: r } 1- compile-fliterals
   93: 	r POSTPONE fliteral
   94:     endif ;
   95: 
   96: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
   97:     \ define a colon definition "name" containing w*uw r*ur as
   98:     \ literals and a call to target.
   99:     { uw ur target }
  100:     header docol: cfa, \ start colon def without stack junk
  101:     ur compile-fliterals uw compile-literals
  102:     target compile, POSTPONE exit reveal ;
  103: 
  104: : const-does> ( run-time: w*uw r*ur uw ur "name" -- ) \ gforth
  105:     \G Defines @var{name} and returns.
  106:     \G  
  107:     \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
  108:     \G code following the @code{const-does>}.
  109:     here >r 0 POSTPONE literal
  110:     POSTPONE (const-does>)
  111:     POSTPONE ;
  112:     noname : POSTPONE rdrop
  113:     latestxt r> cell+ ! \ patch the literal
  114: ; immediate
  115: 
  116: \ !! rewrite slurp-file using slurp-fid
  117: : slurp-file ( c-addr1 u1 -- c-addr2 u2 ) \ gforth
  118:     \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
  119:     r/o bin open-file throw >r
  120:     r@ file-size throw abort" file too large"
  121:     dup allocate throw swap
  122:     2dup r@ read-file throw over <> abort" could not read whole file"
  123:     r> close-file throw ;
  124: 
  125: : slurp-fid ( fid -- addr u ) \ gforth
  126: \G @var{addr u} is the content of the file @var{fid}
  127:     { fid }
  128:     0 0 begin ( awhole uwhole )
  129: 	dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
  130: 	rot r@ fid read-file throw ( awhole uwhole uread R: unew )
  131: 	r> 2dup =
  132:     while ( awhole uwhole uread unew )
  133: 	2drop
  134:     repeat
  135:     - + dup >r resize throw r> ;
  136: 
  137: \ ]] ... [[
  138: 
  139: : compile-literal ( n -- )
  140:     postpone literal ;
  141: 
  142: : compile-compile-literal ( n -- )
  143:     compile-literal postpone compile-literal ;
  144: 
  145: : compile-2literal ( n1 n2 -- )
  146:     postpone 2literal ;
  147: 
  148: : compile-compile-2literal ( n1 n2 -- )
  149:     compile-2literal postpone compile-2literal ;
  150: 
  151: : [[ ( -- ) \ gforth left-bracket-bracket
  152: \G switch from postpone state to compile state
  153:     \ this is only a marker; it is never really interpreted
  154:     compile-only-error ; immediate
  155: 
  156: [ifdef] compiler1
  157: : postponer1 ( c-addr u -- ... xt )
  158:     2dup find-name
  159:     [ifdef] run-prelude run-prelude [then]
  160:     dup if ( c-addr u nt )
  161: 	nip nip name>comp
  162: 	2dup [comp'] [[ d= if
  163: 	    2drop ['] compiler1 is parser1 ['] noop
  164: 	else
  165: 	    ['] postpone,
  166: 	endif
  167:     else
  168: 	drop
  169: 	2dup 2>r snumber? dup if
  170: 	    0> IF
  171: 		['] compile-compile-2literal
  172:             ELSE
  173:                 ['] compile-compile-literal
  174: 	    THEN
  175: 	    2rdrop
  176: 	ELSE
  177: 	    drop 2r> no.extensions
  178: 	THEN
  179:     then ;
  180: 
  181: : ]] ( -- ) \ gforth right-bracket-bracket
  182:     \G switch into postpone state
  183:     ['] postponer1 is parser1 state on ; immediate restrict
  184: 
  185: comp'  literal drop alias postpone-literal
  186: comp' 2literal drop alias postpone-2literal
  187: comp' fliteral drop alias postpone-fliteral
  188: comp' sliteral drop alias postpone-sliteral
  189: 
  190: : ]]L ( postponing: x -- ; compiling: -- x ) \ gforth right-bracket-bracket-l
  191: \G Shortcut for @code{]] literal}.
  192:     ]] postpone-literal ]] [[ ; immediate
  193: 
  194: : ]]2L ( postponing: x1 x2 -- ; compiling: -- x1 x2 ) \ gforth right-bracket-bracket-two-l
  195: \G Shortcut for @code{]] 2literal}.
  196:     ]] postpone-2literal ]] [[ ; immediate
  197: 
  198: : ]]FL ( postponing: r -- ; compiling: -- r ) \ gforth right-bracket-bracket-f-l
  199: \G Shortcut for @code{]] fliteral}.
  200:     ]] postpone-fliteral ]] [[ ; immediate
  201: 
  202: : ]]SL ( postponing: addr1 u -- ; compiling: -- addr2 u ) \ gforth right-bracket-bracket-s-l
  203: \G Shortcut for @code{]] sliteral}; if the string already has been
  204: \G allocated permanently, you can use @code{]]2L} instead.
  205:     ]] postpone-sliteral ]] [[ ; immediate
  206: 
  207: [then]
  208: 
  209: \ f.rdp
  210: 
  211: : push-right ( c-addr u1 u2 cfill -- )
  212:     \ move string at c-addr u1 right by u2 chars (without exceeding
  213:     \ the original bound); fill the gap with cfill
  214:     >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
  215:     dup 2swap /string cmove>
  216:     r> r> r> fill ;
  217: 
  218: : f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
  219:     \ um1 is the mantissa length to try, um2 is the actual mantissa length
  220:     c-addr ur um1 /string '0 fill
  221:     rf c-addr um1 represent if { nexp fsign }
  222: 	nd nexp + up >=
  223: 	ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
  224: 	    \ fixed-point notation
  225: 	    c-addr ur beforep nexp - dup { befored } '0 push-right
  226:             befored 1+ ur >= if \ <=1 digit left, will be pushed out by '.'
  227:                 rf fabs f2* 0.1e nd s>d d>f f** f> if \ round last digit
  228:                     '1 c-addr befored + 1- c!
  229:                 endif
  230:             endif
  231: 	    c-addr beforep 1- befored min dup { beforez } 0 max bl fill
  232: 	    fsign if
  233: 		'- c-addr beforez 1- 0 max + c!
  234: 	    endif
  235: 	    c-addr ur beforep /string 1 '. push-right
  236: 	    nexp nd +
  237: 	else \ exponential notation
  238: 	    c-addr ur 1 /string 1 '. push-right
  239: 	    fsign if
  240: 		c-addr ur 1 '- push-right
  241: 	    endif
  242: 	    nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
  243: 	    ur explen - 1- fsign + { mantlen }
  244: 	    mantlen 0< if \ exponent too large
  245: 		drop c-addr ur '* fill
  246: 	    else
  247: 		c-addr ur + 0 explen negate /string move
  248: 	    endif
  249: 	    #>> mantlen
  250: 	endif
  251:     else \ inf or nan
  252: 	if \ negative
  253: 	    c-addr ur 1 '- push-right
  254: 	endif
  255: 	drop ur
  256: 	\ !! align in some way?
  257:     endif
  258:     1 max ur min ;
  259: 
  260: : f>buf-rdp ( rf c-addr +nr +nd +np -- ) \ gforth
  261: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  262: \G rules and the meanings of @i{nr nd np} are the same as for
  263: \G @code{f.rdp}.
  264:     \ first, get the mantissa length, then convert for real.  The
  265:     \ mantissa length is wrong in a few cases because of different
  266:     \ rounding; In most cases this does not matter, because the
  267:     \ mantissa is shorter than expected and the final digits are 0;
  268:     \ but in a few cases the mantissa gets longer.  Then it is
  269:     \ conceivable that you will see a result that is rounded too much.
  270:     \ However, I have not been able to construct an example where this
  271:     \ leads to an unexpected result.
  272:     swap 0 max swap 0 max
  273:     fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
  274: 
  275: : f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
  276: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  277: \G rules and the meanings of @i{nr +nd np} are the same as for
  278: \G @code{f.rdp}.  The result in in the pictured numeric output buffer
  279: \G and will be destroyed by anything destroying that buffer.
  280:     rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
  281:     over holdbuf u< -&17 and throw
  282:     2tuck 2>r f>buf-rdp 2r> ;
  283: 
  284: : f.rdp ( rf +nr +nd +np -- ) \ gforth
  285: \G Print float @i{rf} formatted.  The total width of the output is
  286: \G @i{nr}.  For fixed-point notation, the number of digits after the
  287: \G decimal point is @i{+nd} and the minimum number of significant
  288: \G digits is @i{np}.  @code{Set-precision} has no effect on
  289: \G @code{f.rdp}.  Fixed-point notation is used if the number of
  290: \G siginicant digits would be at least @i{np} and if the number of
  291: \G digits before the decimal point would fit.  If fixed-point notation
  292: \G is not used, exponential notation is used, and if that does not
  293: \G fit, asterisks are printed.  We recommend using @i{nr}>=7 to avoid
  294: \G the risk of numbers not fitting at all.  We recommend
  295: \G @i{nr}>=@i{np}+5 to avoid cases where @code{f.rdp} switches to
  296: \G exponential notation because fixed-point notation would have too
  297: \G few significant digits, yet exponential notation offers fewer
  298: \G significant digits.  We recommend @i{nr}>=@i{nd}+2, if you want to
  299: \G have fixed-point notation for some numbers.  We recommend
  300: \G @i{np}>@i{nr}, if you want to have exponential notation for all
  301: \G numbers.
  302:     f>str-rdp type ;
  303: 
  304: 0 [if]
  305: : testx ( rf ur nd up -- )
  306:     '| emit f.rdp ;
  307: 
  308: : test ( -- )
  309:     -0.123456789123456789e-20
  310:     40 0 ?do
  311: 	cr
  312: 	fdup 7 3 1 testx
  313: 	fdup 7 3 4 testx
  314: 	fdup 7 3 0 testx
  315: 	fdup 7 7 1 testx
  316: 	fdup 7 5 1 testx
  317: 	fdup 7 0 2 testx
  318: 	fdup 5 2 1 testx
  319: 	fdup 4 2 1 testx
  320: 	fdup 18 8 5 testx
  321: 	'| emit
  322: 	10e f*
  323:     loop ;
  324: [then]
  325: 
  326: : f.s ( -- ) \ gforth f-dot-s
  327: \G Display the number of items on the floating-point stack, followed
  328: \G by a list of the items (but not more than specified by
  329: \G @code{maxdepth-.s}; TOS is the right-most item.
  330:     ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0 
  331:     ?DO  dup i - 1- floats fp@ + f@ 16 5 11 f.rdp space LOOP  drop ; 
  332: 
  333: \ defer stuff
  334: 
  335: [ifundef] defer@ : defer@ >body @ ; [then]
  336: 
  337: :noname    ' defer@ ;
  338: :noname    postpone ['] postpone defer@ ;
  339: interpret/compile: action-of ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth
  340: \G @i{Xt} is the XT that is currently assigned to @i{name}.
  341: 
  342: ' action-of
  343: comp' action-of drop
  344: interpret/compile: what's ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth-obsolete
  345: \G Old name of @code{action-of}
  346: 
  347: 
  348: : typewhite ( addr n -- ) \ gforth
  349: \G Like type, but white space is printed instead of the characters.
  350:     \ bounds u+do
  351:     0 max bounds ?do
  352: 	i c@ #tab = if \ check for tab
  353: 	    #tab
  354: 	else
  355: 	    bl
  356: 	then
  357: 	emit
  358:     loop ;
  359: 
  360: \ w and l stuff
  361: 
  362: environment-wordlist >order
  363: 
  364: 16 address-unit-bits / 1 max constant /w ( -- u ) \ gforth slash-w
  365: \G address units for a 16-bit value
  366:     
  367: 32 address-unit-bits / 1 max constant /l ( -- u ) \ gforth slash-l
  368: \G address units for a 32-bit value
  369: 
  370: previous
  371: 
  372: [ifdef] uw@
  373: \ Open firmware names
  374: ' uw@ alias w@ ( addr -- u )
  375: ' ul@ alias l@ ( addr -- u )
  376: \ ' sw@ alias <w@ ( addr -- n )
  377: [then]
  378: 
  379: \ safe output redirection
  380: 
  381: : outfile-execute ( ... xt file-id -- ... ) \ gforth
  382:     \G execute @i{xt} with the output of @code{type} etc. redirected to
  383:     \G @i{file-id}.
  384:     outfile-id { oldfid } try
  385: 	to outfile-id execute 0
  386:     restore
  387: 	oldfid to outfile-id
  388:     endtry
  389:     throw ;
  390: 
  391: : infile-execute ( ... xt file-id -- ... ) \ gforth
  392:     \G execute @i{xt} with the input of @code{key} etc. redirected to
  393:     \G @i{file-id}.
  394:     infile-id { oldfid } try
  395: 	to infile-id execute 0
  396:     restore
  397: 	oldfid to infile-id
  398:     endtry
  399:     throw ;
  400: 
  401: \ safe BASE wrapper
  402: 
  403: : base-execute ( i*x xt u -- j*x ) \ gforth
  404:     \G execute @i{xt} with the content of @code{BASE} being @i{u}, and
  405:     \G restoring the original @code{BASE} afterwards.
  406:     base @ { oldbase } \ use local, because TRY blocks the return stack
  407:     try
  408: 	base ! execute 0
  409:     restore
  410: 	oldbase base !
  411:     endtry
  412:     throw ;
  413: 
  414: \ th
  415: 
  416: : th ( addr1 u -- addr2 )
  417:     cells + ;
  418: 
  419: \ \\\ - skip to end of file
  420: 
  421: : \\\ ( -- ) \ gforth
  422:     \G skip remaining source file
  423:     source-id dup 0> IF
  424: 	>r r@ file-size throw r> reposition-file throw
  425: 	BEGIN  refill 0= UNTIL  postpone \  THEN ; immediate

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>