1: \ definitions needed for interpreter only
2:
3: \ Copyright (C) 1995-2000 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ \ Revision-Log
22:
23: \ put in seperate file 14sep97jaw
24:
25: \ \ input stream primitives 23feb93py
26:
27: require ./basics.fs \ bounds decimal hex ...
28: require ./io.fs \ type ...
29: require ./nio.fs \ . <# ...
30: require ./errore.fs \ .error ...
31: require kernel/version.fs \ version-string
32: require ./../chains.fs
33:
34: has? new-input 0= [IF]
35: : tib ( -- c-addr ) \ core-ext t-i-b
36: \G @i{c-addr} is the address of the Terminal Input Buffer.
37: \G OBSOLESCENT: @code{source} superceeds the function of this word.
38: >tib @ ;
39:
40: Defer source ( -- c-addr u ) \ core
41: \ used by dodefer:, must be defer
42: \G @i{c-addr} is the address of the input buffer and @i{u} is the
43: \G number of characters in it.
44:
45: : (source) ( -- c-addr u )
46: tib #tib @ ;
47: ' (source) IS source
48: [THEN]
49:
50: : (word) ( addr1 n1 char -- addr2 n2 )
51: dup >r skip 2dup r> scan nip - ;
52:
53: \ (word) should fold white spaces
54: \ this is what (parse-white) does
55:
56: \ word parse 23feb93py
57:
58: : sword ( char -- addr len ) \ gforth s-word
59: \G Parses like @code{word}, but the output is like @code{parse} output.
60: \G @xref{core-idef}.
61: \ this word was called PARSE-WORD until 0.3.0, but Open Firmware and
62: \ dpANS6 A.6.2.2008 have a word with that name that behaves
63: \ differently (like NAME).
64: source 2dup >r >r >in @ over min /string
65: rot dup bl = IF drop (parse-white) ELSE (word) THEN
66: 2dup + r> - 1+ r> min >in ! ;
67:
68: : word ( char "<chars>ccc<char>-- c-addr ) \ core
69: \G Skip leading delimiters. Parse @i{ccc}, delimited by
70: \G @i{char}, in the parse area. @i{c-addr} is the address of a
71: \G transient region containing the parsed string in
72: \G counted-string format. If the parse area was empty or
73: \G contained no characters other than delimiters, the resulting
74: \G string has zero length. A program may replace characters within
75: \G the counted string. OBSOLESCENT: the counted string has a
76: \G trailing space that is not included in its length.
77: sword here place bl here count + c! here ;
78:
79: : parse ( char "ccc<char>" -- c-addr u ) \ core-ext
80: \G Parse @i{ccc}, delimited by @i{char}, in the parse
81: \G area. @i{c-addr u} specifies the parsed string within the
82: \G parse area. If the parse area was empty, @i{u} is 0.
83: >r source >in @ over min /string over swap r> scan >r
84: over - dup r> IF 1+ THEN >in +! ;
85:
86: \ name 13feb93py
87:
88: [IFUNDEF] (name) \ name might be a primitive
89:
90: : (name) ( -- c-addr count ) \ gforth
91: source 2dup >r >r >in @ /string (parse-white)
92: 2dup + r> - 1+ r> min >in ! ;
93: \ name count ;
94: [THEN]
95:
96: : name-too-short? ( c-addr u -- c-addr u )
97: dup 0= -&16 and throw ;
98:
99: : name-too-long? ( c-addr u -- c-addr u )
100: dup lcount-mask u> -&19 and throw ;
101:
102: \ \ Number parsing 23feb93py
103:
104: \ number? number 23feb93py
105:
106: hex
107: const Create bases 10 , 2 , A , 100 ,
108: \ 16 2 10 character
109:
110: \ !! protect BASE saving wrapper against exceptions
111: : getbase ( addr u -- addr' u' )
112: over c@ [char] $ - dup 4 u<
113: IF
114: cells bases + @ base ! 1 /string
115: ELSE
116: drop
117: THEN ;
118:
119: : sign? ( addr u -- addr u flag )
120: over c@ [char] - = dup >r
121: IF
122: 1 /string
123: THEN
124: r> ;
125:
126: : s>unumber? ( addr u -- ud flag )
127: base @ >r dpl on getbase
128: 0. 2swap
129: BEGIN ( d addr len )
130: dup >r >number dup
131: WHILE \ there are characters left
132: dup r> -
133: WHILE \ the last >number parsed something
134: dup 1- dpl ! over c@ [char] . =
135: WHILE \ the current char is '.'
136: 1 /string
137: REPEAT THEN \ there are unparseable characters left
138: 2drop false
139: ELSE
140: rdrop 2drop true
141: THEN
142: r> base ! ;
143:
144: \ ouch, this is complicated; there must be a simpler way - anton
145: : s>number? ( addr len -- d f )
146: \ converts string addr len into d, flag indicates success
147: sign? >r
148: s>unumber?
149: 0= IF
150: rdrop false
151: ELSE \ no characters left, all ok
152: r>
153: IF
154: dnegate
155: THEN
156: true
157: THEN ;
158:
159: : s>number ( addr len -- d )
160: \ don't use this, there is no way to tell success
161: s>number? drop ;
162:
163: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
164: s>number? 0=
165: IF
166: 2drop false EXIT
167: THEN
168: dpl @ dup 0< IF
169: nip
170: ELSE
171: 1+
172: THEN ;
173:
174: : number? ( string -- string 0 / n -1 / d 0> )
175: dup >r count snumber? dup if
176: rdrop
177: else
178: r> swap
179: then ;
180:
181: : number ( string -- d )
182: number? ?dup 0= abort" ?" 0<
183: IF
184: s>d
185: THEN ;
186:
187: \ \ Comments ( \ \G
188:
189: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file paren
190: \G ** this will not get annotated. The alias in glocals.fs will instead **
191: \G It does not work to use "wordset-" prefix since this file is glossed
192: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
193: [char] ) parse 2drop ; immediate
194:
195: : \ ( compilation 'ccc<newline>' -- ; run-time -- ) \ thisone- core-ext,block-ext backslash
196: \G ** this will not get annotated. The alias in glocals.fs will instead **
197: \G It does not work to use "wordset-" prefix since this file is glossed
198: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
199: [ has? file [IF] ]
200: blk @
201: IF
202: >in @ c/l / 1+ c/l * >in !
203: EXIT
204: THEN
205: [ [THEN] ]
206: source >in ! drop ; immediate
207:
208: : \G ( compilation 'ccc<newline>' -- ; run-time -- ) \ gforth backslash-gee
209: \G Equivalent to @code{\} but used as a tag to annotate definition
210: \G comments into documentation.
211: POSTPONE \ ; immediate
212:
213: \ \ object oriented search list 17mar93py
214:
215: \ word list structure:
216:
217: struct
218: cell% field find-method \ xt: ( c_addr u wid -- nt )
219: cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
220: cell% field rehash-method \ xt: ( wid -- ) \ re-initializes a "search-data" (hashtables)
221: cell% field hash-method \ xt: ( wid -- ) \ initializes ""
222: \ \ !! what else
223: end-struct wordlist-map-struct
224:
225: struct
226: cell% field wordlist-map \ pointer to a wordlist-map-struct
227: cell% field wordlist-id \ linked list of words (for WORDS etc.)
228: cell% field wordlist-link \ link field to other wordlists
229: cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
230: end-struct wordlist-struct
231:
232: : f83find ( addr len wordlist -- nt / false )
233: wordlist-id @ (listlfind) ;
234:
235: : initvoc ( wid -- )
236: dup wordlist-map @ hash-method perform ;
237:
238: \ Search list table: find reveal
239: Create f83search ( -- wordlist-map )
240: ' f83find A, ' drop A, ' drop A, ' drop A,
241:
242: here G f83search T A, NIL A, NIL A, NIL A,
243: AValue forth-wordlist \ variable, will be redefined by search.fs
244:
245: AVariable lookup forth-wordlist lookup !
246: \ !! last is user and lookup?! jaw
247: AVariable current ( -- addr ) \ gforth
248: \G @code{Variable} -- holds the @i{wid} of the compilation word list.
249: AVariable voclink forth-wordlist wordlist-link voclink !
250: \ lookup AValue context ( -- addr ) \ gforth
251: Defer context ( -- addr ) \ gforth
252: \G @code{context} @code{@@} is the @i{wid} of the word list at the
253: \G top of the search order.
254:
255: ' lookup is context
256: forth-wordlist current !
257:
258: \ \ header, finding, ticks 17dec92py
259:
260: \ The constants are defined as 32 bits, but then erased
261: \ and overwritten by the right ones
262:
263: $80000000 constant alias-mask
264: 1 bits/char 1 - lshift
265: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
266: [ELSE] 0 1 cells 1- times c, [THEN]
267: $40000000 constant immediate-mask
268: 1 bits/char 2 - lshift
269: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
270: [ELSE] 0 1 cells 1- times c, [THEN]
271: $20000000 constant restrict-mask
272: 1 bits/char 3 - lshift
273: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
274: [ELSE] 0 1 cells 1- times c, [THEN]
275: $1fffffff constant lcount-mask
276: 1 bits/char 3 - lshift 1 -
277: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
278: [ELSE] -1 1 cells 1- times c, [THEN]
279:
280: \ higher level parts of find
281:
282: : flag-sign ( f -- 1|-1 )
283: \ true becomes 1, false -1
284: 0= 2* 1+ ;
285:
286: : ticking-compile-only-error ( ... -- )
287: -&2048 throw ;
288:
289: : (cfa>int) ( cfa -- xt )
290: [ has? compiler [IF] ]
291: dup interpret/compile?
292: if
293: interpret/compile-int @
294: then
295: [ [THEN] ] ;
296:
297: : (x>int) ( cfa w -- xt )
298: \ get interpretation semantics of name
299: restrict-mask and
300: if
301: drop ['] ticking-compile-only-error
302: else
303: (cfa>int)
304: then ;
305:
306: : name>string ( nt -- addr count ) \ gforth head-to-string
307: \g @i{addr count} is the name of the word represented by @i{nt}.
308: cell+ dup cell+ swap @ lcount-mask and ;
309:
310: : ((name>)) ( nfa -- cfa )
311: name>string + cfaligned ;
312:
313: : (name>x) ( nfa -- cfa w )
314: \ cfa is an intermediate cfa and w is the flags cell of nfa
315: dup ((name>))
316: swap cell+ @ dup alias-mask and 0=
317: IF
318: swap @ swap
319: THEN ;
320:
321: : name>int ( nt -- xt ) \ gforth
322: \G @i{xt} represents the interpretation semantics of the word
323: \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
324: \G @code{compile-only}), @i{xt} is the execution token for
325: \G @code{ticking-compile-only-error}, which performs @code{-2048 throw}.
326: (name>x) (x>int) ;
327:
328: : name?int ( nt -- xt ) \ gforth
329: \G Like @code{name>int}, but perform @code{-2048 throw} if @i{nt}
330: \G has no interpretation semantics.
331: (name>x) restrict-mask and
332: if
333: ticking-compile-only-error \ does not return
334: then
335: (cfa>int) ;
336:
337: : (name>comp) ( nt -- w +-1 ) \ gforth
338: \G @i{w xt} is the compilation token for the word @i{nt}.
339: (name>x) >r
340: [ has? compiler [IF] ]
341: dup interpret/compile?
342: if
343: interpret/compile-comp @
344: then
345: [ [THEN] ]
346: r> immediate-mask and flag-sign
347: ;
348:
349: : (name>intn) ( nfa -- xt +-1 )
350: (name>x) tuck (x>int) ( w xt )
351: swap immediate-mask and flag-sign ;
352:
353: const Create ??? 0 , 3 , char ? c, char ? c, char ? c,
354: \ ??? is used by dovar:, must be created/:dovar
355:
356: [IFDEF] forthstart
357: \ if we have a forthstart we can define head? with it
358: \ otherwise leave out the head? check
359:
360: : head? ( addr -- f )
361: \G heuristic check whether addr is a name token; may deliver false
362: \G positives; addr must be a valid address; returns 1 for
363: \G particularly unsafe positives
364: \ we follow the link fields and check for plausibility; two
365: \ iterations should catch most false addresses: on the first
366: \ iteration, we may get an xt, on the second a code address (or
367: \ some code), which is typically not in the dictionary.
368: \ we added a third iteration for working with code and ;code words.
369: 3 0 do
370: dup dup aligned <> if \ protect @ against unaligned accesses
371: drop false unloop exit
372: then
373: dup @ dup
374: if ( addr addr1 )
375: dup rot forthstart within
376: if \ addr1 is outside forthstart..addr, not a head
377: drop false unloop exit
378: then ( addr1 )
379: else \ 0 in the link field, no further checks
380: 2drop 1 unloop exit \ this is very unsure, so return 1
381: then
382: loop
383: \ in dubio pro:
384: drop true ;
385:
386: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
387: \ also heuristic; finds only names with up to 32 chars
388: $25 cell do ( cfa )
389: dup i - dup @ [ alias-mask lcount-mask or ] literal
390: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
391: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
392: [ELSE] -1 1 cells 1- times c, [THEN] ]
393: and ( cfa len|alias )
394: swap + cell + cfaligned over alias-mask + =
395: if ( cfa )
396: dup i - cell - dup head?
397: if
398: nip unloop exit
399: then
400: drop
401: then
402: cell +loop
403: drop ??? ( wouldn't 0 be better? ) ;
404:
405: [ELSE]
406:
407: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
408: $25 cell do ( cfa )
409: dup i - dup @ [ alias-mask lcount-mask or ] literal
410: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
411: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
412: [ELSE] -1 1 cells 1- times c, [THEN] ]
413: and ( cfa len|alias )
414: swap + cell + cfaligned over alias-mask + =
415: if ( cfa ) i - cell - unloop exit
416: then
417: cell +loop
418: drop ??? ( wouldn't 0 be better? ) ;
419:
420: [THEN]
421:
422: cell% 2* 0 0 field >body ( xt -- a_addr ) \ core
423: \G Get the address of the body of the word represented by @i{xt} (the
424: \G address of the word's data field).
425: drop drop
426:
427: cell% -2 * 0 0 field body> ( xt -- a_addr )
428: drop drop
429:
430: has? standardthreading has? compiler and [IF]
431:
432: ' @ alias >code-address ( xt -- c_addr ) \ gforth
433: \G @i{c-addr} is the code address of the word @i{xt}.
434:
435: : >does-code ( xt -- a_addr ) \ gforth
436: \G If @i{xt} is the execution token of a child of a @code{DOES>} word,
437: \G @i{a-addr} is the start of the Forth code after the @code{DOES>};
438: \G Otherwise @i{a-addr} is 0.
439: dup @ dodoes: = if
440: cell+ @
441: else
442: drop 0
443: endif ;
444:
445: [THEN]
446:
447: : (search-wordlist) ( addr count wid -- nt | false )
448: dup wordlist-map @ find-method perform ;
449:
450: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
451: \G Search the word list identified by @i{wid} for the definition
452: \G named by the string at @i{c-addr count}. If the definition is
453: \G not found, return 0. If the definition is found return 1 (if
454: \G the definition is immediate) or -1 (if the definition is not
455: \G immediate) together with the @i{xt}. In Gforth, the @i{xt}
456: \G returned represents the interpretation semantics. ANS Forth
457: \G does not specify clearly what @i{xt} represents.
458: (search-wordlist) dup if
459: (name>intn)
460: then ;
461:
462: : find-name ( c-addr u -- nt | 0 ) \ gforth
463: \g Find the name @i{c-addr u} in the current search
464: \g order. Return its @i{nt}, if found, otherwise 0.
465: lookup @ (search-wordlist) ;
466:
467: : sfind ( c-addr u -- 0 / xt +-1 ) \ gforth-obsolete
468: find-name dup
469: if ( nt )
470: state @
471: if
472: (name>comp)
473: else
474: (name>intn)
475: then
476: then ;
477:
478: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
479: \G Search all word lists in the current search order for the
480: \G definition named by the counted string at @i{c-addr}. If the
481: \G definition is not found, return 0. If the definition is found
482: \G return 1 (if the definition has non-default compilation
483: \G semantics) or -1 (if the definition has default compilation
484: \G semantics). The @i{xt} returned in interpret state represents
485: \G the interpretation semantics. The @i{xt} returned in compile
486: \G state represented either the compilation semantics (for
487: \G non-default compilation semantics) or the run-time semantics
488: \G that the compilation semantics would @code{compile,} (for
489: \G default compilation semantics). The ANS Forth standard does
490: \G not specify clearly what the returned @i{xt} represents (and
491: \G also talks about immediacy instead of non-default compilation
492: \G semantics), so this word is questionable in portable programs.
493: \G If non-portability is ok, @code{find-name} and friends are
494: \G better (@pxref{Name token}).
495: dup count sfind dup
496: if
497: rot drop
498: then ;
499:
500: \ ticks in interpreter
501:
502: : (') ( "name" -- nt ) \ gforth
503: name name-too-short?
504: find-name dup 0=
505: IF
506: drop -&13 throw
507: THEN ;
508:
509: : ' ( "name" -- xt ) \ core tick
510: \g @i{xt} represents @i{name}'s interpretation
511: \g semantics. Perform @code{-14 throw} if the word has no
512: \g interpretation semantics.
513: (') name?int ;
514:
515: has? compiler 0= [IF] \ interpreter only version of IS and TO
516:
517: : IS ' >body ! ;
518: ' IS Alias TO
519:
520: [THEN]
521:
522: \ \ the interpreter loop mar92py
523:
524: \ interpret 10mar92py
525:
526: Defer parser ( c-addr u -- )
527: Defer parse-word ( -- c-addr count ) \ gforth
528: \G Get the next word from the input buffer
529: ' (name) IS parse-word
530:
531: ' parse-word alias name ( -- c-addr u ) \ gforth-obsolete
532: \G old name for @code{parse-word}
533:
534: Defer compiler-notfound ( c-addr count -- )
535: Defer interpreter-notfound ( c-addr count -- )
536:
537: : no.extensions ( addr u -- )
538: 2drop -&13 throw ;
539: ' no.extensions IS compiler-notfound
540: ' no.extensions IS interpreter-notfound
541:
542: : interpret1 ( ... -- ... )
543: [ has? backtrace [IF] ]
544: rp@ backtrace-rp0 !
545: [ [THEN] ]
546: BEGIN
547: ?stack name dup
548: WHILE
549: parser
550: REPEAT
551: 2drop ;
552:
553: : interpret ( ?? -- ?? ) \ gforth
554: \ interpret/compile the (rest of the) input buffer
555: [ has? backtrace [IF] ]
556: backtrace-rp0 @ >r
557: [ [THEN] ]
558: ['] interpret1 catch
559: [ has? backtrace [IF] ]
560: r> backtrace-rp0 !
561: [ [THEN] ]
562: throw ;
563:
564: \ interpreter 30apr92py
565:
566: \ not the most efficient implementations of interpreter and compiler
567: : interpreter ( c-addr u -- )
568: 2dup find-name dup
569: if
570: nip nip name>int execute
571: else
572: drop
573: 2dup 2>r snumber?
574: IF
575: 2rdrop
576: ELSE
577: 2r> interpreter-notfound
578: THEN
579: then ;
580:
581: ' interpreter IS parser
582:
583: \ \ Query Evaluate 07apr93py
584:
585: has? file 0= [IF]
586: : sourceline# ( -- n ) 1 ;
587: [ELSE]
588: has? new-input 0= [IF]
589: Variable #fill-bytes
590: \G number of bytes read via (read-line) by the last refill
591: [THEN]
592: [THEN]
593:
594: has? new-input 0= [IF]
595: : refill ( -- flag ) \ core-ext,block-ext,file-ext
596: \G Attempt to fill the input buffer from the input source. When
597: \G the input source is the user input device, attempt to receive
598: \G input into the terminal input device. If successful, make the
599: \G result the input buffer, set @code{>IN} to 0 and return true;
600: \G otherwise return false. When the input source is a block, add 1
601: \G to the value of @code{BLK} to make the next block the input
602: \G source and current input buffer, and set @code{>IN} to 0;
603: \G return true if the new value of @code{BLK} is a valid block
604: \G number, false otherwise. When the input source is a text file,
605: \G attempt to read the next line from the file. If successful,
606: \G make the result the current input buffer, set @code{>IN} to 0
607: \G and return true; otherwise, return false. A successful result
608: \G includes receipt of a line containing 0 characters.
609: [ has? file [IF] ]
610: blk @ IF 1 blk +! true 0 >in ! EXIT THEN
611: [ [THEN] ]
612: tib /line
613: [ has? file [IF] ]
614: loadfile @ ?dup
615: IF (read-line) throw #fill-bytes !
616: ELSE
617: [ [THEN] ]
618: sourceline# 0< IF 2drop false EXIT THEN
619: accept true
620: [ has? file [IF] ]
621: THEN
622: 1 loadline +!
623: [ [THEN] ]
624: swap #tib ! 0 >in ! ;
625:
626: : query ( -- ) \ core-ext
627: \G Make the user input device the input source. Receive input into
628: \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
629: \G superceeded by @code{accept}.
630: [ has? file [IF] ]
631: blk off loadfile off
632: [ [THEN] ]
633: refill drop ;
634: [THEN]
635:
636: \ save-mem extend-mem
637:
638: has? os [IF]
639: : save-mem ( addr1 u -- addr2 u ) \ gforth
640: \g copy a memory block into a newly allocated region in the heap
641: swap >r
642: dup allocate throw
643: swap 2dup r> -rot move ;
644:
645: : free-mem-var ( addr -- )
646: \ addr is the address of a 2variable containing address and size
647: \ of a memory range; frees memory and clears the 2variable.
648: dup 2@ drop dup
649: if ( addr mem-start )
650: free throw
651: 0 0 rot 2!
652: else
653: 2drop
654: then ;
655:
656: : extend-mem ( addr1 u1 u -- addr addr2 u2 )
657: \ extend memory block allocated from the heap by u aus
658: \ the (possibly reallocated piece is addr2 u2, the extension is at addr
659: over >r + dup >r resize throw
660: r> over r> + -rot ;
661: [THEN]
662:
663: \ EVALUATE 17may93jaw
664:
665: has? file 0= has? new-input 0= and [IF]
666: : push-file ( -- ) r>
667: tibstack @ >r >tib @ >r #tib @ >r
668: >tib @ tibstack @ = IF r@ tibstack +! THEN
669: tibstack @ >tib ! >in @ >r >r ;
670:
671: : pop-file ( throw-code -- throw-code )
672: r>
673: r> >in ! r> #tib ! r> >tib ! r> tibstack ! >r ;
674: [THEN]
675:
676: has? new-input 0= [IF]
677: : evaluate ( c-addr u -- ) \ core,block
678: \G Save the current input source specification. Store @code{-1} in
679: \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
680: \G @code{0} and make the string @i{c-addr u} the input source
681: \G and input buffer. Interpret. When the parse area is empty,
682: \G restore the input source specification.
683: [ has? file [IF] ]
684: loadfilename# @ >r
685: 1 loadfilename# ! \ "*evaluated string*"
686: [ [THEN] ]
687: push-file #tib ! >tib !
688: >in off
689: [ has? file [IF] ]
690: blk off loadfile off -1 loadline !
691: [ [THEN] ]
692: ['] interpret catch
693: pop-file
694: [ has? file [IF] ]
695: r> loadfilename# !
696: [ [THEN] ]
697: throw ;
698: [THEN]
699:
700: \ \ Quit 13feb93py
701:
702: Defer 'quit
703:
704: Defer .status
705:
706: : prompt state @ IF ." compiled" EXIT THEN ." ok" ;
707:
708: : (quit) ( -- )
709: \ exits only through THROW etc.
710: \ sp0 @ cell - handler @ &12 + ! \ !! kludge: fix the stack pointer
711: \ stored in the system's CATCH frame, so the stack depth will be 0
712: \ after the next THROW it catches (it may be off due to BOUNCEs or
713: \ because process-args left something on the stack)
714: BEGIN
715: .status cr query interpret prompt
716: AGAIN ;
717:
718: ' (quit) IS 'quit
719:
720: \ \ DOERROR (DOERROR) 13jun93jaw
721:
722: 8 Constant max-errors
723: Variable error-stack 0 error-stack !
724: max-errors has? file [IF] 6 [ELSE] 4 [THEN] * cells allot
725: \ format of one cell:
726: \ source ( addr u )
727: \ >in
728: \ line-number
729: \ Loadfilename ( addr u )
730:
731: : error> ( -- addr u >in line# [addr u] )
732: -1 error-stack +!
733: error-stack dup @
734: [ has? file [IF] 6 [ELSE] 4 [THEN] ] Literal * cells + cell+
735: [ has? file [IF] 6 [ELSE] 4 [THEN] ] Literal cells bounds DO
736: I @
737: cell +LOOP ;
738: : >error ( addr u >in line# [addr u] -- )
739: error-stack dup @ dup 1+
740: max-errors 1- min error-stack !
741: [ has? file [IF] 6 [ELSE] 4 [THEN] ] Literal * cells + cell+
742: [ has? file [IF] 6 [ELSE] 4 [THEN] 1- ] Literal cells bounds swap DO
743: I !
744: -1 cells +LOOP ;
745:
746: : dec. ( n -- ) \ gforth
747: \G Display @i{n} as a signed decimal number, followed by a space.
748: \ !! not used...
749: base @ decimal swap . base ! ;
750:
751: : dec.r ( u -- ) \ gforth
752: \G Display @i{u} as a unsigned decimal number
753: base @ decimal swap 0 .r base ! ;
754:
755: : hex. ( u -- ) \ gforth
756: \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
757: \G followed by a space.
758: \ !! not used...
759: [char] $ emit base @ swap hex u. base ! ;
760:
761: : typewhite ( addr u -- ) \ gforth
762: \G Like type, but white space is printed instead of the characters.
763: bounds ?do
764: i c@ #tab = if \ check for tab
765: #tab
766: else
767: bl
768: then
769: emit
770: loop ;
771:
772: DEFER DOERROR
773:
774: has? backtrace [IF]
775: Defer dobacktrace ( -- )
776: ' noop IS dobacktrace
777: [THEN]
778:
779: : .error-string ( throw-code -- )
780: dup -2 =
781: IF "error @ ?dup IF count type THEN drop
782: ELSE .error
783: THEN ;
784:
785: : .error-frame ( throwcode addr1 u1 n1 n2 [addr2 u2] -- throwcode )
786: \ addr2 u2: filename of included file - optional
787: \ n2: line number
788: \ n1: error position in input line
789: \ addr1 u1: input line
790: cr error-stack @
791: IF
792: [ has? file [IF] ]
793: ." in file included from "
794: type ." :"
795: [ [THEN] ]
796: dec.r drop 2drop
797: ELSE
798: [ has? file [IF] ]
799: type ." :"
800: [ [THEN] ]
801: dup >r dec.r ." : " 3 pick .error-string
802: r> IF \ if line# non-zero, there is a line
803: cr dup 2over type cr drop
804: nip -trailing 1- ( line-start index2 )
805: 0 >r BEGIN
806: 2dup + c@ bl > WHILE
807: r> 1+ >r 1- dup 0< UNTIL THEN 1+
808: ( line-start index1 )
809: typewhite
810: r> 1 max 0 ?do \ we want at least one "^", even if the length is 0
811: [char] ^ emit
812: loop
813: ELSE
814: 2drop drop
815: THEN
816: THEN ;
817:
818: : (DoError) ( throw-code -- )
819: [ has? os [IF] ]
820: >stderr
821: [ [THEN] ]
822: source >in @ sourceline# [ has? file [IF] ]
823: sourcefilename
824: [ [THEN] ] .error-frame
825: error-stack @ 0 ?DO
826: error>
827: .error-frame
828: LOOP
829: drop
830: [ has? backtrace [IF] ]
831: dobacktrace
832: [ [THEN] ]
833: normal-dp dpp ! ;
834:
835: ' (DoError) IS DoError
836:
837: : quit ( ?? -- ?? ) \ core
838: \G Empty the return stack, make the user input device
839: \G the input source, enter interpret state and start
840: \G the text interpreter.
841: rp0 @ rp! handler off clear-tibstack
842: [ has? new-input 0= [IF] ] >tib @ >r [ [THEN] ]
843: BEGIN
844: [ has? compiler [IF] ]
845: [compile] [
846: [ [THEN] ]
847: ['] 'quit CATCH dup
848: WHILE
849: <# \ reset hold area, or we may get another error
850: DoError
851: [ has? new-input [IF] ] clear-tibstack
852: [ [ELSE] ] r@ >tib ! r@ tibstack !
853: [ [THEN] ]
854: REPEAT
855: drop [ has? new-input [IF] ] clear-tibstack
856: [ [ELSE] ] r> >tib !
857: [ [THEN] ] ;
858:
859: \ \ Cold Boot 13feb93py
860:
861: : (bootmessage)
862: ." GForth " version-string type
863: ." , Copyright (C) 1995-2000 Free Software Foundation, Inc." cr
864: ." GForth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
865: [ has? os [IF] ]
866: cr ." Type `bye' to exit"
867: [ [THEN] ] ;
868:
869: defer bootmessage
870: defer process-args
871:
872: ' (bootmessage) IS bootmessage
873:
874: Defer 'cold ( -- ) \ gforth tick-cold
875: \ hook (deferred word) for things to do right before interpreting the
876: \ command-line arguments
877: ' noop IS 'cold
878:
879:
880: AVariable init8 NIL init8 !
881:
882: : cold ( -- ) \ gforth
883: [ has? backtrace [IF] ]
884: rp@ backtrace-rp0 !
885: [ [THEN] ]
886: [ has? file [IF] ]
887: os-cold
888: [ [THEN] ]
889: 'cold
890: init8 chainperform
891: [ has? file [IF] ]
892: loadfilename# off
893: process-args
894: loadline off
895: [ [THEN] ]
896: bootmessage
897: quit ;
898:
899: has? new-input 0= [IF]
900: : clear-tibstack ( -- )
901: [ has? glocals [IF] ]
902: lp@ forthstart 7 cells + @ -
903: [ [ELSE] ]
904: [ has? os [IF] ]
905: r0 @ forthstart 6 cells + @ -
906: [ [ELSE] ]
907: sp@ $10 cells +
908: [ [THEN] ]
909: [ [THEN] ]
910: dup >tib ! tibstack ! #tib off >in off ;
911: [THEN]
912:
913: : boot ( path n **argv argc -- )
914: main-task up!
915: [ has? os [IF] ]
916: os-boot
917: [ [THEN] ]
918: sp@ sp0 !
919: [ has? peephole [IF] ]
920: primtable prepare-peephole-table TO peeptable
921: [ [THEN] ]
922: [ has? new-input [IF] ]
923: current-input off
924: [ [THEN] ]
925: clear-tibstack
926: rp@ rp0 !
927: [ has? floating [IF] ]
928: fp@ fp0 !
929: [ [THEN] ]
930: handler off
931: ['] cold catch DoError cr
932: [ has? os [IF] ]
933: 1 (bye) \ !! determin exit code from throw code?
934: [ [THEN] ]
935: ;
936:
937: has? os [IF]
938: : bye ( -- ) \ tools-ext
939: [ has? file [IF] ]
940: script? 0= IF cr THEN
941: [ [ELSE] ]
942: cr
943: [ [THEN] ]
944: 0 (bye) ;
945: [THEN]
946:
947: \ **argv may be scanned by the C starter to get some important
948: \ information, as -display and -geometry for an X client FORTH
949: \ or space and stackspace overrides
950:
951: \ 0 arg contains, however, the name of the program.
952:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to int.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth / kernel