1: \ definitions needed for interpreter only
2:
3: \ Copyright (C) 1995-2000,2004,2005,2007,2009,2010 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation, either version 3
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program. If not, see http://www.gnu.org/licenses/.
19:
20: \ \ Revision-Log
21:
22: \ put in seperate file 14sep97jaw
23:
24: \ \ input stream primitives 23feb93py
25:
26: require ./basics.fs \ bounds decimal hex ...
27: require ./io.fs \ type ...
28: require ./nio.fs \ . <# ...
29: require ./errore.fs \ .error ...
30: require kernel/version.fs \ version-string
31:
32: has? new-input 0= [IF]
33: : tib ( -- c-addr ) \ core-ext t-i-b
34: \G @i{c-addr} is the address of the Terminal Input Buffer.
35: \G OBSOLESCENT: @code{source} superceeds the function of this word.
36: >tib @ ;
37:
38: Defer source ( -- c-addr u ) \ core
39: \ used by dodefer:, must be defer
40: \G @i{c-addr} is the address of the input buffer and @i{u} is the
41: \G number of characters in it.
42:
43: : (source) ( -- c-addr u )
44: tib #tib @ ;
45: ' (source) IS source
46: [THEN]
47:
48: : (word) ( addr1 n1 char -- addr2 n2 )
49: dup >r skip 2dup r> scan nip - ;
50:
51: \ (word) should fold white spaces
52: \ this is what (parse-white) does
53:
54: \ parse 23feb93py
55:
56: : parse ( char "ccc<char>" -- c-addr u ) \ core-ext
57: \G Parse @i{ccc}, delimited by @i{char}, in the parse
58: \G area. @i{c-addr u} specifies the parsed string within the
59: \G parse area. If the parse area was empty, @i{u} is 0.
60: >r source >in @ over min /string ( c-addr1 u1 )
61: over swap r> scan >r
62: over - dup r> IF 1+ THEN >in +!
63: [ has? new-input [IF] ]
64: 2dup input-lexeme!
65: [ [THEN] ] ;
66:
67: \ name 13feb93py
68:
69: [IFUNDEF] (name) \ name might be a primitive
70:
71: : (name) ( -- c-addr count ) \ gforth
72: source 2dup >r >r >in @ /string (parse-white)
73: [ has? new-input [IF] ]
74: 2dup input-lexeme!
75: [ [THEN] ]
76: 2dup + r> - 1+ r> min >in ! ;
77: \ name count ;
78: [THEN]
79:
80: : name-too-short? ( c-addr u -- c-addr u )
81: dup 0= -&16 and throw ;
82:
83: : name-too-long? ( c-addr u -- c-addr u )
84: dup lcount-mask u> -&19 and throw ;
85:
86: \ \ Number parsing 23feb93py
87:
88: \ (number?) number 23feb93py
89:
90: hex
91: const Create bases 0A , 10 , 2 , 0A ,
92: \ 10 16 2 10
93:
94: \ !! protect BASE saving wrapper against exceptions
95: : getbase ( addr u -- addr' u' )
96: 2dup s" 0x" string-prefix? >r
97: 2dup s" 0X" string-prefix? r> or
98: base @ &34 < and if
99: hex 2 /string
100: endif
101: over c@ [char] # - dup 4 u<
102: IF
103: cells bases + @ base ! 1 /string
104: ELSE
105: drop
106: THEN ;
107:
108: : sign? ( addr u -- addr1 u1 flag )
109: over c@ [char] - = dup >r
110: IF
111: 1 /string
112: THEN
113: r> ;
114:
115: : ?dnegate ( d1 f -- d2 )
116: if
117: dnegate
118: then ;
119:
120: has? os 0= [IF]
121: : x@+/string ( addr u -- addr' u' c )
122: over c@ >r 1 /string r> ;
123: [THEN]
124:
125: : s'>unumber? ( addr u -- ud flag )
126: \ convert string "C" or "C'" to character code
127: dup 0= if
128: false exit
129: endif
130: x@+/string 0 s" '" 2rot string-prefix? ;
131:
132: : s>unumber? ( c-addr u -- ud flag ) \ gforth
133: \G converts string c-addr u into ud, flag indicates success
134: dpl on
135: over c@ '' = if
136: 1 /string s'>unumber? exit
137: endif
138: base @ >r getbase sign?
139: over if
140: >r 0. 2swap
141: BEGIN ( d addr len )
142: dup >r >number dup
143: WHILE \ there are characters left
144: dup r> -
145: WHILE \ the last >number parsed something
146: dup 1- dpl ! over c@ [char] . =
147: WHILE \ the current char is '.'
148: 1 /string
149: REPEAT THEN \ there are unparseable characters left
150: 2drop rdrop false
151: ELSE
152: rdrop 2drop r> ?dnegate true
153: THEN
154: ELSE
155: drop 2drop 0. false THEN
156: r> base ! ;
157:
158: \ ouch, this is complicated; there must be a simpler way - anton
159: : s>number? ( addr u -- d f ) \ gforth
160: \G converts string addr u into d, flag indicates success
161: sign? >r
162: s>unumber?
163: 0= IF
164: rdrop false
165: ELSE \ no characters left, all ok
166: r> ?dnegate
167: true
168: THEN ;
169:
170: : s>number ( addr len -- d )
171: \ don't use this, there is no way to tell success
172: s>number? drop ;
173:
174: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
175: s>number? 0=
176: IF
177: 2drop false EXIT
178: THEN
179: dpl @ dup 0< IF
180: nip
181: ELSE
182: 1+
183: THEN ;
184:
185: : (number?) ( string -- string 0 / n -1 / d 0> )
186: dup >r count snumber? dup if
187: rdrop
188: else
189: r> swap
190: then ;
191:
192: : number ( string -- d )
193: (number?) ?dup 0= abort" ?" 0<
194: IF
195: s>d
196: THEN ;
197:
198: \ \ Comments ( \ \G
199:
200: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file paren
201: \G ** this will not get annotated. The alias in glocals.fs will instead **
202: \G It does not work to use "wordset-" prefix since this file is glossed
203: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
204: [char] ) parse 2drop ; immediate
205:
206: : \ ( compilation 'ccc<newline>' -- ; run-time -- ) \ thisone- core-ext,block-ext backslash
207: \G ** this will not get annotated. The alias in glocals.fs will instead **
208: \G It does not work to use "wordset-" prefix since this file is glossed
209: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
210: [ has? file [IF] ]
211: blk @
212: IF
213: >in @ c/l / 1+ c/l * >in !
214: EXIT
215: THEN
216: [ [THEN] ]
217: source >in ! drop ; immediate
218:
219: : \G ( compilation 'ccc<newline>' -- ; run-time -- ) \ gforth backslash-gee
220: \G Equivalent to @code{\} but used as a tag to annotate definition
221: \G comments into documentation.
222: POSTPONE \ ; immediate
223:
224: has? ec [IF]
225: AVariable forth-wordlist
226: : find-name ( c-addr u -- nt | 0 ) \ gforth
227: \g Find the name @i{c-addr u} in the current search
228: \g order. Return its @i{nt}, if found, otherwise 0.
229: forth-wordlist (f83find) ;
230: [ELSE]
231: \ \ object oriented search list 17mar93py
232:
233: \ word list structure:
234:
235: struct
236: cell% field find-method \ xt: ( c_addr u wid -- nt )
237: cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
238: cell% field rehash-method \ xt: ( wid -- ) \ re-initializes a "search-data" (hashtables)
239: cell% field hash-method \ xt: ( wid -- ) \ initializes ""
240: \ \ !! what else
241: end-struct wordlist-map-struct
242:
243: struct
244: cell% field wordlist-map \ pointer to a wordlist-map-struct
245: cell% field wordlist-id \ linked list of words (for WORDS etc.)
246: cell% field wordlist-link \ link field to other wordlists
247: cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
248: end-struct wordlist-struct
249:
250: has? f83headerstring [IF]
251: : f83find ( addr len wordlist -- nt / false )
252: wordlist-id @ (f83find) ;
253: [ELSE]
254: : f83find ( addr len wordlist -- nt / false )
255: wordlist-id @ (listlfind) ;
256: [THEN]
257:
258: : initvoc ( wid -- )
259: dup wordlist-map @ hash-method perform ;
260:
261: \ Search list table: find reveal
262: Create f83search ( -- wordlist-map )
263: ' f83find A, ' drop A, ' drop A, ' drop A,
264:
265: here f83search A, NIL A, NIL A, NIL A,
266: AValue forth-wordlist \ variable, will be redefined by search.fs
267:
268: AVariable lookup forth-wordlist lookup !
269: \ !! last is user and lookup?! jaw
270: AVariable current ( -- addr ) \ gforth
271: \G @code{Variable} -- holds the @i{wid} of the compilation word list.
272: AVariable voclink forth-wordlist wordlist-link voclink !
273: \ lookup AValue context ( -- addr ) \ gforth
274: Defer context ( -- addr ) \ gforth
275: \G @code{context} @code{@@} is the @i{wid} of the word list at the
276: \G top of the search order.
277:
278: ' lookup is context
279: forth-wordlist current !
280:
281: : (search-wordlist) ( addr count wid -- nt | false )
282: dup wordlist-map @ find-method perform ;
283:
284: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
285: \G Search the word list identified by @i{wid} for the definition
286: \G named by the string at @i{c-addr count}. If the definition is
287: \G not found, return 0. If the definition is found return 1 (if
288: \G the definition is immediate) or -1 (if the definition is not
289: \G immediate) together with the @i{xt}. In Gforth, the @i{xt}
290: \G returned represents the interpretation semantics. ANS Forth
291: \G does not specify clearly what @i{xt} represents.
292: (search-wordlist) dup if
293: (name>intn)
294: then ;
295:
296: : find-name ( c-addr u -- nt | 0 ) \ gforth
297: \g Find the name @i{c-addr u} in the current search
298: \g order. Return its @i{nt}, if found, otherwise 0.
299: lookup @ (search-wordlist) ;
300: [THEN]
301:
302: \ \ header, finding, ticks 17dec92py
303:
304: \ The constants are defined as 32 bits, but then erased
305: \ and overwritten by the right ones
306:
307: has? f83headerstring [IF]
308: \ to save space, Gforth EC limits words to 31 characters
309: \ also, there's no predule concept in Gforth EC
310: $80 constant alias-mask
311: $40 constant immediate-mask
312: $20 constant restrict-mask
313: $1f constant lcount-mask
314: [ELSE]
315: \ 32-bit systems cannot generate large 64-bit constant in the
316: \ cross-compiler, so we kludge it by generating a constant and then
317: \ storing the proper value into it (and that's another kludge).
318: $80000000 constant alias-mask
319: 1 bits/char 1 - lshift
320: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
321: [ELSE] 0 1 cells 1- times c, [THEN]
322: $40000000 constant immediate-mask
323: 1 bits/char 2 - lshift
324: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
325: [ELSE] 0 1 cells 1- times c, [THEN]
326: $20000000 constant restrict-mask
327: 1 bits/char 3 - lshift
328: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
329: [ELSE] 0 1 cells 1- times c, [THEN]
330: $10000000 constant prelude-mask
331: 1 bits/char 4 - lshift
332: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
333: [ELSE] 0 1 cells 1- times c, [THEN]
334: $0fffffff constant lcount-mask
335: 1 bits/char 4 - lshift 1 -
336: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
337: [ELSE] -1 1 cells 1- times c, [THEN]
338: [THEN]
339:
340: \ higher level parts of find
341:
342: : flag-sign ( f -- 1|-1 )
343: \ true becomes 1, false -1
344: 0= 2* 1+ ;
345:
346: : ticking-compile-only-error ( ... -- )
347: -&2048 throw ;
348:
349: : compile-only-error ( ... -- )
350: -&14 throw ;
351:
352: : (cfa>int) ( cfa -- xt )
353: [ has? compiler [IF] ]
354: dup interpret/compile?
355: if
356: interpret/compile-int @
357: then
358: [ [THEN] ] ;
359:
360: : (x>int) ( cfa w -- xt )
361: \ get interpretation semantics of name
362: restrict-mask and [ has? rom [IF] ] 0= [ [THEN] ]
363: if
364: drop ['] compile-only-error
365: else
366: (cfa>int)
367: then ;
368:
369: has? f83headerstring [IF]
370: : name>string ( nt -- addr count ) \ gforth name-to-string
371: \g @i{addr count} is the name of the word represented by @i{nt}.
372: cell+ count lcount-mask and ;
373:
374: : ((name>)) ( nfa -- cfa )
375: name>string + cfaligned ;
376:
377: : (name>x) ( nfa -- cfa w )
378: \ cfa is an intermediate cfa and w is the flags cell of nfa
379: dup ((name>))
380: swap cell+ c@ dup alias-mask and 0=
381: IF
382: swap @ swap
383: THEN ;
384: [ELSE]
385: : name>string ( nt -- addr count ) \ gforth name-to-string
386: \g @i{addr count} is the name of the word represented by @i{nt}.
387: cell+ dup cell+ swap @ lcount-mask and ;
388:
389: : ((name>)) ( nfa -- cfa )
390: name>string + cfaligned ;
391:
392: : (name>x) ( nfa -- cfa w )
393: \ cfa is an intermediate cfa and w is the flags cell of nfa
394: dup ((name>))
395: swap cell+ @ dup alias-mask and 0=
396: IF
397: swap @ swap
398: THEN ;
399: [THEN]
400:
401: : name>int ( nt -- xt ) \ gforth name-to-int
402: \G @i{xt} represents the interpretation semantics of the word
403: \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
404: \G @code{compile-only}), @i{xt} is the execution token for
405: \G @code{ticking-compile-only-error}, which performs @code{-2048 throw}.
406: (name>x) (x>int) ;
407:
408: : name?int ( nt -- xt ) \ gforth name-question-int
409: \G Like @code{name>int}, but perform @code{-2048 throw} if @i{nt}
410: \G has no interpretation semantics.
411: (name>x) restrict-mask and [ has? rom [IF] ] 0= [ [THEN] ]
412: if
413: ticking-compile-only-error \ does not return
414: then
415: (cfa>int) ;
416:
417: : (name>comp) ( nt -- w +-1 ) \ gforth
418: \G @i{w xt} is the compilation token for the word @i{nt}.
419: (name>x) >r
420: [ has? compiler [IF] ]
421: dup interpret/compile?
422: if
423: interpret/compile-comp @
424: then
425: [ [THEN] ]
426: r> immediate-mask and [ has? rom [IF] ] 0= [ [THEN] ] flag-sign
427: ;
428:
429: : (name>intn) ( nfa -- xt +-1 )
430: (name>x) tuck (x>int) ( w xt )
431: swap immediate-mask and [ has? rom [IF] ] 0= [ [THEN] ] flag-sign ;
432:
433: [IFDEF] prelude-mask
434: : name>prelude ( nt -- xt )
435: dup cell+ @ prelude-mask and if
436: [ -1 cells ] literal + @
437: else
438: drop ['] noop
439: then ;
440: [THEN]
441:
442: const Create ??? 0 , 3 , char ? c, char ? c, char ? c,
443: \ ??? is used by dovar:, must be created/:dovar
444:
445: [IFDEF] forthstart
446: \ if we have a forthstart we can define head? with it
447: \ otherwise leave out the head? check
448:
449: : head? ( addr -- f )
450: \G heuristic check whether addr is a name token; may deliver false
451: \G positives; addr must be a valid address
452: dup dup aligned <>
453: if
454: drop false exit \ heads are aligned
455: then
456: name>string dup $1F > if
457: 2drop false exit \ realistically the name is short
458: then
459: + cfaligned @ here forthstart within ; \ and the cfa is outside
460:
461: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
462: \ also heuristic
463: dup forthstart - max-name-length @
464: [ has? float [IF] ] float+ [ [ELSE] ] cell+ [ [THEN] ] cell+ min
465: cell max cell ?do ( cfa )
466: dup i - dup @ [ alias-mask lcount-mask or ] literal
467: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
468: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
469: [ELSE] -1 1 cells 1- times c, [THEN] ]
470: and ( cfa len|alias )
471: swap + cell+ cfaligned over alias-mask + =
472: if ( cfa )
473: dup i - cell - dup head?
474: if
475: nip unloop exit
476: then
477: drop
478: then
479: cell +loop
480: drop ??? ( wouldn't 0 be better? ) ;
481:
482: [ELSE]
483:
484: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
485: $25 cell do ( cfa )
486: dup i - dup @ [ alias-mask lcount-mask or ] literal
487: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
488: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
489: [ELSE] -1 1 cells 1- times c, [THEN] ]
490: and ( cfa len|alias )
491: swap + cell + cfaligned over alias-mask + =
492: if ( cfa ) i - cell - unloop exit
493: then
494: cell +loop
495: drop ??? ( wouldn't 0 be better? ) ;
496:
497: [THEN]
498:
499: cell% 2* 0 0 field >body ( xt -- a_addr ) \ core to-body
500: \G Get the address of the body of the word represented by @i{xt} (the
501: \G address of the word's data field).
502: drop drop
503:
504: cell% -2 * 0 0 field body> ( xt -- a_addr )
505: drop drop
506:
507: has? standardthreading has? compiler and [IF]
508:
509: ' @ alias >code-address ( xt -- c_addr ) \ gforth
510: \G @i{c-addr} is the code address of the word @i{xt}.
511:
512: : >does-code ( xt -- a_addr ) \ gforth
513: \G If @i{xt} is the execution token of a child of a @code{DOES>} word,
514: \G @i{a-addr} is the start of the Forth code after the @code{DOES>};
515: \G Otherwise @i{a-addr} is 0.
516: dup @ dodoes: = if
517: cell+ @
518: else
519: drop 0
520: endif ;
521:
522: has? prims [IF]
523: : flash! ! ;
524: : flashc! c! ;
525: [THEN]
526:
527: has? flash [IF] ' flash! [ELSE] ' ! [THEN]
528: alias code-address! ( c_addr xt -- ) \ gforth
529: \G Create a code field with code address @i{c-addr} at @i{xt}.
530:
531: : any-code! ( a-addr cfa code-addr -- )
532: \ for implementing DOES> and ;ABI-CODE, maybe :
533: \ code-address is stored at cfa, a-addr at cfa+cell
534: over ! cell+ ! ;
535:
536: : does-code! ( a-addr xt -- ) \ gforth
537: \G Create a code field at @i{xt} for a child of a @code{DOES>}-word;
538: \G @i{a-addr} is the start of the Forth code after @code{DOES>}.
539: [ has? flash [IF] ]
540: dodoes: over flash! cell+ flash!
541: [ [ELSE] ]
542: dodoes: any-code!
543: [ [THEN] ] ;
544:
545: 2 cells constant /does-handler ( -- n ) \ gforth
546: \G The size of a @code{DOES>}-handler (includes possible padding).
547:
548: [THEN]
549:
550: : sfind ( c-addr u -- 0 / xt +-1 ) \ gforth-obsolete
551: find-name dup
552: if ( nt )
553: state @
554: if
555: (name>comp)
556: else
557: (name>intn)
558: then
559: then ;
560:
561: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
562: \G Search all word lists in the current search order for the
563: \G definition named by the counted string at @i{c-addr}. If the
564: \G definition is not found, return 0. If the definition is found
565: \G return 1 (if the definition has non-default compilation
566: \G semantics) or -1 (if the definition has default compilation
567: \G semantics). The @i{xt} returned in interpret state represents
568: \G the interpretation semantics. The @i{xt} returned in compile
569: \G state represented either the compilation semantics (for
570: \G non-default compilation semantics) or the run-time semantics
571: \G that the compilation semantics would @code{compile,} (for
572: \G default compilation semantics). The ANS Forth standard does
573: \G not specify clearly what the returned @i{xt} represents (and
574: \G also talks about immediacy instead of non-default compilation
575: \G semantics), so this word is questionable in portable programs.
576: \G If non-portability is ok, @code{find-name} and friends are
577: \G better (@pxref{Name token}).
578: dup count sfind dup
579: if
580: rot drop
581: then ;
582:
583: \ ticks in interpreter
584:
585: : (') ( "name" -- nt ) \ gforth
586: parse-name name-too-short?
587: find-name dup 0=
588: IF
589: drop -&13 throw
590: THEN ;
591:
592: : ' ( "name" -- xt ) \ core tick
593: \g @i{xt} represents @i{name}'s interpretation
594: \g semantics. Perform @code{-14 throw} if the word has no
595: \g interpretation semantics.
596: (') name?int ;
597:
598: has? compiler 0= [IF] \ interpreter only version of IS and TO
599:
600: : IS ' >body ! ;
601: ' IS Alias TO
602:
603: [THEN]
604:
605: \ \ the interpreter loop mar92py
606:
607: \ interpret 10mar92py
608:
609: Defer parser1 ( c-addr u -- ... xt)
610: \ "... xt" is the action to be performed by the text-interpretation of c-addr u
611:
612: : parser ( c-addr u -- ... )
613: \ text-interpret the word/number c-addr u, possibly producing a number
614: parser1 execute ;
615:
616: has? ec [IF]
617: ' (name) Alias parse-name
618: : no.extensions 2drop -&13 throw ;
619: ' no.extensions Alias compiler-notfound1
620: ' no.extensions Alias interpreter-notfound1
621: [ELSE]
622: Defer parse-name ( "name" -- c-addr u ) \ gforth
623: \G Get the next word from the input buffer
624: ' (name) IS parse-name
625:
626: ' parse-name alias parse-word ( -- c-addr u ) \ gforth-obsolete
627: \G old name for @code{parse-name}
628:
629: ' parse-name alias name ( -- c-addr u ) \ gforth-obsolete
630: \G old name for @code{parse-name}
631:
632: : no.extensions ( addr u -- )
633: 2drop -&13 throw ;
634:
635: has? recognizer 0= [IF]
636: Defer compiler-notfound1 ( c-addr count -- ... xt )
637: Defer interpreter-notfound1 ( c-addr count -- ... xt )
638:
639: ' no.extensions IS compiler-notfound1
640: ' no.extensions IS interpreter-notfound1
641: [THEN]
642:
643: Defer before-word ( -- ) \ gforth
644: \ called before the text interpreter parses the next word
645: ' noop IS before-word
646: [THEN]
647:
648: has? backtrace [IF]
649: : interpret1 ( ... -- ... )
650: rp@ backtrace-rp0 !
651: BEGIN
652: ?stack [ has? EC 0= [IF] ] before-word [ [THEN] ] parse-name dup
653: WHILE
654: parser1 execute
655: REPEAT
656: 2drop ;
657:
658: : interpret ( ?? -- ?? ) \ gforth
659: \ interpret/compile the (rest of the) input buffer
660: backtrace-rp0 @ >r
661: ['] interpret1 catch
662: r> backtrace-rp0 !
663: throw ;
664: [ELSE]
665: : interpret ( ... -- ... )
666: BEGIN
667: ?stack [ has? EC 0= [IF] ] before-word [ [THEN] ] parse-name dup
668: WHILE
669: parser1 execute
670: REPEAT
671: 2drop ;
672: [THEN]
673:
674: \ interpreter 30apr92py
675:
676: [IFDEF] prelude-mask
677: : run-prelude ( nt|0 -- nt|0 )
678: \ run the prelude of the name identified by nt (if present). This
679: \ is used in the text interpreter and similar stuff.
680: dup if
681: dup name>prelude execute
682: then ;
683: [THEN]
684:
685: has? recognizer 0= [IF]
686: \ not the most efficient implementations of interpreter and compiler
687: : interpreter1 ( c-addr u -- ... xt )
688: 2dup find-name [ [IFDEF] prelude-mask ] run-prelude [ [THEN] ] dup
689: if
690: nip nip name>int
691: else
692: drop
693: 2dup 2>r snumber?
694: IF
695: 2rdrop ['] noop
696: ELSE
697: 2r> interpreter-notfound1
698: THEN
699: then ;
700:
701: ' interpreter1 IS parser1
702: [THEN]
703:
704: \ \ Query Evaluate 07apr93py
705:
706: has? file 0= [IF]
707: : sourceline# ( -- n ) 1 ;
708: [ELSE]
709: has? new-input 0= [IF]
710: Variable #fill-bytes
711: \G number of bytes read via (read-line) by the last refill
712: [THEN]
713: [THEN]
714:
715: has? new-input 0= [IF]
716: : input-start-line ( -- ) >in off ;
717: : refill ( -- flag ) \ core-ext,block-ext,file-ext
718: \G Attempt to fill the input buffer from the input source. When
719: \G the input source is the user input device, attempt to receive
720: \G input into the terminal input device. If successful, make the
721: \G result the input buffer, set @code{>IN} to 0 and return true;
722: \G otherwise return false. When the input source is a block, add 1
723: \G to the value of @code{BLK} to make the next block the input
724: \G source and current input buffer, and set @code{>IN} to 0;
725: \G return true if the new value of @code{BLK} is a valid block
726: \G number, false otherwise. When the input source is a text file,
727: \G attempt to read the next line from the file. If successful,
728: \G make the result the current input buffer, set @code{>IN} to 0
729: \G and return true; otherwise, return false. A successful result
730: \G includes receipt of a line containing 0 characters.
731: [ has? file [IF] ]
732: blk @ IF 1 blk +! true EXIT THEN
733: [ [THEN] ]
734: tib /line
735: [ has? file [IF] ]
736: loadfile @ ?dup
737: IF (read-line) throw #fill-bytes !
738: ELSE
739: [ [THEN] ]
740: sourceline# 0< IF 2drop false EXIT THEN
741: accept eof @ 0=
742: [ has? file [IF] ]
743: THEN
744: 1 loadline +!
745: [ [THEN] ]
746: swap #tib !
747: input-start-line ;
748:
749: : query ( -- ) \ core-ext
750: \G Make the user input device the input source. Receive input into
751: \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
752: \G superceeded by @code{accept}.
753: [ has? file [IF] ]
754: blk off loadfile off
755: [ [THEN] ]
756: refill drop ;
757: [THEN]
758:
759: \ save-mem extend-mem
760:
761: has? os [IF]
762: : save-mem ( addr1 u -- addr2 u ) \ gforth
763: \g copy a memory block into a newly allocated region in the heap
764: swap >r
765: dup allocate throw
766: swap 2dup r> -rot move ;
767:
768: : free-mem-var ( addr -- )
769: \ addr is the address of a 2variable containing address and size
770: \ of a memory range; frees memory and clears the 2variable.
771: dup 2@ drop dup
772: if ( addr mem-start )
773: free throw
774: 0 0 rot 2!
775: else
776: 2drop
777: then ;
778:
779: : extend-mem ( addr1 u1 u -- addr addr2 u2 )
780: \ extend memory block allocated from the heap by u aus
781: \ the (possibly reallocated) piece is addr2 u2, the extension is at addr
782: over >r + dup >r resize throw
783: r> over r> + -rot ;
784: [THEN]
785:
786: \ EVALUATE 17may93jaw
787:
788: has? file 0= has? new-input 0= and [IF]
789: : push-file ( -- ) r>
790: tibstack @ >r >tib @ >r #tib @ >r
791: >tib @ tibstack @ = IF r@ tibstack +! THEN
792: tibstack @ >tib ! >in @ >r >r ;
793:
794: : pop-file ( throw-code -- throw-code )
795: r>
796: r> >in ! r> #tib ! r> >tib ! r> tibstack ! >r ;
797: [THEN]
798:
799: has? new-input 0= [IF]
800: : evaluate ( c-addr u -- ) \ core,block
801: \G Save the current input source specification. Store @code{-1} in
802: \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
803: \G @code{0} and make the string @i{c-addr u} the input source
804: \G and input buffer. Interpret. When the parse area is empty,
805: \G restore the input source specification.
806: [ has? file [IF] ]
807: s" *evaluated string*" loadfilename>r
808: [ [THEN] ]
809: push-file #tib ! >tib !
810: input-start-line
811: [ has? file [IF] ]
812: blk off loadfile off -1 loadline !
813: [ [THEN] ]
814: ['] interpret catch
815: pop-file
816: [ has? file [IF] ]
817: r>loadfilename
818: [ [THEN] ]
819: throw ;
820: [THEN]
821:
822: \ \ Quit 13feb93py
823:
824: Defer 'quit
825:
826: has? os [IF]
827: Defer .status
828: [ELSE]
829: [IFUNDEF] bye
830: : (bye) ( 0 -- ) \ back to DOS
831: drop 5 emit ;
832:
833: : bye ( -- ) 0 (bye) ;
834: [THEN]
835: [THEN]
836:
837: : prompt state @ IF ." compiled" EXIT THEN ." ok" ;
838:
839: : (quit) ( -- )
840: \ exits only through THROW etc.
841: BEGIN
842: [ has? ec [IF] ] cr [ [ELSE] ]
843: .status ['] cr catch if
844: [ has? OS [IF] ] >stderr [ [THEN] ]
845: cr ." Can't print to stdout, leaving" cr
846: \ if stderr does not work either, already DoError causes a hang
847: 2 (bye)
848: endif [ [THEN] ]
849: refill WHILE
850: interpret prompt
851: REPEAT
852: bye ;
853:
854: ' (quit) IS 'quit
855:
856: \ \ DOERROR (DOERROR) 13jun93jaw
857:
858: has? os [IF]
859: 8 Constant max-errors
860: 5 has? file 2 and + Constant /error
861: Variable error-stack 0 error-stack !
862: max-errors /error * cells allot
863: \ format of one cell:
864: \ source ( c-addr u )
865: \ last parsed lexeme ( c-addr u )
866: \ line-number
867: \ Loadfilename ( addr u )
868:
869: : error> ( -- c-addr1 u1 c-addr2 u2 line# [addr u] )
870: -1 error-stack +!
871: error-stack dup @
872: /error * cells + cell+
873: /error cells bounds DO
874: I @
875: cell +LOOP ;
876:
877: : >error ( c-addr1 u1 c-addr2 u2 line# [addr u] -- )
878: error-stack dup @ dup 1+
879: max-errors 1- min error-stack !
880: /error * cells + cell+
881: /error 1- cells bounds swap DO
882: I !
883: -1 cells +LOOP ;
884:
885: : input-error-data ( -- c-addr1 u1 c-addr2 u2 line# [addr u] )
886: \ error data for the current input, to be used by >error or .error-frame
887: source over >r save-mem over r> -
888: input-lexeme 2@ >r + r> sourceline#
889: [ has? file [IF] ] sourcefilename [ [THEN] ] ;
890:
891: : dec. ( n -- ) \ gforth
892: \G Display @i{n} as a signed decimal number, followed by a space.
893: \ !! not used...
894: base @ decimal swap . base ! ;
895:
896: : dec.r ( u n -- ) \ gforth
897: \G Display @i{u} as a unsigned decimal number in a field @i{n}
898: \G characters wide.
899: base @ >r decimal .r r> base ! ;
900:
901: : hex. ( u -- ) \ gforth
902: \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
903: \G followed by a space.
904: \ !! not used...
905: [char] $ emit base @ swap hex u. base ! ;
906:
907: : -trailing ( c_addr u1 -- c_addr u2 ) \ string dash-trailing
908: \G Adjust the string specified by @i{c-addr, u1} to remove all
909: \G trailing spaces. @i{u2} is the length of the modified string.
910: BEGIN
911: dup
912: WHILE
913: 1- 2dup + c@ bl <>
914: UNTIL 1+ THEN ;
915:
916: DEFER DOERROR
917:
918: has? backtrace [IF]
919: Defer dobacktrace ( -- )
920: ' noop IS dobacktrace
921: [THEN]
922:
923: : .error-string ( throw-code -- )
924: dup -2 =
925: IF "error @ ?dup IF count type THEN drop
926: ELSE .error
927: THEN ;
928:
929: : umin ( u1 u2 -- u )
930: 2dup u>
931: if
932: swap
933: then
934: drop ;
935:
936: Defer mark-start
937: Defer mark-end
938:
939: :noname ." >>>" ; IS mark-start
940: :noname ." <<<" ; IS mark-end
941:
942: : part-type ( addr1 u1 u -- addr2 u2 )
943: \ print first u characters of addr1 u1, addr2 u2 is the rest
944: over umin 2 pick over type /string ;
945:
946: : .error-line ( c-addr1 u1 c-addr2 u2 -- )
947: \ print error in line c-addr1 u1, where the error-causing lexeme
948: \ is c-addr2 u2
949: >r 2 pick - part-type ( c-addr3 u3 R: u2 )
950: mark-start r> part-type mark-end ( c-addr4 u4 )
951: type ;
952:
953: : .error-frame ( throwcode addr1 u1 addr2 u2 n2 [addr3 u3] -- throwcode )
954: \ addr3 u3: filename of included file - optional
955: \ n2: line number
956: \ addr2 u2: parsed lexeme (should be marked as causing the error)
957: \ addr1 u1: input line
958: error-stack @
959: IF ( throwcode addr1 u1 n0 n1 n2 [addr2 u2] )
960: [ has? file [IF] ] \ !! unbalanced stack effect
961: over IF
962: cr ." in file included from "
963: type ." :"
964: 0 dec.r 2drop 2drop
965: ELSE
966: 2drop 2drop 2drop drop
967: THEN
968: [ [THEN] ] ( throwcode addr1 u1 n0 n1 n2 )
969: ELSE ( throwcode addr1 u1 n0 n1 n2 [addr2 u2] )
970: [ has? file [IF] ]
971: cr type ." :"
972: [ [THEN] ] ( throwcode addr1 u1 n0 n1 n2 )
973: dup 0 dec.r ." : " 5 pick .error-string
974: IF \ if line# non-zero, there is a line
975: cr .error-line
976: ELSE
977: 2drop 2drop
978: THEN
979: THEN ;
980:
981: : (DoError) ( throw-code -- )
982: [ has? os [IF] ]
983: >stderr
984: [ [THEN] ]
985: input-error-data .error-frame
986: error-stack @ 0 ?DO
987: error>
988: .error-frame
989: LOOP
990: drop
991: [ has? backtrace [IF] ]
992: dobacktrace
993: [ [THEN] ]
994: normal-dp dpp ! ;
995:
996: ' (DoError) IS DoError
997:
998: [ELSE]
999: : dec. base @ >r decimal . r> base ! ;
1000: : DoError ( throw-code -- )
1001: cr source drop >in @ type ." <<< "
1002: dup -2 = IF "error @ type drop EXIT THEN
1003: .error ;
1004: [THEN]
1005:
1006: : quit ( ?? -- ?? ) \ core
1007: \G Empty the return stack, make the user input device
1008: \G the input source, enter interpret state and start
1009: \G the text interpreter.
1010: rp0 @ rp! handler off clear-tibstack
1011: [ has? new-input 0= [IF] ] >tib @ >r [ [THEN] ]
1012: BEGIN
1013: [ has? compiler [IF] ]
1014: [compile] [
1015: [ [THEN] ]
1016: \ stack depths may be arbitrary here
1017: ['] 'quit CATCH dup
1018: WHILE
1019: <# \ reset hold area, or we may get another error
1020: DoError
1021: \ stack depths may be arbitrary still (or again), so clear them
1022: clearstacks
1023: [ has? new-input [IF] ] clear-tibstack
1024: [ [ELSE] ] r@ >tib ! r@ tibstack !
1025: [ [THEN] ]
1026: REPEAT
1027: drop [ has? new-input [IF] ] clear-tibstack
1028: [ [ELSE] ] r> >tib !
1029: [ [THEN] ] ;
1030:
1031: \ \ Cold Boot 13feb93py
1032:
1033: : (bootmessage) ( -- )
1034: ." Gforth " version-string type
1035: ." , Copyright (C) 1995-2011 Free Software Foundation, Inc." cr
1036: ." Gforth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
1037: [ has? os [IF] ]
1038: cr ." Type `bye' to exit"
1039: [ [THEN] ] ;
1040:
1041: defer bootmessage ( -- ) \ gforth
1042: \G Hook (deferred word) executed right after interpreting the OS
1043: \G command-line arguments. Normally prints the Gforth startup
1044: \G message.
1045:
1046: has? file [IF]
1047: defer process-args
1048: [THEN]
1049:
1050: ' (bootmessage) IS bootmessage
1051:
1052: has? os [IF]
1053: Defer 'cold ( -- ) \ gforth tick-cold
1054: \G Hook (deferred word) for things to do right before interpreting the
1055: \G OS command-line arguments. Normally does some initializations that
1056: \G you also want to perform.
1057: ' noop IS 'cold
1058: [THEN]
1059:
1060: : cold ( -- ) \ gforth
1061: [ has? backtrace [IF] ]
1062: rp@ backtrace-rp0 !
1063: [ [THEN] ]
1064: [ has? file [IF] ]
1065: os-cold
1066: [ [THEN] ]
1067: [ has? os [IF] ]
1068: set-encoding-fixed-width
1069: 'cold
1070: [ [THEN] ]
1071: [ has? file [IF] ]
1072: process-args
1073: loadline off
1074: [ [THEN] ]
1075: bootmessage
1076: quit ;
1077:
1078: has? new-input 0= [IF]
1079: : clear-tibstack ( -- )
1080: [ has? glocals [IF] ]
1081: lp@ forthstart 7 cells + @ -
1082: [ [ELSE] ]
1083: [ has? os [IF] ]
1084: r0 @ forthstart 6 cells + @ -
1085: [ [ELSE] ]
1086: sp@ cell+
1087: [ [THEN] ]
1088: [ [THEN] ]
1089: dup >tib ! tibstack ! #tib off
1090: input-start-line ;
1091: [THEN]
1092:
1093: : boot ( path n **argv argc -- )
1094: [ has? no-userspace 0= [IF] ]
1095: main-task up!
1096: [ [THEN] ]
1097: [ has? os [IF] ]
1098: os-boot
1099: [ [THEN] ]
1100: [ has? rom [IF] ]
1101: ram-shadow dup @ dup -1 <> >r u> r> and IF
1102: ram-shadow 2@ ELSE
1103: ram-mirror ram-size THEN ram-start swap move
1104: [ [THEN] ]
1105: sp@ sp0 !
1106: [ has? peephole [IF] ]
1107: \ only needed for greedy static superinstruction selection
1108: \ primtable prepare-peephole-table TO peeptable
1109: [ [THEN] ]
1110: [ has? new-input [IF] ]
1111: current-input off
1112: [ [THEN] ]
1113: clear-tibstack
1114: 0 0 includefilename 2!
1115: rp@ rp0 !
1116: [ has? floating [IF] ]
1117: fp@ fp0 !
1118: [ [THEN] ]
1119: [ has? os [IF] ]
1120: handler off
1121: ['] cold catch dup -&2049 <> if \ broken pipe?
1122: DoError cr
1123: endif
1124: [ [ELSE] ]
1125: cold
1126: [ [THEN] ]
1127: [ has? os [IF] ]
1128: 1 (bye) \ !! determin exit code from throw code?
1129: [ [THEN] ]
1130: ;
1131:
1132: has? os [IF]
1133: : bye ( -- ) \ tools-ext
1134: [ has? file [IF] ]
1135: script? 0= IF cr THEN
1136: [ [ELSE] ]
1137: cr
1138: [ [THEN] ]
1139: 0 (bye) ;
1140: [THEN]
1141:
1142: \ **argv may be scanned by the C starter to get some important
1143: \ information, as -display and -geometry for an X client FORTH
1144: \ or space and stackspace overrides
1145:
1146: \ 0 arg contains, however, the name of the program.
1147:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to int.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth / kernel