1: \ LOOK.FS xt -> lfa 22may93jaw
2:
3: \ Copyright (C) 1995,1996,1997,2000 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ Look checks first if the word is a primitive. If yes then the
22: \ vocabulary in the primitive area is beeing searched, meaning
23: \ creating for each word a xt and comparing it...
24:
25: \ If a word is no primitive look searches backwards to find the nfa.
26: \ Problems: A compiled xt via compile, might be created with noname:
27: \ a noname: leaves now a empty name field
28:
29: require stuff.fs
30: require environ.fs
31:
32: decimal
33:
34: \ look 17may93jaw
35:
36: \ rename to discover!!!
37:
38: : xt>threaded ( xt -- x )
39: \G produces the threaded-code cell for the primitive xt
40: threading-method 0= if
41: @
42: then ;
43:
44: : (look) ( xt startlfa -- lfa flag )
45: swap
46: [IFDEF] decompile-prim
47: decompile-prim
48: [THEN]
49: false rot
50: BEGIN
51: @ dup
52: WHILE
53: dup name>int xt>threaded
54: 3 pick = IF
55: nip dup
56: THEN
57: REPEAT
58: drop nip
59: dup 0<> ;
60:
61:
62: \ !!! nicht optimal!
63: [IFUNDEF] look
64: has? ec [IF]
65:
66: has? rom
67: [IF]
68: : look
69: dup [ unlock rom-dictionary area lock ]
70: literal literal within
71: IF
72: >head-noprim dup ?? <>
73: ELSE
74: forth-wordlist @ (look)
75: THEN ;
76: [ELSE]
77: : look ( cfa -- lfa flag )
78: >head-noprim dup ??? <> ;
79: [THEN]
80:
81: [ELSE]
82:
83: : PrimStart ['] true >head-noprim ;
84:
85: : look ( cfa -- lfa flag )
86: dup in-dictionary?
87: IF
88: >head-noprim dup ??? <>
89: ELSE
90: PrimStart (look)
91: THEN ;
92:
93: [THEN]
94: [THEN]
95:
96: : >head ( cfa -- nt|0 ) \ gforth to-head
97: \G tries to find the name token nt of the word represented by cfa;
98: \G returns 0 if it fails. This word is not absolutely reliable,
99: \G it may give false positives and produce wrong nts.
100: look and ;
101:
102: ' >head ALIAS >name \ gforth to-name
103: \G old name of @code{>head}
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>