File:  [gforth] / gforth / stuff.fs
Revision 1.69: download - view: text, annotated - select for diffs
Fri Oct 7 21:46:57 2011 UTC (12 years, 6 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Removed dependencies on old postponer, added .recs in look.fs to print recognizer stack

    1: \ miscelleneous words
    2: 
    3: \ Copyright (C) 1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: require glocals.fs
   21: 
   22: ' require alias needs ( ... "name" -- ... ) \ gforth
   23: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
   24: \ needs is an F-PC name. we will probably switch to 'needs' in the future
   25: 
   26: \ a little more compiler security
   27: 
   28: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
   29: AUser CSP
   30: 
   31: : !CSP ( -- )
   32:     sp@ csp ! ;
   33: 
   34: : ?CSP ( -- )
   35:     sp@ csp @ <> -22 and throw ;
   36: 
   37: \ DMIN and DMAX
   38: 
   39: : dmin ( d1 d2 -- d ) \ double d-min
   40:     2over 2over d> IF  2swap  THEN 2drop ;
   41: 
   42: 
   43: : dmax ( d1 d2 -- d ) \ double d-max
   44:     2over 2over d< IF  2swap  THEN 2drop ;
   45: 
   46: \ shell commands
   47: 
   48: 0 Value $? ( -- n ) \ gforth dollar-question
   49: \G @code{Value} -- the exit status returned by the most recently executed
   50: \G @code{system} command.
   51: 
   52: : system ( c-addr u -- ) \ gforth
   53: \G Pass the string specified by @var{c-addr u} to the host operating
   54: \G system for execution in a sub-shell.  The value of the environment
   55: \G variable @code{GFORTHSYSTEMPREFIX} (or its default value) is
   56: \G prepended to the string (mainly to support using @code{command.com}
   57: \G as shell in Windows instead of whatever shell Cygwin uses by
   58: \G default; @pxref{Environment variables}).
   59:     (system) throw TO $? ;
   60: 
   61: : sh ( "..." -- ) \ gforth
   62: \G Parse a string and use @code{system} to pass it to the host
   63: \G operating system for execution in a sub-shell.
   64:     '# parse cr system ;
   65: 
   66: \ stuff
   67: 
   68: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
   69:     \G equivalent to @code{] literal}
   70:     ] postpone literal ;
   71: 
   72: [ifundef] in-dictionary?
   73: : in-dictionary? ( x -- f )
   74:     forthstart dictionary-end within ;
   75: [endif]
   76: 
   77: : in-return-stack? ( addr -- f )
   78:     rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
   79: 
   80: \ const-does>
   81: 
   82: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
   83:     \ compile u literals, starting with the bottommost one
   84:     ?dup-if
   85: 	swap >r 1- compile-literals
   86: 	r> POSTPONE literal
   87:     endif ;
   88: 
   89: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
   90:     \ compile u fliterals, starting with the bottommost one
   91:     ?dup-if
   92: 	{ F: r } 1- compile-fliterals
   93: 	r POSTPONE fliteral
   94:     endif ;
   95: 
   96: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
   97:     \ define a colon definition "name" containing w*uw r*ur as
   98:     \ literals and a call to target.
   99:     { uw ur target }
  100:     header docol: cfa, \ start colon def without stack junk
  101:     ur compile-fliterals uw compile-literals
  102:     target compile, POSTPONE exit reveal ;
  103: 
  104: : const-does> ( run-time: w*uw r*ur uw ur "name" -- ) \ gforth
  105:     \G Defines @var{name} and returns.
  106:     \G  
  107:     \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
  108:     \G code following the @code{const-does>}.
  109:     here >r 0 POSTPONE literal
  110:     POSTPONE (const-does>)
  111:     POSTPONE ;
  112:     noname : POSTPONE rdrop
  113:     latestxt r> cell+ ! \ patch the literal
  114: ; immediate
  115: 
  116: \ !! rewrite slurp-file using slurp-fid
  117: : slurp-file ( c-addr1 u1 -- c-addr2 u2 ) \ gforth
  118:     \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
  119:     r/o bin open-file throw >r
  120:     r@ file-size throw abort" file too large"
  121:     dup allocate throw swap
  122:     2dup r@ read-file throw over <> abort" could not read whole file"
  123:     r> close-file throw ;
  124: 
  125: : slurp-fid ( fid -- addr u ) \ gforth
  126: \G @var{addr u} is the content of the file @var{fid}
  127:     { fid }
  128:     0 0 begin ( awhole uwhole )
  129: 	dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
  130: 	rot r@ fid read-file throw ( awhole uwhole uread R: unew )
  131: 	r> 2dup =
  132:     while ( awhole uwhole uread unew )
  133: 	2drop
  134:     repeat
  135:     - + dup >r resize throw r> ;
  136: 
  137: \ ]] ... [[
  138: 
  139: : [[ ( -- ) \ gforth left-bracket-bracket
  140: \G switch from postpone state to compile state
  141:     \ this is only a marker; it is never really interpreted
  142:     compile-only-error ; immediate
  143: 
  144: [ifdef] compiler1
  145: : compile-literal ( n -- )
  146:     postpone literal ;
  147: 
  148: : compile-compile-literal ( n -- )
  149:     compile-literal postpone compile-literal ;
  150: 
  151: : compile-2literal ( n1 n2 -- )
  152:     postpone 2literal ;
  153: 
  154: : compile-compile-2literal ( n1 n2 -- )
  155:     compile-2literal postpone compile-2literal ;
  156: 
  157: : postponer1 ( c-addr u -- ... xt )
  158:     2dup find-name
  159:     [ifdef] run-prelude run-prelude [then]
  160:     dup if ( c-addr u nt )
  161: 	nip nip name>comp
  162: 	2dup [comp'] [[ d= if
  163: 	    2drop ['] compiler1 is parser1 ['] noop
  164: 	else
  165: 	    ['] postpone,
  166: 	endif
  167:     else
  168: 	drop
  169: 	2dup 2>r snumber? dup if
  170: 	    0> IF
  171: 		['] compile-compile-2literal
  172:             ELSE
  173:                 ['] compile-compile-literal
  174: 	    THEN
  175: 	    2rdrop
  176: 	ELSE
  177: 	    drop 2r> no.extensions
  178: 	THEN
  179:     then ;
  180: 
  181: : ]] ( -- ) \ gforth right-bracket-bracket
  182:     \G switch into postpone state
  183:     ['] postponer1 is parser1 state on ; immediate restrict
  184: [then]
  185: 
  186: [ifdef] compiler-r
  187: : postponer-r ( addr u -- ... xt )
  188:     forth-recognizer do-recognizer
  189:     over [ s" [[" find-name ] Literal =
  190:     IF  2drop [comp'] ] drop ELSE  ['] >postpone  THEN ;
  191: 
  192: : ]] ( -- ) \ gforth right-bracket-bracket
  193:     \G switch into postpone state
  194:     ['] postponer-r is parser1 state on ; immediate restrict
  195: [then]
  196: 
  197: comp'  literal drop alias postpone-literal
  198: comp' 2literal drop alias postpone-2literal
  199: comp' fliteral drop alias postpone-fliteral
  200: comp' sliteral drop alias postpone-sliteral
  201: 
  202: : ]]L ( postponing: x -- ; compiling: -- x ) \ gforth right-bracket-bracket-l
  203: \G Shortcut for @code{]] literal}.
  204:     ]] postpone-literal ]] [[ ; immediate
  205: 
  206: : ]]2L ( postponing: x1 x2 -- ; compiling: -- x1 x2 ) \ gforth right-bracket-bracket-two-l
  207: \G Shortcut for @code{]] 2literal}.
  208:     ]] postpone-2literal ]] [[ ; immediate
  209: 
  210: : ]]FL ( postponing: r -- ; compiling: -- r ) \ gforth right-bracket-bracket-f-l
  211: \G Shortcut for @code{]] fliteral}.
  212:     ]] postpone-fliteral ]] [[ ; immediate
  213: 
  214: : ]]SL ( postponing: addr1 u -- ; compiling: -- addr2 u ) \ gforth right-bracket-bracket-s-l
  215: \G Shortcut for @code{]] sliteral}; if the string already has been
  216: \G allocated permanently, you can use @code{]]2L} instead.
  217:     ]] postpone-sliteral ]] [[ ; immediate
  218: 
  219: \ f.rdp
  220: 
  221: : push-right ( c-addr u1 u2 cfill -- )
  222:     \ move string at c-addr u1 right by u2 chars (without exceeding
  223:     \ the original bound); fill the gap with cfill
  224:     >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
  225:     dup 2swap /string cmove>
  226:     r> r> r> fill ;
  227: 
  228: : f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
  229:     \ um1 is the mantissa length to try, um2 is the actual mantissa length
  230:     c-addr ur um1 /string '0 fill
  231:     rf c-addr um1 represent if { nexp fsign }
  232: 	nd nexp + up >=
  233: 	ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
  234: 	    \ fixed-point notation
  235: 	    c-addr ur beforep nexp - dup { befored } '0 push-right
  236:             befored 1+ ur >= if \ <=1 digit left, will be pushed out by '.'
  237:                 rf fabs f2* 0.1e nd s>d d>f f** f> if \ round last digit
  238:                     '1 c-addr befored + 1- c!
  239:                 endif
  240:             endif
  241: 	    c-addr beforep 1- befored min dup { beforez } 0 max bl fill
  242: 	    fsign if
  243: 		'- c-addr beforez 1- 0 max + c!
  244: 	    endif
  245: 	    c-addr ur beforep /string 1 '. push-right
  246: 	    nexp nd +
  247: 	else \ exponential notation
  248: 	    c-addr ur 1 /string 1 '. push-right
  249: 	    fsign if
  250: 		c-addr ur 1 '- push-right
  251: 	    endif
  252: 	    nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
  253: 	    ur explen - 1- fsign + { mantlen }
  254: 	    mantlen 0< if \ exponent too large
  255: 		drop c-addr ur '* fill
  256: 	    else
  257: 		c-addr ur + 0 explen negate /string move
  258: 	    endif
  259: 	    #>> mantlen
  260: 	endif
  261:     else \ inf or nan
  262: 	if \ negative
  263: 	    c-addr ur 1 '- push-right
  264: 	endif
  265: 	drop ur
  266: 	\ !! align in some way?
  267:     endif
  268:     1 max ur min ;
  269: 
  270: : f>buf-rdp ( rf c-addr +nr +nd +np -- ) \ gforth
  271: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  272: \G rules and the meanings of @i{nr nd np} are the same as for
  273: \G @code{f.rdp}.
  274:     \ first, get the mantissa length, then convert for real.  The
  275:     \ mantissa length is wrong in a few cases because of different
  276:     \ rounding; In most cases this does not matter, because the
  277:     \ mantissa is shorter than expected and the final digits are 0;
  278:     \ but in a few cases the mantissa gets longer.  Then it is
  279:     \ conceivable that you will see a result that is rounded too much.
  280:     \ However, I have not been able to construct an example where this
  281:     \ leads to an unexpected result.
  282:     swap 0 max swap 0 max
  283:     fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
  284: 
  285: : f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
  286: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  287: \G rules and the meanings of @i{nr +nd np} are the same as for
  288: \G @code{f.rdp}.  The result in in the pictured numeric output buffer
  289: \G and will be destroyed by anything destroying that buffer.
  290:     rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
  291:     over holdbuf u< -&17 and throw
  292:     2tuck 2>r f>buf-rdp 2r> ;
  293: 
  294: : f.rdp ( rf +nr +nd +np -- ) \ gforth
  295: \G Print float @i{rf} formatted.  The total width of the output is
  296: \G @i{nr}.  For fixed-point notation, the number of digits after the
  297: \G decimal point is @i{+nd} and the minimum number of significant
  298: \G digits is @i{np}.  @code{Set-precision} has no effect on
  299: \G @code{f.rdp}.  Fixed-point notation is used if the number of
  300: \G siginicant digits would be at least @i{np} and if the number of
  301: \G digits before the decimal point would fit.  If fixed-point notation
  302: \G is not used, exponential notation is used, and if that does not
  303: \G fit, asterisks are printed.  We recommend using @i{nr}>=7 to avoid
  304: \G the risk of numbers not fitting at all.  We recommend
  305: \G @i{nr}>=@i{np}+5 to avoid cases where @code{f.rdp} switches to
  306: \G exponential notation because fixed-point notation would have too
  307: \G few significant digits, yet exponential notation offers fewer
  308: \G significant digits.  We recommend @i{nr}>=@i{nd}+2, if you want to
  309: \G have fixed-point notation for some numbers.  We recommend
  310: \G @i{np}>@i{nr}, if you want to have exponential notation for all
  311: \G numbers.
  312:     f>str-rdp type ;
  313: 
  314: 0 [if]
  315: : testx ( rf ur nd up -- )
  316:     '| emit f.rdp ;
  317: 
  318: : test ( -- )
  319:     -0.123456789123456789e-20
  320:     40 0 ?do
  321: 	cr
  322: 	fdup 7 3 1 testx
  323: 	fdup 7 3 4 testx
  324: 	fdup 7 3 0 testx
  325: 	fdup 7 7 1 testx
  326: 	fdup 7 5 1 testx
  327: 	fdup 7 0 2 testx
  328: 	fdup 5 2 1 testx
  329: 	fdup 4 2 1 testx
  330: 	fdup 18 8 5 testx
  331: 	'| emit
  332: 	10e f*
  333:     loop ;
  334: [then]
  335: 
  336: : f.s ( -- ) \ gforth f-dot-s
  337: \G Display the number of items on the floating-point stack, followed
  338: \G by a list of the items (but not more than specified by
  339: \G @code{maxdepth-.s}; TOS is the right-most item.
  340:     ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0 
  341:     ?DO  dup i - 1- floats fp@ + f@ 16 5 11 f.rdp space LOOP  drop ; 
  342: 
  343: \ defer stuff
  344: 
  345: [ifundef] defer@ : defer@ >body @ ; [then]
  346: 
  347: :noname    ' defer@ ;
  348: :noname    postpone ['] postpone defer@ ;
  349: interpret/compile: action-of ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth
  350: \G @i{Xt} is the XT that is currently assigned to @i{name}.
  351: 
  352: ' action-of
  353: comp' action-of drop
  354: interpret/compile: what's ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth-obsolete
  355: \G Old name of @code{action-of}
  356: 
  357: 
  358: : typewhite ( addr n -- ) \ gforth
  359: \G Like type, but white space is printed instead of the characters.
  360:     \ bounds u+do
  361:     0 max bounds ?do
  362: 	i c@ #tab = if \ check for tab
  363: 	    #tab
  364: 	else
  365: 	    bl
  366: 	then
  367: 	emit
  368:     loop ;
  369: 
  370: \ w and l stuff
  371: 
  372: environment-wordlist >order
  373: 
  374: 16 address-unit-bits / 1 max constant /w ( -- u ) \ gforth slash-w
  375: \G address units for a 16-bit value
  376:     
  377: 32 address-unit-bits / 1 max constant /l ( -- u ) \ gforth slash-l
  378: \G address units for a 32-bit value
  379: 
  380: previous
  381: 
  382: [ifdef] uw@
  383: \ Open firmware names
  384: ' uw@ alias w@ ( addr -- u )
  385: ' ul@ alias l@ ( addr -- u )
  386: \ ' sw@ alias <w@ ( addr -- n )
  387: [then]
  388: 
  389: \ safe output redirection
  390: 
  391: : outfile-execute ( ... xt file-id -- ... ) \ gforth
  392:     \G execute @i{xt} with the output of @code{type} etc. redirected to
  393:     \G @i{file-id}.
  394:     outfile-id { oldfid } try
  395: 	to outfile-id execute 0
  396:     restore
  397: 	oldfid to outfile-id
  398:     endtry
  399:     throw ;
  400: 
  401: : infile-execute ( ... xt file-id -- ... ) \ gforth
  402:     \G execute @i{xt} with the input of @code{key} etc. redirected to
  403:     \G @i{file-id}.
  404:     infile-id { oldfid } try
  405: 	to infile-id execute 0
  406:     restore
  407: 	oldfid to infile-id
  408:     endtry
  409:     throw ;
  410: 
  411: \ safe BASE wrapper
  412: 
  413: : base-execute ( i*x xt u -- j*x ) \ gforth
  414:     \G execute @i{xt} with the content of @code{BASE} being @i{u}, and
  415:     \G restoring the original @code{BASE} afterwards.
  416:     base @ { oldbase } \ use local, because TRY blocks the return stack
  417:     try
  418: 	base ! execute 0
  419:     restore
  420: 	oldbase base !
  421:     endtry
  422:     throw ;
  423: 
  424: \ th
  425: 
  426: : th ( addr1 u -- addr2 )
  427:     cells + ;
  428: 
  429: \ \\\ - skip to end of file
  430: 
  431: : \\\ ( -- ) \ gforth
  432:     \G skip remaining source file
  433:     source-id dup 0> IF
  434: 	>r r@ file-size throw r> reposition-file throw
  435: 	BEGIN  refill 0= UNTIL  postpone \  THEN ; immediate
  436: 
  437: \ WORD SWORD
  438: 
  439: : sword  ( char -- addr len ) \ gforth-obsolete s-word
  440: \G Parses like @code{word}, but the output is like @code{parse} output.
  441: \G @xref{core-idef}.
  442:     \ this word was called PARSE-WORD until 0.3.0, but Open Firmware and
  443:     \ dpANS6 A.6.2.2008 have a word with that name that behaves
  444:     \ differently (like NAME).
  445:     source 2dup >r >r >in @ over min /string
  446:     rot dup bl = IF
  447:         drop (parse-white)
  448:     ELSE
  449:         (word)
  450:     THEN
  451: [ has? new-input [IF] ]
  452:     2dup input-lexeme!
  453: [ [THEN] ]
  454:     2dup + r> - 1+ r> min >in ! ;
  455: 
  456: : word   ( char "<chars>ccc<char>-- c-addr ) \ core
  457:     \G Skip leading delimiters. Parse @i{ccc}, delimited by
  458:     \G @i{char}, in the parse area. @i{c-addr} is the address of a
  459:     \G transient region containing the parsed string in
  460:     \G counted-string format. If the parse area was empty or
  461:     \G contained no characters other than delimiters, the resulting
  462:     \G string has zero length. A program may replace characters within
  463:     \G the counted string. OBSOLESCENT: the counted string has a
  464:     \G trailing space that is not included in its length.
  465:     sword here place  bl here count + c!  here ;

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>