1: \ miscelleneous words
2:
3: \ Copyright (C) 1996,1997,1998,2000,2003,2004,2005 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: require glocals.fs
22:
23: ' require alias needs ( ... "name" -- ... ) \ gforth
24: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
25: \ needs is an F-PC name. we will probably switch to 'needs' in the future
26:
27: \ a little more compiler security
28:
29: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
30: AUser CSP
31:
32: : !CSP ( -- )
33: sp@ csp ! ;
34:
35: : ?CSP ( -- )
36: sp@ csp @ <> -22 and throw ;
37:
38: \ DMIN and DMAX
39:
40: : dmin ( d1 d2 -- d ) \ double d-min
41: 2over 2over d> IF 2swap THEN 2drop ;
42:
43:
44: : dmax ( d1 d2 -- d ) \ double d-max
45: 2over 2over d< IF 2swap THEN 2drop ;
46:
47: \ shell commands
48:
49: 0 Value $? ( -- n ) \ gforth dollar-question
50: \G @code{Value} -- the exit status returned by the most recently executed
51: \G @code{system} command.
52:
53: : system ( c-addr u -- ) \ gforth
54: \G Pass the string specified by @var{c-addr u} to the host operating
55: \G system for execution in a sub-shell. The value of the environment
56: \G variable @code{GFORTHSYSTEMPREFIX} (or its default value) is
57: \G prepended to the string (mainly to support using @code{command.com}
58: \G as shell in Windows instead of whatever shell Cygwin uses by
59: \G default; @pxref{Environment variables}).
60: (system) throw TO $? ;
61:
62: : sh ( "..." -- ) \ gforth
63: \G Parse a string and use @code{system} to pass it to the host
64: \G operating system for execution in a sub-shell.
65: '# parse cr system ;
66:
67: \ stuff
68:
69: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
70: \G equivalent to @code{] literal}
71: ] postpone literal ;
72:
73: [ifundef] in-dictionary?
74: : in-dictionary? ( x -- f )
75: forthstart dictionary-end within ;
76: [endif]
77:
78: : in-return-stack? ( addr -- f )
79: rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
80:
81: \ const-does>
82:
83: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
84: \ compile u literals, starting with the bottommost one
85: ?dup-if
86: swap >r 1- compile-literals
87: r> POSTPONE literal
88: endif ;
89:
90: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
91: \ compile u fliterals, starting with the bottommost one
92: ?dup-if
93: { F: r } 1- compile-fliterals
94: r POSTPONE fliteral
95: endif ;
96:
97: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
98: \ define a colon definition "name" containing w*uw r*ur as
99: \ literals and a call to target.
100: { uw ur target }
101: header docol: cfa, \ start colon def without stack junk
102: ur compile-fliterals uw compile-literals
103: target compile, POSTPONE exit reveal ;
104:
105: : const-does> ( run-time: w*uw r*ur uw ur "name" -- ) \ gforth
106: \G Defines @var{name} and returns.
107: \G
108: \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
109: \G code following the @code{const-does>}.
110: here >r 0 POSTPONE literal
111: POSTPONE (const-does>)
112: POSTPONE ;
113: noname : POSTPONE rdrop
114: latestxt r> cell+ ! \ patch the literal
115: ; immediate
116:
117: \ !! rewrite slurp-file using slurp-fid
118: : slurp-file ( c-addr1 u1 -- c-addr2 u2 ) \ gforth
119: \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
120: r/o bin open-file throw >r
121: r@ file-size throw abort" file too large"
122: dup allocate throw swap
123: 2dup r@ read-file throw over <> abort" could not read whole file"
124: r> close-file throw ;
125:
126: : slurp-fid ( fid -- addr u ) \ gforth
127: \G @var{addr u} is the content of the file @var{fid}
128: { fid }
129: 0 0 begin ( awhole uwhole )
130: dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
131: rot r@ fid read-file throw ( awhole uwhole uread R: unew )
132: r> 2dup =
133: while ( awhole uwhole uread unew )
134: 2drop
135: repeat
136: - + dup >r resize throw r> ;
137:
138: \ ]] ... [[
139:
140: : compile-literal ( n -- )
141: postpone literal ;
142:
143: : compile-compile-literal ( n -- )
144: compile-literal postpone compile-literal ;
145:
146: : compile-2literal ( n1 n2 -- )
147: postpone 2literal ;
148:
149: : compile-compile-2literal ( n1 n2 -- )
150: compile-2literal postpone compile-2literal ;
151:
152: : [[ ( -- )
153: \G switch from postpone state to compile state
154: \ this is only a marker; it is never really interpreted
155: compile-only-error ; immediate
156:
157: [ifdef] compiler1
158: : postponer1 ( c-addr u -- ... xt )
159: 2dup find-name dup if ( c-addr u nt )
160: nip nip name>comp
161: 2dup [comp'] [[ d= if
162: 2drop ['] compiler1 is parser1 ['] noop
163: else
164: ['] postpone,
165: endif
166: else
167: drop
168: 2dup 2>r snumber? dup if
169: 0> IF
170: ['] compile-compile-2literal
171: ELSE
172: ['] compile-compile-literal
173: THEN
174: 2rdrop
175: ELSE
176: drop 2r> no.extensions
177: THEN
178: then ;
179:
180: : ]] ( -- )
181: \ switch into postpone state
182: ['] postponer1 is parser1 state on ; immediate restrict
183:
184: [then]
185:
186: \ f.rdp
187:
188: : push-right ( c-addr u1 u2 cfill -- )
189: \ move string at c-addr u1 right by u2 chars (without exceeding
190: \ the original bound); fill the gap with cfill
191: >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
192: dup 2swap /string cmove>
193: r> r> r> fill ;
194:
195: : f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
196: \ um1 is the mantissa length to try, um2 is the actual mantissa length
197: c-addr ur um1 /string '0 fill
198: rf c-addr um1 represent if { nexp fsign }
199: nd nexp + up >=
200: ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
201: \ fixed-point notation
202: c-addr ur beforep nexp - dup { befored } '0 push-right
203: befored 1+ ur >= if \ <=1 digit left, will be pushed out by '.'
204: rf fabs f2* 0.1e nd s>d d>f f** f> if \ round last digit
205: '1 c-addr befored + 1- c!
206: endif
207: endif
208: c-addr beforep 1- befored min dup { beforez } 0 max bl fill
209: fsign if
210: '- c-addr beforez 1- 0 max + c!
211: endif
212: c-addr ur beforep /string 1 '. push-right
213: nexp nd +
214: else \ exponential notation
215: c-addr ur 1 /string 1 '. push-right
216: fsign if
217: c-addr ur 1 '- push-right
218: endif
219: nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
220: ur explen - 1- fsign + { mantlen }
221: mantlen 0< if \ exponent too large
222: drop c-addr ur '* fill
223: else
224: c-addr ur + 0 explen negate /string move
225: endif
226: #>> mantlen
227: endif
228: else \ inf or nan
229: if \ negative
230: c-addr ur 1 '- push-right
231: endif
232: drop ur
233: \ !! align in some way?
234: endif
235: 1 max ur min ;
236:
237: : f>buf-rdp ( rf c-addr +nr +nd +np -- ) \ gforth
238: \G Convert @i{rf} into a string at @i{c-addr nr}. The conversion
239: \G rules and the meanings of @i{nr nd np} are the same as for
240: \G @code{f.rdp}.
241: \ first, get the mantissa length, then convert for real. The
242: \ mantissa length is wrong in a few cases because of different
243: \ rounding; In most cases this does not matter, because the
244: \ mantissa is shorter than expected and the final digits are 0;
245: \ but in a few cases the mantissa gets longer. Then it is
246: \ conceivable that you will see a result that is rounded too much.
247: \ However, I have not been able to construct an example where this
248: \ leads to an unexpected result.
249: swap 0 max swap 0 max
250: fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
251:
252: : f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
253: \G Convert @i{rf} into a string at @i{c-addr nr}. The conversion
254: \G rules and the meanings of @i{nr +nd np} are the same as for
255: \G @code{f.rdp}. The result in in the pictured numeric output buffer
256: \G and will be destroyed by anything destroying that buffer.
257: rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
258: over holdbuf u< -&17 and throw
259: 2tuck 2>r f>buf-rdp 2r> ;
260:
261: : f.rdp ( rf +nr +nd +np -- ) \ gforth
262: \G Print float @i{rf} formatted. The total width of the output is
263: \G @i{nr}. For fixed-point notation, the number of digits after the
264: \G decimal point is @i{+nd} and the minimum number of significant
265: \G digits is @i{np}. @code{Set-precision} has no effect on
266: \G @code{f.rdp}. Fixed-point notation is used if the number of
267: \G siginicant digits would be at least @i{np} and if the number of
268: \G digits before the decimal point would fit. If fixed-point notation
269: \G is not used, exponential notation is used, and if that does not
270: \G fit, asterisks are printed. We recommend using @i{nr}>=7 to avoid
271: \G the risk of numbers not fitting at all. We recommend
272: \G @i{nr}>=@i{np}+5 to avoid cases where @code{f.rdp} switches to
273: \G exponential notation because fixed-point notation would have too
274: \G few significant digits, yet exponential notation offers fewer
275: \G significant digits. We recommend @i{nr}>=@i{nd}+2, if you want to
276: \G have fixed-point notation for some numbers. We recommend
277: \G @i{np}>@i{nr}, if you want to have exponential notation for all
278: \G numbers.
279: f>str-rdp type ;
280:
281: 0 [if]
282: : testx ( rf ur nd up -- )
283: '| emit f.rdp ;
284:
285: : test ( -- )
286: -0.123456789123456789e-20
287: 40 0 ?do
288: cr
289: fdup 7 3 1 testx
290: fdup 7 3 4 testx
291: fdup 7 3 0 testx
292: fdup 7 7 1 testx
293: fdup 7 5 1 testx
294: fdup 7 0 2 testx
295: fdup 5 2 1 testx
296: fdup 4 2 1 testx
297: fdup 18 8 5 testx
298: '| emit
299: 10e f*
300: loop ;
301: [then]
302:
303: : f.s ( -- ) \ gforth f-dot-s
304: \G Display the number of items on the floating-point stack, followed
305: \G by a list of the items (but not more than specified by
306: \G @code{maxdepth-.s}; TOS is the right-most item.
307: ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0
308: ?DO dup i - 1- floats fp@ + f@ 16 5 11 f.rdp space LOOP drop ;
309:
310: \ defer stuff
311:
312: [ifundef] defer@ : defer@ >body @ ; [then]
313:
314: :noname ' defer@ ;
315: :noname postpone ['] postpone defer@ ;
316: interpret/compile: action-of ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth
317: \G @i{Xt} is the XT that is currently assigned to @i{name}.
318:
319: ' action-of
320: comp' action-of drop
321: interpret/compile: what's ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth-obsolete
322: \G Old name of @code{action-of}
323:
324:
325: : typewhite ( addr n -- ) \ gforth
326: \G Like type, but white space is printed instead of the characters.
327: \ bounds u+do
328: 0 max bounds ?do
329: i c@ #tab = if \ check for tab
330: #tab
331: else
332: bl
333: then
334: emit
335: loop ;
336:
337: \ w and l stuff
338:
339: environment-wordlist >order
340:
341: 16 address-unit-bits / 1 max constant /w ( -- u ) \ gforth slash-w
342: \G address units for a 16-bit value
343:
344: 32 address-unit-bits / 1 max constant /l ( -- u ) \ gforth slash-l
345: \G address units for a 32-bit value
346:
347: previous
348:
349: [ifdef] uw@
350: \ Open firmware names
351: ' uw@ alias w@ ( addr -- u )
352: ' ul@ alias l@ ( addr -- u )
353: \ ' sw@ alias <w@ ( addr -- n )
354: [then]
355:
356: \ safe output redirection
357:
358: : to-outfile-id ( file-id -- )
359: to outfile-id ;
360:
361: : >outfile ( file-id -- r:old-file-id )
362: ]] outfile-id >r try to-outfile-id [[ ; immediate compile-only
363:
364: : outfile< ( r:old-file-id -- )
365: 0 ]] literal recover endtry r> to-outfile-id throw [[
366: ; immediate compile-only
367:
368: : to-infile-id ( file-id -- )
369: to infile-id ;
370:
371: : >infile ( file-id -- r:old-file-id )
372: ]] infile-id >r try to-infile-id [[ ; immediate compile-only
373:
374: : infile< ( r:old-file-id -- )
375: 0 ]] literal recover endtry r> to-infile-id throw [[
376: ; immediate compile-only
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to stuff.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth