1: \ LOOK.FS xt -> lfa 22may93jaw
2:
3: \ Copyright (C) 1995,1996,1997,2000 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ Look checks first if the word is a primitive. If yes then the
22: \ vocabulary in the primitive area is beeing searched, meaning
23: \ creating for each word a xt and comparing it...
24:
25: \ If a word is no primitive look searches backwards to find the nfa.
26: \ Problems: A compiled xt via compile, might be created with noname:
27: \ a noname: leaves now a empty name field
28:
29: require stuff.fs
30: require environ.fs
31:
32: decimal
33:
34: \ look 17may93jaw
35:
36: \ rename to discover!!!
37:
38: : (look) ( xt startlfa -- lfa flag )
39: false swap
40: BEGIN
41: @ dup
42: WHILE
43: dup name>int
44: threading-method 0= if
45: @
46: then
47: 3 pick = IF
48: nip dup
49: THEN
50: REPEAT
51: drop nip
52: dup 0<> ;
53:
54:
55: \ !!! nicht optimal!
56: [IFUNDEF] look
57: has? ec [IF]
58:
59: has? rom
60: [IF]
61: : look
62: dup [ unlock rom-dictionary area lock ]
63: literal literal within
64: IF
65: >head-noprim dup ?? <>
66: ELSE
67: forth-wordlist @ (look)
68: THEN ;
69: [ELSE]
70: : look ( cfa -- lfa flag )
71: >head-noprim dup ??? <> ;
72: [THEN]
73:
74: [ELSE]
75:
76: : PrimStart ['] true >head-noprim ;
77:
78: : look ( cfa -- lfa flag )
79: dup in-dictionary?
80: IF
81: >head-noprim dup ??? <>
82: ELSE
83: PrimStart (look)
84: THEN ;
85:
86: [THEN]
87: [THEN]
88:
89: : >head ( cfa -- nt|0 ) \ gforth to-head
90: \G tries to find the name token nt of the word represented by cfa;
91: \G returns 0 if it fails. This word is not absolutely reliable,
92: \G it may give false positives and produce wrong nts.
93: look and ;
94:
95: ' >head ALIAS >name \ gforth to-name
96: \G old name of @code{>head}
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>