File:  [gforth] / gforth / kernel / require.fs
Revision 1.11: download - view: text, annotated - select for diffs
Thu Aug 17 12:46:59 2000 UTC (21 years, 3 months ago) by anton
Branches: MAIN
CVS tags: HEAD
documentation changes
added path-allot and clear-path

    1: \ require.fs
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: \ Now: Kernel Module, Reloadable
   22: 
   23: create included-files 0 , 0 , ( pointer to and count of included files )
   24: \ here ," ./the terminal" dup c@ swap 1 + swap , A, here 2 cells -
   25: \ ./ is confusing for the search path stuff! There should be never a .
   26: \ in sourcefilename....
   27: here ," #terminal#" dup c@ swap 1 + swap , A, here 2 cells -
   28: create image-included-files  1 , A, ( pointer to and count of included files )
   29: \ included-files points to ALLOCATEd space, while image-included-files
   30: \ points to ALLOTed objects, so it survives a save-system
   31: 
   32: : loadfilename ( -- a-addr ) \ gforth-internal
   33:     \G @i{a-addr} @code{2@@} produces the current file name ( @i{c-addr u} )
   34:     included-files 2@ loadfilename# @ min 2* cells + ;
   35: 
   36: : sourcefilename ( -- c-addr u ) \ gforth
   37:     \G The name of the source file which is currently the input
   38:     \G source.  The result is valid only while the file is being
   39:     \G loaded.  If the current input source is no (stream) file, the
   40:     \G result is undefined.  In Gforth, the result is valid during the
   41:     \G whole seesion (but not across @code{savesystem} etc.).
   42:     loadfilename 2@ ;
   43: 
   44: : sourceline# ( -- u ) \ gforth		sourceline-number
   45:     \G The line number of the line that is currently being interpreted
   46:     \G from a (stream) file. The first line has the number 1. If the
   47:     \G current input source is not a (stream) file, the result is
   48:     \G undefined.
   49:     loadline @ ;
   50: 
   51: : init-included-files ( -- ) \ gforth-internal
   52:     image-included-files 2@ 2* cells save-mem drop ( addr )
   53:     image-included-files 2@ nip included-files 2! ;
   54: 
   55: : included? ( c-addr u -- f ) \ gforth
   56:     \G True only if the file @var{c-addr u} is in the list of earlier
   57:     \G included files. If the file has been loaded, it may have been
   58:     \G specified as, say, @file{foo.fs} and found somewhere on the
   59:     \G Forth search path. To return @code{true} from @code{included?},
   60:     \G you must specify the exact path to the file, even if that is
   61:     \G @file{./foo.fs}
   62:     included-files 2@ 0
   63:     ?do ( c-addr u addr )
   64: 	dup >r 2@ 2over compare 0=
   65: 	if
   66: 	    2drop rdrop unloop
   67: 	    true EXIT
   68: 	then
   69: 	r> cell+ cell+
   70:     loop
   71:     2drop drop false ;
   72: 
   73: : add-included-file ( c-addr u -- ) \ gforth
   74:     \G add name c-addr u to included-files
   75:     included-files 2@ 2* cells 2 cells extend-mem
   76:     2/ cell / included-files 2!
   77:     2! ;
   78: 
   79: : included1 ( i*x file-id c-addr u -- j*x ) \ gforth
   80:     \G Include the file file-id with the name given by @var{c-addr u}.
   81:     loadfilename# @ >r
   82:     save-mem add-included-file ( file-id )
   83:     included-files 2@ nip 1- loadfilename# !
   84:     ['] include-file catch
   85:     r> loadfilename# !
   86:     throw ;
   87:     
   88: : included ( i*x c-addr u -- j*x ) \ file
   89:     \G @code{include-file} the file whose name is given by the string
   90:     \G @var{c-addr u}.
   91:     open-fpath-file throw included1 ;
   92: 
   93: : required ( i*x addr u -- j*x ) \ gforth
   94:     \G @code{include-file} the file with the name given by @var{addr
   95:     \G u}, if it is not @code{included} (or @code{required})
   96:     \G already. Currently this works by comparing the name of the file
   97:     \G (with path) against the names of earlier included files.
   98:     \ however, it may be better to fstat the file,
   99:     \ and compare the device and inode. The advantages would be: no
  100:     \ problems with several paths to the same file (e.g., due to
  101:     \ links) and we would catch files included with include-file and
  102:     \ write a require-file.
  103:     open-fpath-file throw 2dup included?
  104:     if
  105: 	2drop close-file throw
  106:     else
  107: 	included1
  108:     then ;
  109: 
  110: \ INCLUDE                                               9may93jaw
  111: 
  112: : include  ( ... "file" -- ... ) \ gforth
  113:     \G @code{include-file} the file @var{file}.
  114:     name included ;
  115: 
  116: : require  ( ... "file" -- ... ) \ gforth
  117:     \G @code{include-file} @var{file} only if it is not included already.
  118:     name required ;
  119: 
  120: 0 [IF]
  121: : \I
  122:   here 
  123:   0 word count
  124:   string,
  125:   needsrcs^ @ ! ;
  126: 
  127: : .included ( -- ) \ gforth
  128:     \G list the names of the files that have been @code{included}
  129:   cr
  130:   needs^ @
  131:   BEGIN		dup 
  132:   WHILE		dup cell+ count type cr
  133: 		5 spaces
  134: 		dup cell+ count + aligned
  135: 		@ dup IF count type ELSE drop THEN cr
  136: 		@
  137:   REPEAT
  138:   drop ;
  139: 
  140: : loadfilename#>str ( n -- adr len )
  141: \ this converts the filenumber into the string
  142:   loadfilenamecount @ swap -
  143:   needs^ @
  144:   swap 0 ?DO dup 0= IF LEAVE THEN @ LOOP 
  145:   dup IF cell+ count ELSE drop s" NOT FOUND" THEN ;
  146: [THEN]
  147: 
  148: : loadfilename#>str ( n -- adr len )
  149:     included-files 2@ drop swap 2* cells + 2@ ;
  150: 
  151: : .included ( -- ) \ gforth
  152:     \G list the names of the files that have been @code{included}
  153:     included-files 2@ 2* cells bounds ?DO
  154: 	cr I 2@ type  2 cells +LOOP ;  
  155: 
  156: \ contains tools/newrequire.fs
  157: \ \I $Id: require.fs,v 1.11 2000/08/17 12:46:59 anton Exp $
  158: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>