1: \ libffi.fs shared library support package 14aug05py
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000,2003,2005,2006,2007 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation, either version 3
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program. If not, see http://www.gnu.org/licenses/.
19:
20: \ replacements for former primitives
21: \ note that the API functions have their arguments reversed and other
22: \ deviations.
23:
24: require libcc.fs
25:
26: s" libffi" open-lib 0= [if]
27: .( cannot open libffi ) cr abort
28: [then]
29:
30: \c #include <ffi.h>
31: \c static Cell *gforth_RP;
32: \c static char *gforth_LP;
33: \c static void **gforth_clist;
34: \c static void *gforth_ritem;
35: \c typedef void *Label;
36: \c typedef Label *Xt;
37: \c static void gforth_callback_ffi(ffi_cif * cif, void * resp, void ** args, void * ip)
38: \c {
39: \c Cell *rp1 = gforth_RP;
40: \c Cell *sp = gforth_SP;
41: \c Float *fp = gforth_FP;
42: \c char *lp = gforth_LP;
43: \c void ** clist = gforth_clist;
44: \c void * ritem = gforth_ritem;
45: \c
46: \c gforth_clist = args;
47: \c gforth_ritem = resp;
48: \c
49: \c gforth_engine((Xt *)ip, sp, rp1, fp, lp);
50: \c
51: \c /* restore global variables */
52: \c gforth_RP = rp1;
53: \c gforth_SP = sp;
54: \c gforth_FP = fp;
55: \c gforth_LP = lp;
56: \c gforth_clist = clist;
57: \c gforth_ritem = ritem;
58: \c }
59:
60: \c static void* ffi_types[] =
61: \c { &ffi_type_void,
62: \c &ffi_type_uint8, &ffi_type_sint8,
63: \c &ffi_type_uint16, &ffi_type_sint16,
64: \c &ffi_type_uint32, &ffi_type_sint32,
65: \c &ffi_type_uint64, &ffi_type_sint64,
66: \c &ffi_type_float, &ffi_type_double, &ffi_type_longdouble,
67: \c &ffi_type_pointer };
68: \c #define ffi_type(n) (ffi_types[n])
69: c-function ffi-type ffi_type n -- a
70:
71: \c static int ffi_sizes[] = { sizeof(ffi_cif), sizeof(ffi_closure) };
72: \c #define ffi_size(n1) (ffi_sizes[n1])
73: c-function ffi-size ffi_size n -- n
74:
75: \c #define ffi_prep_cif1(atypes, n, rtype, cif) \
76: \c ffi_prep_cif((ffi_cif *)cif, FFI_DEFAULT_ABI, n, \
77: \c (ffi_type *)rtype, (ffi_type **)atypes)
78: c-function ffi-prep-cif ffi_prep_cif1 a n a a -- n
79:
80: \c #define ffi_call1(a_avalues, a_rvalue ,a_ip ,a_cif) \
81: \c ffi_call((ffi_cif *)a_cif, (void(*)())a_ip, \
82: \c (void *)a_rvalue, (void **)a_avalues)
83: c-function ffi-call ffi_call1 a a a a -- void
84:
85: \c #define ffi_prep_closure1(a_ip, a_cif, a_closure) \
86: \c ffi_prep_closure((ffi_closure *)a_closure, (ffi_cif *)a_cif, gforth_callback_ffi, (void *)a_ip)
87: c-function ffi-prep-closure a a a -- n
88:
89: \ !! use ud?
90: \c #define ffi_2fetch(a_addr) (*(long long *)a_addr)
91: c-function ffi-2@ ffi_2fetch a -- d
92:
93: \c #define ffi_2store(d,a_addr) ((*(long long *)a_addr) = (long long)d)
94: c-function ffi-2! ffi_2store d a -- void
95:
96: \c #define ffi_arg_int() (*(int *)(*gforth_clist++))
97: c-function ffi-arg-int ffi_arg_int -- n
98:
99: \c #define ffi_arg_long() (*(long *)(*gforth_clist++))
100: c-function ffi-arg-long ffi_arg_long -- n
101:
102: \c #define ffi_arg_longlong() (*(long long *)(*gforth_clist++))
103: c-function ffi-arg-longlong ffi_arg_longlong -- d
104:
105: \ !! correct? The primitive is different, but looks funny
106: c-function ffi-arg-dlong ffi_arg_long -- d
107:
108: \c #define ffi_arg_ptr() (*(char **)(*gforth_clist++))
109: c-function ffi-arg-ptr ffi_arg_ptr -- a
110:
111: \c #define ffi_arg_float() (*(float *)(*gforth_clist++))
112: c-function ffi-arg-float ffi_arg_float -- r
113:
114: \c #define ffi_arg_double() (*(double *)(*gforth_clist++))
115: c-function ffi-arg-double ffi_arg_double -- r
116:
117: : ffi-ret-void ( -- )
118: 0 (bye) ;
119:
120: \c #define ffi_ret_int1(w) (*(int*)(gforth_ritem) = w)
121: c-function ffi-ret-int1 ffi_ret_int1 n -- void
122: : ffi-ret-int ( w -- ) ffi-ret-int1 ffi-ret-void ;
123:
124: \c #define ffi_ret_longlong1(d) (*(long long *)(gforth_ritem) = d)
125: c-function ffi-ret-longlong1 ffi_ret_longlong1 d -- void
126: : ffi-ret-longlong ( d -- ) ffi-ret-longlong1 ffi-ret-void ;
127:
128: \c #define ffi_ret_dlong1(d) (*(long *)(gforth_ritem) = d)
129: c-function ffi-ret-dlong1 ffi_ret_dlong1 d -- void
130: : ffi-ret-dlong ( d -- ) ffi-ret-dlong1 ffi-ret-void ;
131:
132: c-function ffi-ret-long1 ffi_ret_dlong1 n -- void
133: : ffi-ret-long ( n -- ) ffi-ret-long1 ffi-ret-void ;
134:
135: \c #define ffi_ret_ptr1(w) (*(char **)(gforth_ritem) = w)
136: c-function ffi-ret-ptr1 ffi_ret_ptr1 a -- void
137: : ffi-ret-ptr ( a -- ) ffi-ret-ptr1 ffi-ret-void ;
138:
139: \c #define ffi_ret_float1(r) (*(float *)(gforth_ritem) = r)
140: c-function ffi-ret-float1 ffi_ret_float1 r -- void
141: : ffi-ret-float ( r -- ) ffi-ret-float1 ffi-ret-void ;
142:
143: \c #define ffi_ret_double1(r) (*(double *)(gforth_ritem) = r)
144: c-function ffi-ret-double1 ffi_ret_double1 r -- void
145: : ffi-ret-double ( r -- ) ffi-ret-double1 ffi-ret-void ;
146:
147: \ common stuff, same as fflib.fs
148:
149: Variable libs 0 libs !
150: \ links between libraries
151: Variable thisproc
152: Variable thislib
153:
154: Variable revdec revdec off
155: \ turn revdec on to compile bigFORTH libraries
156: Variable revarg revarg off
157: \ turn revarg on to compile declarations with reverse arguments
158: Variable legacy legacy off
159: \ turn legacy on to compile bigFORTH legacy libraries
160:
161: Vocabulary c-decl
162: Vocabulary cb-decl
163:
164: : @lib ( lib -- )
165: \G obtains library handle
166: cell+ dup 2 cells + count open-lib
167: dup 0= abort" Library not found" swap ! ;
168:
169: : @proc ( lib addr -- )
170: \G obtains symbol address
171: cell+ tuck cell+ @ count rot cell+ @
172: lib-sym dup 0= abort" Proc not found!" swap ! ;
173:
174: : proc, ( lib -- )
175: \G allocates and initializes proc stub
176: \G stub format:
177: \G linked list in library
178: \G address of proc
179: \G ptr to OS name of symbol as counted string
180: \G threaded code for invocation
181: here dup thisproc !
182: swap 2 cells + dup @ A, !
183: 0 , 0 A, ;
184:
185: Defer legacy-proc ' noop IS legacy-proc
186:
187: : proc: ( lib "name" -- )
188: \G Creates a named proc stub
189: Create proc, 0 also c-decl
190: legacy @ IF legacy-proc THEN
191: DOES> ( x1 .. xn -- r )
192: 3 cells + >r ;
193:
194: : library ( "name" "file" -- )
195: \G loads library "file" and creates a proc defining word "name"
196: \G library format:
197: \G linked list of libraries
198: \G library handle
199: \G linked list of library's procs
200: \G OS name of library as counted string
201: Create here libs @ A, dup libs !
202: 0 , 0 A, parse-name string, @lib
203: DOES> ( -- ) dup thislib ! proc: ;
204:
205: : init-shared-libs ( -- )
206: defers 'cold libs
207: 0 libs BEGIN @ dup WHILE dup REPEAT drop
208: BEGIN dup WHILE >r
209: r@ @lib
210: r@ 2 cells + BEGIN @ dup WHILE r@ over @proc REPEAT
211: drop rdrop
212: REPEAT drop ;
213:
214: ' init-shared-libs IS 'cold
215:
216: : symbol, ( "c-symbol" -- )
217: here thisproc @ 2 cells + ! parse-name s,
218: thislib @ thisproc @ @proc ;
219:
220: \ stuff for libffi
221:
222: \ libffi uses a parameter array for the input
223:
224: $20 Value maxargs
225:
226: Create retbuf 2 cells allot
227: Create argbuf maxargs 2* cells allot
228: Create argptr maxargs 0 [DO] argbuf [I] 2* cells + A, [LOOP]
229:
230: \ "forward" when revarg is on
231:
232: \ : >c+ ( char buf -- buf' ) tuck c! cell+ cell+ ;
233: : >i+ ( n buf -- buf' ) tuck l! cell+ cell+ ;
234: : >p+ ( addr buf -- buf' ) tuck ! cell+ cell+ ;
235: : >d+ ( d buf -- buf' ) dup >r ffi-2! r> cell+ cell+ ;
236: : >dl+ ( d buf -- buf' ) nip dup >r ! r> cell+ cell+ ;
237: : >sf+ ( r buf -- buf' ) dup sf! cell+ cell+ ;
238: : >df+ ( r buf -- buf' ) dup df! cell+ cell+ ;
239:
240: \ "backward" when revarg is off
241:
242: : >i- ( n buf -- buf' ) 2 cells - tuck l! ;
243: : >p- ( addr buf -- buf' ) 2 cells - tuck ! ;
244: : >d- ( d buf -- buf' ) 2 cells - dup >r ffi-2! r> ;
245: : >dl- ( d buf -- buf' ) 2 cells - nip dup >r ! r> ;
246: : >sf- ( r buf -- buf' ) 2 cells - dup sf! ;
247: : >df- ( r buf -- buf' ) 2 cells - dup df! ;
248:
249: \ return value
250:
251: : i>x ( -- n ) retbuf l@ ;
252: : is>x ( -- n ) retbuf sl@ ;
253: : p>x ( -- addr ) retbuf @ ;
254: : dl>x ( -- d ) retbuf @ s>d ;
255: : d>x ( -- d ) retbuf ffi-2@ ;
256: : sf>x ( -- r ) retbuf sf@ ;
257: : df>x ( -- r ) retbuf df@ ;
258:
259: wordlist constant cifs
260:
261: Variable cifbuf $40 allot \ maximum: 64 parameters
262: : cifreset cifbuf cell+ cifbuf ! ;
263: cifreset
264: Variable args args off
265:
266: : argtype ( bkxt fwxt type "name" -- )
267: Create , , , DOES> 1 args +! ;
268:
269: : arg@ ( arg -- type pushxt )
270: dup @ swap cell+
271: revarg @ IF cell+ THEN @ ;
272:
273: : arg, ( xt -- )
274: dup ['] noop = IF drop EXIT THEN compile, ;
275:
276: : start, ( n -- ) cifbuf cell+ cifbuf !
277: revarg @ IF drop 0 ELSE 2* cells THEN argbuf +
278: postpone Literal ;
279:
280: Variable ind-call ind-call off
281: : fptr ind-call on Create here thisproc !
282: 0 , 0 , 0 , 0 also c-decl DOES> cell+ dup cell+ cell+ >r ! ;
283:
284: : ffi-call, ( -- lit-cif )
285: postpone drop postpone argptr postpone retbuf
286: thisproc @ cell+ postpone literal postpone @
287: 0 postpone literal here cell -
288: postpone ffi-call ;
289:
290: : cif, ( n -- )
291: cifbuf @ c! 1 cifbuf +! ;
292:
293: : cif@ ( -- addr u )
294: cifbuf cell+ cifbuf @ over - ;
295:
296: : create-cif ( rtype -- addr ) cif,
297: cif@ cifs search-wordlist
298: IF execute EXIT THEN
299: get-current >r cifs set-current
300: cif@ nextname Create here >r
301: cif@ 1- bounds ?DO I c@ ffi-type , LOOP r>
302: r> set-current ;
303:
304: : make-cif ( rtype -- addr ) create-cif
305: cif@ 1- tuck + c@ ffi-type here 0 ffi-size allot
306: dup >r ffi-prep-cif throw r> ;
307:
308: : decl, ( 0 arg1 .. argn call rtype start -- )
309: start, { retxt rtype } cifreset
310: revdec @ IF 0 >r
311: BEGIN dup WHILE >r REPEAT
312: BEGIN r> dup WHILE arg@ arg, REPEAT
313: ffi-call, retxt compile, postpone EXIT
314: BEGIN dup WHILE cif, REPEAT drop
315: ELSE 0 >r
316: BEGIN dup WHILE arg@ arg, >r REPEAT drop
317: ffi-call, retxt compile, postpone EXIT
318: BEGIN r> dup WHILE cif, REPEAT drop
319: THEN rtype make-cif swap ! here thisproc @ 2 cells + ! ;
320:
321: : rettype ( endxt n "name" -- )
322: Create 2,
323: DOES> 2@ args @ decl, ind-call @ 0= IF symbol, THEN
324: previous revarg off args off ind-call off ;
325:
326: 6 1 cells 4 > 2* - Constant _long
327:
328: also c-decl definitions
329:
330: : <rev> revarg on ;
331:
332: ' >i+ ' >i- 6 argtype int
333: ' >p+ ' >p- _long argtype long
334: ' >p+ ' >p- &12 argtype ptr
335: ' >d+ ' >d- 8 argtype llong
336: ' >dl+ ' >dl- 6 argtype dlong
337: ' >sf+ ' >sf- 9 argtype sf
338: ' >df+ ' >df- &10 argtype df
339:
340: ' noop 0 rettype (void)
341: ' is>x 6 rettype (int)
342: ' i>x 5 rettype (uint)
343: ' p>x _long rettype (long)
344: ' p>x &12 rettype (ptr)
345: ' d>x 8 rettype (llong)
346: ' dl>x 6 rettype (dlong)
347: ' sf>x 9 rettype (sf)
348: ' df>x &10 rettype (fp)
349:
350: : (addr) thisproc @ cell+ postpone Literal postpone @ postpone EXIT
351: drop symbol, previous revarg off args off ;
352:
353: previous definitions
354:
355: \ legacy support for old library interfaces
356: \ interface to old vararg stuff not implemented yet
357:
358: also c-decl
359:
360: :noname ( n 0 -- 0 int1 .. intn )
361: legacy @ 0< revarg !
362: swap 0 ?DO int LOOP (int)
363: ; IS legacy-proc
364:
365: : (int) ( n -- )
366: >r ' execute r> 0 ?DO int LOOP (int) ;
367: : (void) ( n -- )
368: >r ' execute r> 0 ?DO int LOOP (void) ;
369: : (float) ( n -- )
370: >r ' execute r> 0 ?DO df LOOP (fp) ;
371:
372: previous
373:
374: \ callback stuff
375:
376: Variable callbacks
377: \G link between callbacks
378:
379: Variable rtype
380:
381: : alloc-callback ( ip -- addr )
382: rtype @ make-cif here 1 ffi-size allot
383: dup >r ffi-prep-closure throw r> ;
384:
385: : callback ( -- )
386: Create 0 ] postpone >r also cb-decl cifreset
387: DOES>
388: 0 Value -1 cells allot
389: here >r 0 , callbacks @ A, r@ callbacks !
390: swap postpone Literal postpone call , postpone EXIT
391: r@ cell+ cell+ alloc-callback r> ! ;
392:
393: \ !! is the stack effect right? or is it ( 0 ret arg1 .. argn -- ) ?
394: : callback; ( 0 arg1 .. argn -- )
395: BEGIN over WHILE compile, REPEAT
396: postpone r> postpone execute compile, drop
397: \ !! should we put ]] 0 (bye) [[ here?
398: \ !! is the EXIT ever executed?
399: postpone EXIT postpone [ previous ; immediate
400:
401: : rettype' ( xt n -- )
402: Create , A, immediate
403: DOES> 2@ rtype ! ;
404: : argtype' ( xt n -- )
405: Create , A, immediate
406: DOES> 2@ cif, ;
407:
408: : init-callbacks ( -- )
409: defers 'cold callbacks cell -
410: BEGIN cell+ @ dup WHILE dup cell+ cell+ alloc-callback over !
411: REPEAT drop ;
412:
413: ' init-callbacks IS 'cold
414:
415: also cb-decl definitions
416:
417: \ arguments
418:
419: ' ffi-arg-int 6 argtype' int
420: ' ffi-arg-float 9 argtype' sf
421: ' ffi-arg-double &10 argtype' df
422: ' ffi-arg-long _long argtype' long
423: ' ffi-arg-longlong 8 argtype' llong
424: ' ffi-arg-dlong 6 argtype' dlong
425: ' ffi-arg-ptr &12 argtype' ptr
426:
427: ' ffi-ret-void 0 rettype' (void)
428: ' ffi-ret-int 6 rettype' (int)
429: ' ffi-ret-float 9 rettype' (sf)
430: ' ffi-ret-double &10 rettype' (fp)
431: ' ffi-ret-longlong 8 rettype' (llong)
432: ' ffi-ret-long _long rettype' (long)
433: ' ffi-ret-dlong _long rettype' (dlong)
434: ' ffi-ret-ptr &12 rettype' (ptr)
435:
436: previous definitions
437:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to libffi.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth