1: \ definitions needed for interpreter only
2:
3: \ Copyright (C) 1995-2000 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ \ Revision-Log
22:
23: \ put in seperate file 14sep97jaw
24:
25: \ \ input stream primitives 23feb93py
26:
27: require ./basics.fs \ bounds decimal hex ...
28: require ./io.fs \ type ...
29: require ./nio.fs \ . <# ...
30: require ./errore.fs \ .error ...
31: require kernel/version.fs \ version-string
32: require ./../chains.fs
33:
34: has? new-input 0= [IF]
35: : tib ( -- c-addr ) \ core-ext t-i-b
36: \G @i{c-addr} is the address of the Terminal Input Buffer.
37: \G OBSOLESCENT: @code{source} superceeds the function of this word.
38: >tib @ ;
39:
40: Defer source ( -- c-addr u ) \ core
41: \ used by dodefer:, must be defer
42: \G @i{c-addr} is the address of the input buffer and @i{u} is the
43: \G number of characters in it.
44:
45: : (source) ( -- c-addr u )
46: tib #tib @ ;
47: ' (source) IS source
48: [THEN]
49:
50: : (word) ( addr1 n1 char -- addr2 n2 )
51: dup >r skip 2dup r> scan nip - ;
52:
53: \ (word) should fold white spaces
54: \ this is what (parse-white) does
55:
56: \ word parse 23feb93py
57:
58: : sword ( char -- addr len ) \ gforth s-word
59: \G Parses like @code{word}, but the output is like @code{parse} output.
60: \G @xref{core-idef}.
61: \ this word was called PARSE-WORD until 0.3.0, but Open Firmware and
62: \ dpANS6 A.6.2.2008 have a word with that name that behaves
63: \ differently (like NAME).
64: source 2dup >r >r >in @ over min /string
65: rot dup bl = IF drop (parse-white) ELSE (word) THEN
66: 2dup + r> - 1+ r> min >in ! ;
67:
68: : word ( char "<chars>ccc<char>-- c-addr ) \ core
69: \G Skip leading delimiters. Parse @i{ccc}, delimited by
70: \G @i{char}, in the parse area. @i{c-addr} is the address of a
71: \G transient region containing the parsed string in
72: \G counted-string format. If the parse area was empty or
73: \G contained no characters other than delimiters, the resulting
74: \G string has zero length. A program may replace characters within
75: \G the counted string. OBSOLESCENT: the counted string has a
76: \G trailing space that is not included in its length.
77: sword here place bl here count + c! here ;
78:
79: : parse ( char "ccc<char>" -- c-addr u ) \ core-ext
80: \G Parse @i{ccc}, delimited by @i{char}, in the parse
81: \G area. @i{c-addr u} specifies the parsed string within the
82: \G parse area. If the parse area was empty, @i{u} is 0.
83: >r source >in @ over min /string over swap r> scan >r
84: over - dup r> IF 1+ THEN >in +! ;
85:
86: \ name 13feb93py
87:
88: [IFUNDEF] (name) \ name might be a primitive
89:
90: : (name) ( -- c-addr count ) \ gforth
91: source 2dup >r >r >in @ /string (parse-white)
92: 2dup + r> - 1+ r> min >in ! ;
93: \ name count ;
94: [THEN]
95:
96: : name-too-short? ( c-addr u -- c-addr u )
97: dup 0= -&16 and throw ;
98:
99: : name-too-long? ( c-addr u -- c-addr u )
100: dup lcount-mask u> -&19 and throw ;
101:
102: \ \ Number parsing 23feb93py
103:
104: \ number? number 23feb93py
105:
106: hex
107: const Create bases 10 , 2 , A , 100 ,
108: \ 16 2 10 character
109:
110: \ !! protect BASE saving wrapper against exceptions
111: : getbase ( addr u -- addr' u' )
112: over c@ [char] $ - dup 4 u<
113: IF
114: cells bases + @ base ! 1 /string
115: ELSE
116: drop
117: THEN ;
118:
119: : sign? ( addr u -- addr u flag )
120: over c@ [char] - = dup >r
121: IF
122: 1 /string
123: THEN
124: r> ;
125:
126: : s>unumber? ( addr u -- ud flag )
127: base @ >r dpl on getbase
128: 0. 2swap
129: BEGIN ( d addr len )
130: dup >r >number dup
131: WHILE \ there are characters left
132: dup r> -
133: WHILE \ the last >number parsed something
134: dup 1- dpl ! over c@ [char] . =
135: WHILE \ the current char is '.'
136: 1 /string
137: REPEAT THEN \ there are unparseable characters left
138: 2drop false
139: ELSE
140: rdrop 2drop true
141: THEN
142: r> base ! ;
143:
144: \ ouch, this is complicated; there must be a simpler way - anton
145: : s>number? ( addr len -- d f )
146: \ converts string addr len into d, flag indicates success
147: sign? >r
148: s>unumber?
149: 0= IF
150: rdrop false
151: ELSE \ no characters left, all ok
152: r>
153: IF
154: dnegate
155: THEN
156: true
157: THEN ;
158:
159: : s>number ( addr len -- d )
160: \ don't use this, there is no way to tell success
161: s>number? drop ;
162:
163: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
164: s>number? 0=
165: IF
166: 2drop false EXIT
167: THEN
168: dpl @ dup 0< IF
169: nip
170: ELSE
171: 1+
172: THEN ;
173:
174: : number? ( string -- string 0 / n -1 / d 0> )
175: dup >r count snumber? dup if
176: rdrop
177: else
178: r> swap
179: then ;
180:
181: : number ( string -- d )
182: number? ?dup 0= abort" ?" 0<
183: IF
184: s>d
185: THEN ;
186:
187: \ \ Comments ( \ \G
188:
189: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file paren
190: \G ** this will not get annotated. The alias in glocals.fs will instead **
191: \G It does not work to use "wordset-" prefix since this file is glossed
192: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
193: [char] ) parse 2drop ; immediate
194:
195: : \ ( compilation 'ccc<newline>' -- ; run-time -- ) \ thisone- core-ext,block-ext backslash
196: \G ** this will not get annotated. The alias in glocals.fs will instead **
197: \G It does not work to use "wordset-" prefix since this file is glossed
198: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
199: [ has? file [IF] ]
200: blk @
201: IF
202: >in @ c/l / 1+ c/l * >in !
203: EXIT
204: THEN
205: [ [THEN] ]
206: source >in ! drop ; immediate
207:
208: : \G ( compilation 'ccc<newline>' -- ; run-time -- ) \ gforth backslash-gee
209: \G Equivalent to @code{\} but used as a tag to annotate definition
210: \G comments into documentation.
211: POSTPONE \ ; immediate
212:
213: \ \ object oriented search list 17mar93py
214:
215: \ word list structure:
216:
217: struct
218: cell% field find-method \ xt: ( c_addr u wid -- nt )
219: cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
220: cell% field rehash-method \ xt: ( wid -- ) \ re-initializes a "search-data" (hashtables)
221: cell% field hash-method \ xt: ( wid -- ) \ initializes ""
222: \ \ !! what else
223: end-struct wordlist-map-struct
224:
225: struct
226: cell% field wordlist-map \ pointer to a wordlist-map-struct
227: cell% field wordlist-id \ linked list of words (for WORDS etc.)
228: cell% field wordlist-link \ link field to other wordlists
229: cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
230: end-struct wordlist-struct
231:
232: : f83find ( addr len wordlist -- nt / false )
233: wordlist-id @ (listlfind) ;
234:
235: : initvoc ( wid -- )
236: dup wordlist-map @ hash-method perform ;
237:
238: \ Search list table: find reveal
239: Create f83search ( -- wordlist-map )
240: ' f83find A, ' drop A, ' drop A, ' drop A,
241:
242: here G f83search T A, NIL A, NIL A, NIL A,
243: AValue forth-wordlist \ variable, will be redefined by search.fs
244:
245: AVariable lookup forth-wordlist lookup !
246: \ !! last is user and lookup?! jaw
247: AVariable current ( -- addr ) \ gforth
248: \G @code{Variable} -- holds the @i{wid} of the compilation word list.
249: AVariable voclink forth-wordlist wordlist-link voclink !
250: \ lookup AValue context ( -- addr ) \ gforth
251: Defer context ( -- addr ) \ gforth
252: \G @code{context} @code{@@} is the @i{wid} of the word list at the
253: \G top of the search order.
254:
255: ' lookup is context
256: forth-wordlist current !
257:
258: \ \ header, finding, ticks 17dec92py
259:
260: \ The constants are defined as 32 bits, but then erased
261: \ and overwritten by the right ones
262:
263: $80000000 constant alias-mask
264: 1 bits/char 1 - lshift
265: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
266: [ELSE] 0 1 cells 1- times c, [THEN]
267: $40000000 constant immediate-mask
268: 1 bits/char 2 - lshift
269: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
270: [ELSE] 0 1 cells 1- times c, [THEN]
271: $20000000 constant restrict-mask
272: 1 bits/char 3 - lshift
273: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
274: [ELSE] 0 1 cells 1- times c, [THEN]
275: $1fffffff constant lcount-mask
276: 1 bits/char 3 - lshift 1 -
277: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
278: [ELSE] -1 1 cells 1- times c, [THEN]
279:
280: \ higher level parts of find
281:
282: : flag-sign ( f -- 1|-1 )
283: \ true becomes 1, false -1
284: 0= 2* 1+ ;
285:
286: : ticking-compile-only-error ( ... -- )
287: -&2048 throw ;
288:
289: : (cfa>int) ( cfa -- xt )
290: [ has? compiler [IF] ]
291: dup interpret/compile?
292: if
293: interpret/compile-int @
294: then
295: [ [THEN] ] ;
296:
297: : (x>int) ( cfa w -- xt )
298: \ get interpretation semantics of name
299: restrict-mask and
300: if
301: drop ['] ticking-compile-only-error
302: else
303: (cfa>int)
304: then ;
305:
306: : name>string ( nt -- addr count ) \ gforth head-to-string
307: \g @i{addr count} is the name of the word represented by @i{nt}.
308: cell+ dup cell+ swap @ lcount-mask and ;
309:
310: : ((name>)) ( nfa -- cfa )
311: name>string + cfaligned ;
312:
313: : (name>x) ( nfa -- cfa w )
314: \ cfa is an intermediate cfa and w is the flags cell of nfa
315: dup ((name>))
316: swap cell+ @ dup alias-mask and 0=
317: IF
318: swap @ swap
319: THEN ;
320:
321: : name>int ( nt -- xt ) \ gforth
322: \G @i{xt} represents the interpretation semantics of the word
323: \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
324: \G @code{compile-only}), @i{xt} is the execution token for
325: \G @code{ticking-compile-only-error}, which performs @code{-2048 throw}.
326: (name>x) (x>int) ;
327:
328: : name?int ( nt -- xt ) \ gforth
329: \G Like @code{name>int}, but perform @code{-2048 throw} if @i{nt}
330: \G has no interpretation semantics.
331: (name>x) restrict-mask and
332: if
333: ticking-compile-only-error \ does not return
334: then
335: (cfa>int) ;
336:
337: : (name>comp) ( nt -- w +-1 ) \ gforth
338: \G @i{w xt} is the compilation token for the word @i{nt}.
339: (name>x) >r
340: [ has? compiler [IF] ]
341: dup interpret/compile?
342: if
343: interpret/compile-comp @
344: then
345: [ [THEN] ]
346: r> immediate-mask and flag-sign
347: ;
348:
349: : (name>intn) ( nfa -- xt +-1 )
350: (name>x) tuck (x>int) ( w xt )
351: swap immediate-mask and flag-sign ;
352:
353: const Create ??? 0 , 3 , char ? c, char ? c, char ? c,
354: \ ??? is used by dovar:, must be created/:dovar
355:
356: [IFDEF] forthstart
357: \ if we have a forthstart we can define head? with it
358: \ otherwise leave out the head? check
359:
360: : head? ( addr -- f )
361: \G heuristic check whether addr is a name token; may deliver false
362: \G positives; addr must be a valid address; returns 1 for
363: \G particularly unsafe positives
364: \ we follow the link fields and check for plausibility; two
365: \ iterations should catch most false addresses: on the first
366: \ iteration, we may get an xt, on the second a code address (or
367: \ some code), which is typically not in the dictionary.
368: \ we added a third iteration for working with code and ;code words.
369: 3 0 do
370: dup dup aligned <> if \ protect @ against unaligned accesses
371: drop false unloop exit
372: then
373: dup @ dup
374: if ( addr addr1 )
375: dup rot forthstart within
376: if \ addr1 is outside forthstart..addr, not a head
377: drop false unloop exit
378: then ( addr1 )
379: else \ 0 in the link field, no further checks
380: 2drop 1 unloop exit \ this is very unsure, so return 1
381: then
382: loop
383: \ in dubio pro:
384: drop true ;
385:
386: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
387: \ also heuristic; finds only names with up to 32 chars
388: $25 cell do ( cfa )
389: dup i - dup @ [ alias-mask lcount-mask or ] literal
390: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
391: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
392: [ELSE] -1 1 cells 1- times c, [THEN] ]
393: and ( cfa len|alias )
394: swap + cell + cfaligned over alias-mask + =
395: if ( cfa )
396: dup i - cell - dup head?
397: if
398: nip unloop exit
399: then
400: drop
401: then
402: cell +loop
403: drop ??? ( wouldn't 0 be better? ) ;
404:
405: [ELSE]
406:
407: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
408: $25 cell do ( cfa )
409: dup i - dup @ [ alias-mask lcount-mask or ] literal
410: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
411: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
412: [ELSE] -1 1 cells 1- times c, [THEN] ]
413: and ( cfa len|alias )
414: swap + cell + cfaligned over alias-mask + =
415: if ( cfa ) i - cell - unloop exit
416: then
417: cell +loop
418: drop ??? ( wouldn't 0 be better? ) ;
419:
420: [THEN]
421:
422: : body> 0 >body - ;
423:
424: : (search-wordlist) ( addr count wid -- nt | false )
425: dup wordlist-map @ find-method perform ;
426:
427: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
428: \G Search the word list identified by @i{wid} for the definition
429: \G named by the string at @i{c-addr count}. If the definition is
430: \G not found, return 0. If the definition is found return 1 (if
431: \G the definition is immediate) or -1 (if the definition is not
432: \G immediate) together with the @i{xt}. In Gforth, the @i{xt}
433: \G returned represents the interpretation semantics. ANS Forth
434: \G does not specify clearly what @i{xt} represents.
435: (search-wordlist) dup if
436: (name>intn)
437: then ;
438:
439: : find-name ( c-addr u -- nt | 0 ) \ gforth
440: \g Find the name @i{c-addr u} in the current search
441: \g order. Return its @i{nt}, if found, otherwise 0.
442: lookup @ (search-wordlist) ;
443:
444: : sfind ( c-addr u -- 0 / xt +-1 ) \ gforth-obsolete
445: find-name dup
446: if ( nt )
447: state @
448: if
449: (name>comp)
450: else
451: (name>intn)
452: then
453: then ;
454:
455: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
456: \G Search all word lists in the current search order for the
457: \G definition named by the counted string at @i{c-addr}. If the
458: \G definition is not found, return 0. If the definition is found
459: \G return 1 (if the definition has non-default compilation
460: \G semantics) or -1 (if the definition has default compilation
461: \G semantics). The @i{xt} returned in interpret state represents
462: \G the interpretation semantics. The @i{xt} returned in compile
463: \G state represented either the compilation semantics (for
464: \G non-default compilation semantics) or the run-time semantics
465: \G that the compilation semantics would @code{compile,} (for
466: \G default compilation semantics). The ANS Forth standard does
467: \G not specify clearly what the returned @i{xt} represents (and
468: \G also talks about immediacy instead of non-default compilation
469: \G semantics), so this word is questionable in portable programs.
470: \G If non-portability is ok, @code{find-name} and friends are
471: \G better (@pxref{Name token}).
472: dup count sfind dup
473: if
474: rot drop
475: then ;
476:
477: \ ticks in interpreter
478:
479: : (') ( "name" -- nt ) \ gforth
480: name name-too-short?
481: find-name dup 0=
482: IF
483: drop -&13 throw
484: THEN ;
485:
486: : ' ( "name" -- xt ) \ core tick
487: \g @i{xt} represents @i{name}'s interpretation
488: \g semantics. Perform @code{-14 throw} if the word has no
489: \g interpretation semantics.
490: (') name?int ;
491:
492: has? compiler 0= [IF] \ interpreter only version of IS and TO
493:
494: : IS ' >body ! ;
495: ' IS Alias TO
496:
497: [THEN]
498:
499: \ \ the interpreter loop mar92py
500:
501: \ interpret 10mar92py
502:
503: Defer parser ( c-addr u -- )
504: Defer parse-word ( -- c-addr count ) \ gforth
505: \G Get the next word from the input buffer
506: ' (name) IS parse-word
507:
508: ' parse-word alias name ( -- c-addr u ) \ gforth-obsolete
509: \G old name for @code{parse-word}
510:
511: Defer compiler-notfound ( c-addr count -- )
512: Defer interpreter-notfound ( c-addr count -- )
513:
514: : no.extensions ( addr u -- )
515: 2drop -&13 throw ;
516: ' no.extensions IS compiler-notfound
517: ' no.extensions IS interpreter-notfound
518:
519: : interpret1 ( ... -- ... )
520: [ has? backtrace [IF] ]
521: rp@ backtrace-rp0 !
522: [ [THEN] ]
523: BEGIN
524: ?stack name dup
525: WHILE
526: parser
527: REPEAT
528: 2drop ;
529:
530: : interpret ( ?? -- ?? ) \ gforth
531: \ interpret/compile the (rest of the) input buffer
532: [ has? backtrace [IF] ]
533: backtrace-rp0 @ >r
534: [ [THEN] ]
535: ['] interpret1 catch
536: [ has? backtrace [IF] ]
537: r> backtrace-rp0 !
538: [ [THEN] ]
539: throw ;
540:
541: \ interpreter 30apr92py
542:
543: \ not the most efficient implementations of interpreter and compiler
544: : interpreter ( c-addr u -- )
545: 2dup find-name dup
546: if
547: nip nip name>int execute
548: else
549: drop
550: 2dup 2>r snumber?
551: IF
552: 2rdrop
553: ELSE
554: 2r> interpreter-notfound
555: THEN
556: then ;
557:
558: ' interpreter IS parser
559:
560: \ \ Query Evaluate 07apr93py
561:
562: has? file 0= [IF]
563: : sourceline# ( -- n ) 1 ;
564: [ELSE]
565: has? new-input 0= [IF]
566: Variable #fill-bytes
567: \G number of bytes read via (read-line) by the last refill
568: [THEN]
569: [THEN]
570:
571: has? new-input 0= [IF]
572: : refill ( -- flag ) \ core-ext,block-ext,file-ext
573: \G Attempt to fill the input buffer from the input source. When
574: \G the input source is the user input device, attempt to receive
575: \G input into the terminal input device. If successful, make the
576: \G result the input buffer, set @code{>IN} to 0 and return true;
577: \G otherwise return false. When the input source is a block, add 1
578: \G to the value of @code{BLK} to make the next block the input
579: \G source and current input buffer, and set @code{>IN} to 0;
580: \G return true if the new value of @code{BLK} is a valid block
581: \G number, false otherwise. When the input source is a text file,
582: \G attempt to read the next line from the file. If successful,
583: \G make the result the current input buffer, set @code{>IN} to 0
584: \G and return true; otherwise, return false. A successful result
585: \G includes receipt of a line containing 0 characters.
586: [ has? file [IF] ]
587: blk @ IF 1 blk +! true 0 >in ! EXIT THEN
588: [ [THEN] ]
589: tib /line
590: [ has? file [IF] ]
591: loadfile @ ?dup
592: IF (read-line) throw #fill-bytes !
593: ELSE
594: [ [THEN] ]
595: sourceline# 0< IF 2drop false EXIT THEN
596: accept true
597: [ has? file [IF] ]
598: THEN
599: 1 loadline +!
600: [ [THEN] ]
601: swap #tib ! 0 >in ! ;
602:
603: : query ( -- ) \ core-ext
604: \G Make the user input device the input source. Receive input into
605: \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
606: \G superceeded by @code{accept}.
607: [ has? file [IF] ]
608: blk off loadfile off
609: [ [THEN] ]
610: refill drop ;
611: [THEN]
612:
613: \ save-mem extend-mem
614:
615: has? os [IF]
616: : save-mem ( addr1 u -- addr2 u ) \ gforth
617: \g copy a memory block into a newly allocated region in the heap
618: swap >r
619: dup allocate throw
620: swap 2dup r> -rot move ;
621:
622: : free-mem-var ( addr -- )
623: \ addr is the address of a 2variable containing address and size
624: \ of a memory range; frees memory and clears the 2variable.
625: dup 2@ drop dup
626: if ( addr mem-start )
627: free throw
628: 0 0 rot 2!
629: else
630: 2drop
631: then ;
632:
633: : extend-mem ( addr1 u1 u -- addr addr2 u2 )
634: \ extend memory block allocated from the heap by u aus
635: \ the (possibly reallocated piece is addr2 u2, the extension is at addr
636: over >r + dup >r resize throw
637: r> over r> + -rot ;
638: [THEN]
639:
640: \ EVALUATE 17may93jaw
641:
642: has? file 0= has? new-input 0= and [IF]
643: : push-file ( -- ) r>
644: tibstack @ >r >tib @ >r #tib @ >r
645: >tib @ tibstack @ = IF r@ tibstack +! THEN
646: tibstack @ >tib ! >in @ >r >r ;
647:
648: : pop-file ( throw-code -- throw-code )
649: r>
650: r> >in ! r> #tib ! r> >tib ! r> tibstack ! >r ;
651: [THEN]
652:
653: has? new-input 0= [IF]
654: : evaluate ( c-addr u -- ) \ core,block
655: \G Save the current input source specification. Store @code{-1} in
656: \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
657: \G @code{0} and make the string @i{c-addr u} the input source
658: \G and input buffer. Interpret. When the parse area is empty,
659: \G restore the input source specification.
660: [ has? file [IF] ]
661: loadfilename# @ >r
662: 1 loadfilename# ! \ "*evaluated string*"
663: [ [THEN] ]
664: push-file #tib ! >tib !
665: >in off
666: [ has? file [IF] ]
667: blk off loadfile off -1 loadline !
668: [ [THEN] ]
669: ['] interpret catch
670: pop-file
671: [ has? file [IF] ]
672: r> loadfilename# !
673: [ [THEN] ]
674: throw ;
675: [THEN]
676:
677: \ \ Quit 13feb93py
678:
679: Defer 'quit
680:
681: Defer .status
682:
683: : prompt state @ IF ." compiled" EXIT THEN ." ok" ;
684:
685: : (quit) ( -- )
686: \ exits only through THROW etc.
687: \ sp0 @ cell - handler @ &12 + ! \ !! kludge: fix the stack pointer
688: \ stored in the system's CATCH frame, so the stack depth will be 0
689: \ after the next THROW it catches (it may be off due to BOUNCEs or
690: \ because process-args left something on the stack)
691: BEGIN
692: .status cr query interpret prompt
693: AGAIN ;
694:
695: ' (quit) IS 'quit
696:
697: \ \ DOERROR (DOERROR) 13jun93jaw
698:
699: 8 Constant max-errors
700: Variable error-stack 0 error-stack !
701: max-errors has? file [IF] 6 [ELSE] 4 [THEN] * cells allot
702: \ format of one cell:
703: \ source ( addr u )
704: \ >in
705: \ line-number
706: \ Loadfilename ( addr u )
707:
708: : error> ( -- addr u >in line# [addr u] )
709: -1 error-stack +!
710: error-stack dup @
711: [ has? file [IF] 6 [ELSE] 4 [THEN] ] Literal * cells + cell+
712: [ has? file [IF] 6 [ELSE] 4 [THEN] ] Literal cells bounds DO
713: I @
714: cell +LOOP ;
715: : >error ( addr u >in line# [addr u] -- )
716: error-stack dup @ dup 1+
717: max-errors 1- min error-stack !
718: [ has? file [IF] 6 [ELSE] 4 [THEN] ] Literal * cells + cell+
719: [ has? file [IF] 6 [ELSE] 4 [THEN] 1- ] Literal cells bounds swap DO
720: I !
721: -1 cells +LOOP ;
722:
723: : dec. ( n -- ) \ gforth
724: \G Display @i{n} as a signed decimal number, followed by a space.
725: \ !! not used...
726: base @ decimal swap . base ! ;
727:
728: : dec.r ( u -- ) \ gforth
729: \G Display @i{u} as a unsigned decimal number
730: base @ decimal swap 0 .r base ! ;
731:
732: : hex. ( u -- ) \ gforth
733: \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
734: \G followed by a space.
735: \ !! not used...
736: [char] $ emit base @ swap hex u. base ! ;
737:
738: : typewhite ( addr u -- ) \ gforth
739: \G Like type, but white space is printed instead of the characters.
740: bounds ?do
741: i c@ #tab = if \ check for tab
742: #tab
743: else
744: bl
745: then
746: emit
747: loop ;
748:
749: DEFER DOERROR
750:
751: has? backtrace [IF]
752: Defer dobacktrace ( -- )
753: ' noop IS dobacktrace
754: [THEN]
755:
756: : .error-string ( throw-code -- )
757: dup -2 =
758: IF "error @ ?dup IF count type THEN drop
759: ELSE .error
760: THEN ;
761:
762: : .error-frame ( throwcode addr1 u1 n1 n2 [addr2 u2] -- throwcode )
763: \ addr2 u2: filename of included file - optional
764: \ n2: line number
765: \ n1: error position in input line
766: \ addr1 u1: input line
767: cr error-stack @
768: IF
769: [ has? file [IF] ]
770: ." in file included from "
771: type ." :"
772: [ [THEN] ]
773: dec.r drop 2drop
774: ELSE
775: [ has? file [IF] ]
776: type ." :"
777: [ [THEN] ]
778: dup >r dec.r ." : " 3 pick .error-string
779: r> IF \ if line# non-zero, there is a line
780: cr dup 2over type cr drop
781: nip -trailing 1- ( line-start index2 )
782: 0 >r BEGIN
783: 2dup + c@ bl > WHILE
784: r> 1+ >r 1- dup 0< UNTIL THEN 1+
785: ( line-start index1 )
786: typewhite
787: r> 1 max 0 ?do \ we want at least one "^", even if the length is 0
788: [char] ^ emit
789: loop
790: ELSE
791: 2drop drop
792: THEN
793: THEN ;
794:
795: : (DoError) ( throw-code -- )
796: [ has? os [IF] ]
797: >stderr
798: [ [THEN] ]
799: source >in @ sourceline# [ has? file [IF] ]
800: sourcefilename
801: [ [THEN] ] .error-frame
802: error-stack @ 0 ?DO
803: error>
804: .error-frame
805: LOOP
806: drop
807: [ has? backtrace [IF] ]
808: dobacktrace
809: [ [THEN] ]
810: normal-dp dpp ! ;
811:
812: ' (DoError) IS DoError
813:
814: : quit ( ?? -- ?? ) \ core
815: \G Empty the return stack, make the user input device
816: \G the input source, enter interpret state and start
817: \G the text interpreter.
818: rp0 @ rp! handler off clear-tibstack
819: [ has? new-input 0= [IF] ] >tib @ >r [ [THEN] ]
820: BEGIN
821: [ has? compiler [IF] ]
822: [compile] [
823: [ [THEN] ]
824: ['] 'quit CATCH dup
825: WHILE
826: <# \ reset hold area, or we may get another error
827: DoError
828: [ has? new-input [IF] ] clear-tibstack
829: [ [ELSE] ] r@ >tib ! r@ tibstack !
830: [ [THEN] ]
831: REPEAT
832: drop [ has? new-input [IF] ] clear-tibstack
833: [ [ELSE] ] r> >tib !
834: [ [THEN] ] ;
835:
836: \ \ Cold Boot 13feb93py
837:
838: : (bootmessage)
839: ." GForth " version-string type
840: ." , Copyright (C) 1995-2000 Free Software Foundation, Inc." cr
841: ." GForth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
842: [ has? os [IF] ]
843: cr ." Type `bye' to exit"
844: [ [THEN] ] ;
845:
846: defer bootmessage
847: defer process-args
848:
849: ' (bootmessage) IS bootmessage
850:
851: Defer 'cold ( -- ) \ gforth tick-cold
852: \ hook (deferred word) for things to do right before interpreting the
853: \ command-line arguments
854: ' noop IS 'cold
855:
856:
857: AVariable init8 NIL init8 !
858:
859: : cold ( -- ) \ gforth
860: [ has? backtrace [IF] ]
861: rp@ backtrace-rp0 !
862: [ [THEN] ]
863: [ has? file [IF] ]
864: os-cold
865: [ [THEN] ]
866: 'cold
867: init8 chainperform
868: [ has? file [IF] ]
869: loadfilename# off
870: process-args
871: loadline off
872: [ [THEN] ]
873: bootmessage
874: quit ;
875:
876: has? new-input 0= [IF]
877: : clear-tibstack ( -- )
878: [ has? glocals [IF] ]
879: lp@ forthstart 7 cells + @ -
880: [ [ELSE] ]
881: [ has? os [IF] ]
882: r0 @ forthstart 6 cells + @ -
883: [ [ELSE] ]
884: sp@ $10 cells +
885: [ [THEN] ]
886: [ [THEN] ]
887: dup >tib ! tibstack ! #tib off >in off ;
888: [THEN]
889:
890: : boot ( path n **argv argc -- )
891: main-task up!
892: [ has? os [IF] ]
893: os-boot
894: [ [THEN] ]
895: sp@ sp0 !
896: [ has? peephole [IF] ]
897: primtable prepare-peephole-table TO peeptable
898: [ [THEN] ]
899: [ has? new-input [IF] ]
900: current-input off
901: [ [THEN] ]
902: clear-tibstack
903: rp@ rp0 !
904: [ has? floating [IF] ]
905: fp@ fp0 !
906: [ [THEN] ]
907: handler off
908: ['] cold catch DoError cr
909: [ has? os [IF] ]
910: 1 (bye) \ !! determin exit code from throw code?
911: [ [THEN] ]
912: ;
913:
914: has? os [IF]
915: : bye ( -- ) \ tools-ext
916: [ has? file [IF] ]
917: script? 0= IF cr THEN
918: [ [ELSE] ]
919: cr
920: [ [THEN] ]
921: 0 (bye) ;
922: [THEN]
923:
924: \ **argv may be scanned by the C starter to get some important
925: \ information, as -display and -geometry for an X client FORTH
926: \ or space and stackspace overrides
927:
928: \ 0 arg contains, however, the name of the program.
929:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>