1: \ libcc.fs foreign function interface implemented using a C compiler
2:
3: \ Copyright (C) 2006 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: \ What this implementation does is this: if it sees a declaration like
23:
24: \ \ something that tells it that the current library is libc
25: \ \c #include <unistd.h>
26: \ c-function dlseek lseek n d n -- d
27:
28: \ it genererates C code similar to the following:
29:
30: \ #include <gforth.h>
31: \ #include <unistd.h>
32: \
33: \ void gforth_c_lseek_ndn_d(void)
34: \ {
35: \ Cell *sp = gforth_SP;
36: \ Float *fp = gforth_FP;
37: \ long long result; /* longest type in C */
38: \ gforth_ll2d(lseek(sp[3],gforth_d2ll(sp[2],sp[1]),sp[0]),sp[3],sp[2]);
39: \ gforth_SP = sp+2;
40: \ }
41:
42: \ Then it compiles this code and dynamically links it into the Gforth
43: \ system (batching and caching are future work). It also dynamically
44: \ links lseek. Performing DLSEEK then puts the function pointer of
45: \ the function pointer of gforth_c_lseek_ndn_d on the stack and
46: \ calls CALL-C.
47:
48: \ ToDo:
49:
50: \ Batching, caching and lazy evaluation:
51:
52: \ Batching:
53:
54: \ New words are deferred, and the corresponding C functions are
55: \ collected in one file, until the first word is EXECUTEd; then the
56: \ file is compiled and linked into the system, and the word is
57: \ resolved.
58:
59: \ Caching:
60:
61: \ Instead of compiling all this stuff anew for every execution, we
62: \ keep the files around and have an index file containing the function
63: \ names and their corresponding .so files. If the needed wrapper name
64: \ is already present, it is just linked instead of generating the
65: \ wrapper again. This is all done by loading the index file(s?),
66: \ which define words for the wrappers in a separate wordlist.
67:
68: \ The files are built in .../lib/gforth/$VERSION/libcc/ or
69: \ ~/.gforth/libcc/$HOST/.
70:
71: \ other things to do:
72:
73: \ c-variable forth-name c-name
74: \ c-constant forth-name c-name
75:
76: \ Todo: conversion between function pointers and xts (both directions)
77:
78: \ taking an xt and turning it into a function pointer:
79:
80: \ e.g., assume we have the xt of + and want to create a C function int
81: \ gforth_callback_plus(int, int), and then pass the pointer to that
82: \ function:
83:
84: \ There should be Forth code like this:
85: \ ] + 0 (bye)
86: \ Assume that the start of this code is START
87:
88: \ Now, there should be a C function:
89:
90: \ int gforth_callback_plus(int p1, int p2)
91: \ {
92: \ Cell *sp = gforth_SP;
93: \ Float *fp = gforth_FP;
94: \ Float *fp = gforth_FP;
95: \ Address lp = gforth_LP;
96: \ sp -= 2;
97: \ sp[0] = p1;
98: \ sp[1] = p2;
99: \ gforth_engine(START, sp, rp, fp, lp);
100: \ sp += 1;
101: \ gforth_RP = rp;
102: \ gforth_SP = sp;
103: \ gforth_FP = fp;
104: \ gforth_LP = lp;
105: \ return sp[0];
106: \ }
107:
108: \ and the pointer to that function is the C function pointer for the XT of +.
109:
110: \ Future problems:
111: \ how to combine the Forth code generation with inlining
112: \ START is not a constant across executions (when caching the C files)
113: \ Solution: make START a variable, and store into it on startup with dlsym
114:
115: \ Syntax:
116: \ callback <rettype> <params> <paramtypes> -- <rettype>
117:
118:
119: \ data structures
120:
121: \ For every c-function, we have three words: two anonymous words
122: \ created by c-function-ft (first time) and c-function-rt (run-time),
123: \ and a named deferred word. The deferred word first points to the
124: \ first-time word, then to the run-time word; the run-time word calls
125: \ the c function.
126:
127: : delete-file 2drop 0 ;
128:
129: require struct.fs
130:
131: \ counted-string
132:
133: \ c-function-ft word body:
134: struct
135: cell% field cff-cfr \ xt of c-function-rt word
136: cell% field cff-deferred \ xt of c-function deferred word
137: cell% field cff-lha \ address of the lib-handle for the lib that
138: \ contains the wrapper function of the word
139: char% field cff-rtype \ return type
140: char% field cff-np \ number of parameters
141: 1 0 field cff-ptypes \ #npar parameter types
142: \ counted string: c-name
143: end-struct cff%
144:
145: variable c-source-file-id \ contains the source file id of the current batch
146: 0 c-source-file-id !
147: variable lib-handle-addr \ points to the library handle of the current batch.
148: \ the library handle is 0 if the current
149: \ batch is not yet compiled.
150: 2variable lib-filename \ filename without extension
151:
152: : .nb ( n -- )
153: 0 .r ;
154:
155: : const+ ( n1 "name" -- n2 )
156: dup constant 1+ ;
157:
158: : front-string { c-addr1 u1 c-addr2 u2 -- c-addr3 u3 }
159: \ insert string c-addr2 u2 in buffer c-addr1 u1; c-addr3 u3 is the
160: \ remainder of the buffer.
161: assert( u1 u2 u>= )
162: c-addr2 c-addr1 u2 move
163: c-addr1 u1 u2 /string ;
164:
165: : front-char { c-addr1 u1 c -- c-addr3 u2 }
166: \ insert c in buffer c-addr1 u1; c-addr3 u3 is the remainder of
167: \ the buffer.
168: assert( u1 0 u> )
169: c c-addr1 c!
170: c-addr1 u1 1 /string ;
171:
172: : s+ { addr1 u1 addr2 u2 -- addr u }
173: u1 u2 + allocate throw { addr }
174: addr1 addr u1 move
175: addr2 addr u1 + u2 move
176: addr u1 u2 +
177: ;
178:
179: : append { addr1 u1 addr2 u2 -- addr u }
180: addr1 u1 u2 + dup { u } resize throw { addr }
181: addr2 addr u1 + u2 move
182: addr u ;
183:
184: \ linked list stuff (should go elsewhere)
185:
186: struct
187: cell% field list-next
188: 1 0 field list-payload
189: end-struct list%
190:
191: : list-insert { node list -- }
192: list list-next @ node list-next !
193: node list list-next ! ;
194:
195: : list-append { node endlistp -- }
196: \ insert node at place pointed to by endlistp
197: node endlistp @ list-insert
198: node list-next endlistp ! ;
199:
200: : list-map ( ... list xt -- ... )
201: \ xt ( ... node -- ... )
202: { xt } begin { node }
203: node while
204: node xt execute
205: node list-next @
206: repeat ;
207:
208: \ C prefix lines
209:
210: \ linked list of longcstrings: [ link | count-cell | characters ]
211:
212: list%
213: cell% field c-prefix-count
214: 1 0 field c-prefix-chars
215: end-struct c-prefix%
216:
217: variable c-prefix-lines 0 c-prefix-lines !
218: variable c-prefix-lines-end c-prefix-lines c-prefix-lines-end !
219:
220: : print-c-prefix-line ( node -- )
221: dup c-prefix-chars swap c-prefix-count @ type cr ;
222:
223: : print-c-prefix-lines ( -- )
224: c-prefix-lines @ ['] print-c-prefix-line list-map ;
225:
226: : save-c-prefix-line ( c-addr u -- )
227: c-source-file-id @ ?dup-if
228: >r 2dup r> write-line throw
229: then
230: align here 0 , c-prefix-lines-end list-append ( c-addr u )
231: longstring, ;
232:
233: : \c ( "rest-of-line" -- ) \ gforth backslash-c
234: \G One line of C declarations for the C interface
235: -1 parse save-c-prefix-line ;
236:
237: s" #include <gforth/" version-string s+ s" /libcc.h>" append ( c-addr u )
238: 2dup save-c-prefix-line drop free throw
239:
240: \ Types (for parsing)
241:
242: wordlist constant libcc-types
243:
244: get-current libcc-types set-current
245:
246: \ index values
247: -1
248: const+ -- \ end of arguments
249: const+ n \ integer cell
250: const+ a \ address cell
251: const+ d \ double
252: const+ r \ float
253: const+ func \ C function pointer
254: const+ void
255: drop
256:
257: set-current
258:
259: : parse-libcc-type ( "libcc-type" -- u )
260: parse-name libcc-types search-wordlist 0= -13 and throw execute ;
261:
262: : parse-function-types ( "{libcc-type}" "--" "libcc-type" -- )
263: here 2 chars allot here begin
264: parse-libcc-type dup 0>= while
265: c,
266: repeat
267: drop here swap - over char+ c!
268: parse-libcc-type dup 0< -32 and throw swap c! ;
269:
270: : type-letter ( n -- c )
271: chars s" nadrfv" drop + c@ ;
272:
273: \ count-stacks
274:
275: : count-stacks-n ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
276: 1+ ;
277:
278: : count-stacks-a ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
279: 1+ ;
280:
281: : count-stacks-d ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
282: 2 + ;
283:
284: : count-stacks-r ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
285: swap 1+ swap ;
286:
287: : count-stacks-func ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
288: 1+ ;
289:
290: : count-stacks-void ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
291: ;
292:
293: create count-stacks-types
294: ' count-stacks-n ,
295: ' count-stacks-a ,
296: ' count-stacks-d ,
297: ' count-stacks-r ,
298: ' count-stacks-func ,
299: ' count-stacks-void ,
300:
301: : count-stacks ( pars -- fp-change sp-change )
302: \ pars is an addr u pair
303: 0 0 2swap over + swap u+do
304: i c@ cells count-stacks-types + @ execute
305: loop ;
306:
307: \ gen-pars
308:
309: : gen-par-n ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
310: ." sp[" 1- dup .nb ." ]" ;
311:
312: : gen-par-a ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
313: ." (void *)(" gen-par-n ." )" ;
314:
315: : gen-par-d ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
316: ." gforth_d2ll(" gen-par-n ." ," gen-par-n ." )" ;
317:
318: : gen-par-r ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
319: swap 1- tuck ." fp[" .nb ." ]" ;
320:
321: : gen-par-func ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
322: gen-par-a ;
323:
324: : gen-par-void ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
325: -32 throw ;
326:
327: create gen-par-types
328: ' gen-par-n ,
329: ' gen-par-a ,
330: ' gen-par-d ,
331: ' gen-par-r ,
332: ' gen-par-func ,
333: ' gen-par-void ,
334:
335: : gen-par ( fp-depth1 sp-depth1 partype -- fp-depth2 sp-depth2 )
336: cells gen-par-types + @ execute ;
337:
338: \ the call itself
339:
340: : gen-wrapped-call { d: pars d: c-name fp-change1 sp-change1 -- }
341: c-name type ." ("
342: fp-change1 sp-change1 pars over + swap u+do
343: i c@ gen-par
344: i 1+ i' < if
345: ." ,"
346: endif
347: loop
348: 2drop ." )" ;
349:
350: \ calls for various kinds of return values
351:
352: : gen-wrapped-void ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
353: 2dup 2>r gen-wrapped-call 2r> ;
354:
355: : gen-wrapped-n ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
356: 2dup gen-par-n 2>r ." =" gen-wrapped-call 2r> ;
357:
358: : gen-wrapped-a ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
359: 2dup gen-par-n 2>r ." =(Cell)" gen-wrapped-call 2r> ;
360:
361: : gen-wrapped-d ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
362: ." gforth_ll2d(" gen-wrapped-void
363: ." ," gen-par-n ." ," gen-par-n ." )" ;
364:
365: : gen-wrapped-r ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
366: 2dup gen-par-r 2>r ." =" gen-wrapped-void 2r> ;
367:
368: : gen-wrapped-func ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
369: gen-wrapped-a ;
370:
371: create gen-wrapped-types
372: ' gen-wrapped-n ,
373: ' gen-wrapped-a ,
374: ' gen-wrapped-d ,
375: ' gen-wrapped-r ,
376: ' gen-wrapped-func ,
377: ' gen-wrapped-void ,
378:
379: : gen-wrapped-stmt ( pars c-name fp-change1 sp-change1 ret -- fp-change sp-change )
380: cells gen-wrapped-types + @ execute ;
381:
382: : wrapper-function-name ( addr -- c-addr u )
383: \ addr points to the return type index of a c-function descriptor
384: count { r-type } count { d: pars }
385: pars + count { d: c-name }
386: s" gforth_c_" { d: prefix }
387: prefix nip c-name nip + pars nip + 3 + { u }
388: u allocate throw { c-addr }
389: c-addr u
390: prefix front-string c-name front-string '_ front-char
391: pars bounds u+do
392: i c@ type-letter front-char
393: loop
394: '_ front-char r-type type-letter front-char assert( dup 0= )
395: 2drop c-addr u ;
396:
397: : gen-wrapper-function ( addr -- )
398: \ addr points to the return type index of a c-function descriptor
399: dup { descriptor }
400: count { ret } count 2dup { d: pars } chars + count { d: c-name }
401: ." void " descriptor wrapper-function-name 2dup type drop free throw
402: .\" (void)\n"
403: .\" {\n Cell MAYBE_UNUSED *sp = gforth_SP;\n Float MAYBE_UNUSED *fp = gforth_FP;\n "
404: pars c-name 2over count-stacks ret gen-wrapped-stmt .\" ;\n"
405: ?dup-if
406: ." gforth_SP = sp+" .nb .\" ;\n"
407: endif
408: ?dup-if
409: ." gforth_FP = fp+" .nb .\" ;\n"
410: endif
411: .\" }\n" ;
412:
413: : tempdir ( -- c-addr u )
414: s" TMPDIR" getenv dup 0= if
415: 2drop s" /tmp"
416: then ;
417:
418: : gen-filename ( x -- c-addr u )
419: \ generates a filename without extension for lib-handle-addr X
420: 0 <<# ['] #s $10 base-execute #>
421: tempdir s" /gforth-c-" s+ 2swap append #>> ;
422:
423: : init-c-source-file ( -- )
424: c-source-file-id @ 0= if
425: here 0 , dup lib-handle-addr ! gen-filename 2dup lib-filename 2!
426: s" .c" s+ 2dup w/o create-file throw dup c-source-file-id !
427: ['] print-c-prefix-lines swap outfile-execute
428: drop free throw
429: endif ;
430:
431: : c-source-file ( -- file-id )
432: c-source-file-id @ assert( dup ) ;
433:
434: DEFER compile-wrapper-function
435: :NONAME ( -- )
436: c-source-file close-file throw
437: 0 c-source-file-id !
438: [ s" libtool --silent --mode=link gcc -module -I "
439: s" includedir" getenv append s" -rpath " append ] sliteral
440: tempdir s+ s" -O -c " append lib-filename 2@ append s" .c -o " append
441: lib-filename 2@ append s" .la" append ( c-addr u )
442: \ s" gcc -fPIC -shared -Wl,-soname," lib-filename 2@ s+
443: \ s" .so.1 -Wl,-export_dynamic -o " append lib-filename 2@ append
444: \ [ s" .so.1 -O -I " s" includedir" getenv append s" " append ] sliteral
445: \ append lib-filename 2@ append s" .c" append ( c-addr u )
446: ~~ 2dup type 2dup system drop free throw
447: $? abort" compiler generated error" \ !! call dlerror
448: tempdir s" /.libs/" s+ lib-filename 2@ append s" .so.0" append
449: 2dup type
450: 2dup open-lib dup 0= abort" open-lib failed" \ !! call dlerror
451: ( lib-handle ) lib-handle-addr @ !
452: 2dup delete-file throw drop free throw
453: lib-filename 2@ s" .c" s+ 2dup delete-file throw drop free throw
454: lib-filename 2@ drop free throw 0 0 lib-filename 2! ; IS compile-wrapper-function
455: \ s" ar rcs xxx.a xxx.o" system
456: \ $? abort" ar generated error" ;
457:
458: : link-wrapper-function { cff -- sym }
459: cff cff-rtype wrapper-function-name { d: wrapper-name }
460: wrapper-name cff cff-lha @ @ assert( dup ) lib-sym dup 0= -&32 and throw
461: wrapper-name drop free throw ;
462:
463: : c-function-ft ( xt-defr xt-cfr "c-name" "{libcc-type}" "--" "libcc-type" -- )
464: \ build time/first time action for c-function
465: init-c-source-file
466: noname create 2, lib-handle-addr @ ,
467: parse-name { d: c-name }
468: here parse-function-types c-name string,
469: ['] gen-wrapper-function c-source-file outfile-execute
470: does> ( ... -- ... )
471: dup 2@ { xt-defer xt-cfr }
472: dup cff-lha @ @ 0= if
473: compile-wrapper-function
474: endif
475: link-wrapper-function xt-cfr >body !
476: xt-cfr xt-defer defer!
477: xt-cfr execute ;
478:
479: : c-function-rt ( -- )
480: \ run-time definition for c function; addr is the address where
481: \ the sym should be stored
482: noname create 0 ,
483: does> ( ... -- ... )
484: @ call-c ;
485:
486: : c-function ( "forth-name" "c-name" "@{type@}" "--" "type" -- ) \ gforth
487: \G Define a Forth word @i{forth-name}. @i{Forth-name} has the
488: \G specified stack effect and calls the C function @code{c-name}.
489: defer lastxt dup c-function-rt lastxt c-function-ft
490: lastxt swap defer! ;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to libcc.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth