1: \ Number IO
2:
3: \ Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: require ./io.fs
22:
23: : pad ( -- c-addr ) \ core-ext
24: \G @var{c-addr} is the address of a transient region that can be
25: \G used as temporary data storage. At least 84 characters of space
26: \G is available.
27: here word-pno-size + aligned ;
28:
29: \ hold <# #> sign # #s 25jan92py
30:
31: : hold ( char -- ) \ core
32: \G Used within @code{<#} and @code{#>}. Append the character
33: \G @var{char} to the pictured numeric output string.
34: -1 chars holdptr +!
35: holdptr @ dup holdbuf u< -&17 and throw
36: c! ;
37:
38: : <# ( -- ) \ core less-number-sign
39: \G Initialise/clear the pictured numeric output string.
40: holdbuf-end dup holdptr ! holdend ! ;
41:
42: : #> ( xd -- addr u ) \ core number-sign-greater
43: \G Complete the pictured numeric output string by
44: \G discarding xd and returning addr u; the address and length
45: \G of the formatted string. A Standard program may modify characters
46: \G within the string.
47: 2drop holdptr @ holdend @ over - ;
48:
49: : <<# ( -- ) \ gforth less-less-number-sign
50: \G Start a hold area that ends with @code{#>>}. Can be nested in
51: \G each other and in @code{<#}. Note: if you do not match up the
52: \G @code{<<#}s with @code{#>>}s, you will eventually run out of
53: \G hold area; you can reset the hold area to empty with @code{<#}.
54: holdend @ holdptr @ - hold
55: holdptr @ holdend ! ;
56:
57: : #>> ( -- ) \ gforth number-sign-greater-greater
58: \G Release the hold area started with @code{<<#}.
59: holdend @ dup holdbuf-end u>= -&11 and throw
60: count chars bounds holdptr ! holdend ! ;
61:
62: : sign ( n -- ) \ core
63: \G Used within @code{<#} and @code{#>}. If n (a @var{single} number)
64: \G is negative, append the display code for a minus sign to the pictured
65: \G numeric output string. Since the string is built up "backwards"
66: \G this is usually used immediately prior to @code{#>}, as shown in
67: \G the examples below.
68: 0< IF [char] - hold THEN ;
69:
70: : # ( ud1 -- ud2 ) \ core number-sign
71: \G Used within @code{<#} and @code{#>}. Add the next least-significant
72: \G digit to the pictured numeric output string. This is achieved by dividing ud1
73: \G by the number in @code{base} to leave quotient ud2 and remainder n; n
74: \G is converted to the appropriate display code (eg ASCII code) and appended
75: \G to the string. If the number has been fully converted, ud1 will be 0 and
76: \G @code{#} will append a "0" to the string.
77: base @ ud/mod rot 9 over <
78: IF
79: [ char A char 9 - 1- ] Literal +
80: THEN
81: [char] 0 + hold ;
82:
83: : #s ( ud -- 0 0 ) \ core number-sign-s
84: \G Used within @code{<#} and @code{#>}. Convert all remaining digits
85: \G using the same algorithm as for @code{#}. @code{#s} will convert
86: \G at least one digit. Therefore, if ud is 0, @code{#s} will append
87: \G a "0" to the pictured numeric output string.
88: BEGIN
89: # 2dup or 0=
90: UNTIL ;
91:
92: \ print numbers 07jun92py
93:
94: : d.r ( d n -- ) \ double d-dot-r
95: \G Display @var{d} right-aligned in a field @var{n} characters wide. If more than
96: \G @var{n} characters are needed to display the number, all digits are displayed.
97: \G If appropriate, @var{n} must include a character for a leading "-".
98: >r tuck dabs <<# #s rot sign #>
99: r> over - spaces type #>> ;
100:
101: : ud.r ( ud n -- ) \ gforth u-d-dot-r
102: \G Display @var{ud} right-aligned in a field @var{n} characters wide. If more than
103: \G @var{n} characters are needed to display the number, all digits are displayed.
104: >r <<# #s #> r> over - spaces type #>> ;
105:
106: : .r ( n1 n2 -- ) \ core-ext dot-r
107: \G Display @var{n1} right-aligned in a field @var{n2} characters wide. If more than
108: \G @var{n2} characters are needed to display the number, all digits are displayed.
109: \G If appropriate, @var{n2} must include a character for a leading "-".
110: >r s>d r> d.r ;
111:
112: : u.r ( u n -- ) \ core-ext u-dot-r
113: \G Display @var{u} right-aligned in a field @var{n} characters wide. If more than
114: \G @var{n} characters are needed to display the number, all digits are displayed.
115: 0 swap ud.r ;
116:
117: : d. ( d -- ) \ double d-dot
118: \G Display (the signed double number) @var{d} in free-format. followed by a space.
119: 0 d.r space ;
120:
121: : ud. ( ud -- ) \ gforth u-d-dot
122: \G Display (the signed double number) @var{ud} in free-format, followed by a space.
123: 0 ud.r space ;
124:
125: : . ( n -- ) \ core dot
126: \G Display (the signed single number) @var{n} in free-format, followed by a space.
127: s>d d. ;
128:
129: : u. ( u -- ) \ core u-dot
130: \G Display (the unsigned single number) @var{u} in free-format, followed by a space.
131: 0 ud. ;
132:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>