File:  [gforth] / gforth / kernel / int.fs
Revision 1.56: download - view: text, annotated - select for diffs
Wed Sep 6 20:30:07 2000 UTC (23 years, 6 months ago) by anton
Branches: MAIN
CVS tags: HEAD
improved error messages for errors happening in non-files.

    1: \ definitions needed for interpreter only
    2: 
    3: \ Copyright (C) 1995-2000 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: \ \ Revision-Log
   22: 
   23: \       put in seperate file				14sep97jaw 
   24: 
   25: \ \ input stream primitives                       	23feb93py
   26: 
   27: require ./basics.fs 	\ bounds decimal hex ...
   28: require ./io.fs		\ type ...
   29: require ./nio.fs	\ . <# ...
   30: require ./errore.fs	\ .error ...
   31: require kernel/version.fs	\ version-string
   32: require ./../chains.fs
   33: 
   34: : tib ( -- c-addr ) \ core-ext t-i-b
   35:     \G @i{c-addr} is the address of the Terminal Input Buffer.
   36:     \G OBSOLESCENT: @code{source} superceeds the function of this word.
   37:     >tib @ ;
   38: 
   39: Defer source ( -- c-addr u ) \ core
   40: \ used by dodefer:, must be defer
   41: \G @i{c-addr} is the address of the input buffer and @i{u} is the
   42: \G number of characters in it.
   43: 
   44: : (source) ( -- c-addr u )
   45:     tib #tib @ ;
   46: ' (source) IS source
   47: 
   48: : (word) ( addr1 n1 char -- addr2 n2 )
   49:   dup >r skip 2dup r> scan  nip - ;
   50: 
   51: \ (word) should fold white spaces
   52: \ this is what (parse-white) does
   53: 
   54: \ word parse                                           23feb93py
   55: 
   56: : sword  ( char -- addr len ) \ gforth s-word
   57:     \G Parses like @code{word}, but the output is like @code{parse} output.
   58:     \G @xref{core-idef}.
   59:   \ this word was called PARSE-WORD until 0.3.0, but Open Firmware and
   60:   \ dpANS6 A.6.2.2008 have a word with that name that behaves
   61:   \ differently (like NAME).
   62:   source 2dup >r >r >in @ over min /string
   63:   rot dup bl = IF  drop (parse-white)  ELSE  (word)  THEN
   64:   2dup + r> - 1+ r> min >in ! ;
   65: 
   66: : word   ( char "<chars>ccc<char>-- c-addr ) \ core
   67:     \G Skip leading delimiters. Parse @i{ccc}, delimited by
   68:     \G @i{char}, in the parse area. @i{c-addr} is the address of a
   69:     \G transient region containing the parsed string in
   70:     \G counted-string format. If the parse area was empty or
   71:     \G contained no characters other than delimiters, the resulting
   72:     \G string has zero length. A program may replace characters within
   73:     \G the counted string. OBSOLESCENT: the counted string has a
   74:     \G trailing space that is not included in its length.
   75:     sword here place  bl here count + c!  here ;
   76: 
   77: : parse    ( char "ccc<char>" -- c-addr u ) \ core-ext
   78:     \G Parse @i{ccc}, delimited by @i{char}, in the parse
   79:     \G area. @i{c-addr u} specifies the parsed string within the
   80:     \G parse area. If the parse area was empty, @i{u} is 0.
   81:     >r  source  >in @ over min /string  over  swap r>  scan >r
   82:   over - dup r> IF 1+ THEN  >in +! ;
   83: 
   84: \ name                                                 13feb93py
   85: 
   86: [IFUNDEF] (name) \ name might be a primitive
   87: 
   88: : (name) ( -- c-addr count ) \ gforth
   89:     source 2dup >r >r >in @ /string (parse-white)
   90:     2dup + r> - 1+ r> min >in ! ;
   91: \    name count ;
   92: [THEN]
   93: 
   94: : name-too-short? ( c-addr u -- c-addr u )
   95:     dup 0= -&16 and throw ;
   96: 
   97: : name-too-long? ( c-addr u -- c-addr u )
   98:     dup $1F u> -&19 and throw ;
   99: 
  100: \ \ Number parsing					23feb93py
  101: 
  102: \ number? number                                       23feb93py
  103: 
  104: hex
  105: const Create bases   10 ,   2 ,   A , 100 ,
  106: \                     16     2    10   character
  107: 
  108: \ !! protect BASE saving wrapper against exceptions
  109: : getbase ( addr u -- addr' u' )
  110:     over c@ [char] $ - dup 4 u<
  111:     IF
  112: 	cells bases + @ base ! 1 /string
  113:     ELSE
  114: 	drop
  115:     THEN ;
  116: 
  117: : sign? ( addr u -- addr u flag )
  118:     over c@ [char] - =  dup >r
  119:     IF
  120: 	1 /string
  121:     THEN
  122:     r> ;
  123: 
  124: : s>unumber? ( addr u -- ud flag )
  125:     base @ >r  dpl on  getbase
  126:     0. 2swap
  127:     BEGIN ( d addr len )
  128: 	dup >r >number dup
  129:     WHILE \ there are characters left
  130: 	dup r> -
  131:     WHILE \ the last >number parsed something
  132: 	dup 1- dpl ! over c@ [char] . =
  133:     WHILE \ the current char is '.'
  134: 	1 /string
  135:     REPEAT  THEN \ there are unparseable characters left
  136: 	2drop false
  137:     ELSE
  138: 	rdrop 2drop true
  139:     THEN
  140:     r> base ! ;
  141: 
  142: \ ouch, this is complicated; there must be a simpler way - anton
  143: : s>number? ( addr len -- d f )
  144:     \ converts string addr len into d, flag indicates success
  145:     sign? >r
  146:     s>unumber?
  147:     0= IF
  148:         rdrop false
  149:     ELSE \ no characters left, all ok
  150: 	r>
  151: 	IF
  152: 	    dnegate
  153: 	THEN
  154: 	true
  155:     THEN ;
  156: 
  157: : s>number ( addr len -- d )
  158:     \ don't use this, there is no way to tell success
  159:     s>number? drop ;
  160: 
  161: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
  162:     s>number? 0=
  163:     IF
  164: 	2drop false  EXIT
  165:     THEN
  166:     dpl @ dup 0< IF
  167: 	nip
  168:     ELSE
  169: 	1+
  170:     THEN ;
  171: 
  172: : number? ( string -- string 0 / n -1 / d 0> )
  173:     dup >r count snumber? dup if
  174: 	rdrop
  175:     else
  176: 	r> swap
  177:     then ;
  178: 
  179: : number ( string -- d )
  180:     number? ?dup 0= abort" ?"  0<
  181:     IF
  182: 	s>d
  183:     THEN ;
  184: 
  185: \ \ Comments ( \ \G
  186: 
  187: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file	paren
  188:     \G ** this will not get annotated. The alias in glocals.fs will instead **
  189:     \G It does not work to use "wordset-" prefix since this file is glossed
  190:     \G by cross.fs which doesn't have the same functionalty as makedoc.fs
  191:     [char] ) parse 2drop ; immediate
  192: 
  193: : \ ( compilation 'ccc<newline>' -- ; run-time -- ) \ thisone- core-ext,block-ext backslash
  194:     \G ** this will not get annotated. The alias in glocals.fs will instead ** 
  195:     \G It does not work to use "wordset-" prefix since this file is glossed
  196:     \G by cross.fs which doesn't have the same functionalty as makedoc.fs
  197:     [ has? file [IF] ]
  198:     blk @
  199:     IF
  200: 	>in @ c/l / 1+ c/l * >in !
  201: 	EXIT
  202:     THEN
  203:     [ [THEN] ]
  204:     source >in ! drop ; immediate
  205: 
  206: : \G ( compilation 'ccc<newline>' -- ; run-time -- ) \ gforth backslash-gee
  207:     \G Equivalent to @code{\} but used as a tag to annotate definition
  208:     \G comments into documentation.
  209:     POSTPONE \ ; immediate
  210: 
  211: \ \ object oriented search list                         17mar93py
  212: 
  213: \ word list structure:
  214: 
  215: struct
  216:   cell% field find-method   \ xt: ( c_addr u wid -- nt )
  217:   cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
  218:   cell% field rehash-method \ xt: ( wid -- )	   \ re-initializes a "search-data" (hashtables)
  219:   cell% field hash-method   \ xt: ( wid -- )    \ initializes ""
  220: \   \ !! what else
  221: end-struct wordlist-map-struct
  222: 
  223: struct
  224:   cell% field wordlist-map \ pointer to a wordlist-map-struct
  225:   cell% field wordlist-id \ linked list of words (for WORDS etc.)
  226:   cell% field wordlist-link \ link field to other wordlists
  227:   cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
  228: end-struct wordlist-struct
  229: 
  230: : f83find      ( addr len wordlist -- nt / false )
  231:     wordlist-id @ (f83find) ;
  232: 
  233: : initvoc		( wid -- )
  234:   dup wordlist-map @ hash-method perform ;
  235: 
  236: \ Search list table: find reveal
  237: Create f83search ( -- wordlist-map )
  238:     ' f83find A,  ' drop A,  ' drop A, ' drop A,
  239: 
  240: here G f83search T A, NIL A, NIL A, NIL A,
  241: AValue forth-wordlist \ variable, will be redefined by search.fs
  242: 
  243: AVariable lookup       	forth-wordlist lookup !
  244: \ !! last is user and lookup?! jaw
  245: AVariable current ( -- addr ) \ gforth
  246: \G @code{Variable} -- holds the @i{wid} of the compilation word list.
  247: AVariable voclink	forth-wordlist wordlist-link voclink !
  248: \ lookup AValue context ( -- addr ) \ gforth
  249: Defer context ( -- addr ) \ gforth
  250: \G @code{context} @code{@@} is the @i{wid} of the word list at the
  251: \G top of the search order.
  252: 
  253: ' lookup is context
  254: forth-wordlist current !
  255: 
  256: \ \ header, finding, ticks                              17dec92py
  257: 
  258: hex
  259: 80 constant alias-mask \ set when the word is not an alias!
  260: 40 constant immediate-mask
  261: 20 constant restrict-mask
  262: 
  263: \ higher level parts of find
  264: 
  265: : flag-sign ( f -- 1|-1 )
  266:     \ true becomes 1, false -1
  267:     0= 2* 1+ ;
  268: 
  269: : compile-only-error ( ... -- )
  270:     -&14 throw ;
  271: 
  272: : (cfa>int) ( cfa -- xt )
  273: [ has? compiler [IF] ]
  274:     dup interpret/compile?
  275:     if
  276: 	interpret/compile-int @
  277:     then 
  278: [ [THEN] ] ;
  279: 
  280: : (x>int) ( cfa b -- xt )
  281:     \ get interpretation semantics of name
  282:     restrict-mask and
  283:     if
  284: 	drop ['] compile-only-error
  285:     else
  286: 	(cfa>int)
  287:     then ;
  288: 
  289: : name>string ( nt -- addr count ) \ gforth     head-to-string
  290:     \g @i{addr count} is the name of the word represented by @i{nt}.
  291:     cell+ count $1F and ;
  292: 
  293: : ((name>))  ( nfa -- cfa )
  294:     name>string + cfaligned ;
  295: 
  296: : (name>x) ( nfa -- cfa b )
  297:     \ cfa is an intermediate cfa and b is the flags byte of nfa
  298:     dup ((name>))
  299:     swap cell+ c@ dup alias-mask and 0=
  300:     IF
  301:         swap @ swap
  302:     THEN ;
  303: 
  304: : name>int ( nt -- xt ) \ gforth
  305:     \G @i{xt} represents the interpretation semantics of the word
  306:     \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
  307:     \G @code{compile-only}), @i{xt} is the execution token for
  308:     \G @code{compile-only-error}, which performs @code{-14 throw}.
  309:     (name>x) (x>int) ;
  310: 
  311: : name?int ( nt -- xt ) \ gforth
  312:     \G Like @code{name>int}, but perform @code{-14 throw} if @i{nt}
  313:     \G has no interpretation semantics.
  314:     (name>x) restrict-mask and
  315:     if
  316: 	compile-only-error \ does not return
  317:     then
  318:     (cfa>int) ;
  319: 
  320: : (name>comp) ( nt -- w +-1 ) \ gforth
  321:     \G @i{w xt} is the compilation token for the word @i{nt}.
  322:     (name>x) >r 
  323: [ has? compiler [IF] ]
  324:     dup interpret/compile?
  325:     if
  326:         interpret/compile-comp @
  327:     then 
  328: [ [THEN] ]
  329:     r> immediate-mask and flag-sign
  330:     ;
  331: 
  332: : (name>intn) ( nfa -- xt +-1 )
  333:     (name>x) tuck (x>int) ( b xt )
  334:     swap immediate-mask and flag-sign ;
  335: 
  336: const Create ???  0 , 3 c, char ? c, char ? c, char ? c,
  337: \ ??? is used by dovar:, must be created/:dovar
  338: 
  339: [IFDEF] forthstart
  340: \ if we have a forthstart we can define head? with it
  341: \ otherwise leave out the head? check
  342: 
  343: : head? ( addr -- f )
  344:     \G heuristic check whether addr is a name token; may deliver false
  345:     \G positives; addr must be a valid address
  346:     \ we follow the link fields and check for plausibility; two
  347:     \ iterations should catch most false addresses: on the first
  348:     \ iteration, we may get an xt, on the second a code address (or
  349:     \ some code), which is typically not in the dictionary.
  350:     2 0 do
  351: 	dup dup aligned <> if \ protect @ against unaligned accesses
  352: 	    drop false unloop exit
  353: 	then
  354: 	dup @ dup
  355: 	if ( addr addr1 )
  356: 	    dup rot forthstart within
  357: 	    if \ addr1 is outside forthstart..addr, not a head
  358: 		drop false unloop exit
  359: 	    then ( addr1 )
  360: 	else \ 0 in the link field, no further checks
  361: 	    2drop true unloop exit
  362: 	then
  363:     loop
  364:     \ in dubio pro:
  365:     drop true ;
  366: 
  367: : >head-noprim ( cfa -- nt ) \ gforth  to-head-noprim
  368:     $25 cell do ( cfa )
  369: 	dup i - count $9F and + cfaligned over alias-mask + =
  370: 	if ( cfa )
  371: 	    dup i - cell - dup head?
  372: 	    if
  373: 		nip unloop exit
  374: 	    then
  375: 	    drop
  376: 	then
  377: 	cell +loop
  378:     drop ??? ( wouldn't 0 be better? ) ;
  379: 
  380: [ELSE]
  381: 
  382: : >head-noprim ( cfa -- nt ) \ gforth  to-head-noprim
  383:     $25 cell do ( cfa )
  384: 	dup i - count $9F and + cfaligned over alias-mask + =
  385: 	if ( cfa ) i - cell - unloop exit
  386: 	then
  387: 	cell +loop
  388:     drop ??? ( wouldn't 0 be better? ) ;
  389: 
  390: [THEN]
  391: 
  392: : body> 0 >body - ;
  393: 
  394: : (search-wordlist)  ( addr count wid -- nt | false )
  395:     dup wordlist-map @ find-method perform ;
  396: 
  397: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
  398:     \G Search the word list identified by @i{wid} for the definition
  399:     \G named by the string at @i{c-addr count}.  If the definition is
  400:     \G not found, return 0. If the definition is found return 1 (if
  401:     \G the definition is immediate) or -1 (if the definition is not
  402:     \G immediate) together with the @i{xt}.  In Gforth, the @i{xt}
  403:     \G returned represents the interpretation semantics.  ANS Forth
  404:     \G does not specify clearly what @i{xt} represents.
  405:     (search-wordlist) dup if
  406: 	(name>intn)
  407:     then ;
  408: 
  409: : find-name ( c-addr u -- nt | 0 ) \ gforth
  410:     \g Find the name @i{c-addr u} in the current search
  411:     \g order. Return its @i{nt}, if found, otherwise 0.
  412:     lookup @ (search-wordlist) ;
  413: 
  414: : sfind ( c-addr u -- 0 / xt +-1  ) \ gforth-obsolete
  415:     find-name dup
  416:     if ( nt )
  417: 	state @
  418: 	if
  419: 	    (name>comp)
  420: 	else
  421: 	    (name>intn)
  422: 	then
  423:    then ;
  424: 
  425: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
  426:     \G Search all word lists in the current search order for the
  427:     \G definition named by the counted string at @i{c-addr}.  If the
  428:     \G definition is not found, return 0. If the definition is found
  429:     \G return 1 (if the definition has non-default compilation
  430:     \G semantics) or -1 (if the definition has default compilation
  431:     \G semantics).  The @i{xt} returned in interpret state represents
  432:     \G the interpretation semantics.  The @i{xt} returned in compile
  433:     \G state represented either the compilation semantics (for
  434:     \G non-default compilation semantics) or the run-time semantics
  435:     \G that the compilation semantics would @code{compile,} (for
  436:     \G default compilation semantics).  The ANS Forth standard does
  437:     \G not specify clearly what the returned @i{xt} represents (and
  438:     \G also talks about immediacy instead of non-default compilation
  439:     \G semantics), so this word is questionable in portable programs.
  440:     \G If non-portability is ok, @code{find-name} and friends are
  441:     \G better (@pxref{Name token}).
  442:     dup count sfind dup
  443:     if
  444: 	rot drop
  445:     then ;
  446: 
  447: \ ticks in interpreter
  448: 
  449: : (') ( "name" -- nt ) \ gforth
  450:     name name-too-short?
  451:     find-name dup 0=
  452:     IF
  453: 	drop -&13 throw
  454:     THEN  ;
  455: 
  456: : '    ( "name" -- xt ) \ core	tick
  457:     \g @i{xt} represents @i{name}'s interpretation
  458:     \g semantics. Perform @code{-14 throw} if the word has no
  459:     \g interpretation semantics.
  460:     (') name?int ;
  461: 
  462: has? compiler 0= [IF]	\ interpreter only version of IS and TO
  463: 
  464: : IS ' >body ! ;
  465: ' IS Alias TO
  466: 
  467: [THEN]
  468: 
  469: \ \ the interpreter loop				  mar92py
  470: 
  471: \ interpret                                            10mar92py
  472: 
  473: Defer parser ( c-addr u -- )
  474: Defer name ( -- c-addr count ) \ gforth
  475: \G Get the next word from the input buffer
  476: ' (name) IS name
  477: Defer compiler-notfound ( c-addr count -- )
  478: Defer interpreter-notfound ( c-addr count -- )
  479: 
  480: : no.extensions  ( addr u -- )
  481:     2drop -&13 throw ;
  482: ' no.extensions IS compiler-notfound
  483: ' no.extensions IS interpreter-notfound
  484: 
  485: : interpret ( ?? -- ?? ) \ gforth
  486:     \ interpret/compile the (rest of the) input buffer
  487: [ has? backtrace [IF] ]
  488:     rp@ backtrace-rp0 !
  489: [ [THEN] ]
  490:     BEGIN
  491: 	?stack name dup
  492:     WHILE
  493: 	parser
  494:     REPEAT
  495:     2drop ;
  496: 
  497: \ interpreter                                 	30apr92py
  498: 
  499: \ not the most efficient implementations of interpreter and compiler
  500: : interpreter ( c-addr u -- ) 
  501:     2dup find-name dup
  502:     if
  503: 	nip nip name>int execute
  504:     else
  505: 	drop
  506: 	2dup 2>r snumber?
  507: 	IF
  508: 	    2rdrop
  509: 	ELSE
  510: 	    2r> interpreter-notfound
  511: 	THEN
  512:     then ;
  513: 
  514: ' interpreter  IS  parser
  515: 
  516: \ \ Query Evaluate                                 	07apr93py
  517: 
  518: has? file 0= [IF]
  519: : sourceline# ( -- n )  1 ;
  520: [THEN]
  521: 
  522: : refill ( -- flag ) \ core-ext,block-ext,file-ext
  523:     \G Attempt to fill the input buffer from the input source.  When
  524:     \G the input source is the user input device, attempt to receive
  525:     \G input into the terminal input device. If successful, make the
  526:     \G result the input buffer, set @code{>IN} to 0 and return true;
  527:     \G otherwise return false. When the input source is a block, add 1
  528:     \G to the value of @code{BLK} to make the next block the input
  529:     \G source and current input buffer, and set @code{>IN} to 0;
  530:     \G return true if the new value of @code{BLK} is a valid block
  531:     \G number, false otherwise. When the input source is a text file,
  532:     \G attempt to read the next line from the file. If successful,
  533:     \G make the result the current input buffer, set @code{>IN} to 0
  534:     \G and return true; otherwise, return false.  A successful result
  535:     \G includes receipt of a line containing 0 characters.
  536:     [ has? file [IF] ]
  537: 	blk @  IF  1 blk +!  true  0 >in !  EXIT  THEN
  538: 	[ [THEN] ]
  539:     tib /line
  540:     [ has? file [IF] ]
  541: 	loadfile @ ?dup
  542: 	IF    read-line throw
  543: 	ELSE
  544: 	    [ [THEN] ]
  545: 	sourceline# 0< IF 2drop false EXIT THEN
  546: 	accept true
  547: 	[ has? file [IF] ]
  548: 	THEN
  549: 	1 loadline +!
  550: 	[ [THEN] ]
  551:     swap #tib ! 0 >in ! ;
  552: 
  553: : query   ( -- ) \ core-ext
  554:     \G Make the user input device the input source. Receive input into
  555:     \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
  556:     \G superceeded by @code{accept}.
  557:     [ has? file [IF] ]
  558: 	blk off loadfile off
  559: 	[ [THEN] ]
  560:     tib /line accept #tib ! 0 >in ! ;
  561: 
  562: \ save-mem extend-mem
  563: 
  564: has? os [IF]
  565: : save-mem	( addr1 u -- addr2 u ) \ gforth
  566:     \g copy a memory block into a newly allocated region in the heap
  567:     swap >r
  568:     dup allocate throw
  569:     swap 2dup r> -rot move ;
  570: 
  571: : extend-mem	( addr1 u1 u -- addr addr2 u2 )
  572:     \ extend memory block allocated from the heap by u aus
  573:     \ the (possibly reallocated piece is addr2 u2, the extension is at addr
  574:     over >r + dup >r resize throw
  575:     r> over r> + -rot ;
  576: [THEN]
  577: 
  578: \ EVALUATE                                              17may93jaw
  579: 
  580: has? file 0= [IF]
  581: : push-file  ( -- )  r>
  582:   tibstack @ >r  >tib @ >r  #tib @ >r
  583:   >tib @ tibstack @ = IF  r@ tibstack +!  THEN
  584:   tibstack @ >tib ! >in @ >r  >r ;
  585: 
  586: : pop-file   ( throw-code -- throw-code )
  587:   r>
  588:   r> >in !  r> #tib !  r> >tib !  r> tibstack !  >r ;
  589: [THEN]
  590: 
  591: : evaluate ( c-addr u -- ) \ core,block
  592:     \G Save the current input source specification. Store @code{-1} in
  593:     \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
  594:     \G @code{0} and make the string @i{c-addr u} the input source
  595:     \G and input buffer. Interpret. When the parse area is empty,
  596:     \G restore the input source specification.
  597:     loadfilename# @ >r
  598:     1 loadfilename# ! \ "\evaluated string/"
  599:     push-file #tib ! >tib !
  600:     >in off
  601:     [ has? file [IF] ]
  602: 	blk off loadfile off -1 loadline !
  603: 	[ [THEN] ]
  604:     ['] interpret catch
  605:     pop-file
  606:     r> loadfilename# !
  607:     throw ;
  608: 
  609: \ \ Quit                                            	13feb93py
  610: 
  611: Defer 'quit
  612: 
  613: Defer .status
  614: 
  615: : prompt        state @ IF ."  compiled" EXIT THEN ."  ok" ;
  616: 
  617: : (Query)  ( -- )
  618:     [ has? file [IF] ]
  619: 	loadfile off  blk off loadline off
  620: 	[ [THEN] ]
  621:     refill drop ;
  622: 
  623: : (quit) ( -- )
  624:     \ exits only through THROW etc.
  625: \    sp0 @ cell - handler @ &12 + ! \ !! kludge: fix the stack pointer
  626:     \ stored in the system's CATCH frame, so the stack depth will be 0
  627:     \ after the next THROW it catches (it may be off due to BOUNCEs or
  628:     \ because process-args left something on the stack)
  629:     BEGIN
  630: 	.status cr (query) interpret prompt
  631:     AGAIN ;
  632: 
  633: ' (quit) IS 'quit
  634: 
  635: \ \ DOERROR (DOERROR)                        		13jun93jaw
  636: 
  637: 8 Constant max-errors
  638: Variable error-stack  0 error-stack !
  639: max-errors 6 * cells allot
  640: \ format of one cell:
  641: \ source ( addr u )
  642: \ >in
  643: \ line-number
  644: \ Loadfilename ( addr u )
  645: 
  646: : dec. ( n -- ) \ gforth
  647:     \G Display @i{n} as a signed decimal number, followed by a space.
  648:     \ !! not used...
  649:     base @ decimal swap . base ! ;
  650: 
  651: : dec.r ( u -- ) \ gforth
  652:     \G Display @i{u} as a unsigned decimal number
  653:     base @ decimal swap 0 .r base ! ;
  654: 
  655: : hex. ( u -- ) \ gforth
  656:     \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
  657:     \G followed by a space.
  658:     \ !! not used...
  659:     [char] $ emit base @ swap hex u. base ! ;
  660: 
  661: : typewhite ( addr u -- ) \ gforth
  662:     \G Like type, but white space is printed instead of the characters.
  663:     bounds ?do
  664: 	i c@ #tab = if \ check for tab
  665: 	    #tab
  666: 	else
  667: 	    bl
  668: 	then
  669: 	emit
  670:     loop ;
  671: 
  672: DEFER DOERROR
  673: 
  674: has? backtrace [IF]
  675: Defer dobacktrace ( -- )
  676: ' noop IS dobacktrace
  677: [THEN]
  678: 
  679: : .error-string ( throw-code -- )
  680:   dup -2 = 
  681:   IF 	"error @ ?dup IF count type  THEN drop
  682:   ELSE	.error
  683:   THEN ;
  684: 
  685: : .error-frame ( throwcode addr1 u1 n1 n2 addr2 u2 -- throwcode )
  686: \ addr2 u2: 	filename of included file
  687: \ n2:		line number
  688: \ n1:		error position in input line
  689: \ addr1 u1:	input line
  690: 
  691:   cr error-stack @
  692:   IF
  693:      ." in file included from "
  694:      type ." :" dec.r  drop 2drop
  695:   ELSE
  696:      type ." :" dec.r ." : " 3 pick .error-string cr
  697:      dup 2over type cr drop
  698:      nip -trailing 1- ( line-start index2 )
  699:      0 >r  BEGIN
  700:                   2dup + c@ bl >  WHILE
  701: 		  r> 1+ >r  1- dup 0<  UNTIL  THEN  1+
  702:      ( line-start index1 )
  703:      typewhite
  704:      r> 1 max 0 ?do \ we want at least one "^", even if the length is 0
  705:                   [char] ^ emit
  706:      loop
  707:   THEN ;
  708: 
  709: : (DoError) ( throw-code -- )
  710:   [ has? os [IF] ]
  711:       >stderr
  712:   [ [THEN] ] 
  713:   sourceline# IF
  714:       source >in @ sourceline# sourcefilename .error-frame
  715:   THEN
  716:   error-stack @ 0 ?DO
  717:     -1 error-stack +!
  718:     error-stack dup @ 6 * cells + cell+
  719:     6 cells bounds DO
  720:       I @
  721:     cell +LOOP
  722:     .error-frame
  723:   LOOP
  724:   drop 
  725: [ has? backtrace [IF] ]
  726:   dobacktrace
  727: [ [THEN] ]
  728:   normal-dp dpp ! ;
  729: 
  730: ' (DoError) IS DoError
  731: 
  732: : quit ( ?? -- ?? ) \ core
  733:     \G Empty the return stack, make the user input device
  734:     \G the input source, enter interpret state and start
  735:     \G the text interpreter.
  736:     rp0 @ rp! handler off clear-tibstack >tib @ >r
  737:     BEGIN
  738: 	[ has? compiler [IF] ]
  739: 	postpone [
  740: 	[ [THEN] ]
  741: 	['] 'quit CATCH dup
  742:     WHILE
  743: 	<# \ reset hold area, or we may get another error
  744: 	DoError r@ >tib ! r@ tibstack !
  745:     REPEAT
  746:     drop r> >tib ! ;
  747: 
  748: \ \ Cold Boot                                    	13feb93py
  749: 
  750: : (bootmessage)
  751:     ." GForth " version-string type 
  752:     ." , Copyright (C) 1995-2000 Free Software Foundation, Inc." cr
  753:     ." GForth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
  754: [ has? os [IF] ]
  755:      cr ." Type `bye' to exit"
  756: [ [THEN] ] ;
  757: 
  758: defer bootmessage
  759: defer process-args
  760: 
  761: ' (bootmessage) IS bootmessage
  762: 
  763: Defer 'cold ( -- ) \ gforth  tick-cold
  764: \ hook (deferred word) for things to do right before interpreting the
  765: \ command-line arguments
  766: ' noop IS 'cold
  767: 
  768: 
  769: Variable init8
  770: 
  771: : cold ( -- ) \ gforth
  772: [ has? backtrace [IF] ]
  773:     rp@ backtrace-rp0 !
  774: [ [THEN] ]
  775: [ has? file [IF] ]
  776:     pathstring 2@ fpath only-path 
  777:     init-included-files
  778: [ [THEN] ]
  779:     'cold
  780:     init8 chainperform
  781: [ has? file [IF] ]
  782:     process-args
  783:     loadline off
  784:     loadfilename# off
  785: [ [THEN] ]
  786:     bootmessage
  787:     quit ;
  788: 
  789: : clear-tibstack ( -- )
  790: [ has? glocals [IF] ]
  791:     lp@ forthstart 7 cells + @ - 
  792: [ [ELSE] ]
  793:     [ has? os [IF] ]
  794:     r0 @ forthstart 6 cells + @ -
  795:     [ [ELSE] ]
  796:     sp@ $10 cells +
  797:     [ [THEN] ]
  798: [ [THEN] ]
  799:     dup >tib ! tibstack ! #tib off >in off ;
  800: 
  801: : boot ( path **argv argc -- )
  802:     main-task up!
  803: [ has? os [IF] ]
  804:     stdout TO outfile-id
  805:     stdin  TO infile-id
  806: \ !! [ [THEN] ]
  807: \ !! [ has? file [IF] ]
  808:     argc ! argv ! pathstring 2!
  809: [ [THEN] ]
  810:     sp@ sp0 !
  811:     clear-tibstack
  812:     rp@ rp0 !
  813: [ has? floating [IF] ]
  814:     fp@ fp0 !
  815: [ [THEN] ]
  816:     handler off
  817:     ['] cold catch DoError cr
  818: [ has? os [IF] ]
  819:     1 (bye) \ !! determin exit code from throw code?
  820: [ [THEN] ]
  821: ;
  822: 
  823: has? os [IF]
  824: : bye ( -- ) \ tools-ext
  825: [ has? file [IF] ]
  826:     script? 0= IF  cr  THEN
  827: [ [ELSE] ]
  828:     cr
  829: [ [THEN] ]
  830:     0 (bye) ;
  831: [THEN]
  832: 
  833: \ **argv may be scanned by the C starter to get some important
  834: \ information, as -display and -geometry for an X client FORTH
  835: \ or space and stackspace overrides
  836: 
  837: \ 0 arg contains, however, the name of the program.
  838: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>