1: \ require.fs
2:
3: \ Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: \ Now: Kernel Module, Reloadable
22:
23: create included-files 0 , 0 , ( pointer to and count of included files )
24: \ note: these names must not contain a "/" or "\"; otherwise a part of
25: \ that name might be used when expanding "./" (see expandtopic).
26: here ," *a file*" dup c@ swap 1 + swap
27: here ," *a block*" dup c@ swap 1 + swap
28: here ," *evaluated string*" dup c@ swap 1 + swap
29: here ," *the terminal*" dup c@ swap 1 + swap
30: , A, , A, , A, , A, here 8 cells -
31: create image-included-files 4 , A, ( pointer to and count of included
32: \ files ) included-files points to ALLOCATEd space, while
33: \ image-included-files points to ALLOTed objects, so it survives a
34: \ save-system
35:
36: : sourcefilename ( -- c-addr u ) \ gforth
37: \G The name of the source file which is currently the input
38: \G source. The result is valid only while the file is being
39: \G loaded. If the current input source is no (stream) file, the
40: \G result is undefined. In Gforth, the result is valid during the
41: \G whole seesion (but not across @code{savesystem} etc.).
42: loadfilename# @ loadfilename#>str ;
43:
44: : sourceline# ( -- u ) \ gforth sourceline-number
45: \G The line number of the line that is currently being interpreted
46: \G from a (stream) file. The first line has the number 1. If the
47: \G current input source is not a (stream) file, the result is
48: \G undefined.
49: loadline @ ;
50:
51: : init-included-files ( -- ) \ gforth-internal
52: image-included-files 2@ 2* cells save-mem drop ( addr )
53: image-included-files 2@ nip included-files 2! ;
54:
55: : included? ( c-addr u -- f ) \ gforth
56: \G True only if the file @var{c-addr u} is in the list of earlier
57: \G included files. If the file has been loaded, it may have been
58: \G specified as, say, @file{foo.fs} and found somewhere on the
59: \G Forth search path. To return @code{true} from @code{included?},
60: \G you must specify the exact path to the file, even if that is
61: \G @file{./foo.fs}
62: included-files 2@ 0
63: ?do ( c-addr u addr )
64: dup >r 2@ 2over compare 0=
65: if
66: 2drop rdrop unloop
67: true EXIT
68: then
69: r> cell+ cell+
70: loop
71: 2drop drop false ;
72:
73: : add-included-file ( c-addr u -- ) \ gforth
74: \G add name c-addr u to included-files
75: included-files 2@ 2* cells 2 cells extend-mem
76: 2/ cell / included-files 2!
77: 2! ;
78:
79: : included1 ( i*x file-id c-addr u -- j*x ) \ gforth
80: \G Include the file file-id with the name given by @var{c-addr u}.
81: loadfilename# @ >r
82: save-mem add-included-file ( file-id )
83: included-files 2@ nip 1- loadfilename# !
84: ['] include-file2 catch
85: r> loadfilename# !
86: throw ;
87:
88: : included ( i*x c-addr u -- j*x ) \ file
89: \G @code{include-file} the file whose name is given by the string
90: \G @var{c-addr u}.
91: open-fpath-file throw included1 ;
92:
93: : required ( i*x addr u -- j*x ) \ gforth
94: \G @code{include-file} the file with the name given by @var{addr
95: \G u}, if it is not @code{included} (or @code{required})
96: \G already. Currently this works by comparing the name of the file
97: \G (with path) against the names of earlier included files.
98: \ however, it may be better to fstat the file,
99: \ and compare the device and inode. The advantages would be: no
100: \ problems with several paths to the same file (e.g., due to
101: \ links) and we would catch files included with include-file and
102: \ write a require-file.
103: open-fpath-file throw 2dup included?
104: if
105: 2drop close-file throw
106: else
107: included1
108: then ;
109:
110: \ INCLUDE 9may93jaw
111:
112: : include ( ... "file" -- ... ) \ gforth
113: \G @code{include-file} the file @var{file}.
114: name included ;
115:
116: : require ( ... "file" -- ... ) \ gforth
117: \G @code{include-file} @var{file} only if it is not included already.
118: name required ;
119:
120: \ : \I
121: \ here
122: \ 0 word count
123: \ string,
124: \ needsrcs^ @ ! ;
125:
126: \ : .included ( -- ) \ gforth
127: \ \G list the names of the files that have been @code{included}
128: \ cr
129: \ needs^ @
130: \ BEGIN dup
131: \ WHILE dup cell+ count type cr
132: \ 5 spaces
133: \ dup cell+ count + aligned
134: \ @ dup IF count type ELSE drop THEN cr
135: \ @
136: \ REPEAT
137: \ drop ;
138:
139: \ : loadfilename#>str ( n -- adr len )
140: \ \ this converts the filenumber into the string
141: \ loadfilenamecount @ swap -
142: \ needs^ @
143: \ swap 0 ?DO dup 0= IF LEAVE THEN @ LOOP
144: \ dup IF cell+ count ELSE drop s" NOT FOUND" THEN ;
145:
146: : loadfilename#>str ( n -- adr len )
147: included-files 2@ drop swap 2* cells + 2@ ;
148:
149: : .strings ( addr u -- ) \ gforth
150: \G list the strings from an array of string descriptors at addr
151: \G with u entries, one per line.
152: 2* cells bounds ?DO
153: cr I 2@ type 2 cells +LOOP ;
154:
155: : .included ( -- ) \ gforth
156: \G list the names of the files that have been @code{included}
157: included-files 2@ .strings ;
158:
159: \ contains tools/newrequire.fs
160: \ \I $Id: require.fs,v 1.15 2000/09/11 20:56:39 anton Exp $
161:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>