File:  [gforth] / gforth / stuff.fs
Revision 1.44: download - view: text, annotated - select for diffs
Mon Sep 12 08:50:19 2005 UTC (16 years, 3 months ago) by anton
Branches: MAIN
CVS tags: HEAD
bugfix: 'X is never a double
bugfix: 0.009e 5 2 0 f.rdp now outputs 0.01 (not 0.00)

    1: \ miscelleneous words
    2: 
    3: \ Copyright (C) 1996,1997,1998,2000,2003,2004 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: require glocals.fs
   22: 
   23: ' require alias needs ( ... "name" -- ... ) \ gforth
   24: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
   25: \ needs is an F-PC name. we will probably switch to 'needs' in the future
   26: 
   27: \ a little more compiler security
   28: 
   29: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
   30: AUser CSP
   31: 
   32: : !CSP ( -- )
   33:     sp@ csp ! ;
   34: 
   35: : ?CSP ( -- )
   36:     sp@ csp @ <> -22 and throw ;
   37: 
   38: \ DMIN and DMAX
   39: 
   40: : dmin ( d1 d2 -- d ) \ double d-min
   41:     2over 2over d> IF  2swap  THEN 2drop ;
   42: 
   43: 
   44: : dmax ( d1 d2 -- d ) \ double d-max
   45:     2over 2over d< IF  2swap  THEN 2drop ;
   46: 
   47: \ shell commands
   48: 
   49: 0 Value $? ( -- n ) \ gforth dollar-question
   50: \G @code{Value} -- the exit status returned by the most recently executed
   51: \G @code{system} command.
   52: 
   53: : system ( c-addr u -- ) \ gforth
   54: \G Pass the string specified by @var{c-addr u} to the host operating
   55: \G system for execution in a sub-shell.  The value of the environment
   56: \G variable @code{GFORTHSYSTEMPREFIX} (or its default value) is
   57: \G prepended to the string (mainly to support using @code{command.com}
   58: \G as shell in Windows instead of whatever shell Cygwin uses by
   59: \G default; @pxref{Environment variables}).
   60:     (system) throw TO $? ;
   61: 
   62: : sh ( "..." -- ) \ gforth
   63: \G Parse a string and use @code{system} to pass it to the host
   64: \G operating system for execution in a sub-shell.
   65:     '# parse cr system ;
   66: 
   67: \ stuff
   68: 
   69: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
   70:     \G equivalent to @code{] literal}
   71:     ] postpone literal ;
   72: 
   73: [ifundef] in-dictionary?
   74: : in-dictionary? ( x -- f )
   75:     forthstart dictionary-end within ;
   76: [endif]
   77: 
   78: : in-return-stack? ( addr -- f )
   79:     rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
   80: 
   81: \ const-does>
   82: 
   83: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
   84:     \ compile u literals, starting with the bottommost one
   85:     ?dup-if
   86: 	swap >r 1- compile-literals
   87: 	r> POSTPONE literal
   88:     endif ;
   89: 
   90: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
   91:     \ compile u fliterals, starting with the bottommost one
   92:     ?dup-if
   93: 	{ F: r } 1- compile-fliterals
   94: 	r POSTPONE fliteral
   95:     endif ;
   96: 
   97: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
   98:     \ define a colon definition "name" containing w*uw r*ur as
   99:     \ literals and a call to target.
  100:     { uw ur target }
  101:     header docol: cfa, \ start colon def without stack junk
  102:     ur compile-fliterals uw compile-literals
  103:     target compile, POSTPONE exit reveal ;
  104: 
  105: : const-does> ( run-time: w*uw r*ur uw ur "name" -- ) \ gforth
  106:     \G Defines @var{name} and returns.
  107:     \G  
  108:     \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
  109:     \G code following the @code{const-does>}.
  110:     here >r 0 POSTPONE literal
  111:     POSTPONE (const-does>)
  112:     POSTPONE ;
  113:     noname : POSTPONE rdrop
  114:     latestxt r> cell+ ! \ patch the literal
  115: ; immediate
  116: 
  117: \ !! rewrite slurp-file using slurp-fid
  118: : slurp-file ( c-addr1 u1 -- c-addr2 u2 ) \ gforth
  119:     \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
  120:     r/o bin open-file throw >r
  121:     r@ file-size throw abort" file too large"
  122:     dup allocate throw swap
  123:     2dup r@ read-file throw over <> abort" could not read whole file"
  124:     r> close-file throw ;
  125: 
  126: : slurp-fid { fid -- addr u } \ gforth
  127:     \G @var{addr u} is the content of the file @var{fid}
  128:     0 0 begin ( awhole uwhole )
  129: 	dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
  130: 	rot r@ fid read-file throw ( awhole uwhole uread R: unew )
  131: 	r> 2dup =
  132:     while ( awhole uwhole uread unew )
  133: 	2drop
  134:     repeat
  135:     - + dup >r resize throw r> ;
  136: 
  137: \ ]] ... [[
  138: 
  139: : compile-literal ( n -- )
  140:     postpone literal ;
  141: 
  142: : compile-compile-literal ( n -- )
  143:     compile-literal postpone compile-literal ;
  144: 
  145: : compile-2literal ( n1 n2 -- )
  146:     postpone 2literal ;
  147: 
  148: : compile-compile-2literal ( n1 n2 -- )
  149:     compile-2literal postpone compile-2literal ;
  150: 
  151: : [[ ( -- )
  152: \G switch from postpone state to compile state
  153:     \ this is only a marker; it is never really interpreted
  154:     compile-only-error ; immediate
  155: 
  156: [ifdef] compiler1
  157: : postponer1 ( c-addr u -- ... xt )
  158:     2dup find-name dup if ( c-addr u nt )
  159: 	nip nip name>comp
  160: 	2dup [comp'] [[ d= if
  161: 	    2drop ['] compiler1 is parser1
  162: 	else
  163: 	    ['] postpone,
  164: 	endif
  165:     else
  166: 	drop
  167: 	2dup 2>r snumber? dup if
  168: 	    0> IF
  169: 		['] compile-compile-2literal
  170:             ELSE
  171:                 ['] compile-compile-literal
  172: 	    THEN
  173: 	    2rdrop
  174: 	ELSE
  175: 	    drop 2r> no.extensions
  176: 	THEN
  177:     then ;
  178: 
  179: : ]] ( -- )
  180:     \ switch into postpone state
  181:     ['] postponer1 is parser1 state on ; immediate restrict
  182: 
  183: [then]
  184: 
  185: \ f.rdp
  186: 
  187: : push-right ( c-addr u1 u2 cfill -- )
  188:     \ move string at c-addr u1 right by u2 chars (without exceeding
  189:     \ the original bound); fill the gap with cfill
  190:     >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
  191:     dup 2swap /string cmove>
  192:     r> r> r> fill ;
  193: 
  194: : f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
  195:     \ um1 is the mantissa length to try, um2 is the actual mantissa length
  196:     c-addr ur um1 /string '0 fill
  197:     rf c-addr um1 represent if { nexp fsign }
  198: 	nd nexp + up >=
  199: 	ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
  200: 	    \ fixed-point notation
  201: 	    c-addr ur beforep nexp - dup { befored } '0 push-right
  202:             befored 1+ ur >= if \ <=1 digit left, will be pushed out by '.'
  203:                 rf fabs f2* 0.1e nd s>d d>f f** f> if \ round last digit
  204:                     '1 c-addr befored + 1- c!
  205:                 endif
  206:             endif
  207: 	    c-addr beforep 1- befored min dup { beforez } 0 max bl fill
  208: 	    fsign if
  209: 		'- c-addr beforez 1- 0 max + c!
  210: 	    endif
  211: 	    c-addr ur beforep /string 1 '. push-right
  212: 	    nexp nd +
  213: 	else \ exponential notation
  214: 	    c-addr ur 1 /string 1 '. push-right
  215: 	    fsign if
  216: 		c-addr ur 1 '- push-right
  217: 	    endif
  218: 	    nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
  219: 	    ur explen - 1- fsign + { mantlen }
  220: 	    mantlen 0< if \ exponent too large
  221: 		drop c-addr ur '* fill
  222: 	    else
  223: 		c-addr ur + 0 explen negate /string move
  224: 	    endif
  225: 	    #>> mantlen
  226: 	endif
  227:     else \ inf or nan
  228: 	if \ negative
  229: 	    c-addr ur 1 '- push-right
  230: 	endif
  231: 	drop ur
  232: 	\ !! align in some way?
  233:     endif
  234:     1 max ur min ;
  235: 
  236: : f>buf-rdp ( rf c-addr +nr +nd +np -- ) \ gforth
  237: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  238: \G rules and the meanings of @i{nr nd np} are the same as for
  239: \G @code{f.rdp}.
  240:     \ first, get the mantissa length, then convert for real.  The
  241:     \ mantissa length is wrong in a few cases because of different
  242:     \ rounding; In most cases this does not matter, because the
  243:     \ mantissa is shorter than expected and the final digits are 0;
  244:     \ but in a few cases the mantissa gets longer.  Then it is
  245:     \ conceivable that you will see a result that is rounded too much.
  246:     \ However, I have not been able to construct an example where this
  247:     \ leads to an unexpected result.
  248:     swap 0 max swap 0 max
  249:     fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
  250: 
  251: : f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
  252: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  253: \G rules and the meanings of @i{nr +nd np} are the same as for
  254: \G @code{f.rdp}.  The result in in the pictured numeric output buffer
  255: \G and will be destroyed by anything destroying that buffer.
  256:     rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
  257:     over holdbuf u< -&17 and throw
  258:     2tuck 2>r f>buf-rdp 2r> ;
  259: 
  260: : f.rdp ( rf +nr +nd +np -- ) \ gforth
  261: \G Print float @i{rf} formatted.  The total width of the output is
  262: \G @i{nr}.  For fixed-point notation, the number of digits after the
  263: \G decimal point is @i{+nd} and the minimum number of significant
  264: \G digits is @i{np}.  @code{Set-precision} has no effect on
  265: \G @code{f.rdp}.  Fixed-point notation is used if the number of
  266: \G siginicant digits would be at least @i{np} and if the number of
  267: \G digits before the decimal point would fit.  If fixed-point notation
  268: \G is not used, exponential notation is used, and if that does not
  269: \G fit, asterisks are printed.  We recommend using @i{nr}>=7 to avoid
  270: \G the risk of numbers not fitting at all.  We recommend
  271: \G @i{nr}>=@i{np}+5 to avoid cases where @code{f.rdp} switches to
  272: \G exponential notation because fixed-point notation would have too
  273: \G few significant digits, yet exponential notation offers fewer
  274: \G significant digits.  We recommend @i{nr}>=@i{nd}+2, if you want to
  275: \G have fixed-point notation for some numbers.  We recommend
  276: \G @i{np}>@i{nr}, if you want to have exponential notation for all
  277: \G numbers.
  278:     f>str-rdp type ;
  279: 
  280: 0 [if]
  281: : testx ( rf ur nd up -- )
  282:     '| emit f.rdp ;
  283: 
  284: : test ( -- )
  285:     -0.123456789123456789e-20
  286:     40 0 ?do
  287: 	cr
  288: 	fdup 7 3 1 testx
  289: 	fdup 7 3 4 testx
  290: 	fdup 7 3 0 testx
  291: 	fdup 7 7 1 testx
  292: 	fdup 7 5 1 testx
  293: 	fdup 7 0 2 testx
  294: 	fdup 5 2 1 testx
  295: 	fdup 4 2 1 testx
  296: 	fdup 18 8 5 testx
  297: 	'| emit
  298: 	10e f*
  299:     loop ;
  300: [then]
  301: 
  302: : f.s ( -- ) \ gforth f-dot-s
  303:     \G Display the number of items on the floating-point stack,
  304:     \G followed by a list of the items; TOS is the right-most item.
  305:     ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0 
  306:     ?DO  dup i - 1- floats fp@ + f@ 16 5 11 f.rdp space LOOP  drop ; 
  307: 
  308: \ defer stuff
  309: 
  310: [ifundef] defer@ : defer@ >body @ ; [then]
  311: 
  312: :noname    ' defer@ ;
  313: :noname    postpone ['] postpone defer@ ;
  314: interpret/compile: action-of ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth
  315: \G @i{Xt} is the XT that is currently assigned to @i{name}.
  316: 
  317: ' action-of
  318: comp' action-of drop
  319: interpret/compile: what's ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth-obsolete
  320: \G Old name of @code{action-of}
  321: 
  322: 
  323: : typewhite ( addr n -- ) \ gforth
  324: \G Like type, but white space is printed instead of the characters.
  325:     \ bounds u+do
  326:     0 max bounds ?do
  327: 	i c@ #tab = if \ check for tab
  328: 	    #tab
  329: 	else
  330: 	    bl
  331: 	then
  332: 	emit
  333:     loop ;
  334: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>