--- gforth/stuff.fs	2003/01/22 18:52:47	1.25
+++ gforth/stuff.fs	2003/01/25 20:11:30	1.28
@@ -164,3 +164,112 @@ AUser CSP
     \ switch into postpone state
     ['] postponer is parser state on ; immediate restrict
 
+\ f.rdp
+
+: push-right ( c-addr u1 u2 cfill -- )
+    \ move string at c-addr u1 right by u2 chars (without exceeding
+    \ the original bound); fill the gap with cfill
+    >r over min dup >r rot dup >r ( u1 u2 c-addr R: cfill u2 c-addr )
+    dup 2swap /string cmove>
+    r> r> r> fill ;
+
+: f>buf-rdp-try { f: rf c-addr ur nd up um1 -- um2 }
+    \ um1 is the mantissa length to try, um2 is the actual mantissa length
+    c-addr ur um1 /string '0 fill
+    rf c-addr um1 represent if { nexp fsign }
+	nd nexp + up >=
+	ur nd - 1- dup { beforep } fsign + nexp 0 max >= and if
+	    \ fixed-point notation
+	    c-addr ur beforep nexp - dup { befored } '0 push-right
+	    c-addr beforep 1- befored min dup { beforez } 0 max bl fill
+	    fsign if
+		'- c-addr beforez 1- 0 max + c!
+	    endif
+	    c-addr ur beforep /string 1 '. push-right
+	    nexp nd +
+	else \ exponential notation
+	    c-addr ur 1 /string 1 '. push-right
+	    fsign if
+		c-addr ur 1 '- push-right
+	    endif
+	    nexp 1- s>d tuck dabs <<# #s rot sign 'E hold #> { explen }
+	    ur explen - 1- fsign + { mantlen }
+	    mantlen 0< if \ exponent too large
+		drop c-addr ur '* fill
+	    else
+		c-addr ur + 0 explen negate /string move
+	    endif
+	    #>> mantlen
+	endif
+    else \ inf or nan
+	if \ negative
+	    c-addr ur 1 '- push-right
+	endif
+	drop ur
+	\ !! align in some way?
+    endif
+    1 max ur min ;
+
+: f>buf-rdp ( rf c-addr +nr nd np -- ) \ gforth
+\G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
+\G rules and the meanings of @i{nr nd np} are the same as for
+\G @code{f.rdp}.
+    \ first, get the mantissa length, then convert for real.  The
+    \ mantissa length is wrong in a few cases because of different
+    \ rounding; In most cases this does not matter, because the
+    \ mantissa is shorter than expected and the final digits are 0;
+    \ but in a few cases the mantissa gets longer.  Then it is
+    \ conceivable that you will see a result that is rounded too much.
+    \ However, I have not been able to construct an example where this
+    \ leads to an unexpected result.
+    swap 0 max swap 0 max
+    fdup 2over 2over 2 pick f>buf-rdp-try f>buf-rdp-try drop ;
+
+: f>str-rdp ( rf +nr +nd +np -- c-addr nr ) \ gforth
+\G Convert @i{rf} into a string at @i{c-addr nr}.  The conversion
+\G rules and the meanings of @i{nr +nd np} are the same as for
+\G @code{f.rdp}.  The result in in the pictured numeric output buffer
+\G and will be destroyed by anything destroying that buffer.
+    rot holdptr @ 1- 0 rot negate /string ( rf +nd np c-addr nr )
+    over holdbuf u< -&17 and throw
+    2tuck 2>r f>buf-rdp 2r> ;
+
+: f.rdp ( rf +nr +nd +np -- ) \ gforth
+\G Print float @i{rf} formatted.  The total width of the output is
+\G @i{nr}, the number of digits after the decimal point is @i{+nd},
+\G the minimum number of significant digits for fixed-point notation
+\G is @i{np}.  @code{Set-precision} has no effect on @code{f.rdp}.
+\G Fixed-point notation is used if the number of siginicant digits
+\G would be larger than @i{np} and if the number of digits before the
+\G decimal point would fit.  If fixed-point notation is not used,
+\G exponential notation is used, and if that does not fit, asterisks
+\G are printed.  We recommend using @i{nr}>=7 to avoid the risk of
+\G numbers not fitting at all.  We recommend @i{nr}>=@i{np}+5 to avoid
+\G cases where @code{f.rdp} switches to exponential notation because
+\G fixed-point notation would have too few significant digits, yet
+\G exponential notation offers fewer significant digits.  We recomment
+\G @i{nr}>=@i{nd}+2, if you want to have fixed-point notation for some
+\G numbers.
+    f>str-rdp type ;
+
+0 [if]
+: testx ( rf ur nd up -- )
+    '| emit f.rdp ;
+
+: test ( -- )
+    -0.123456789123456789e-20
+    40 0 ?do
+	cr
+	fdup 7 3 1 testx
+	fdup 7 3 4 testx
+	fdup 7 3 0 testx
+	fdup 7 7 1 testx
+	fdup 7 5 1 testx
+	fdup 7 0 2 testx
+	fdup 5 2 1 testx
+	fdup 4 2 1 testx
+	fdup 18 8 5 testx
+	'| emit
+	10e f*
+    loop ;
+[then]