Return to source.fs CVS log

Up to [gforth] / gforth

added #LINE

    1: \ source location handling
    2: 
    3: \ Copyright (C) 1995,1997,2003,2004,2007,2009 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: \ related stuff can be found in kernel.fs
   21: 
   22: \ this stuff is used by (at least) assert.fs and debugs.fs
   23: 
   24: : loadfilename#>str ( n -- addr u )
   25:     included-files 2@ rot min 2* cells + 2@ ;
   26: 
   27: : str>loadfilename# ( addr u -- n )
   28:     included-files 2@ 0 ?do ( addr u included-files )
   29: 	i over >r 2* cells + 2@
   30: 	2over str= if
   31: 	    rdrop 2drop i unloop exit
   32: 	endif
   33: 	r> loop
   34:     drop 2drop -1 ;
   35: 
   36: \ we encode line and character in one cell to keep the interface the same
   37: : encode-pos ( nline nchar -- npos )
   38:     $ff min swap 8 lshift + ;
   39: 
   40: : decode-pos ( npos -- nline nchar )
   41:     dup 8 rshift swap $ff and ;
   42: 
   43: : current-sourcepos ( -- nfile npos )
   44:     sourcefilename  str>loadfilename# sourceline# >in @ encode-pos ;
   45: 
   46: : compile-sourcepos ( compile-time: -- ; run-time: -- nfile npos )
   47:     \ compile the current source position as literals: nfile is the
   48:     \ source file index, nline the line number within the file.
   49:     current-sourcepos
   50:     swap postpone literal
   51:     postpone literal ;
   52: 
   53: : .sourcepos ( nfile npos -- )
   54:     \ print source position
   55:     swap loadfilename#>str type ': emit
   56:     base @ decimal
   57:     swap decode-pos swap 0 .r ': emit 0 .r
   58:     base ! ;
   59: 
   60: : save-source-filename ( c-addr1 u1 -- c-addr2 u2 )
   61:     \ c-addr1 u1 is a temporary string for a file name, c-addr2 u2 is
   62:     \ a permanent one.  Reuses strings for the same file names and
   63:     \ adds them to the included files (not sure if that's a good idea)
   64:     2dup str>loadfilename# dup 0< if
   65: 	drop save-mem 2dup add-included-file
   66:     else
   67: 	nip nip loadfilename#>str
   68:     then ;
   69: 
   70: : #line ( "u" "["file"]" -- )
   71:     \g Set the line number to @i{u} and (if present) the file name to @i{file}.  Consumes the rest of the line.
   72:     \g 
   73:     parse-name ['] evaluate 10 base-execute 1- loadline !
   74:     '"' parse 2drop '"' parse dup if
   75: 	save-source-filename loadfilename 2!
   76:     else
   77: 	2drop
   78:     then
   79:     postpone \ ;