Return to toolsext.fs CVS log

Up to [gforth] / gforth / kernel

Provided [defined] and [undefined]
Changed stack comments in toolsext.fs

    1: \ Copyright (C) 1995,1998,2000 Free Software Foundation, Inc.
    2: 
    3: \ This file is part of Gforth.
    4: 
    5: \ Gforth is free software; you can redistribute it and/or
    6: \ modify it under the terms of the GNU General Public License
    7: \ as published by the Free Software Foundation; either version 2
    8: \ of the License, or (at your option) any later version.
    9: 
   10: \ This program is distributed in the hope that it will be useful,
   11: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   12: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   13: \ GNU General Public License for more details.
   14: 
   15: \ You should have received a copy of the GNU General Public License
   16: \ along with this program; if not, write to the Free Software
   17: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   18: 
   19: Warnings off
   20: 
   21: Variable countif
   22: 
   23: : dummy ;  immediate
   24: : >exec  >r ; restrict ( :-)
   25: : scanIF   f83find  dup 0=  IF  drop ['] dummy >head-noprim  THEN  ;
   26: 
   27: Create [struct]-search    ' scanIF A,  ' (reveal) A,  ' drop A, ' drop A,
   28: Create [struct]-voc       [struct]-search A,
   29:                           NIL A,       NIL A,       NIL A,
   30: 
   31: : ?if  countif @ 0<
   32:   IF  [ [struct]-voc 3 cells + ] ALiteral @ lookup !  THEN ;
   33: 
   34: UNLOCK  Tlast @ TNIL Tlast !  LOCK
   35: \ last @  0 last !
   36: 
   37: : [IF]
   38:   1 countif +! ?if ;       immediate
   39: : [THEN]
   40:   -1 countif +! ?if ;       immediate
   41: : [ELSE]
   42:   postpone [THEN] postpone [IF] ;
   43:                                      immediate
   44: ' [IF]   Alias [IFDEF]               immediate
   45: ' [IF]   Alias [IFUNDEF]             immediate
   46: ' [THEN] Alias [ENDIF]               immediate
   47: ' [IF]   Alias [BEGIN]               immediate
   48: ' [IF]   Alias [WHILE]               immediate
   49: ' [THEN] Alias [UNTIL]               immediate
   50: ' [THEN] Alias [AGAIN]               immediate
   51: ' [IF]   Alias [DO]                  immediate
   52: ' [IF]   Alias [?DO]                 immediate
   53: ' [THEN] Alias [LOOP]                immediate
   54: ' [THEN] Alias [+LOOP]               immediate
   55: : [REPEAT]  postpone [AGAIN] postpone [THEN] ;
   56:                                      immediate
   57: ' ( Alias (                          immediate ( keep fontify happy)
   58: ' \ Alias \                          immediate
   59: 
   60: UNLOCK Tlast @ swap Tlast ! LOCK
   61: \ last @ swap last !
   62: 1 cells - [struct]-voc cell+ !
   63: 
   64: \ Interpretative Structuren                            30apr92py
   65: 
   66: : [defined] ( "<spaces>name" -- flag )   bl word find nip 0<> ; immediate
   67:   \G returns true if name is found in current search order
   68: : [undefined] ( "<spaces>name" -- flag ) postpone [defined] 0= ; immediate
   69:   \G returns false if name is found in current search order
   70: 
   71: : [IF] ( flag -- ) \ tools-ext bracket-if
   72:   \G If flag is @code{TRUE} do nothing (and therefore
   73:   \G execute subsequent words as normal). If flag is @code{FALSE},
   74:   \G parse and discard words from the parse
   75:   \G area (refilling it if necessary using
   76:   \G @code{REFILL}) including nested instances of @code{[IF]}..
   77:   \G @code{[ELSE]}.. @code{[THEN]} and @code{[IF]}.. @code{[THEN]}
   78:   \G until the balancing @code{[ELSE]} or @code{[THEN]} has been
   79:   \G parsed and discarded. Immediate word.
   80:        0= IF  countif off
   81:               lookup @ [ [struct]-voc 3 cells + ] ALiteral !
   82: 	      [struct]-voc lookup !
   83:           THEN ;                                      immediate
   84: 
   85: : [IFDEF] ( "<spaces>name" -- ) \ gforth bracket-if-def
   86:   \G If name is found in the current search-order, behave like
   87:   \G @code{[IF]} with a @code{TRUE} flag, otherwise behave like
   88:   \G @code{[IF]} with a @code{FALSE} flag. Immediate word.
   89:   postpone [defined]    postpone [IF] ;                 immediate
   90: 
   91: : [IFUNDEF] ( "<spaces>name" -- ) \ gforth bracket-if-un-def
   92:   \G If name is not found in the current search-order, behave like
   93:   \G @code{[IF]} with a @code{TRUE} flag, otherwise behave like
   94:   \G @code{[IF]} with a @code{FALSE} flag. Immediate word.
   95:   postpone [defined] 0= postpone [IF] ;                 immediate
   96: 
   97: : [ELSE]  ( -- ) \ tools-ext bracket-else
   98:   \G Parse and discard words from the parse
   99:   \G area (refilling it if necessary using
  100:   \G @code{REFILL}) including nested instances of @code{[IF]}..
  101:   \G @code{[ELSE]}.. @code{[THEN]} and @code{[IF]}.. @code{[THEN]}
  102:   \G until the balancing @code{[THEN]} has been parsed and discarded.
  103:   \G @code{[ELSE]} only gets executed if the balancing @code{[IF]}
  104:   \G was @code{TRUE}; if it was @code{FALSE}, @code{[IF]} would
  105:   \G have parsed and discarded the @code{[ELSE]}, leaving the
  106:   \G subsequent words to be executed as normal.
  107:   \G Immediate word.
  108:   0 postpone [IF] ;                                   immediate
  109: 
  110: : [THEN] ( -- ) \ tools-ext bracket-then
  111:   \G Do nothing; used as a marker for other words to parse
  112:   \G and discard up to. Immediate word.
  113:   ;                                                   immediate
  114: 
  115: : [ENDIF] ( -- ) \ gforth bracket-end-if
  116:   \G Do nothing; synonym for @code{[THEN]}
  117:   ;                                                   immediate
  118: 
  119: \ Structs for interpreter                              28nov92py
  120: 
  121: User (i)
  122: 
  123: : [DO]  ( n-limit n-index -- ) \ gforth bracket-do
  124:   >in @ -rot
  125:   DO   I (i) ! dup >r >in ! interpret r> swap +LOOP  drop ;
  126:                                                       immediate
  127: 
  128: : [?DO] ( n-limit n-index -- ) \ gforth bracket-question-do
  129:   2dup = IF 2drop postpone [ELSE] ELSE postpone [DO] THEN ;
  130:                                                       immediate
  131: 
  132: : [+LOOP] ( n -- ) \ gforth bracket-question-plus-loop
  133:   rdrop rdrop ;                                       immediate
  134: 
  135: : [LOOP] ( -- ) \ gforth bracket-loop
  136:   1 rdrop rdrop ;                                     immediate
  137: 
  138: : [FOR] ( n -- ) \ gforth bracket-for
  139:   0 swap postpone [DO] ;                              immediate
  140: 
  141: : [NEXT] ( n -- ) \ gforth bracket-next
  142:   -1 rdrop rdrop ;                                    immediate
  143: 
  144: :noname (i) @ ;
  145: :noname (i) @ postpone Literal ;
  146: interpret/compile: [I] ( -- n ) \ gforth bracket-i
  147: 
  148: : [BEGIN] ( -- ) \ gforth bracket-begin
  149:   >in @ >r BEGIN r@ >in ! interpret UNTIL rdrop ;     immediate
  150: 
  151: ' [+LOOP]  Alias [UNTIL] ( flag -- ) \ gforth bracket-until
  152:                                                       immediate
  153: 
  154: : [REPEAT]  ( -- ) \ gforth bracket-repeat
  155:   false rdrop rdrop ;                                 immediate
  156: 
  157: ' [REPEAT] Alias [AGAIN] ( -- ) \ gforth bracket-again
  158:                                                       immediate
  159: 
  160: : [WHILE]   ( flag -- ) \ gforth bracket-while
  161:   0= IF   postpone [ELSE] true rdrop rdrop 1 countif +!  THEN ;
  162:                                                       immediate
  163: 
  164: Warnings on