File:  [gforth] / gforth / kernel / int.fs
Revision 1.177: download - view: text, annotated - select for diffs
Fri Dec 31 18:09:02 2010 UTC (13 years, 3 months ago) by anton
Branches: MAIN
CVS tags: HEAD
updated copyright years

    1: \ definitions needed for interpreter only
    2: 
    3: \ Copyright (C) 1995-2000,2004,2005,2007,2009,2010 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation, either version 3
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program. If not, see http://www.gnu.org/licenses/.
   19: 
   20: \ \ Revision-Log
   21: 
   22: \       put in seperate file				14sep97jaw 
   23: 
   24: \ \ input stream primitives                       	23feb93py
   25: 
   26: require ./basics.fs 	\ bounds decimal hex ...
   27: require ./io.fs		\ type ...
   28: require ./nio.fs	\ . <# ...
   29: require ./errore.fs	\ .error ...
   30: require kernel/version.fs \ version-string
   31: 
   32: has? new-input 0= [IF]
   33: : tib ( -- c-addr ) \ core-ext t-i-b
   34:     \G @i{c-addr} is the address of the Terminal Input Buffer.
   35:     \G OBSOLESCENT: @code{source} superceeds the function of this word.
   36:     >tib @ ;
   37: 
   38: Defer source ( -- c-addr u ) \ core
   39: \ used by dodefer:, must be defer
   40: \G @i{c-addr} is the address of the input buffer and @i{u} is the
   41: \G number of characters in it.
   42: 
   43: : (source) ( -- c-addr u )
   44:     tib #tib @ ;
   45: ' (source) IS source
   46: [THEN]
   47: 
   48: : (word) ( addr1 n1 char -- addr2 n2 )
   49:   dup >r skip 2dup r> scan  nip - ;
   50: 
   51: \ (word) should fold white spaces
   52: \ this is what (parse-white) does
   53: 
   54: \ parse                                           23feb93py
   55: 
   56: : parse    ( char "ccc<char>" -- c-addr u ) \ core-ext
   57: \G Parse @i{ccc}, delimited by @i{char}, in the parse
   58: \G area. @i{c-addr u} specifies the parsed string within the
   59: \G parse area. If the parse area was empty, @i{u} is 0.
   60:     >r  source  >in @ over min /string ( c-addr1 u1 )
   61:     over  swap r>  scan >r
   62:     over - dup r> IF 1+ THEN  >in +!
   63: [ has? new-input [IF] ]
   64:     2dup input-lexeme!
   65: [ [THEN] ] ;
   66: 
   67: \ name                                                 13feb93py
   68: 
   69: [IFUNDEF] (name) \ name might be a primitive
   70: 
   71: : (name) ( -- c-addr count ) \ gforth
   72:     source 2dup >r >r >in @ /string (parse-white)
   73: [ has? new-input [IF] ]
   74:     2dup input-lexeme!
   75: [ [THEN] ]
   76:     2dup + r> - 1+ r> min >in ! ;
   77: \    name count ;
   78: [THEN]
   79: 
   80: : name-too-short? ( c-addr u -- c-addr u )
   81:     dup 0= -&16 and throw ;
   82: 
   83: : name-too-long? ( c-addr u -- c-addr u )
   84:     dup lcount-mask u> -&19 and throw ;
   85: 
   86: \ \ Number parsing					23feb93py
   87: 
   88: \ (number?) number                                       23feb93py
   89: 
   90: hex
   91: const Create bases   0A , 10 ,   2 ,   0A ,
   92: \                    10   16     2     10
   93: 
   94: \ !! protect BASE saving wrapper against exceptions
   95: : getbase ( addr u -- addr' u' )
   96:     2dup s" 0x" string-prefix? >r
   97:     2dup s" 0X" string-prefix? r> or
   98:     base @ &34 < and if
   99: 	hex 2 /string
  100:     endif
  101:     over c@ [char] # - dup 4 u<
  102:     IF
  103: 	cells bases + @ base ! 1 /string
  104:     ELSE
  105: 	drop
  106:     THEN ;
  107: 
  108: : sign? ( addr u -- addr1 u1 flag )
  109:     over c@ [char] - =  dup >r
  110:     IF
  111: 	1 /string
  112:     THEN
  113:     r> ;
  114: 
  115: : ?dnegate ( d1 f -- d2 )
  116:     if
  117:         dnegate
  118:     then ;
  119: 
  120: has? os 0= [IF]
  121: : x@+/string ( addr u -- addr' u' c )
  122:     over c@ >r 1 /string r> ;
  123: [THEN]
  124: 
  125: : s'>unumber? ( addr u -- ud flag )
  126:     \ convert string "C" or "C'" to character code
  127:     dup 0= if
  128: 	false exit
  129:     endif
  130:     x@+/string 0 s" '" 2rot string-prefix? ;
  131: 
  132: : s>unumber? ( c-addr u -- ud flag ) \ gforth
  133:     \G converts string c-addr u into ud, flag indicates success
  134:     dpl on
  135:     over c@ '' = if
  136: 	1 /string s'>unumber? exit
  137:     endif
  138:     base @ >r  getbase sign?
  139:     over if
  140:         >r 0. 2swap
  141:         BEGIN ( d addr len )
  142:             dup >r >number dup
  143:         WHILE \ there are characters left
  144:                 dup r> -
  145:             WHILE \ the last >number parsed something
  146:                     dup 1- dpl ! over c@ [char] . =
  147:                 WHILE \ the current char is '.'
  148:                         1 /string
  149:                 REPEAT  THEN \ there are unparseable characters left
  150:             2drop rdrop false
  151:         ELSE
  152:             rdrop 2drop r> ?dnegate true
  153:         THEN
  154:     ELSE
  155:         drop 2drop 0. false THEN
  156:     r> base ! ;
  157: 
  158: \ ouch, this is complicated; there must be a simpler way - anton
  159: : s>number? ( addr u -- d f ) \ gforth
  160:     \G converts string addr u into d, flag indicates success
  161:     sign? >r
  162:     s>unumber?
  163:     0= IF
  164:         rdrop false
  165:     ELSE \ no characters left, all ok
  166: 	r> ?dnegate
  167: 	true
  168:     THEN ;
  169: 
  170: : s>number ( addr len -- d )
  171:     \ don't use this, there is no way to tell success
  172:     s>number? drop ;
  173: 
  174: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
  175:     s>number? 0=
  176:     IF
  177: 	2drop false  EXIT
  178:     THEN
  179:     dpl @ dup 0< IF
  180: 	nip
  181:     ELSE
  182: 	1+
  183:     THEN ;
  184: 
  185: : (number?) ( string -- string 0 / n -1 / d 0> )
  186:     dup >r count snumber? dup if
  187: 	rdrop
  188:     else
  189: 	r> swap
  190:     then ;
  191: 
  192: : number ( string -- d )
  193:     (number?) ?dup 0= abort" ?"  0<
  194:     IF
  195: 	s>d
  196:     THEN ;
  197: 
  198: \ \ Comments ( \ \G
  199: 
  200: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file	paren
  201:     \G ** this will not get annotated. The alias in glocals.fs will instead **
  202:     \G It does not work to use "wordset-" prefix since this file is glossed
  203:     \G by cross.fs which doesn't have the same functionalty as makedoc.fs
  204:     [char] ) parse 2drop ; immediate
  205: 
  206: : \ ( compilation 'ccc<newline>' -- ; run-time -- ) \ thisone- core-ext,block-ext backslash
  207:     \G ** this will not get annotated. The alias in glocals.fs will instead ** 
  208:     \G It does not work to use "wordset-" prefix since this file is glossed
  209:     \G by cross.fs which doesn't have the same functionalty as makedoc.fs
  210:     [ has? file [IF] ]
  211:     blk @
  212:     IF
  213: 	>in @ c/l / 1+ c/l * >in !
  214: 	EXIT
  215:     THEN
  216:     [ [THEN] ]
  217:     source >in ! drop ; immediate
  218: 
  219: : \G ( compilation 'ccc<newline>' -- ; run-time -- ) \ gforth backslash-gee
  220:     \G Equivalent to @code{\} but used as a tag to annotate definition
  221:     \G comments into documentation.
  222:     POSTPONE \ ; immediate
  223: 
  224: has? ec [IF]
  225:     AVariable forth-wordlist
  226:     : find-name ( c-addr u -- nt | 0 ) \ gforth
  227: 	\g Find the name @i{c-addr u} in the current search
  228: 	\g order. Return its @i{nt}, if found, otherwise 0.
  229: 	forth-wordlist (f83find) ;
  230: [ELSE]
  231: \ \ object oriented search list                         17mar93py
  232: 
  233: \ word list structure:
  234: 
  235: struct
  236:   cell% field find-method   \ xt: ( c_addr u wid -- nt )
  237:   cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
  238:   cell% field rehash-method \ xt: ( wid -- )	   \ re-initializes a "search-data" (hashtables)
  239:   cell% field hash-method   \ xt: ( wid -- )    \ initializes ""
  240: \   \ !! what else
  241: end-struct wordlist-map-struct
  242: 
  243: struct
  244:   cell% field wordlist-map \ pointer to a wordlist-map-struct
  245:   cell% field wordlist-id \ linked list of words (for WORDS etc.)
  246:   cell% field wordlist-link \ link field to other wordlists
  247:   cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
  248: end-struct wordlist-struct
  249: 
  250: has? f83headerstring [IF]
  251: : f83find      ( addr len wordlist -- nt / false )
  252:     wordlist-id @ (f83find) ;
  253: [ELSE]
  254: : f83find      ( addr len wordlist -- nt / false )
  255:     wordlist-id @ (listlfind) ;
  256: [THEN]
  257: 
  258: : initvoc		( wid -- )
  259:   dup wordlist-map @ hash-method perform ;
  260: 
  261: \ Search list table: find reveal
  262: Create f83search ( -- wordlist-map )
  263:     ' f83find A,  ' drop A,  ' drop A, ' drop A,
  264: 
  265: here f83search A, NIL A, NIL A, NIL A,
  266: AValue forth-wordlist \ variable, will be redefined by search.fs
  267: 
  268: AVariable lookup       	forth-wordlist lookup !
  269: \ !! last is user and lookup?! jaw
  270: AVariable current ( -- addr ) \ gforth
  271: \G @code{Variable} -- holds the @i{wid} of the compilation word list.
  272: AVariable voclink	forth-wordlist wordlist-link voclink !
  273: \ lookup AValue context ( -- addr ) \ gforth
  274: Defer context ( -- addr ) \ gforth
  275: \G @code{context} @code{@@} is the @i{wid} of the word list at the
  276: \G top of the search order.
  277: 
  278: ' lookup is context
  279: forth-wordlist current !
  280: 
  281: : (search-wordlist)  ( addr count wid -- nt | false )
  282:     dup wordlist-map @ find-method perform ;
  283: 
  284: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
  285:     \G Search the word list identified by @i{wid} for the definition
  286:     \G named by the string at @i{c-addr count}.  If the definition is
  287:     \G not found, return 0. If the definition is found return 1 (if
  288:     \G the definition is immediate) or -1 (if the definition is not
  289:     \G immediate) together with the @i{xt}.  In Gforth, the @i{xt}
  290:     \G returned represents the interpretation semantics.  ANS Forth
  291:     \G does not specify clearly what @i{xt} represents.
  292:     (search-wordlist) dup if
  293: 	(name>intn)
  294:     then ;
  295: 
  296: : find-name ( c-addr u -- nt | 0 ) \ gforth
  297:     \g Find the name @i{c-addr u} in the current search
  298:     \g order. Return its @i{nt}, if found, otherwise 0.
  299:     lookup @ (search-wordlist) ;
  300: [THEN]
  301: 
  302: \ \ header, finding, ticks                              17dec92py
  303: 
  304: \ The constants are defined as 32 bits, but then erased
  305: \ and overwritten by the right ones
  306: 
  307: has? f83headerstring [IF]
  308:     \ to save space, Gforth EC limits words to 31 characters
  309:     \ also, there's no predule concept in Gforth EC
  310:     $80 constant alias-mask
  311:     $40 constant immediate-mask
  312:     $20 constant restrict-mask
  313:     $1f constant lcount-mask
  314: [ELSE]
  315: \ 32-bit systems cannot generate large 64-bit constant in the
  316: \ cross-compiler, so we kludge it by generating a constant and then
  317: \ storing the proper value into it (and that's another kludge).
  318: $80000000 constant alias-mask
  319: 1 bits/char 1 - lshift
  320: -1 cells allot  bigendian [IF]   c, 0 1 cells 1- times
  321:                           [ELSE] 0 1 cells 1- times c, [THEN]
  322: $40000000 constant immediate-mask
  323: 1 bits/char 2 - lshift
  324: -1 cells allot  bigendian [IF]   c, 0 1 cells 1- times
  325:                           [ELSE] 0 1 cells 1- times c, [THEN]
  326: $20000000 constant restrict-mask
  327: 1 bits/char 3 - lshift
  328: -1 cells allot  bigendian [IF]   c, 0 1 cells 1- times
  329:                           [ELSE] 0 1 cells 1- times c, [THEN]
  330: $10000000 constant prelude-mask
  331: 1 bits/char 4 - lshift
  332: -1 cells allot  bigendian [IF]   c, 0 1 cells 1- times
  333:                           [ELSE] 0 1 cells 1- times c, [THEN]
  334: $0fffffff constant lcount-mask
  335: 1 bits/char 4 - lshift 1 -
  336: -1 cells allot  bigendian [IF]   c, -1 1 cells 1- times
  337:                           [ELSE] -1 1 cells 1- times c, [THEN]
  338: [THEN]
  339: 
  340: \ higher level parts of find
  341: 
  342: : flag-sign ( f -- 1|-1 )
  343:     \ true becomes 1, false -1
  344:     0= 2* 1+ ;
  345: 
  346: : ticking-compile-only-error ( ... -- )
  347:     -&2048 throw ;
  348: 
  349: : compile-only-error ( ... -- )
  350:     -&14 throw ;
  351: 
  352: : (cfa>int) ( cfa -- xt )
  353: [ has? compiler [IF] ]
  354:     dup interpret/compile?
  355:     if
  356: 	interpret/compile-int @
  357:     then 
  358: [ [THEN] ] ;
  359: 
  360: : (x>int) ( cfa w -- xt )
  361:     \ get interpretation semantics of name
  362:     restrict-mask and [ has? rom [IF] ] 0= [ [THEN] ]
  363:     if
  364: 	drop ['] compile-only-error
  365:     else
  366: 	(cfa>int)
  367:     then ;
  368: 
  369: has? f83headerstring [IF]
  370: : name>string ( nt -- addr count ) \ gforth     name-to-string
  371:     \g @i{addr count} is the name of the word represented by @i{nt}.
  372:     cell+ count lcount-mask and ;
  373: 
  374: : ((name>))  ( nfa -- cfa )
  375:     name>string + cfaligned ;
  376: 
  377: : (name>x) ( nfa -- cfa w )
  378:     \ cfa is an intermediate cfa and w is the flags cell of nfa
  379:     dup ((name>))
  380:     swap cell+ c@ dup alias-mask and 0=
  381:     IF
  382:         swap @ swap
  383:     THEN ;
  384: [ELSE]
  385: : name>string ( nt -- addr count ) \ gforth     name-to-string
  386:     \g @i{addr count} is the name of the word represented by @i{nt}.
  387:     cell+ dup cell+ swap @ lcount-mask and ;
  388: 
  389: : ((name>))  ( nfa -- cfa )
  390:     name>string + cfaligned ;
  391: 
  392: : (name>x) ( nfa -- cfa w )
  393:     \ cfa is an intermediate cfa and w is the flags cell of nfa
  394:     dup ((name>))
  395:     swap cell+ @ dup alias-mask and 0=
  396:     IF
  397:         swap @ swap
  398:     THEN ;
  399: [THEN]
  400: 
  401: : name>int ( nt -- xt ) \ gforth name-to-int
  402:     \G @i{xt} represents the interpretation semantics of the word
  403:     \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
  404:     \G @code{compile-only}), @i{xt} is the execution token for
  405:     \G @code{ticking-compile-only-error}, which performs @code{-2048 throw}.
  406:     (name>x) (x>int) ;
  407: 
  408: : name?int ( nt -- xt ) \ gforth name-question-int
  409:     \G Like @code{name>int}, but perform @code{-2048 throw} if @i{nt}
  410:     \G has no interpretation semantics.
  411:     (name>x) restrict-mask and [ has? rom [IF] ] 0= [ [THEN] ]
  412:     if
  413: 	ticking-compile-only-error \ does not return
  414:     then
  415:     (cfa>int) ;
  416: 
  417: : (name>comp) ( nt -- w +-1 ) \ gforth
  418:     \G @i{w xt} is the compilation token for the word @i{nt}.
  419:     (name>x) >r 
  420: [ has? compiler [IF] ]
  421:     dup interpret/compile?
  422:     if
  423:         interpret/compile-comp @
  424:     then 
  425: [ [THEN] ]
  426:     r> immediate-mask and [ has? rom [IF] ] 0= [ [THEN] ] flag-sign
  427:     ;
  428: 
  429: : (name>intn) ( nfa -- xt +-1 )
  430:     (name>x) tuck (x>int) ( w xt )
  431:     swap immediate-mask and [ has? rom [IF] ] 0= [ [THEN] ] flag-sign ;
  432: 
  433: [IFDEF] prelude-mask
  434: : name>prelude ( nt -- xt )
  435:     dup cell+ @ prelude-mask and if
  436: 	[ -1 cells ] literal + @
  437:     else
  438: 	drop ['] noop
  439:     then ;
  440: [THEN]
  441: 
  442: const Create ???  0 , 3 , char ? c, char ? c, char ? c,
  443: \ ??? is used by dovar:, must be created/:dovar
  444: 
  445: [IFDEF] forthstart
  446: \ if we have a forthstart we can define head? with it
  447: \ otherwise leave out the head? check
  448: 
  449: : head? ( addr -- f )
  450: \G heuristic check whether addr is a name token; may deliver false
  451: \G positives; addr must be a valid address; returns 1 for
  452: \G particularly unsafe positives
  453:     \ we follow the link fields and check for plausibility; two
  454:     \ iterations should catch most false addresses: on the first
  455:     \ iteration, we may get an xt, on the second a code address (or
  456:     \ some code), which is typically not in the dictionary.
  457:     \ we added a third iteration for working with code and ;code words.
  458:     3 0 do
  459: 	dup dup aligned <> if \ protect @ against unaligned accesses
  460: 	    drop false unloop exit
  461: 	then
  462: 	dup @ dup
  463: 	if ( addr addr1 )
  464: 	    dup rot forthstart within
  465: 	    if \ addr1 is outside forthstart..addr, not a head
  466: 		drop false unloop exit
  467: 	    then ( addr1 )
  468: 	else \ 0 in the link field, no further checks
  469: 	    2drop 1 unloop exit \ this is very unsure, so return 1
  470: 	then
  471:     loop
  472:     \ in dubio pro:
  473:     drop true ;
  474: 
  475: : >head-noprim ( cfa -- nt ) \ gforth  to-head-noprim
  476:     \ also heuristic
  477:     dup forthstart - max-name-length @
  478:     [ has? float [IF] ] float+ [ [ELSE] ] cell+ [ [THEN] ] cell+ min
  479:     cell max cell ?do ( cfa )
  480: 	dup i - dup @ [ alias-mask lcount-mask or ] literal
  481: 	[ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
  482: 	-1 cells allot bigendian [IF]   c, -1 1 cells 1- times
  483: 	[ELSE] -1 1 cells 1- times c, [THEN] ]
  484: 	and ( cfa len|alias )
  485: 	swap + cell+ cfaligned over alias-mask + =
  486: 	if ( cfa )
  487: 	    dup i - cell - dup head?
  488: 	    if
  489: 		nip unloop exit
  490: 	    then
  491: 	    drop
  492: 	then
  493: 	cell +loop
  494:     drop ??? ( wouldn't 0 be better? ) ;
  495: 
  496: [ELSE]
  497: 
  498: : >head-noprim ( cfa -- nt ) \ gforth  to-head-noprim
  499:     $25 cell do ( cfa )
  500: 	dup i - dup @ [ alias-mask lcount-mask or ] literal
  501: 	[ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
  502: 	-1 cells allot bigendian [IF]   c, -1 1 cells 1- times
  503: 	[ELSE] -1 1 cells 1- times c, [THEN] ]
  504: 	and ( cfa len|alias )
  505: 	swap + cell + cfaligned over alias-mask + =
  506: 	if ( cfa ) i - cell - unloop exit
  507: 	then
  508: 	cell +loop
  509:     drop ??? ( wouldn't 0 be better? ) ;
  510: 
  511: [THEN]
  512: 
  513: cell% 2* 0 0 field >body ( xt -- a_addr ) \ core to-body
  514: \G Get the address of the body of the word represented by @i{xt} (the
  515: \G address of the word's data field).
  516: drop drop
  517: 
  518: cell% -2 * 0 0 field body> ( xt -- a_addr )
  519:     drop drop
  520: 
  521: has? standardthreading has? compiler and [IF]
  522: 
  523: ' @ alias >code-address ( xt -- c_addr ) \ gforth
  524: \G @i{c-addr} is the code address of the word @i{xt}.
  525: 
  526: : >does-code ( xt -- a_addr ) \ gforth
  527: \G If @i{xt} is the execution token of a child of a @code{DOES>} word,
  528: \G @i{a-addr} is the start of the Forth code after the @code{DOES>};
  529: \G Otherwise @i{a-addr} is 0.
  530:     dup @ dodoes: = if
  531: 	cell+ @
  532:     else
  533: 	drop 0
  534:     endif ;
  535: 
  536: has? prims [IF]
  537:     : flash! ! ;
  538:     : flashc! c! ;
  539: [THEN]
  540: 
  541: has? flash [IF] ' flash! [ELSE] ' ! [THEN]
  542: alias code-address! ( c_addr xt -- ) \ gforth
  543: \G Create a code field with code address @i{c-addr} at @i{xt}.
  544: 
  545: : any-code! ( a-addr cfa code-addr -- )
  546:     \ for implementing DOES> and ;ABI-CODE, maybe :
  547:     \ code-address is stored at cfa, a-addr at cfa+cell
  548:     over ! cell+ ! ;
  549:     
  550: : does-code! ( a-addr xt -- ) \ gforth
  551: \G Create a code field at @i{xt} for a child of a @code{DOES>}-word;
  552: \G @i{a-addr} is the start of the Forth code after @code{DOES>}.
  553:     [ has? flash [IF] ]
  554:     dodoes: over flash! cell+ flash!
  555:     [ [ELSE] ]
  556:     dodoes: any-code! 
  557:     [ [THEN] ] ;
  558: 
  559: 2 cells constant /does-handler ( -- n ) \ gforth
  560: \G The size of a @code{DOES>}-handler (includes possible padding).
  561: 
  562: [THEN]	
  563: 
  564: : sfind ( c-addr u -- 0 / xt +-1  ) \ gforth-obsolete
  565:     find-name dup
  566:     if ( nt )
  567: 	state @
  568: 	if
  569: 	    (name>comp)
  570: 	else
  571: 	    (name>intn)
  572: 	then
  573:    then ;
  574: 
  575: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
  576:     \G Search all word lists in the current search order for the
  577:     \G definition named by the counted string at @i{c-addr}.  If the
  578:     \G definition is not found, return 0. If the definition is found
  579:     \G return 1 (if the definition has non-default compilation
  580:     \G semantics) or -1 (if the definition has default compilation
  581:     \G semantics).  The @i{xt} returned in interpret state represents
  582:     \G the interpretation semantics.  The @i{xt} returned in compile
  583:     \G state represented either the compilation semantics (for
  584:     \G non-default compilation semantics) or the run-time semantics
  585:     \G that the compilation semantics would @code{compile,} (for
  586:     \G default compilation semantics).  The ANS Forth standard does
  587:     \G not specify clearly what the returned @i{xt} represents (and
  588:     \G also talks about immediacy instead of non-default compilation
  589:     \G semantics), so this word is questionable in portable programs.
  590:     \G If non-portability is ok, @code{find-name} and friends are
  591:     \G better (@pxref{Name token}).
  592:     dup count sfind dup
  593:     if
  594: 	rot drop
  595:     then ;
  596: 
  597: \ ticks in interpreter
  598: 
  599: : (') ( "name" -- nt ) \ gforth
  600:     parse-name name-too-short?
  601:     find-name dup 0=
  602:     IF
  603: 	drop -&13 throw
  604:     THEN  ;
  605: 
  606: : '    ( "name" -- xt ) \ core	tick
  607:     \g @i{xt} represents @i{name}'s interpretation
  608:     \g semantics. Perform @code{-14 throw} if the word has no
  609:     \g interpretation semantics.
  610:     (') name?int ;
  611: 
  612: has? compiler 0= [IF]	\ interpreter only version of IS and TO
  613: 
  614: : IS ' >body ! ;
  615: ' IS Alias TO
  616: 
  617: [THEN]
  618: 
  619: \ \ the interpreter loop				  mar92py
  620: 
  621: \ interpret                                            10mar92py
  622: 
  623: Defer parser1 ( c-addr u -- ... xt)
  624: \ "... xt" is the action to be performed by the text-interpretation of c-addr u
  625: 
  626: : parser ( c-addr u -- ... )
  627: \ text-interpret the word/number c-addr u, possibly producing a number
  628:     parser1 execute ;
  629: 
  630: has? ec [IF]
  631:     ' (name) Alias parse-name
  632:     : no.extensions  2drop -&13 throw ;
  633:     ' no.extensions Alias compiler-notfound1
  634:     ' no.extensions Alias interpreter-notfound1
  635: [ELSE]    
  636: Defer parse-name ( "name" -- c-addr u ) \ gforth
  637: \G Get the next word from the input buffer
  638: ' (name) IS parse-name
  639: 
  640: ' parse-name alias parse-word ( -- c-addr u ) \ gforth-obsolete
  641: \G old name for @code{parse-name}
  642:     
  643: ' parse-name alias name ( -- c-addr u ) \ gforth-obsolete
  644: \G old name for @code{parse-name}
  645:     
  646: Defer compiler-notfound1 ( c-addr count -- ... xt )
  647: Defer interpreter-notfound1 ( c-addr count -- ... xt )
  648: 
  649: : no.extensions  ( addr u -- )
  650:     2drop -&13 throw ;
  651: ' no.extensions IS compiler-notfound1
  652: ' no.extensions IS interpreter-notfound1
  653: 
  654: Defer before-word ( -- ) \ gforth
  655: \ called before the text interpreter parses the next word
  656: ' noop IS before-word
  657: [THEN]
  658: 
  659: has? backtrace [IF]
  660: : interpret1 ( ... -- ... )
  661:     rp@ backtrace-rp0 !
  662:     BEGIN
  663: 	?stack [ has? EC 0= [IF] ] before-word [ [THEN] ] parse-name dup
  664:     WHILE
  665: 	parser1 execute
  666:     REPEAT
  667:     2drop ;
  668:     
  669: : interpret ( ?? -- ?? ) \ gforth
  670:     \ interpret/compile the (rest of the) input buffer
  671:     backtrace-rp0 @ >r	
  672:     ['] interpret1 catch
  673:     r> backtrace-rp0 !
  674:     throw ;
  675: [ELSE]
  676: : interpret ( ... -- ... )
  677:     BEGIN
  678: 	?stack [ has? EC 0= [IF] ] before-word [ [THEN] ] parse-name dup
  679:     WHILE
  680: 	parser1 execute
  681:     REPEAT
  682:     2drop ;
  683: [THEN]
  684: 
  685: \ interpreter                                 	30apr92py
  686: 
  687: [IFDEF] prelude-mask
  688: : run-prelude ( nt|0 -- nt|0 )
  689:     \ run the prelude of the name identified by nt (if present).  This
  690:     \ is used in the text interpreter and similar stuff.
  691:     dup if
  692: 	dup name>prelude execute
  693:     then ;
  694: [THEN]
  695: 
  696: \ not the most efficient implementations of interpreter and compiler
  697: : interpreter1 ( c-addr u -- ... xt ) 
  698:     2dup find-name [ [IFDEF] prelude-mask ] run-prelude [ [THEN] ] dup
  699:     if
  700: 	nip nip name>int
  701:     else
  702: 	drop
  703: 	2dup 2>r snumber?
  704: 	IF
  705: 	    2rdrop ['] noop
  706: 	ELSE
  707: 	    2r> interpreter-notfound1
  708: 	THEN
  709:     then ;
  710: 
  711: ' interpreter1  IS  parser1
  712: 
  713: \ \ Query Evaluate                                 	07apr93py
  714: 
  715: has? file 0= [IF]
  716: : sourceline# ( -- n )  1 ;
  717: [ELSE]
  718: has? new-input 0= [IF]
  719: Variable #fill-bytes
  720: \G number of bytes read via (read-line) by the last refill
  721: [THEN]
  722: [THEN]
  723: 
  724: has? new-input 0= [IF]
  725: : input-start-line ( -- )  >in off ;
  726: : refill ( -- flag ) \ core-ext,block-ext,file-ext
  727:     \G Attempt to fill the input buffer from the input source.  When
  728:     \G the input source is the user input device, attempt to receive
  729:     \G input into the terminal input device. If successful, make the
  730:     \G result the input buffer, set @code{>IN} to 0 and return true;
  731:     \G otherwise return false. When the input source is a block, add 1
  732:     \G to the value of @code{BLK} to make the next block the input
  733:     \G source and current input buffer, and set @code{>IN} to 0;
  734:     \G return true if the new value of @code{BLK} is a valid block
  735:     \G number, false otherwise. When the input source is a text file,
  736:     \G attempt to read the next line from the file. If successful,
  737:     \G make the result the current input buffer, set @code{>IN} to 0
  738:     \G and return true; otherwise, return false.  A successful result
  739:     \G includes receipt of a line containing 0 characters.
  740:     [ has? file [IF] ]
  741: 	blk @  IF  1 blk +!  true  EXIT  THEN
  742: 	[ [THEN] ]
  743:     tib /line
  744:     [ has? file [IF] ]
  745: 	loadfile @ ?dup
  746: 	IF    (read-line) throw #fill-bytes !
  747: 	ELSE
  748: 	    [ [THEN] ]
  749: 	sourceline# 0< IF 2drop false EXIT THEN
  750: 	accept eof @ 0=
  751: 	[ has? file [IF] ]
  752: 	THEN
  753: 	1 loadline +!
  754: 	[ [THEN] ]
  755:     swap #tib !
  756:     input-start-line ;
  757: 
  758: : query   ( -- ) \ core-ext
  759:     \G Make the user input device the input source. Receive input into
  760:     \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
  761:     \G superceeded by @code{accept}.
  762:     [ has? file [IF] ]
  763: 	blk off loadfile off
  764: 	[ [THEN] ]
  765:     refill drop ;
  766: [THEN]
  767: 
  768: \ save-mem extend-mem
  769: 
  770: has? os [IF]
  771: : save-mem	( addr1 u -- addr2 u ) \ gforth
  772:     \g copy a memory block into a newly allocated region in the heap
  773:     swap >r
  774:     dup allocate throw
  775:     swap 2dup r> -rot move ;
  776: 
  777: : free-mem-var ( addr -- )
  778:     \ addr is the address of a 2variable containing address and size
  779:     \ of a memory range; frees memory and clears the 2variable.
  780:     dup 2@ drop dup
  781:     if ( addr mem-start )
  782: 	free throw
  783: 	0 0 rot 2!
  784:     else
  785: 	2drop
  786:     then ;
  787: 
  788: : extend-mem	( addr1 u1 u -- addr addr2 u2 )
  789:     \ extend memory block allocated from the heap by u aus
  790:     \ the (possibly reallocated) piece is addr2 u2, the extension is at addr
  791:     over >r + dup >r resize throw
  792:     r> over r> + -rot ;
  793: [THEN]
  794: 
  795: \ EVALUATE                                              17may93jaw
  796: 
  797: has? file 0= has? new-input 0= and [IF]
  798: : push-file  ( -- )  r>
  799:   tibstack @ >r  >tib @ >r  #tib @ >r
  800:   >tib @ tibstack @ = IF  r@ tibstack +!  THEN
  801:   tibstack @ >tib ! >in @ >r  >r ;
  802: 
  803: : pop-file   ( throw-code -- throw-code )
  804:   r>
  805:   r> >in !  r> #tib !  r> >tib !  r> tibstack !  >r ;
  806: [THEN]
  807: 
  808: has? new-input 0= [IF]
  809: : evaluate ( c-addr u -- ) \ core,block
  810:     \G Save the current input source specification. Store @code{-1} in
  811:     \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
  812:     \G @code{0} and make the string @i{c-addr u} the input source
  813:     \G and input buffer. Interpret. When the parse area is empty,
  814:     \G restore the input source specification.
  815: [ has? file [IF] ]
  816:     s" *evaluated string*" loadfilename>r
  817: [ [THEN] ]
  818:     push-file #tib ! >tib !
  819:     input-start-line
  820:     [ has? file [IF] ]
  821: 	blk off loadfile off -1 loadline !
  822: 	[ [THEN] ]
  823:     ['] interpret catch
  824:     pop-file
  825: [ has? file [IF] ]
  826:     r>loadfilename
  827: [ [THEN] ]
  828:     throw ;
  829: [THEN]
  830: 
  831: \ \ Quit                                            	13feb93py
  832: 
  833: Defer 'quit
  834: 
  835: has? os [IF]
  836:     Defer .status
  837: [ELSE]
  838:     [IFUNDEF] bye
  839: 	: (bye)     ( 0 -- ) \ back to DOS
  840: 	    drop 5 emit ;
  841: 	
  842: 	: bye ( -- )  0 (bye) ;
  843:     [THEN]
  844: [THEN]
  845: 
  846: : prompt        state @ IF ."  compiled" EXIT THEN ."  ok" ;
  847: 
  848: : (quit) ( -- )
  849:     \ exits only through THROW etc.
  850:     BEGIN
  851: 	[ has? ec [IF] ] cr [ [ELSE] ]
  852: 	.status ['] cr catch if
  853: 	    [ has? OS [IF] ] >stderr [ [THEN] ]
  854: 	    cr ." Can't print to stdout, leaving" cr
  855: 	    \ if stderr does not work either, already DoError causes a hang
  856: 	    2 (bye)
  857: 	endif [ [THEN] ]
  858: 	refill  WHILE
  859: 	    interpret prompt
  860:     REPEAT
  861:     bye ;
  862: 
  863: ' (quit) IS 'quit
  864: 
  865: \ \ DOERROR (DOERROR)                        		13jun93jaw
  866: 
  867: has? os [IF]
  868: 8 Constant max-errors
  869: 5 has? file 2 and + Constant /error
  870: Variable error-stack  0 error-stack !
  871: max-errors /error * cells allot
  872: \ format of one cell:
  873: \ source ( c-addr u )
  874: \ last parsed lexeme ( c-addr u )
  875: \ line-number
  876: \ Loadfilename ( addr u )
  877: 
  878: : error> ( --  c-addr1 u1 c-addr2 u2 line# [addr u] )
  879:     -1 error-stack +!
  880:     error-stack dup @
  881:     /error * cells + cell+
  882:     /error cells bounds DO
  883:         I @
  884:     cell +LOOP ;
  885: 
  886: : >error ( c-addr1 u1 c-addr2 u2 line# [addr u] -- )
  887:     error-stack dup @ dup 1+
  888:     max-errors 1- min error-stack !
  889:     /error * cells + cell+
  890:     /error 1- cells bounds swap DO
  891:         I !
  892:     -1 cells +LOOP ;
  893: 
  894: : input-error-data ( -- c-addr1 u1 c-addr2 u2 line# [addr u] )
  895:     \ error data for the current input, to be used by >error or .error-frame
  896:     source input-lexeme 2@ sourceline#
  897:     [ has? file [IF] ] sourcefilename [ [THEN] ] ;
  898: 
  899: : dec. ( n -- ) \ gforth
  900:     \G Display @i{n} as a signed decimal number, followed by a space.
  901:     \ !! not used...
  902:     base @ decimal swap . base ! ;
  903: 
  904: : dec.r ( u n -- ) \ gforth
  905:     \G Display @i{u} as a unsigned decimal number in a field @i{n}
  906:     \G characters wide.
  907:     base @ >r decimal .r r> base ! ;
  908: 
  909: : hex. ( u -- ) \ gforth
  910:     \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
  911:     \G followed by a space.
  912:     \ !! not used...
  913:     [char] $ emit base @ swap hex u. base ! ;
  914: 
  915: : -trailing  ( c_addr u1 -- c_addr u2 ) \ string dash-trailing
  916: \G Adjust the string specified by @i{c-addr, u1} to remove all
  917: \G trailing spaces. @i{u2} is the length of the modified string.
  918:     BEGIN
  919: 	dup
  920:     WHILE
  921: 	1- 2dup + c@ bl <>
  922:     UNTIL  1+  THEN ;
  923: 
  924: DEFER DOERROR
  925: 
  926: has? backtrace [IF]
  927: Defer dobacktrace ( -- )
  928: ' noop IS dobacktrace
  929: [THEN]
  930: 
  931: : .error-string ( throw-code -- )
  932:   dup -2 = 
  933:   IF 	"error @ ?dup IF count type  THEN drop
  934:   ELSE	.error
  935:   THEN ;
  936: 
  937: : umin ( u1 u2 -- u )
  938:     2dup u>
  939:     if
  940: 	swap
  941:     then
  942:     drop ;
  943: 
  944: Defer mark-start
  945: Defer mark-end
  946: 
  947: :noname ." >>>" ; IS mark-start
  948: :noname ." <<<" ; IS mark-end
  949: 
  950: : part-type ( addr1 u1 u -- addr2 u2 )
  951:     \ print first u characters of addr1 u1, addr2 u2 is the rest
  952:     over umin 2 pick over type /string ;
  953: 
  954: : .error-line ( c-addr1 u1 c-addr2 u2 -- )
  955:     \ print error in line c-addr1 u1, where the error-causing lexeme
  956:     \ is c-addr2 u2
  957:     >r 2 pick - part-type ( c-addr3 u3 R: u2 )
  958:     mark-start r> part-type mark-end ( c-addr4 u4 )
  959:     type ;
  960: 
  961: : .error-frame ( throwcode addr1 u1 addr2 u2 n2 [addr3 u3] -- throwcode )
  962:     \ addr3 u3: filename of included file - optional
  963:     \ n2:       line number
  964:     \ addr2 u2: parsed lexeme (should be marked as causing the error)
  965:     \ addr1 u1: input line
  966:     error-stack @
  967:     IF ( throwcode addr1 u1 n0 n1 n2 [addr2 u2] )
  968:         [ has? file [IF] ] \ !! unbalanced stack effect
  969: 	  over IF
  970: 	      cr ." in file included from "
  971: 	      type ." :"
  972: 	      0 dec.r  2drop 2drop
  973:           ELSE
  974:               2drop 2drop 2drop drop
  975:           THEN
  976:           [ [THEN] ] ( throwcode addr1 u1 n0 n1 n2 )
  977:     ELSE ( throwcode addr1 u1 n0 n1 n2 [addr2 u2] )
  978:         [ has? file [IF] ]
  979:             cr type ." :"
  980:             [ [THEN] ] ( throwcode addr1 u1 n0 n1 n2 )
  981:         dup 0 dec.r ." : " 5 pick .error-string
  982:         IF \ if line# non-zero, there is a line
  983:             cr .error-line
  984:         ELSE
  985:             2drop 2drop
  986:         THEN
  987:     THEN ;
  988: 
  989: : (DoError) ( throw-code -- )
  990:   [ has? os [IF] ]
  991:       >stderr
  992:   [ [THEN] ] 
  993:   input-error-data .error-frame
  994:   error-stack @ 0 ?DO
  995:     error>
  996:     .error-frame
  997:   LOOP
  998:   drop 
  999: [ has? backtrace [IF] ]
 1000:   dobacktrace
 1001: [ [THEN] ]
 1002:   normal-dp dpp ! ;
 1003: 
 1004: ' (DoError) IS DoError
 1005: 
 1006: [ELSE]
 1007:     : dec.  base @ >r decimal . r> base ! ;
 1008:     : DoError ( throw-code -- )
 1009: 	cr source drop >in @ type ." <<< "
 1010: 	dup -2 =  IF  "error @ type  drop  EXIT  THEN
 1011: 	.error ;
 1012: [THEN]
 1013: 
 1014: : quit ( ?? -- ?? ) \ core
 1015:     \G Empty the return stack, make the user input device
 1016:     \G the input source, enter interpret state and start
 1017:     \G the text interpreter.
 1018:     rp0 @ rp! handler off clear-tibstack
 1019:     [ has? new-input 0= [IF] ] >tib @ >r [ [THEN] ]
 1020:     BEGIN
 1021: 	[ has? compiler [IF] ]
 1022: 	    [compile] [
 1023: 	[ [THEN] ]
 1024: 	\ stack depths may be arbitrary here
 1025: 	['] 'quit CATCH dup
 1026:     WHILE
 1027: 	    <# \ reset hold area, or we may get another error
 1028: 	    DoError
 1029: 	    \ stack depths may be arbitrary still (or again), so clear them
 1030: 	    clearstacks
 1031: 	    [ has? new-input [IF] ] clear-tibstack
 1032: 	    [ [ELSE] ] r@ >tib ! r@ tibstack !
 1033: 	    [ [THEN] ]
 1034:     REPEAT
 1035:     drop [ has? new-input [IF] ] clear-tibstack
 1036:     [ [ELSE] ] r> >tib !
 1037:     [ [THEN] ] ;
 1038: 
 1039: \ \ Cold Boot                                    	13feb93py
 1040: 
 1041: : (bootmessage) ( -- )
 1042:     ." Gforth " version-string type 
 1043:     ." , Copyright (C) 1995-2009,2010 Free Software Foundation, Inc." cr
 1044:     ." Gforth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
 1045: [ has? os [IF] ]
 1046:      cr ." Type `bye' to exit"
 1047: [ [THEN] ] ;
 1048: 
 1049: defer bootmessage ( -- ) \ gforth
 1050: \G Hook (deferred word) executed right after interpreting the OS
 1051: \G command-line arguments.  Normally prints the Gforth startup
 1052: \G message.
 1053: 
 1054: has? file [IF]
 1055: defer process-args
 1056: [THEN]
 1057: 
 1058: ' (bootmessage) IS bootmessage
 1059: 
 1060: has? os [IF]
 1061: Defer 'cold ( -- ) \ gforth  tick-cold
 1062: \G Hook (deferred word) for things to do right before interpreting the
 1063: \G OS command-line arguments.  Normally does some initializations that
 1064: \G you also want to perform.
 1065: ' noop IS 'cold
 1066: [THEN]
 1067: 
 1068: : cold ( -- ) \ gforth
 1069: [ has? backtrace [IF] ]
 1070:     rp@ backtrace-rp0 !
 1071: [ [THEN] ]
 1072: [ has? file [IF] ]
 1073:     os-cold
 1074: [ [THEN] ]
 1075: [ has? os [IF] ]
 1076:     set-encoding-fixed-width
 1077:     'cold
 1078: [ [THEN] ]
 1079: [ has? file [IF] ]
 1080:     process-args
 1081:     loadline off
 1082: [ [THEN] ]
 1083:     bootmessage
 1084:     quit ;
 1085: 
 1086: has? new-input 0= [IF]
 1087: : clear-tibstack ( -- )
 1088: [ has? glocals [IF] ]
 1089:     lp@ forthstart 7 cells + @ - 
 1090: [ [ELSE] ]
 1091:     [ has? os [IF] ]
 1092:     r0 @ forthstart 6 cells + @ -
 1093:     [ [ELSE] ]
 1094:     sp@ cell+
 1095:     [ [THEN] ]
 1096: [ [THEN] ]
 1097:     dup >tib ! tibstack ! #tib off
 1098:     input-start-line ;
 1099: [THEN]
 1100: 
 1101: : boot ( path n **argv argc -- )
 1102: [ has? no-userspace 0= [IF] ]
 1103:     main-task up!
 1104: [ [THEN] ]
 1105: [ has? os [IF] ]
 1106:     os-boot
 1107: [ [THEN] ]
 1108: [ has? rom [IF] ]
 1109:     ram-shadow dup @ dup -1 <> >r u> r> and IF
 1110: 	ram-shadow 2@  ELSE
 1111: 	ram-mirror ram-size  THEN  ram-start swap move
 1112: [ [THEN] ]
 1113:     sp@ sp0 !
 1114: [ has? peephole [IF] ]
 1115:     \ only needed for greedy static superinstruction selection
 1116:     \ primtable prepare-peephole-table TO peeptable
 1117: [ [THEN] ]
 1118: [ has? new-input [IF] ]
 1119:     current-input off
 1120: [ [THEN] ]
 1121:     clear-tibstack
 1122:     0 0 includefilename 2!
 1123:     rp@ rp0 !
 1124: [ has? floating [IF] ]
 1125:     fp@ fp0 !
 1126: [ [THEN] ]
 1127: [ has? os [IF] ]
 1128:     handler off
 1129:     ['] cold catch dup -&2049 <> if \ broken pipe?
 1130: 	DoError cr
 1131:     endif
 1132: [ [ELSE] ]
 1133:     cold
 1134: [ [THEN] ]
 1135: [ has? os [IF] ]
 1136:     1 (bye) \ !! determin exit code from throw code?
 1137: [ [THEN] ]
 1138: ;
 1139: 
 1140: has? os [IF]
 1141: : bye ( -- ) \ tools-ext
 1142: [ has? file [IF] ]
 1143:     script? 0= IF  cr  THEN
 1144: [ [ELSE] ]
 1145:     cr
 1146: [ [THEN] ]
 1147:     0 (bye) ;
 1148: [THEN]
 1149: 
 1150: \ **argv may be scanned by the C starter to get some important
 1151: \ information, as -display and -geometry for an X client FORTH
 1152: \ or space and stackspace overrides
 1153: 
 1154: \ 0 arg contains, however, the name of the program.
 1155: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>