File:
[gforth] /
gforth /
kernel /
int.fs
Revision
1.42:
download - view:
text,
annotated -
select for diffs
Sat Nov 20 12:12:54 1999 UTC (24 years, 4 months ago) by
anton
Branches:
MAIN
CVS tags:
HEAD
took exception handling out of the kernel into exceptions.fs
added inline exception handling (TRY...RECOVER...ENDTRY)
added exception handling without affecting sp or fp (PROTECT...ENDPROTECT)
1: \ definitions needed for interpreter only
2:
3: \ Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: \ \ Revision-Log
22:
23: \ put in seperate file 14sep97jaw
24:
25: \ \ input stream primitives 23feb93py
26:
27: require ./basics.fs \ bounds decimal hex ...
28: require ./io.fs \ type ...
29: require ./nio.fs \ . <# ...
30: require ./errore.fs \ .error ...
31: require ~+/kernel/version.fs \ version-string
32: require ./../chains.fs
33:
34: : tib ( -- c-addr ) \ core-ext
35: \G @i{c-addr} is the address of the Terminal Input Buffer.
36: \G OBSOLESCENT: @code{source} superceeds the function of this word.
37: >tib @ ;
38:
39: Defer source ( -- c-addr u ) \ core
40: \ used by dodefer:, must be defer
41: \G @i{c-addr} is the address of the input buffer and @i{u} is the
42: \G number of characters in it.
43:
44: : (source) ( -- c-addr u )
45: tib #tib @ ;
46: ' (source) IS source
47:
48: : (word) ( addr1 n1 char -- addr2 n2 )
49: dup >r skip 2dup r> scan nip - ;
50:
51: \ (word) should fold white spaces
52: \ this is what (parse-white) does
53:
54: \ word parse 23feb93py
55:
56: : sword ( char -- addr len ) \ gforth s-word
57: \G Parses like @code{word}, but the output is like @code{parse} output.
58: \G @xref{core-idef}
59: \ this word was called PARSE-WORD until 0.3.0, but Open Firmware and
60: \ dpANS6 A.6.2.2008 have a word with that name that behaves
61: \ differently (like NAME).
62: source 2dup >r >r >in @ over min /string
63: rot dup bl = IF drop (parse-white) ELSE (word) THEN
64: 2dup + r> - 1+ r> min >in ! ;
65:
66: : word ( char "<chars>ccc<char>-- c-addr ) \ core
67: \G Skip leading delimiters. Parse @i{ccc}, delimited by
68: \G @i{char}, in the parse area. @i{c-addr} is the address of a
69: \G transient region containing the parsed string in
70: \G counted-string format. If the parse area was empty or
71: \G contained no characters other than delimiters, the resulting
72: \G string has zero length. A program may replace characters within
73: \G the counted string. OBSOLESCENT: the counted string has a
74: \G trailing space that is not included in its length.
75: sword here place bl here count + c! here ;
76:
77: : parse ( char "ccc<char>" -- c-addr u ) \ core-ext
78: \G Parse @i{ccc}, delimited by @i{char}, in the parse
79: \G area. @i{c-addr u} specifies the parsed string within the
80: \G parse area. If the parse area was empty, @i{u} is 0.
81: >r source >in @ over min /string over swap r> scan >r
82: over - dup r> IF 1+ THEN >in +! ;
83:
84: \ name 13feb93py
85:
86: [IFUNDEF] (name) \ name might be a primitive
87:
88: : (name) ( -- c-addr count ) \ gforth
89: source 2dup >r >r >in @ /string (parse-white)
90: 2dup + r> - 1+ r> min >in ! ;
91: \ name count ;
92: [THEN]
93:
94: : name-too-short? ( c-addr u -- c-addr u )
95: dup 0= -&16 and throw ;
96:
97: : name-too-long? ( c-addr u -- c-addr u )
98: dup $1F u> -&19 and throw ;
99:
100: \ \ Number parsing 23feb93py
101:
102: \ number? number 23feb93py
103:
104: hex
105: const Create bases 10 , 2 , A , 100 ,
106: \ 16 2 10 character
107:
108: \ !! protect BASE saving wrapper against exceptions
109: : getbase ( addr u -- addr' u' )
110: over c@ [char] $ - dup 4 u<
111: IF
112: cells bases + @ base ! 1 /string
113: ELSE
114: drop
115: THEN ;
116:
117: : sign? ( addr u -- addr u flag )
118: over c@ [char] - = dup >r
119: IF
120: 1 /string
121: THEN
122: r> ;
123:
124: : s>unumber? ( addr u -- ud flag )
125: base @ >r dpl on getbase
126: 0. 2swap
127: BEGIN ( d addr len )
128: dup >r >number dup
129: WHILE \ there are characters left
130: dup r> -
131: WHILE \ the last >number parsed something
132: dup 1- dpl ! over c@ [char] . =
133: WHILE \ the current char is '.'
134: 1 /string
135: REPEAT THEN \ there are unparseable characters left
136: 2drop false
137: ELSE
138: rdrop 2drop true
139: THEN
140: r> base ! ;
141:
142: \ ouch, this is complicated; there must be a simpler way - anton
143: : s>number? ( addr len -- d f )
144: \ converts string addr len into d, flag indicates success
145: sign? >r
146: s>unumber?
147: 0= IF
148: rdrop false
149: ELSE \ no characters left, all ok
150: r>
151: IF
152: dnegate
153: THEN
154: true
155: THEN ;
156:
157: : s>number ( addr len -- d )
158: \ don't use this, there is no way to tell success
159: s>number? drop ;
160:
161: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
162: s>number? 0=
163: IF
164: 2drop false EXIT
165: THEN
166: dpl @ dup 0< IF
167: nip
168: ELSE
169: 1+
170: THEN ;
171:
172: : number? ( string -- string 0 / n -1 / d 0> )
173: dup >r count snumber? dup if
174: rdrop
175: else
176: r> swap
177: then ;
178:
179: : number ( string -- d )
180: number? ?dup 0= abort" ?" 0<
181: IF
182: s>d
183: THEN ;
184:
185: \ \ Comments ( \ \G
186:
187: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file paren
188: \G ** this will not get annotated. The alias in glocals.fs will instead **
189: \G It does not work to use "wordset-" prefix since this file is glossed
190: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
191: [char] ) parse 2drop ; immediate
192:
193: : \ ( -- ) \ thisone- core-ext,block-ext backslash
194: \G ** this will not get annotated. The alias in glocals.fs will instead **
195: \G It does not work to use "wordset-" prefix since this file is glossed
196: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
197: [ has? file [IF] ]
198: blk @
199: IF
200: >in @ c/l / 1+ c/l * >in !
201: EXIT
202: THEN
203: [ [THEN] ]
204: source >in ! drop ; immediate
205:
206: : \G ( -- ) \ gforth backslash-gee
207: \G Equivalent to @code{\} but used as a tag to annotate definition
208: \G comments into documentation.
209: POSTPONE \ ; immediate
210:
211: \ \ object oriented search list 17mar93py
212:
213: \ word list structure:
214:
215: struct
216: cell% field find-method \ xt: ( c_addr u wid -- nt )
217: cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
218: cell% field rehash-method \ xt: ( wid -- ) \ re-initializes a "search-data" (hashtables)
219: cell% field hash-method \ xt: ( wid -- ) \ initializes ""
220: \ \ !! what else
221: end-struct wordlist-map-struct
222:
223: struct
224: cell% field wordlist-map \ pointer to a wordlist-map-struct
225: cell% field wordlist-id \ linked list of words (for WORDS etc.)
226: cell% field wordlist-link \ link field to other wordlists
227: cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
228: end-struct wordlist-struct
229:
230: : f83find ( addr len wordlist -- nt / false )
231: wordlist-id @ (f83find) ;
232:
233: : initvoc ( wid -- )
234: dup wordlist-map @ hash-method perform ;
235:
236: \ Search list table: find reveal
237: Create f83search ( -- wordlist-map )
238: ' f83find A, ' drop A, ' drop A, ' drop A,
239:
240: here G f83search T A, NIL A, NIL A, NIL A,
241: AValue forth-wordlist \ variable, will be redefined by search.fs
242:
243: AVariable lookup forth-wordlist lookup !
244: \ !! last is user and lookup?! jaw
245: AVariable current ( -- addr ) \ gforth
246: \G @code{Variable} -- holds the wid of the current compilation word list.
247: AVariable voclink forth-wordlist wordlist-link voclink !
248: \ lookup AValue context ( -- addr ) \ gforth
249: Defer context ( -- addr ) \ gforth
250: \G @code{context} @code{@@} is the wid of the word list at the
251: \G top of the search order stack.
252:
253: ' lookup is context
254: forth-wordlist current !
255:
256: \ \ header, finding, ticks 17dec92py
257:
258: hex
259: 80 constant alias-mask \ set when the word is not an alias!
260: 40 constant immediate-mask
261: 20 constant restrict-mask
262:
263: \ higher level parts of find
264:
265: : flag-sign ( f -- 1|-1 )
266: \ true becomes 1, false -1
267: 0= 2* 1+ ;
268:
269: : compile-only-error ( ... -- )
270: -&14 throw ;
271:
272: : (cfa>int) ( cfa -- xt )
273: [ has? compiler [IF] ]
274: dup interpret/compile?
275: if
276: interpret/compile-int @
277: then
278: [ [THEN] ] ;
279:
280: : (x>int) ( cfa b -- xt )
281: \ get interpretation semantics of name
282: restrict-mask and
283: if
284: drop ['] compile-only-error
285: else
286: (cfa>int)
287: then ;
288:
289: : name>string ( nt -- addr count ) \ gforth head-to-string
290: \g @i{addr count} is the name of the word represented by @i{nt}.
291: cell+ count $1F and ;
292:
293: : ((name>)) ( nfa -- cfa )
294: name>string + cfaligned ;
295:
296: : (name>x) ( nfa -- cfa b )
297: \ cfa is an intermediate cfa and b is the flags byte of nfa
298: dup ((name>))
299: swap cell+ c@ dup alias-mask and 0=
300: IF
301: swap @ swap
302: THEN ;
303:
304: : name>int ( nt -- xt ) \ gforth
305: \G @i{xt} represents the interpretation semantics of the word
306: \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
307: \G @code{compile-only}), @i{xt} is the execution token for
308: \G @code{compile-only-error}, which performs @code{-14 throw}.
309: (name>x) (x>int) ;
310:
311: : name?int ( nt -- xt ) \ gforth
312: \G Like @code{name>int}, but perform @code{-14 throw} if @i{nt}
313: \G has no interpretation semantics.
314: (name>x) restrict-mask and
315: if
316: compile-only-error \ does not return
317: then
318: (cfa>int) ;
319:
320: : (name>comp) ( nt -- w +-1 ) \ gforth
321: \G @i{w xt} is the compilation token for the word @i{nt}.
322: (name>x) >r
323: [ has? compiler [IF] ]
324: dup interpret/compile?
325: if
326: interpret/compile-comp @
327: then
328: [ [THEN] ]
329: r> immediate-mask and flag-sign
330: ;
331:
332: : (name>intn) ( nfa -- xt +-1 )
333: (name>x) tuck (x>int) ( b xt )
334: swap immediate-mask and flag-sign ;
335:
336: const Create ??? 0 , 3 c, char ? c, char ? c, char ? c,
337: \ ??? is used by dovar:, must be created/:dovar
338:
339: [IFDEF] forthstart
340: \ if we have a forthstart we can define head? with it
341: \ otherwise leave out the head? check
342:
343: : head? ( addr -- f )
344: \G heuristic check whether addr is a name token; may deliver false
345: \G positives; addr must be a valid address
346: \ we follow the link fields and check for plausibility; two
347: \ iterations should catch most false addresses: on the first
348: \ iteration, we may get an xt, on the second a code address (or
349: \ some code), which is typically not in the dictionary.
350: 2 0 do
351: dup dup aligned <> if \ protect @ against unaligned accesses
352: drop false unloop exit
353: then
354: dup @ dup
355: if ( addr addr1 )
356: dup rot forthstart within
357: if \ addr1 is outside forthstart..addr, not a head
358: drop false unloop exit
359: then ( addr1 )
360: else \ 0 in the link field, no further checks
361: 2drop true unloop exit
362: then
363: loop
364: \ in dubio pro:
365: drop true ;
366:
367: : >head ( cfa -- nt ) \ gforth to-head
368: $21 cell do ( cfa )
369: dup i - count $9F and + cfaligned over alias-mask + =
370: if ( cfa )
371: dup i - cell - dup head?
372: if
373: nip unloop exit
374: then
375: drop
376: then
377: cell +loop
378: drop ??? ( wouldn't 0 be better? ) ;
379:
380: [ELSE]
381:
382: : >head ( cfa -- nt ) \ gforth to-head
383: $21 cell do ( cfa )
384: dup i - count $9F and + cfaligned over alias-mask + =
385: if ( cfa ) i - cell - unloop exit
386: then
387: cell +loop
388: drop ??? ( wouldn't 0 be better? ) ;
389:
390: [THEN]
391:
392: ' >head ALIAS >name
393:
394: : body> 0 >body - ;
395:
396: : (search-wordlist) ( addr count wid -- nt | false )
397: dup wordlist-map @ find-method perform ;
398:
399: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
400: \G Search the word list identified by @i{wid}
401: \G for the definition named by the string at @i{c-addr count}.
402: \G If the definition is not found, return 0. If the definition
403: \G is found return 1 (if the definition is immediate) or -1
404: \G (if the definition is not immediate) together with the @i{xt}.
405: \G The @i{xt} returned represents the interpretation semantics.
406: (search-wordlist) dup if
407: (name>intn)
408: then ;
409:
410: : find-name ( c-addr u -- nt | 0 ) \ gforth
411: \g Find the name @i{c-addr u} in the current search
412: \g order. Return its @i{nt}, if found, otherwise 0.
413: lookup @ (search-wordlist) ;
414:
415: : sfind ( c-addr u -- 0 / xt +-1 ) \ gforth-obsolete
416: find-name dup
417: if ( nt )
418: state @
419: if
420: (name>comp)
421: else
422: (name>intn)
423: then
424: then ;
425:
426: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
427: \G Search all word lists in the current search order
428: \G for the definition named by the counted string at @i{c-addr}.
429: \G If the definition is not found, return 0. If the definition
430: \G is found return 1 (if the definition is immediate) or -1
431: \G (if the definition is not immediate) together with the @i{xt}.
432: dup count sfind dup
433: if
434: rot drop
435: then ;
436:
437: \ ticks in interpreter
438:
439: : (') ( "name" -- nt ) \ gforth
440: name name-too-short?
441: find-name dup 0=
442: IF
443: drop -&13 throw
444: THEN ;
445:
446: : ' ( "name" -- xt ) \ core tick
447: \g @i{xt} represents @i{name}'s interpretation
448: \g semantics. Perform @code{-14 throw} if the word has no
449: \g interpretation semantics.
450: (') name?int ;
451:
452: has? compiler 0= [IF] \ interpreter only version of IS and TO
453:
454: : IS ' >body ! ;
455: ' IS Alias TO
456:
457: [THEN]
458:
459: \ \ the interpreter loop mar92py
460:
461: \ interpret 10mar92py
462:
463: Defer parser ( c-addr u -- )
464: Defer name ( -- c-addr count ) \ gforth
465: \ get the next word from the input buffer
466: ' (name) IS name
467: Defer compiler-notfound ( c-addr count -- )
468: Defer interpreter-notfound ( c-addr count -- )
469:
470: : no.extensions ( addr u -- )
471: 2drop -&13 throw ;
472: ' no.extensions IS compiler-notfound
473: ' no.extensions IS interpreter-notfound
474:
475: : interpret ( ?? -- ?? ) \ gforth
476: \ interpret/compile the (rest of the) input buffer
477: [ has? backtrace [IF] ]
478: rp@ backtrace-rp0 !
479: [ [THEN] ]
480: BEGIN
481: ?stack name dup
482: WHILE
483: parser
484: REPEAT
485: 2drop ;
486:
487: \ interpreter 30apr92py
488:
489: \ not the most efficient implementations of interpreter and compiler
490: : interpreter ( c-addr u -- )
491: 2dup find-name dup
492: if
493: nip nip name>int execute
494: else
495: drop
496: 2dup 2>r snumber?
497: IF
498: 2rdrop
499: ELSE
500: 2r> interpreter-notfound
501: THEN
502: then ;
503:
504: ' interpreter IS parser
505:
506: \ \ Query Evaluate 07apr93py
507:
508: has? file 0= [IF]
509: : sourceline# ( -- n ) 1 ;
510: [THEN]
511:
512: : refill ( -- flag ) \ core-ext,block-ext,file-ext
513: \G Attempt to fill the input buffer from the input source. When
514: \G the input source is the user input device, attempt to receive
515: \G input into the terminal input device. If successful, make the
516: \G result the input buffer, set @code{>IN} to 0 and return true;
517: \G otherwise return false. When the input source is a block, add 1
518: \G to the value of @code{BLK} to make the next block the input
519: \G source and current input buffer, and set @code{>IN} to 0;
520: \G return true if the new value of @code{BLK} is a valid block
521: \G number, false otherwise. When the input source is a text file,
522: \G attempt to read the next line from the file. If successful,
523: \G make the result the current input buffer, set @code{>IN} to 0
524: \G and return true; otherwise, return false. A successful result
525: \G includes receipt of a line containing 0 characters.
526: [ has? file [IF] ]
527: blk @ IF 1 blk +! true 0 >in ! EXIT THEN
528: [ [THEN] ]
529: tib /line
530: [ has? file [IF] ]
531: loadfile @ ?dup
532: IF read-line throw
533: ELSE
534: [ [THEN] ]
535: sourceline# 0< IF 2drop false EXIT THEN
536: accept true
537: [ has? file [IF] ]
538: THEN
539: 1 loadline +!
540: [ [THEN] ]
541: swap #tib ! 0 >in ! ;
542:
543: : query ( -- ) \ core-ext
544: \G Make the user input device the input source. Receive input into
545: \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
546: \G superceeded by @code{accept}.
547: [ has? file [IF] ]
548: blk off loadfile off
549: [ [THEN] ]
550: tib /line accept #tib ! 0 >in ! ;
551:
552: \ save-mem extend-mem
553:
554: has? os [IF]
555: : save-mem ( addr1 u -- addr2 u ) \ gforth
556: \g copy a memory block into a newly allocated region in the heap
557: swap >r
558: dup allocate throw
559: swap 2dup r> -rot move ;
560:
561: : extend-mem ( addr1 u1 u -- addr addr2 u2 )
562: \ extend memory block allocated from the heap by u aus
563: \ the (possibly reallocated piece is addr2 u2, the extension is at addr
564: over >r + dup >r resize throw
565: r> over r> + -rot ;
566: [THEN]
567:
568: \ EVALUATE 17may93jaw
569:
570: has? file 0= [IF]
571: : push-file ( -- ) r>
572: tibstack @ >r >tib @ >r #tib @ >r
573: >tib @ tibstack @ = IF r@ tibstack +! THEN
574: tibstack @ >tib ! >in @ >r >r ;
575:
576: : pop-file ( throw-code -- throw-code )
577: r>
578: r> >in ! r> #tib ! r> >tib ! r> tibstack ! >r ;
579: [THEN]
580:
581: : evaluate ( c-addr u -- ) \ core,block
582: \G Save the current input source specification. Store @code{-1} in
583: \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
584: \G @code{0} and make the string @i{c-addr u} the input source
585: \G and input buffer. Interpret. When the parse area is empty,
586: \G restore the input source specification.
587: push-file #tib ! >tib !
588: >in off
589: [ has? file [IF] ]
590: blk off loadfile off -1 loadline !
591: [ [THEN] ]
592: ['] interpret catch
593: pop-file throw ;
594:
595: \ \ Quit 13feb93py
596:
597: Defer 'quit
598:
599: Defer .status
600:
601: : prompt state @ IF ." compiled" EXIT THEN ." ok" ;
602:
603: : (Query) ( -- )
604: [ has? file [IF] ]
605: loadfile off blk off loadline off
606: [ [THEN] ]
607: refill drop ;
608:
609: : (quit) ( -- )
610: \ exits only through THROW etc.
611: \ sp0 @ cell - handler @ &12 + ! \ !! kludge: fix the stack pointer
612: \ stored in the system's CATCH frame, so the stack depth will be 0
613: \ after the next THROW it catches (it may be off due to BOUNCEs or
614: \ because process-args left something on the stack)
615: BEGIN
616: .status cr (query) interpret prompt
617: AGAIN ;
618:
619: ' (quit) IS 'quit
620:
621: \ \ DOERROR (DOERROR) 13jun93jaw
622:
623: 8 Constant max-errors
624: Variable error-stack 0 error-stack !
625: max-errors 6 * cells allot
626: \ format of one cell:
627: \ source ( addr u )
628: \ >in
629: \ line-number
630: \ Loadfilename ( addr u )
631:
632: : dec. ( n -- ) \ gforth
633: \G Display @i{n} as a signed decimal number, followed by a space.
634: \ !! not used...
635: base @ decimal swap . base ! ;
636:
637: : dec.r ( u -- ) \ gforth
638: \G Display @i{u} as a unsigned decimal number
639: base @ decimal swap 0 .r base ! ;
640:
641: : hex. ( u -- ) \ gforth
642: \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
643: \G followed by a space.
644: \ !! not used...
645: [char] $ emit base @ swap hex u. base ! ;
646:
647: : typewhite ( addr u -- ) \ gforth
648: \G Like type, but white space is printed instead of the characters.
649: bounds ?do
650: i c@ #tab = if \ check for tab
651: #tab
652: else
653: bl
654: then
655: emit
656: loop ;
657:
658: DEFER DOERROR
659:
660: has? backtrace [IF]
661: Defer dobacktrace ( -- )
662: ' noop IS dobacktrace
663: [THEN]
664:
665: : .error-string ( throw-code -- )
666: dup -2 =
667: IF "error @ ?dup IF count type THEN drop
668: ELSE .error
669: THEN ;
670:
671: : .error-frame ( throwcode addr1 u1 n1 n2 addr2 u2 -- throwcode )
672: \ addr2 u2: filename of included file
673: \ n2: line number
674: \ n1: error position in input line
675: \ addr1 u1: input line
676:
677: cr error-stack @
678: IF
679: ." in file included from "
680: type ." :" dec.r drop 2drop
681: ELSE
682: type ." :" dec.r ." : " 3 pick .error-string cr
683: dup 2over type cr drop
684: nip -trailing 1- ( line-start index2 )
685: 0 >r BEGIN
686: 2dup + c@ bl > WHILE
687: r> 1+ >r 1- dup 0< UNTIL THEN 1+
688: ( line-start index1 )
689: typewhite
690: r> 1 max 0 ?do \ we want at least one "^", even if the length is 0
691: [char] ^ emit
692: loop
693: THEN ;
694:
695: : (DoError) ( throw-code -- )
696: [ has? os [IF] ]
697: >stderr
698: [ [THEN] ]
699: sourceline# IF
700: source >in @ sourceline# 0 0 .error-frame
701: THEN
702: error-stack @ 0 ?DO
703: -1 error-stack +!
704: error-stack dup @ 6 * cells + cell+
705: 6 cells bounds DO
706: I @
707: cell +LOOP
708: .error-frame
709: LOOP
710: drop
711: [ has? backtrace [IF] ]
712: dobacktrace
713: [ [THEN] ]
714: normal-dp dpp ! ;
715:
716: ' (DoError) IS DoError
717:
718: : quit ( ?? -- ?? ) \ core
719: \G Empty the return stack, make the user input device
720: \G the input source, enter interpret state and start
721: \G the text interpreter.
722: rp0 @ rp! handler off clear-tibstack >tib @ >r
723: BEGIN
724: [ has? compiler [IF] ]
725: postpone [
726: [ [THEN] ]
727: ['] 'quit CATCH dup
728: WHILE
729: <# \ reset hold area, or we may get another error
730: DoError r@ >tib ! r@ tibstack !
731: REPEAT
732: drop r> >tib ! ;
733:
734: \ \ Cold Boot 13feb93py
735:
736: : (bootmessage)
737: ." GForth " version-string type
738: ." , Copyright (C) 1998 Free Software Foundation, Inc." cr
739: ." GForth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
740: [ has? os [IF] ]
741: cr ." Type `bye' to exit"
742: [ [THEN] ] ;
743:
744: defer bootmessage
745: defer process-args
746:
747: ' (bootmessage) IS bootmessage
748:
749: Defer 'cold ( -- ) \ gforth tick-cold
750: \ hook (deferred word) for things to do right before interpreting the
751: \ command-line arguments
752: ' noop IS 'cold
753:
754:
755: Variable init8
756:
757: : cold ( -- ) \ gforth
758: [ has? file [IF] ]
759: pathstring 2@ fpath only-path
760: init-included-files
761: [ [THEN] ]
762: 'cold
763: init8 chainperform
764: [ has? file [IF] ]
765: process-args
766: loadline off
767: [ [THEN] ]
768: bootmessage
769: quit ;
770:
771: : clear-tibstack ( -- )
772: [ has? glocals [IF] ]
773: lp@ forthstart 7 cells + @ -
774: [ [ELSE] ]
775: [ has? os [IF] ]
776: r0 @ forthstart 6 cells + @ -
777: [ [ELSE] ]
778: sp@ $10 cells +
779: [ [THEN] ]
780: [ [THEN] ]
781: dup >tib ! tibstack ! #tib off >in off ;
782:
783: : boot ( path **argv argc -- )
784: main-task up!
785: [ has? os [IF] ]
786: stdout TO outfile-id
787: stdin TO infile-id
788: \ !! [ [THEN] ]
789: \ !! [ has? file [IF] ]
790: argc ! argv ! pathstring 2!
791: [ [THEN] ]
792: sp@ sp0 !
793: clear-tibstack
794: rp@ rp0 !
795: [ has? floating [IF] ]
796: fp@ fp0 !
797: [ [THEN] ]
798: ['] cold catch DoError cr
799: [ has? os [IF] ]
800: 1 (bye) \ !! determin exit code from throw code?
801: [ [THEN] ]
802: ;
803:
804: has? os [IF]
805: : bye ( -- ) \ tools-ext
806: [ has? file [IF] ]
807: script? 0= IF cr THEN
808: [ [ELSE] ]
809: cr
810: [ [THEN] ]
811: 0 (bye) ;
812: [THEN]
813:
814: \ **argv may be scanned by the C starter to get some important
815: \ information, as -display and -geometry for an X client FORTH
816: \ or space and stackspace overrides
817:
818: \ 0 arg contains, however, the name of the program.
819:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>