File:  [gforth] / gforth / libffi.fs
Revision 1.2: download - view: text, annotated - select for diffs
Sun Nov 20 23:15:42 2005 UTC (15 years, 8 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
further work on libffi.fs (not fully completed yet for callbacks)

    1: \ libffi.fs	shared library support package 		14aug05py
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998,2000,2003,2005 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: \ common stuff, same as fflib.fs
   22: 
   23: Variable libs 0 libs !
   24: \ links between libraries
   25: Variable thisproc
   26: Variable thislib
   27: 
   28: Variable revdec  revdec off
   29: \ turn revdec on to compile bigFORTH libraries
   30: Variable revarg  revarg off
   31: \ turn revarg on to compile declarations with reverse arguments
   32: Variable legacy  legacy off
   33: \ turn legacy on to compile bigFORTH legacy libraries
   34: 
   35: Vocabulary c-decl
   36: Vocabulary cb-decl
   37: 
   38: : @lib ( lib -- )
   39:     \G obtains library handle
   40:     cell+ dup 2 cells + count open-lib
   41:     dup 0= abort" Library not found" swap ! ;
   42: 
   43: : @proc ( lib addr -- )
   44:     \G obtains symbol address
   45:     cell+ tuck cell+ @ count rot cell+ @
   46:     lib-sym  dup 0= abort" Proc not found!" swap ! ;
   47: 
   48: : proc, ( lib -- )
   49: \G allocates and initializes proc stub
   50: \G stub format:
   51: \G    linked list in library
   52: \G    address of proc
   53: \G    ptr to OS name of symbol as counted string
   54: \G    threaded code for invocation
   55:     here dup thisproc !
   56:     swap 2 cells + dup @ A, !
   57:     0 , 0 A, ;
   58: 
   59: Defer legacy-proc  ' noop IS legacy-proc
   60: 
   61: : proc:  ( lib "name" -- )
   62: \G Creates a named proc stub
   63:     Create proc, 0 also c-decl
   64:     legacy @ IF  legacy-proc  THEN
   65: DOES> ( x1 .. xn -- r )
   66:     3 cells + >r ;
   67: 
   68: : library ( "name" "file" -- )
   69: \G loads library "file" and creates a proc defining word "name"
   70: \G library format:
   71: \G    linked list of libraries
   72: \G    library handle
   73: \G    linked list of library's procs
   74: \G    OS name of library as counted string
   75:     Create  here libs @ A, dup libs !
   76:     0 , 0 A, parse-name string, @lib
   77: DOES> ( -- )  dup thislib ! proc: ;
   78: 
   79: : init-shared-libs ( -- )
   80:     defers 'cold  libs
   81:     0  libs  BEGIN  @ dup  WHILE  dup  REPEAT  drop
   82:     BEGIN  dup  WHILE  >r
   83: 	r@ @lib
   84: 	r@ 2 cells +  BEGIN  @ dup  WHILE  r@ over @proc  REPEAT
   85: 	drop rdrop
   86:     REPEAT  drop ;
   87: 
   88: ' init-shared-libs IS 'cold
   89: 
   90: : symbol, ( "c-symbol" -- )
   91:     here thisproc @ 2 cells + ! parse-name s,
   92:     thislib @ thisproc @ @proc ;
   93: 
   94: \ stuff for libffi
   95: 
   96: \ libffi uses a parameter array for the input
   97: 
   98: $20 Value maxargs
   99: 
  100: Create retbuf 2 cells allot
  101: Create argbuf maxargs 2* cells allot
  102: Create argptr maxargs 0 [DO]  argbuf [I] 2* cells + A, [LOOP]
  103: 
  104: \ "forward" when revarg is on
  105: 
  106: \ : >c+  ( char buf -- buf' )  tuck   c!    cell+ cell+ ;
  107: : >i+  ( n buf -- buf' )     tuck    !    cell+ cell+ ;
  108: : >p+  ( addr buf -- buf' )  tuck    !    cell+ cell+ ;
  109: : >d+  ( d buf -- buf' )     dup >r ffi-2! r> cell+ cell+ ;
  110: : >sf+ ( r buf -- buf' )     dup   sf!    cell+ cell+ ;
  111: : >df+ ( r buf -- buf' )     dup   df!    cell+ cell+ ;
  112: 
  113: \ "backward" when revarg is off
  114: 
  115: : >i-  ( n buf -- buf' )     2 cells - tuck   ffi-i! ;
  116: : >p-  ( addr buf -- buf' )  2 cells - tuck    ! ;
  117: : >d-  ( d buf -- buf' )     2 cells - dup >r ffi-2! r> ;
  118: : >sf- ( r buf -- buf' )     2 cells - dup   sf! ;
  119: : >df- ( r buf -- buf' )     2 cells - dup   df! ;
  120: 
  121: \ return value
  122: 
  123: : i>x   ( -- n )  retbuf ffi-i@ ;
  124: : p>x   ( -- addr ) retbuf @ ;
  125: : d>x   ( -- d )  retbuf ffi-2@ ;
  126: : sf>x  ( -- r )  retbuf sf@ ;
  127: : df>x  ( -- r )  retbuf df@ ;
  128: 
  129: wordlist constant cifs
  130: 
  131: Variable cifbuf $40 allot \ maximum: 64 parameters
  132: : cifreset  cifbuf cell+ cifbuf ! ;
  133: cifreset
  134: Variable args args off
  135: 
  136: : argtype ( bkxt fwxt type "name" -- )
  137:     Create , , , DOES>  1 args +! ;
  138: 
  139: : arg@ ( arg -- type pushxt )
  140:     dup @ swap cell+
  141:     revarg @ IF  cell+  THEN  @    ;
  142: 
  143: : arg, ( xt -- )
  144:     dup ['] noop = IF  drop  EXIT  THEN  compile, ;
  145: 
  146: : start, ( n -- )  cifbuf cell+ cifbuf !
  147:     revarg @ IF  drop 0  ELSE  2* cells  THEN  argbuf +
  148:     postpone Literal ;
  149: 
  150: : ffi-call, ( -- lit-cif )
  151:     postpone drop postpone argptr postpone retbuf
  152:     thisproc @ cell+ postpone literal postpone @
  153:     0 postpone literal here cell -
  154:     postpone ffi-call ;
  155: 
  156: : cif, ( n -- )
  157:     cifbuf @ c! 1 cifbuf +! ;
  158: 
  159: : cif@ ( -- addr u )
  160:     cifbuf cell+ cifbuf @ over - ;
  161: 
  162: : make-cif ( rtype -- addr ) cif,
  163:     cif@ cifs search-wordlist
  164:     IF  execute  EXIT  THEN
  165:     get-current >r cifs set-current
  166:     cif@ nextname Create  here >r
  167:     cif@ 1- bounds ?DO  I c@ ffi-type ,  LOOP
  168:     r> cif@ 1- tuck + c@ ffi-type here dup >r 0 ffi-size allot
  169:     ffi-prep-cif throw
  170:     r> r> set-current ;
  171: 
  172: : decl, ( 0 arg1 .. argn call rtype start -- )
  173:     start, { retxt rtype } cifreset
  174:     revdec @ IF  0 >r
  175: 	BEGIN  dup  WHILE  >r  REPEAT
  176: 	BEGIN  r> dup  WHILE  arg@ arg,  REPEAT
  177: 	ffi-call, retxt compile,  postpone  EXIT
  178: 	BEGIN  dup  WHILE  cif,  REPEAT drop
  179:     ELSE  0 >r
  180: 	BEGIN  dup  WHILE  arg@ arg, >r REPEAT drop
  181: 	ffi-call, retxt compile,  postpone  EXIT
  182: 	BEGIN  r> dup  WHILE  cif,  REPEAT  drop
  183:     THEN  rtype make-cif swap ! here thisproc @ 2 cells + ! ;
  184: 
  185: : rettype ( endxt n "name" -- )
  186:     Create 2,
  187:   DOES>  2@ args @ decl, symbol, previous revarg off args off ;
  188: 
  189: also c-decl definitions
  190: 
  191: : <rev>  revarg on ;
  192: 
  193: ' >i+  ' >i-    6 argtype int
  194: ' >p+  ' >p-  &12 argtype ptr
  195: ' >d+  ' >d-    8 argtype llong
  196: ' >sf+ ' >sf-   9 argtype sf
  197: ' >df+ ' >df- &10 argtype df
  198: 
  199: ' noop   0 rettype (void)
  200: ' i>x    6 rettype (int)
  201: ' p>x  &12 rettype (ptr)
  202: ' d>x    8 rettype (llong)
  203: ' sf>x   9 rettype (sf)
  204: ' df>x &10 rettype (fp)
  205: 
  206: previous definitions
  207: 
  208: \ legacy support for old library interfaces
  209: \ interface to old vararg stuff not implemented yet
  210: 
  211: also c-decl
  212: 
  213: :noname ( n 0 -- 0 int1 .. intn )
  214:     legacy @ 0< revarg !
  215:     swap 0 ?DO  int  LOOP  (int)
  216: ; IS legacy-proc
  217: 
  218: : (int) ( n -- )
  219:     >r ' execute r> 0 ?DO  int  LOOP  (int) ;
  220: : (void) ( n -- )
  221:     >r ' execute r> 0 ?DO  int  LOOP  (void) ;
  222: : (float) ( n -- )
  223:     >r ' execute r> 0 ?DO  df   LOOP  (fp) ;
  224: 
  225: previous
  226: 
  227: \ callback stuff
  228: 
  229: Variable callbacks
  230: \G link between callbacks
  231: 
  232: Variable rtype
  233: 
  234: : alloc-callback ( -- addr )
  235:     rtype @ cif,
  236:     here >r
  237:     cif@ 1- bounds ?DO  I c@ ffi-type ,  LOOP
  238:     r> cif@ 1- tuck + c@ ffi-type here dup >r 1 ffi-size allot
  239:     ffi-prep-closure throw r> ;
  240: 
  241: : callback ( -- )
  242:     Create  0 ] postpone >r also cb-decl cifreset
  243:   DOES>
  244:     Create here >r 0 , callbacks @ A, r@ callbacks !
  245:     swap postpone Literal postpone call , postpone EXIT
  246:     r> dup cell+ cell+ alloc-callback swap !
  247:   DOES> @ ;
  248: 
  249: : callback; ( 0 arg1 .. argn -- )
  250:     BEGIN  over  WHILE  compile,  REPEAT
  251:     postpone r> postpone execute compile, drop
  252:     postpone EXIT postpone [ previous ; immediate
  253: 
  254: : rettype' ( xt n -- )
  255:     Create , A, immediate
  256:   DOES> 2@ rtype ! ;
  257: : argtype' ( xt n -- )
  258:     Create , A, immediate
  259:   DOES> 2@ cif, ;
  260: 
  261: : init-callbacks ( -- )
  262:     defers 'cold  callbacks cell -
  263:     BEGIN  cell+ @ dup  WHILE  dup cell+ cell+ alloc-callback over !
  264:     REPEAT  drop ;
  265: 
  266: ' init-callbacks IS 'cold
  267: 
  268: also cb-decl definitions
  269: 
  270: \ arguments
  271: 
  272: ' ffi-arg-int        6 argtype' int
  273: ' ffi-arg-float      9 argtype' sf
  274: ' ffi-arg-double   &10 argtype' df
  275: ' ffi-arg-longlong   8 argtype' llong
  276: ' ffi-arg-ptr      &12 argtype' ptr
  277: 
  278: ' ffi-ret-void       0 rettype' (void)
  279: ' ffi-ret-int        6 rettype' (int)
  280: ' ffi-ret-float      9 rettype' (sf)
  281: ' ffi-ret-double   &10 rettype' (fp)
  282: ' ffi-ret-longlong   8 rettype' (llong)
  283: ' ffi-ret-ptr      &12 rettype' (ptr)
  284: 
  285: previous definitions
  286:     

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>