File:  [gforth] / gforth / stuff.fs
Revision 1.38: download - view: text, annotated - select for diffs
Sun Nov 28 20:35:06 2004 UTC (17 years ago) by anton
Branches: MAIN
CVS tags: HEAD
uninitialized deferred words now give a warning when executed

    1: \ miscelleneous words
    2: 
    3: \ Copyright (C) 1996,1997,1998,2000,2003 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: require glocals.fs
   22: 
   23: ' require alias needs ( ... "name" -- ... ) \ gforth
   24: \G An alias for @code{require}; exists on other systems (e.g., Win32Forth).
   25: \ needs is an F-PC name. we will probably switch to 'needs' in the future
   26: 
   27: \ a little more compiler security
   28: 
   29: \ currently not used by Gforth, but maybe by add-ons e.g., the 486asm
   30: AUser CSP
   31: 
   32: : !CSP ( -- )
   33:     sp@ csp ! ;
   34: 
   35: : ?CSP ( -- )
   36:     sp@ csp @ <> -22 and throw ;
   37: 
   38: \ DMIN and DMAX
   39: 
   40: : dmin ( d1 d2 -- d ) \ double d-min
   41:     2over 2over d> IF  2swap  THEN 2drop ;
   42: 
   43: 
   44: : dmax ( d1 d2 -- d ) \ double d-max
   45:     2over 2over d< IF  2swap  THEN 2drop ;
   46: 
   47: \ shell commands
   48: 
   49: 0 Value $? ( -- n ) \ gforth dollar-question
   50: \G @code{Value} -- the exit status returned by the most recently executed
   51: \G @code{system} command.
   52: 
   53: : system ( c-addr u -- ) \ gforth
   54: \G Pass the string specified by @var{c-addr u} to the host operating
   55: \G system for execution in a sub-shell.  The value of the environment
   56: \G variable @code{GFORTHSYSTEMPREFIX} (or its default value) is
   57: \G prepended to the string (mainly to support using @code{command.com}
   58: \G as shell in Windows instead of whatever shell Cygwin uses by
   59: \G default; @pxref{Environment variables}).
   60:     (system) throw TO $? ;
   61: 
   62: : sh ( "..." -- ) \ gforth
   63: \G Parse a string and use @code{system} to pass it to the host
   64: \G operating system for execution in a sub-shell.
   65:     '# parse cr system ;
   66: 
   67: \ stuff
   68: 
   69: : ]L ( compilation: n -- ; run-time: -- n ) \ gforth
   70:     \G equivalent to @code{] literal}
   71:     ] postpone literal ;
   72: 
   73: [ifundef] in-dictionary?
   74: : in-dictionary? ( x -- f )
   75:     forthstart dictionary-end within ;
   76: [endif]
   77: 
   78: : in-return-stack? ( addr -- f )
   79:     rp0 @ swap - [ forthstart 6 cells + ]L @ u< ;
   80: 
   81: \ const-does>
   82: 
   83: : compile-literals ( w*u u -- ; run-time: -- w*u ) recursive
   84:     \ compile u literals, starting with the bottommost one
   85:     ?dup-if
   86: 	swap >r 1- compile-literals
   87: 	r> POSTPONE literal
   88:     endif ;
   89: 
   90: : compile-fliterals ( r*u u -- ; run-time: -- w*u ) recursive
   91:     \ compile u fliterals, starting with the bottommost one
   92:     ?dup-if
   93: 	{ F: r } 1- compile-fliterals
   94: 	r POSTPONE fliteral
   95:     endif ;
   96: 
   97: : (const-does>) ( w*uw r*ur uw ur target "name" -- )
   98:     \ define a colon definition "name" containing w*uw r*ur as
   99:     \ literals and a call to target.
  100:     { uw ur target }
  101:     header docol: cfa, \ start colon def without stack junk
  102:     ur compile-fliterals uw compile-literals
  103:     target compile, POSTPONE exit reveal ;
  104: 
  105: : const-does> ( run-time: w*uw r*ur uw ur "name" -- ) \ gforth
  106:     \G Defines @var{name} and returns.
  107:     \G  
  108:     \G @var{name} execution: pushes @var{w*uw r*ur}, then performs the
  109:     \G code following the @code{const-does>}.
  110:     here >r 0 POSTPONE literal
  111:     POSTPONE (const-does>)
  112:     POSTPONE ;
  113:     noname : POSTPONE rdrop
  114:     latestxt r> cell+ ! \ patch the literal
  115: ; immediate
  116: 
  117: \ !! rewrite slurp-file using slurp-fid
  118: : slurp-file ( c-addr1 u1 -- c-addr2 u2 ) \ gforth
  119:     \G @var{c-addr1 u1} is the filename, @var{c-addr2 u2} is the file's contents
  120:     r/o bin open-file throw >r
  121:     r@ file-size throw abort" file too large"
  122:     dup allocate throw swap
  123:     2dup r@ read-file throw over <> abort" could not read whole file"
  124:     r> close-file throw ;
  125: 
  126: : slurp-fid { fid -- addr u } \ gforth
  127:     \G @var{addr u} is the content of the file @var{fid}
  128:     0 0 begin ( awhole uwhole )
  129: 	dup 1024 + dup >r extend-mem ( anew awhole uwhole R: unew )
  130: 	rot r@ fid read-file throw ( awhole uwhole uread R: unew )
  131: 	r> 2dup =
  132:     while ( awhole uwhole uread unew )
  133: 	2drop
  134:     repeat
  135:     - + dup >r resize throw r> ;
  136: 
  137: \ ]] ... [[
  138: 
  139: : compile-literal ( n -- )
  140:     postpone literal ;
  141: 
  142: : [[ ( -- )
  143: \G switch from postpone state to compile state
  144:     \ this is only a marker; it is never really interpreted
  145:     compile-only-error ; immediate
  146: 
  147: : postponer ( c-addr u -- )
  148:     2dup find-name dup if ( c-addr u nt )
  149: 	nip nip name>comp
  150: 	2dup [comp'] [[ d= if
  151: 	    2drop ['] compiler is parser
  152: 	else
  153: 	    postpone,
  154: 	endif
  155:     else
  156: 	drop
  157: 	2dup snumber? dup if
  158: 	    0> IF
  159: 		swap postpone literal postpone compile-literal
  160: 	    THEN
  161: 	    postpone Literal postpone compile-literal
  162: 	    2drop
  163: 	ELSE
  164: 	    drop no.extensions
  165: 	THEN
  166:     then ;
  167: 
  168: : ]] ( -- )
  169:     \ switch into postpone state
  170:     ['] postponer is parser state on ; immediate restrict
  171: 
  172: \ f.rdp
  173: 
  174: : push-right ( c-addr u1 u2 cfill -- )
  175:     \ move string at c-addr u1 right by u2 chars (without exceeding
  176:     \ the original bound); fill the gap with cfill
  177:     >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
  178:     dup 2swap /string cmove>
  179:     r> r> r> fill ;
  180: 
  181: : f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
  182:     \ um1 is the mantissa length to try, um2 is the actual mantissa length
  183:     c-addr ur um1 /string '0 fill
  184:     rf c-addr um1 represent if { nexp fsign }
  185: 	nd nexp + up >=
  186: 	ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
  187: 	    \ fixed-point notation
  188: 	    c-addr ur beforep nexp - dup { befored } '0 push-right
  189: 	    c-addr beforep 1- befored min dup { beforez } 0 max bl fill
  190: 	    fsign if
  191: 		'- c-addr beforez 1- 0 max + c!
  192: 	    endif
  193: 	    c-addr ur beforep /string 1 '. push-right
  194: 	    nexp nd +
  195: 	else \ exponential notation
  196: 	    c-addr ur 1 /string 1 '. push-right
  197: 	    fsign if
  198: 		c-addr ur 1 '- push-right
  199: 	    endif
  200: 	    nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
  201: 	    ur explen - 1- fsign + { mantlen }
  202: 	    mantlen 0< if \ exponent too large
  203: 		drop c-addr ur '* fill
  204: 	    else
  205: 		c-addr ur + 0 explen negate /string move
  206: 	    endif
  207: 	    #>> mantlen
  208: 	endif
  209:     else \ inf or nan
  210: 	if \ negative
  211: 	    c-addr ur 1 '- push-right
  212: 	endif
  213: 	drop ur
  214: 	\ !! align in some way?
  215:     endif
  216:     1 max ur min ;
  217: 
  218: : f>buf-rdp ( rf c-addr +nr +nd +np -- ) \ gforth
  219: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  220: \G rules and the meanings of @i{nr nd np} are the same as for
  221: \G @code{f.rdp}.
  222:     \ first, get the mantissa length, then convert for real.  The
  223:     \ mantissa length is wrong in a few cases because of different
  224:     \ rounding; In most cases this does not matter, because the
  225:     \ mantissa is shorter than expected and the final digits are 0;
  226:     \ but in a few cases the mantissa gets longer.  Then it is
  227:     \ conceivable that you will see a result that is rounded too much.
  228:     \ However, I have not been able to construct an example where this
  229:     \ leads to an unexpected result.
  230:     swap 0 max swap 0 max
  231:     fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
  232: 
  233: : f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
  234: \G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
  235: \G rules and the meanings of @i{nr +nd np} are the same as for
  236: \G @code{f.rdp}.  The result in in the pictured numeric output buffer
  237: \G and will be destroyed by anything destroying that buffer.
  238:     rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
  239:     over holdbuf u< -&17 and throw
  240:     2tuck 2>r f>buf-rdp 2r> ;
  241: 
  242: : f.rdp ( rf +nr +nd +np -- ) \ gforth
  243: \G Print float @i{rf} formatted.  The total width of the output is
  244: \G @i{nr}.  For fixed-point notation, the number of digits after the
  245: \G decimal point is @i{+nd} and the minimum number of significant
  246: \G digits is @i{np}.  @code{Set-precision} has no effect on
  247: \G @code{f.rdp}.  Fixed-point notation is used if the number of
  248: \G siginicant digits would be at least @i{np} and if the number of
  249: \G digits before the decimal point would fit.  If fixed-point notation
  250: \G is not used, exponential notation is used, and if that does not
  251: \G fit, asterisks are printed.  We recommend using @i{nr}>=7 to avoid
  252: \G the risk of numbers not fitting at all.  We recommend
  253: \G @i{nr}>=@i{np}+5 to avoid cases where @code{f.rdp} switches to
  254: \G exponential notation because fixed-point notation would have too
  255: \G few significant digits, yet exponential notation offers fewer
  256: \G significant digits.  We recommend @i{nr}>=@i{nd}+2, if you want to
  257: \G have fixed-point notation for some numbers.  We recommend
  258: \G @i{np}>@i{nr}, if you want to have exponential notation for all
  259: \G numbers.
  260:     f>str-rdp type ;
  261: 
  262: 0 [if]
  263: : testx ( rf ur nd up -- )
  264:     '| emit f.rdp ;
  265: 
  266: : test ( -- )
  267:     -0.123456789123456789e-20
  268:     40 0 ?do
  269: 	cr
  270: 	fdup 7 3 1 testx
  271: 	fdup 7 3 4 testx
  272: 	fdup 7 3 0 testx
  273: 	fdup 7 7 1 testx
  274: 	fdup 7 5 1 testx
  275: 	fdup 7 0 2 testx
  276: 	fdup 5 2 1 testx
  277: 	fdup 4 2 1 testx
  278: 	fdup 18 8 5 testx
  279: 	'| emit
  280: 	10e f*
  281:     loop ;
  282: [then]
  283: 
  284: : f.s ( -- ) \ gforth f-dot-s
  285:     \G Display the number of items on the floating-point stack,
  286:     \G followed by a list of the items; TOS is the right-most item.
  287:     ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0 
  288:     ?DO  dup i - 1- floats fp@ + f@ 16 5 11 f.rdp space LOOP  drop ; 
  289: 
  290: \ defer stuff
  291: 
  292: :noname    ' defer@ ;
  293: :noname    postpone ['] postpone defer@ ;
  294: interpret/compile: action-of ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth
  295: \G @i{Xt} is the XT that is currently assigned to @i{name}.
  296: 
  297: ' action-of
  298: comp' action-of drop
  299: interpret/compile: what's ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth-obsolete
  300: \G Old name of @code{action-of}

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>