1: \ libcc.fs foreign function interface implemented using a C compiler
2:
3: \ Copyright (C) 2006,2007,2008 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation, either version 3
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: \ What this implementation does is this: if it sees a declaration like
22:
23: \ \ something that tells it that the current library is libc
24: \ \c #include <unistd.h>
25: \ c-function dlseek lseek n d n -- d
26:
27: \ it genererates C code similar to the following:
28:
29: \ #include <gforth.h>
30: \ #include <unistd.h>
31: \
32: \ void gforth_c_lseek_ndn_d(void)
33: \ {
34: \ Cell *sp = gforth_SP;
35: \ Float *fp = gforth_FP;
36: \ long long result; /* longest type in C */
37: \ gforth_ll2d(lseek(sp[3],gforth_d2ll(sp[2],sp[1]),sp[0]),sp[3],sp[2]);
38: \ gforth_SP = sp+2;
39: \ }
40:
41: \ Then it compiles this code and dynamically links it into the Gforth
42: \ system (batching and caching are future work). It also dynamically
43: \ links lseek. Performing DLSEEK then puts the function pointer of
44: \ the function pointer of gforth_c_lseek_ndn_d on the stack and
45: \ calls CALL-C.
46:
47: \ ToDo:
48:
49: \ Batching, caching and lazy evaluation:
50:
51: \ Batching:
52:
53: \ New words are deferred, and the corresponding C functions are
54: \ collected in one file, until the first word is EXECUTEd; then the
55: \ file is compiled and linked into the system, and the word is
56: \ resolved.
57:
58: \ Caching:
59:
60: \ Instead of compiling all this stuff anew for every execution, we
61: \ keep the files around and have an index file containing the function
62: \ names and their corresponding .so files. If the needed wrapper name
63: \ is already present, it is just linked instead of generating the
64: \ wrapper again. This is all done by loading the index file(s?),
65: \ which define words for the wrappers in a separate wordlist.
66:
67: \ The files are built in .../lib/gforth/$VERSION/libcc/ or
68: \ ~/.gforth/libcc/$HOST/.
69:
70: \ other things to do:
71:
72: \ c-variable forth-name c-name
73: \ c-constant forth-name c-name
74:
75: \ Todo: conversion between function pointers and xts (both directions)
76:
77: \ taking an xt and turning it into a function pointer:
78:
79: \ e.g., assume we have the xt of + and want to create a C function int
80: \ gforth_callback_plus(int, int), and then pass the pointer to that
81: \ function:
82:
83: \ There should be Forth code like this:
84: \ ] + 0 (bye)
85: \ Assume that the start of this code is START
86:
87: \ Now, there should be a C function:
88:
89: \ int gforth_callback_plus(int p1, int p2)
90: \ {
91: \ Cell *sp = gforth_SP;
92: \ Float *fp = gforth_FP;
93: \ Float *fp = gforth_FP;
94: \ Address lp = gforth_LP;
95: \ sp -= 2;
96: \ sp[0] = p1;
97: \ sp[1] = p2;
98: \ gforth_engine(START, sp, rp, fp, lp);
99: \ sp += 1;
100: \ gforth_RP = rp;
101: \ gforth_SP = sp;
102: \ gforth_FP = fp;
103: \ gforth_LP = lp;
104: \ return sp[0];
105: \ }
106:
107: \ and the pointer to that function is the C function pointer for the XT of +.
108:
109: \ Future problems:
110: \ how to combine the Forth code generation with inlining
111: \ START is not a constant across executions (when caching the C files)
112: \ Solution: make START a variable, and store into it on startup with dlsym
113:
114: \ Syntax:
115: \ callback <rettype> <params> <paramtypes> -- <rettype>
116:
117:
118: \ data structures
119:
120: \ For every c-function, we have three words: two anonymous words
121: \ created by c-function-ft (first time) and c-function-rt (run-time),
122: \ and a named deferred word. The deferred word first points to the
123: \ first-time word, then to the run-time word; the run-time word calls
124: \ the c function.
125:
126: [ifundef] parse-name
127: ' parse-word alias parse-name
128: [then]
129: [ifundef] defer!
130: : defer! ( xt xt-deferred -- ) \ gforth defer-store
131: \G Changes the @code{defer}red word @var{xt-deferred} to execute @var{xt}.
132: >body [ has? rom [IF] ] @ [ [THEN] ] ! ;
133: [then]
134:
135: \ : delete-file 2drop 0 ;
136:
137: require struct.fs
138: require mkdir.fs
139:
140: \ c-function-ft word body:
141: struct
142: cell% field cff-cfr \ xt of c-function-rt word
143: cell% field cff-deferred \ xt of c-function deferred word
144: cell% field cff-lha \ address of the lib-handle for the lib that
145: \ contains the wrapper function of the word
146: char% field cff-rtype \ return type
147: char% field cff-np \ number of parameters
148: 1 0 field cff-ptypes \ #npar parameter types
149: \ counted string: c-name
150: end-struct cff%
151:
152: variable c-source-file-id \ contains the source file id of the current batch
153: 0 c-source-file-id !
154: variable lib-handle-addr \ points to the library handle of the current batch.
155: \ the library handle is 0 if the current
156: \ batch is not yet compiled.
157: here 0 , lib-handle-addr ! \ just make sure LIB-HANDLE always works
158: 2variable lib-filename \ filename without extension
159: 2variable lib-modulename \ basename of the file without extension
160: 2variable libcc-named-dir-v \ directory for named libcc wrapper libraries
161: 0 value libcc-path \ pointer to path of library directories
162:
163: defer replace-rpath ( c-addr1 u1 -- c-addr2 u2 )
164: ' noop is replace-rpath
165:
166: : .nb ( n -- )
167: 0 .r ;
168:
169: : const+ ( n1 "name" -- n2 )
170: dup constant 1+ ;
171:
172: : front-string { c-addr1 u1 c-addr2 u2 -- c-addr3 u3 }
173: \ insert string c-addr2 u2 in buffer c-addr1 u1; c-addr3 u3 is the
174: \ remainder of the buffer.
175: assert( u1 u2 u>= )
176: c-addr2 c-addr1 u2 move
177: c-addr1 u1 u2 /string ;
178:
179: : front-char { c-addr1 u1 c -- c-addr3 u2 }
180: \ insert c in buffer c-addr1 u1; c-addr3 u3 is the remainder of
181: \ the buffer.
182: assert( u1 0 u> )
183: c c-addr1 c!
184: c-addr1 u1 1 /string ;
185:
186: : s+ { addr1 u1 addr2 u2 -- addr u }
187: u1 u2 + allocate throw { addr }
188: addr1 addr u1 move
189: addr2 addr u1 + u2 move
190: addr u1 u2 +
191: ;
192:
193: : append { addr1 u1 addr2 u2 -- addr u }
194: addr1 u1 u2 + dup { u } resize throw { addr }
195: addr2 addr u1 + u2 move
196: addr u ;
197:
198: \ linked list stuff (should go elsewhere)
199:
200: struct
201: cell% field list-next
202: 1 0 field list-payload
203: end-struct list%
204:
205: : list-insert { node list -- }
206: list list-next @ node list-next !
207: node list list-next ! ;
208:
209: : list-append { node endlistp -- }
210: \ insert node at place pointed to by endlistp
211: node endlistp @ list-insert
212: node list-next endlistp ! ;
213:
214: : list-map ( ... list xt -- ... )
215: \ xt ( ... node -- ... )
216: { xt } begin { node }
217: node while
218: node xt execute
219: node list-next @
220: repeat ;
221:
222: 2variable c-libs \ library names in a string (without "lib")
223:
224: : add-lib ( c-addr u -- ) \ gforth
225: \G Add library lib@i{string} to the list of libraries, where
226: \G @i{string} is represented by @i{c-addr u}.
227: c-libs 2@ d0= IF 0 allocate throw 0 c-libs 2! THEN
228: c-libs 2@ s" -l" append 2swap append c-libs 2! ;
229:
230: : add-libpath ( c-addr u -- ) \ gforth
231: \G Add path @i{string} to the list of library search pathes, where
232: \G @i{string} is represented by @i{c-addr u}.
233: c-libs 2@ d0= IF 0 allocate throw 0 c-libs 2! THEN
234: c-libs 2@ s" -L" append 2swap append c-libs 2! ;
235:
236: \ C prefix lines
237:
238: \ linked list of longcstrings: [ link | count-cell | characters ]
239:
240: list%
241: cell% field c-prefix-count
242: 1 0 field c-prefix-chars
243: end-struct c-prefix%
244:
245: variable c-prefix-lines 0 c-prefix-lines !
246: variable c-prefix-lines-end c-prefix-lines c-prefix-lines-end !
247:
248: : print-c-prefix-line ( node -- )
249: dup c-prefix-chars swap c-prefix-count @ type cr ;
250:
251: : print-c-prefix-lines ( -- )
252: c-prefix-lines @ ['] print-c-prefix-line list-map ;
253:
254: : save-c-prefix-line ( c-addr u -- )
255: c-source-file-id @ ?dup-if
256: >r 2dup r> write-line throw
257: then
258: align here 0 , c-prefix-lines-end list-append ( c-addr u )
259: longstring, ;
260:
261: : \c ( "rest-of-line" -- ) \ gforth backslash-c
262: \G One line of C declarations for the C interface
263: -1 parse save-c-prefix-line ;
264:
265: s" #include <gforth/" version-string s+ s" /libcc.h>" append ( c-addr u )
266: 2dup save-c-prefix-line drop free throw
267:
268: \ Types (for parsing)
269:
270: wordlist constant libcc-types
271:
272: get-current libcc-types set-current
273:
274: \ index values
275: -1
276: const+ -- \ end of arguments
277: const+ n \ integer cell
278: const+ a \ address cell
279: const+ d \ double
280: const+ r \ float
281: const+ func \ C function pointer
282: const+ void
283: drop
284:
285: set-current
286:
287: : parse-libcc-type ( "libcc-type" -- u )
288: parse-name libcc-types search-wordlist 0= -13 and throw execute ;
289:
290: : parse-function-types ( "{libcc-type}" "--" "libcc-type" -- )
291: here 2 chars allot here begin
292: parse-libcc-type dup 0>= while
293: c,
294: repeat
295: drop here swap - over char+ c!
296: parse-libcc-type dup 0< -32 and throw swap c! ;
297:
298: : type-letter ( n -- c )
299: chars s" nadrfv" drop + c@ ;
300:
301: \ count-stacks
302:
303: : count-stacks-n ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
304: 1+ ;
305:
306: : count-stacks-a ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
307: 1+ ;
308:
309: : count-stacks-d ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
310: 2 + ;
311:
312: : count-stacks-r ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
313: swap 1+ swap ;
314:
315: : count-stacks-func ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
316: 1+ ;
317:
318: : count-stacks-void ( fp-change1 sp-change1 -- fp-change2 sp-change2 )
319: ;
320:
321: create count-stacks-types
322: ' count-stacks-n ,
323: ' count-stacks-a ,
324: ' count-stacks-d ,
325: ' count-stacks-r ,
326: ' count-stacks-func ,
327: ' count-stacks-void ,
328:
329: : count-stacks ( pars -- fp-change sp-change )
330: \ pars is an addr u pair
331: 0 0 2swap over + swap u+do
332: i c@ cells count-stacks-types + @ execute
333: loop ;
334:
335: \ gen-pars
336:
337: : gen-par-n ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
338: ." sp[" 1- dup .nb ." ]" ;
339:
340: : gen-par-a ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
341: ." (void *)(" gen-par-n ." )" ;
342:
343: : gen-par-d ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
344: ." gforth_d2ll(" gen-par-n ." ," gen-par-n ." )" ;
345:
346: : gen-par-r ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
347: swap 1- tuck ." fp[" .nb ." ]" ;
348:
349: : gen-par-func ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
350: gen-par-a ;
351:
352: : gen-par-void ( fp-depth1 sp-depth1 -- fp-depth2 sp-depth2 )
353: -32 throw ;
354:
355: create gen-par-types
356: ' gen-par-n ,
357: ' gen-par-a ,
358: ' gen-par-d ,
359: ' gen-par-r ,
360: ' gen-par-func ,
361: ' gen-par-void ,
362:
363: : gen-par ( fp-depth1 sp-depth1 partype -- fp-depth2 sp-depth2 )
364: cells gen-par-types + @ execute ;
365:
366: \ the call itself
367:
368: : gen-wrapped-call { d: pars d: c-name fp-change1 sp-change1 -- }
369: c-name type ." ("
370: fp-change1 sp-change1 pars over + swap u+do
371: i c@ gen-par
372: i 1+ i' < if
373: ." ,"
374: endif
375: loop
376: 2drop ." )" ;
377:
378: \ calls for various kinds of return values
379:
380: : gen-wrapped-void ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
381: 2dup 2>r gen-wrapped-call 2r> ;
382:
383: : gen-wrapped-n ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
384: 2dup gen-par-n 2>r ." =" gen-wrapped-call 2r> ;
385:
386: : gen-wrapped-a ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
387: 2dup gen-par-n 2>r ." =(Cell)" gen-wrapped-call 2r> ;
388:
389: : gen-wrapped-d ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
390: ." gforth_ll2d(" gen-wrapped-void
391: ." ," gen-par-n ." ," gen-par-n ." )" ;
392:
393: : gen-wrapped-r ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
394: 2dup gen-par-r 2>r ." =" gen-wrapped-call 2r> ;
395:
396: : gen-wrapped-func ( pars c-name fp-change1 sp-change1 -- fp-change sp-change )
397: gen-wrapped-a ;
398:
399: create gen-wrapped-types
400: ' gen-wrapped-n ,
401: ' gen-wrapped-a ,
402: ' gen-wrapped-d ,
403: ' gen-wrapped-r ,
404: ' gen-wrapped-func ,
405: ' gen-wrapped-void ,
406:
407: : gen-wrapped-stmt ( pars c-name fp-change1 sp-change1 ret -- fp-change sp-change )
408: cells gen-wrapped-types + @ execute ;
409:
410: : wrapper-function-name ( addr -- c-addr u )
411: \ addr points to the return type index of a c-function descriptor
412: count { r-type } count { d: pars }
413: pars + count { d: c-name }
414: s" gforth_c_" { d: prefix }
415: prefix nip c-name nip + pars nip + 3 + { u }
416: u allocate throw { c-addr }
417: c-addr u
418: prefix front-string c-name front-string '_ front-char
419: pars bounds u+do
420: i c@ type-letter front-char
421: loop
422: '_ front-char r-type type-letter front-char assert( dup 0= )
423: 2drop c-addr u ;
424:
425: : gen-wrapper-function ( addr -- )
426: \ addr points to the return type index of a c-function descriptor
427: dup { descriptor }
428: count { ret } count 2dup { d: pars } chars + count { d: c-name }
429: ." void " lib-modulename 2@ type ." _LTX_" descriptor wrapper-function-name 2dup type drop free throw
430: .\" (GFORTH_ARGS)\n"
431: .\" {\n Cell MAYBE_UNUSED *sp = gforth_SP;\n Float MAYBE_UNUSED *fp = gforth_FP;\n "
432: pars c-name 2over count-stacks ret gen-wrapped-stmt .\" ;\n"
433: ?dup-if
434: ." gforth_SP = sp+" .nb .\" ;\n"
435: endif
436: ?dup-if
437: ." gforth_FP = fp+" .nb .\" ;\n"
438: endif
439: .\" }\n" ;
440:
441: : scan-back { c-addr u1 c -- c-addr u2 }
442: \ the last occurence of c in c-addr u1 is at u2-1; if it does not
443: \ occur, u2=0.
444: c-addr 1- c-addr u1 + 1- u-do
445: i c@ c = if
446: c-addr i over - 1+ unloop exit endif
447: 1 -loop
448: c-addr 0 ;
449:
450: : dirname ( c-addr1 u1 -- c-addr2 u2 )
451: \ directory name of the file name c-addr1 u1, including the final "/".
452: '/ scan-back ;
453:
454: : basename ( c-addr1 u1 -- c-addr2 u2 )
455: \ file name without directory component
456: 2dup dirname nip /string ;
457:
458: : gen-filename ( x -- c-addr u )
459: \ generates a file basename for lib-handle-addr X
460: 0 <<# ['] #s $10 base-execute #>
461: s" gforth_c_" 2swap s+ #>> ;
462:
463: : libcc-named-dir ( -- c-addr u )
464: libcc-named-dir-v 2@ ;
465:
466: : libcc-tmp-dir ( -- c-addr u )
467: s" ~/.gforth/libcc-tmp/" ;
468:
469: : prepend-dirname ( c-addr1 u1 c-addr2 u2 -- c-addr3 u3 )
470: 2over s+ 2swap drop free throw ;
471:
472: : open-wrappers ( -- addr|0 )
473: lib-filename 2@ s" .la" s+
474: 2dup libcc-named-dir string-prefix? if ( c-addr u )
475: \ see if we can open it in the path
476: libcc-named-dir nip /string
477: libcc-path open-path-file if
478: 0 exit endif
479: ( wfile-id c-addr2 u2 ) rot close-file throw save-mem ( c-addr2 u2 )
480: endif
481: \ 2dup cr type
482: 2dup open-lib >r
483: drop free throw r> ;
484:
485: : c-library-name-setup ( c-addr u -- )
486: assert( c-source-file-id @ 0= )
487: { d: filename }
488: here 0 , lib-handle-addr ! filename lib-filename 2!
489: filename basename lib-modulename 2! ;
490:
491: : c-library-name-create ( -- )
492: lib-filename 2@ s" .c" s+ 2dup w/o create-file throw
493: dup c-source-file-id !
494: ['] print-c-prefix-lines swap outfile-execute
495: drop free throw ;
496:
497: : c-named-library-name ( c-addr u -- )
498: \ set up filenames for a (possibly new) library; c-addr u is the
499: \ basename of the library
500: libcc-named-dir prepend-dirname c-library-name-setup
501: open-wrappers dup if
502: lib-handle-addr @ !
503: else
504: libcc-named-dir $1ff mkdir-parents drop
505: drop c-library-name-create
506: endif ;
507:
508: : c-tmp-library-name ( c-addr u -- )
509: \ set up filenames for a new library; c-addr u is the basename of
510: \ the library
511: libcc-tmp-dir 2dup $1ff mkdir-parents drop
512: prepend-dirname c-library-name-setup c-library-name-create ;
513:
514: : lib-handle ( -- addr )
515: lib-handle-addr @ @ ;
516:
517: : init-c-source-file ( -- )
518: lib-handle 0= if
519: c-source-file-id @ 0= if
520: here gen-filename c-tmp-library-name
521: endif
522: endif ;
523:
524: : c-source-file ( -- file-id )
525: c-source-file-id @ assert( dup ) ;
526:
527: : notype-execute ( ... xt -- ... )
528: what's type { oldtype } try
529: ['] 2drop is type execute 0
530: restore
531: oldtype is type
532: endtry
533: throw ;
534:
535: : c-source-file-execute ( ... xt -- ... )
536: \ direct the output of xt to c-source-file, or nothing
537: lib-handle if
538: notype-execute
539: else
540: c-source-file outfile-execute
541: endif ;
542:
543: : .lib-error ( -- )
544: [ifdef] lib-error
545: ['] cr stderr outfile-execute
546: lib-error ['] type stderr outfile-execute
547: [then] ;
548:
549: DEFER compile-wrapper-function ( -- )
550: : compile-wrapper-function1 ( -- )
551: lib-handle 0= if
552: c-source-file close-file throw
553: 0 c-source-file-id !
554: [ libtool-command s" --silent --mode=compile " s+
555: libtool-cc append s" -I '" append
556: s" includedir" getenv append s" '" append ] sliteral
557: s" -O -c " s+ lib-filename 2@ append s" .c -o " append
558: lib-filename 2@ append s" .lo" append ( c-addr u )
559: \ 2dup type cr
560: 2dup system drop free throw $? abort" libtool compile failed"
561: [ libtool-command s" --silent --mode=link " s+
562: libtool-cc append libtool-flags append s" -module -rpath " s+ ] sliteral
563: lib-filename 2@ dirname replace-rpath s+ s" " append
564: lib-filename 2@ append s" .lo -o " append
565: lib-filename 2@ append s" .la" append ( c-addr u )
566: c-libs 2@ append
567: \ 2dup type cr
568: 2dup system drop free throw $? abort" libtool link failed"
569: open-wrappers dup 0= if
570: .lib-error true abort" open-lib failed"
571: endif
572: ( lib-handle ) lib-handle-addr @ !
573: endif
574: lib-filename 2@ drop free throw 0 0 lib-filename 2! ;
575: ' compile-wrapper-function1 IS compile-wrapper-function
576: \ s" ar rcs xxx.a xxx.o" system
577: \ $? abort" ar generated error" ;
578:
579: : link-wrapper-function { cff -- sym }
580: cff cff-rtype wrapper-function-name { d: wrapper-name }
581: wrapper-name cff cff-lha @ @ assert( dup ) lib-sym dup 0= if
582: .lib-error -&32 throw
583: endif
584: wrapper-name drop free throw ;
585:
586: : c-function-ft ( xt-defr xt-cfr "c-name" "{libcc-type}" "--" "libcc-type" -- )
587: \ build time/first time action for c-function
588: init-c-source-file
589: noname create 2, lib-handle-addr @ ,
590: parse-name { d: c-name }
591: here parse-function-types c-name string,
592: ['] gen-wrapper-function c-source-file-execute
593: does> ( ... -- ... )
594: dup 2@ { xt-defer xt-cfr }
595: dup cff-lha @ @ 0= if
596: compile-wrapper-function
597: endif
598: link-wrapper-function xt-cfr >body !
599: xt-cfr xt-defer defer!
600: xt-cfr execute ;
601:
602: : c-function-rt ( -- )
603: \ run-time definition for c function; addr is the address where
604: \ the sym should be stored
605: noname create 0 ,
606: does> ( ... -- ... )
607: @ call-c ;
608:
609: : c-function ( "forth-name" "c-name" "@{type@}" "--" "type" -- ) \ gforth
610: \G Define a Forth word @i{forth-name}. @i{Forth-name} has the
611: \G specified stack effect and calls the C function @code{c-name}.
612: defer lastxt dup c-function-rt lastxt c-function-ft
613: lastxt swap defer! ;
614:
615: : clear-libs ( -- ) \ gforth
616: \G Clear the list of libs
617: c-source-file-id @ if
618: compile-wrapper-function
619: endif
620: 0. c-libs 2! ;
621: clear-libs
622:
623: : c-library-incomplete ( -- )
624: true abort" Called function of unfinished named C library" ;
625:
626: : c-library-name ( c-addr u -- ) \ gforth
627: \G Start a C library interface with name @i{c-addr u}.
628: clear-libs
629: ['] c-library-incomplete is compile-wrapper-function
630: c-named-library-name ;
631:
632: : c-library ( "name" -- ) \ gforth
633: \G Parsing version of @code{c-library-name}
634: parse-name save-mem c-library-name ;
635:
636: : end-c-library ( -- ) \ gforth
637: \G Finish and (if necessary) build the latest C library interface.
638: ['] compile-wrapper-function1 is compile-wrapper-function
639: compile-wrapper-function1 ;
640:
641: : init-libcc ( -- )
642: s" ~/.gforth/libcc-named/" libcc-named-dir-v 2!
643: [IFDEF] make-path
644: make-path to libcc-path
645: libcc-named-dir libcc-path also-path
646: [ s" libccdir" getenv ] sliteral libcc-path also-path
647: [THEN]
648: ;
649:
650: init-libcc
651:
652: :noname ( -- )
653: defers 'cold
654: init-libcc ;
655: is 'cold
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>