1: \ definitions needed for interpreter only
2:
3: \ Copyright (C) 1995-2000,2004,2005 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ \ Revision-Log
22:
23: \ put in seperate file 14sep97jaw
24:
25: \ \ input stream primitives 23feb93py
26:
27: require ./basics.fs \ bounds decimal hex ...
28: require ./io.fs \ type ...
29: require ./nio.fs \ . <# ...
30: require ./errore.fs \ .error ...
31: require kernel/version.fs \ version-string
32: require ./../chains.fs
33:
34: has? new-input 0= [IF]
35: : tib ( -- c-addr ) \ core-ext t-i-b
36: \G @i{c-addr} is the address of the Terminal Input Buffer.
37: \G OBSOLESCENT: @code{source} superceeds the function of this word.
38: >tib @ ;
39:
40: Defer source ( -- c-addr u ) \ core
41: \ used by dodefer:, must be defer
42: \G @i{c-addr} is the address of the input buffer and @i{u} is the
43: \G number of characters in it.
44:
45: : (source) ( -- c-addr u )
46: tib #tib @ ;
47: ' (source) IS source
48: [THEN]
49:
50: : (word) ( addr1 n1 char -- addr2 n2 )
51: dup >r skip 2dup r> scan nip - ;
52:
53: \ (word) should fold white spaces
54: \ this is what (parse-white) does
55:
56: \ word parse 23feb93py
57:
58: : sword ( char -- addr len ) \ gforth s-word
59: \G Parses like @code{word}, but the output is like @code{parse} output.
60: \G @xref{core-idef}.
61: \ this word was called PARSE-WORD until 0.3.0, but Open Firmware and
62: \ dpANS6 A.6.2.2008 have a word with that name that behaves
63: \ differently (like NAME).
64: source 2dup >r >r >in @ over min /string
65: rot dup bl = IF drop (parse-white) ELSE (word) THEN
66: 2dup + r> - 1+ r> min >in ! ;
67:
68: : word ( char "<chars>ccc<char>-- c-addr ) \ core
69: \G Skip leading delimiters. Parse @i{ccc}, delimited by
70: \G @i{char}, in the parse area. @i{c-addr} is the address of a
71: \G transient region containing the parsed string in
72: \G counted-string format. If the parse area was empty or
73: \G contained no characters other than delimiters, the resulting
74: \G string has zero length. A program may replace characters within
75: \G the counted string. OBSOLESCENT: the counted string has a
76: \G trailing space that is not included in its length.
77: sword here place bl here count + c! here ;
78:
79: : parse ( char "ccc<char>" -- c-addr u ) \ core-ext
80: \G Parse @i{ccc}, delimited by @i{char}, in the parse
81: \G area. @i{c-addr u} specifies the parsed string within the
82: \G parse area. If the parse area was empty, @i{u} is 0.
83: >r source >in @ over min /string over swap r> scan >r
84: over - dup r> IF 1+ THEN >in +! ;
85:
86: \ name 13feb93py
87:
88: [IFUNDEF] (name) \ name might be a primitive
89:
90: : (name) ( -- c-addr count ) \ gforth
91: source 2dup >r >r >in @ /string (parse-white)
92: 2dup + r> - 1+ r> min >in ! ;
93: \ name count ;
94: [THEN]
95:
96: : name-too-short? ( c-addr u -- c-addr u )
97: dup 0= -&16 and throw ;
98:
99: : name-too-long? ( c-addr u -- c-addr u )
100: dup lcount-mask u> -&19 and throw ;
101:
102: \ \ Number parsing 23feb93py
103:
104: \ number? number 23feb93py
105:
106: hex
107: const Create bases 0A , 10 , 2 , 0A ,
108: \ 10 16 2 10
109:
110: \ !! protect BASE saving wrapper against exceptions
111: : getbase ( addr u -- addr' u' )
112: 2dup s" 0x" string-prefix? >r
113: 2dup s" 0X" string-prefix? r> or
114: base @ &34 < and if
115: hex 2 /string
116: endif
117: over c@ [char] # - dup 4 u<
118: IF
119: cells bases + @ base ! 1 /string
120: ELSE
121: drop
122: THEN ;
123:
124: : sign? ( addr u -- addr1 u1 flag )
125: over c@ [char] - = dup >r
126: IF
127: 1 /string
128: THEN
129: r> ;
130:
131: : s'>unumber? ( addr u -- ud flag )
132: \ convert string "C" or "C'" to character code
133: dup 0= if
134: false exit
135: endif
136: x@+/string 0 s" '" 2rot string-prefix? ;
137:
138: : s>unumber? ( addr u -- ud flag ) \ gforth
139: \G converts string addr u into ud, flag indicates success
140: dpl on
141: over c@ '' = if
142: 1 /string s'>unumber? exit
143: endif
144: base @ >r getbase
145: 0. 2swap
146: BEGIN ( d addr len )
147: dup >r >number dup
148: WHILE \ there are characters left
149: dup r> -
150: WHILE \ the last >number parsed something
151: dup 1- dpl ! over c@ [char] . =
152: WHILE \ the current char is '.'
153: 1 /string
154: REPEAT THEN \ there are unparseable characters left
155: 2drop false
156: ELSE
157: rdrop 2drop true
158: THEN
159: r> base ! ;
160:
161: \ ouch, this is complicated; there must be a simpler way - anton
162: : s>number? ( addr u -- d f ) \ gforth
163: \G converts string addr u into d, flag indicates success
164: sign? >r
165: s>unumber?
166: 0= IF
167: rdrop false
168: ELSE \ no characters left, all ok
169: r>
170: IF
171: dnegate
172: THEN
173: true
174: THEN ;
175:
176: : s>number ( addr len -- d )
177: \ don't use this, there is no way to tell success
178: s>number? drop ;
179:
180: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
181: s>number? 0=
182: IF
183: 2drop false EXIT
184: THEN
185: dpl @ dup 0< IF
186: nip
187: ELSE
188: 1+
189: THEN ;
190:
191: : number? ( string -- string 0 / n -1 / d 0> )
192: dup >r count snumber? dup if
193: rdrop
194: else
195: r> swap
196: then ;
197:
198: : number ( string -- d )
199: number? ?dup 0= abort" ?" 0<
200: IF
201: s>d
202: THEN ;
203:
204: \ \ Comments ( \ \G
205:
206: : ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ thisone- core,file paren
207: \G ** this will not get annotated. The alias in glocals.fs will instead **
208: \G It does not work to use "wordset-" prefix since this file is glossed
209: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
210: [char] ) parse 2drop ; immediate
211:
212: : \ ( compilation 'ccc<newline>' -- ; run-time -- ) \ thisone- core-ext,block-ext backslash
213: \G ** this will not get annotated. The alias in glocals.fs will instead **
214: \G It does not work to use "wordset-" prefix since this file is glossed
215: \G by cross.fs which doesn't have the same functionalty as makedoc.fs
216: [ has? file [IF] ]
217: blk @
218: IF
219: >in @ c/l / 1+ c/l * >in !
220: EXIT
221: THEN
222: [ [THEN] ]
223: source >in ! drop ; immediate
224:
225: : \G ( compilation 'ccc<newline>' -- ; run-time -- ) \ gforth backslash-gee
226: \G Equivalent to @code{\} but used as a tag to annotate definition
227: \G comments into documentation.
228: POSTPONE \ ; immediate
229:
230: \ \ object oriented search list 17mar93py
231:
232: \ word list structure:
233:
234: struct
235: cell% field find-method \ xt: ( c_addr u wid -- nt )
236: cell% field reveal-method \ xt: ( nt wid -- ) \ used by dofield:, must be field
237: cell% field rehash-method \ xt: ( wid -- ) \ re-initializes a "search-data" (hashtables)
238: cell% field hash-method \ xt: ( wid -- ) \ initializes ""
239: \ \ !! what else
240: end-struct wordlist-map-struct
241:
242: struct
243: cell% field wordlist-map \ pointer to a wordlist-map-struct
244: cell% field wordlist-id \ linked list of words (for WORDS etc.)
245: cell% field wordlist-link \ link field to other wordlists
246: cell% field wordlist-extend \ wordlist extensions (eg bucket offset)
247: end-struct wordlist-struct
248:
249: has? f83headerstring [IF]
250: : f83find ( addr len wordlist -- nt / false )
251: wordlist-id @ (f83find) ;
252: [ELSE]
253: : f83find ( addr len wordlist -- nt / false )
254: wordlist-id @ (listlfind) ;
255: [THEN]
256:
257: : initvoc ( wid -- )
258: dup wordlist-map @ hash-method perform ;
259:
260: \ Search list table: find reveal
261: Create f83search ( -- wordlist-map )
262: ' f83find A, ' drop A, ' drop A, ' drop A,
263:
264: here G f83search T A, NIL A, NIL A, NIL A,
265: AValue forth-wordlist \ variable, will be redefined by search.fs
266:
267: AVariable lookup forth-wordlist lookup !
268: \ !! last is user and lookup?! jaw
269: AVariable current ( -- addr ) \ gforth
270: \G @code{Variable} -- holds the @i{wid} of the compilation word list.
271: AVariable voclink forth-wordlist wordlist-link voclink !
272: \ lookup AValue context ( -- addr ) \ gforth
273: Defer context ( -- addr ) \ gforth
274: \G @code{context} @code{@@} is the @i{wid} of the word list at the
275: \G top of the search order.
276:
277: ' lookup is context
278: forth-wordlist current !
279:
280: \ \ header, finding, ticks 17dec92py
281:
282: \ The constants are defined as 32 bits, but then erased
283: \ and overwritten by the right ones
284:
285: has? f83headerstring [IF]
286: \ to save space, Gforth EC limits words to 31 characters
287: $80 constant alias-mask
288: $40 constant immediate-mask
289: $20 constant restrict-mask
290: $1f constant lcount-mask
291: [ELSE]
292: $80000000 constant alias-mask
293: 1 bits/char 1 - lshift
294: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
295: [ELSE] 0 1 cells 1- times c, [THEN]
296: $40000000 constant immediate-mask
297: 1 bits/char 2 - lshift
298: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
299: [ELSE] 0 1 cells 1- times c, [THEN]
300: $20000000 constant restrict-mask
301: 1 bits/char 3 - lshift
302: -1 cells allot bigendian [IF] c, 0 1 cells 1- times
303: [ELSE] 0 1 cells 1- times c, [THEN]
304: $1fffffff constant lcount-mask
305: 1 bits/char 3 - lshift 1 -
306: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
307: [ELSE] -1 1 cells 1- times c, [THEN]
308: [THEN]
309:
310: \ higher level parts of find
311:
312: : flag-sign ( f -- 1|-1 )
313: \ true becomes 1, false -1
314: 0= 2* 1+ ;
315:
316: : ticking-compile-only-error ( ... -- )
317: -&2048 throw ;
318:
319: : compile-only-error ( ... -- )
320: -&14 throw ;
321:
322: : (cfa>int) ( cfa -- xt )
323: [ has? compiler [IF] ]
324: dup interpret/compile?
325: if
326: interpret/compile-int @
327: then
328: [ [THEN] ] ;
329:
330: : (x>int) ( cfa w -- xt )
331: \ get interpretation semantics of name
332: restrict-mask and
333: if
334: drop ['] compile-only-error
335: else
336: (cfa>int)
337: then ;
338:
339: has? f83headerstring [IF]
340: : name>string ( nt -- addr count ) \ gforth head-to-string
341: \g @i{addr count} is the name of the word represented by @i{nt}.
342: cell+ count lcount-mask and ;
343:
344: : ((name>)) ( nfa -- cfa )
345: name>string + cfaligned ;
346:
347: : (name>x) ( nfa -- cfa w )
348: \ cfa is an intermediate cfa and w is the flags cell of nfa
349: dup ((name>))
350: swap cell+ c@ dup alias-mask and 0=
351: IF
352: swap @ swap
353: THEN ;
354: [ELSE]
355: : name>string ( nt -- addr count ) \ gforth head-to-string
356: \g @i{addr count} is the name of the word represented by @i{nt}.
357: cell+ dup cell+ swap @ lcount-mask and ;
358:
359: : ((name>)) ( nfa -- cfa )
360: name>string + cfaligned ;
361:
362: : (name>x) ( nfa -- cfa w )
363: \ cfa is an intermediate cfa and w is the flags cell of nfa
364: dup ((name>))
365: swap cell+ @ dup alias-mask and 0=
366: IF
367: swap @ swap
368: THEN ;
369: [THEN]
370:
371: : name>int ( nt -- xt ) \ gforth
372: \G @i{xt} represents the interpretation semantics of the word
373: \G @i{nt}. If @i{nt} has no interpretation semantics (i.e. is
374: \G @code{compile-only}), @i{xt} is the execution token for
375: \G @code{ticking-compile-only-error}, which performs @code{-2048 throw}.
376: (name>x) (x>int) ;
377:
378: : name?int ( nt -- xt ) \ gforth
379: \G Like @code{name>int}, but perform @code{-2048 throw} if @i{nt}
380: \G has no interpretation semantics.
381: (name>x) restrict-mask and
382: if
383: ticking-compile-only-error \ does not return
384: then
385: (cfa>int) ;
386:
387: : (name>comp) ( nt -- w +-1 ) \ gforth
388: \G @i{w xt} is the compilation token for the word @i{nt}.
389: (name>x) >r
390: [ has? compiler [IF] ]
391: dup interpret/compile?
392: if
393: interpret/compile-comp @
394: then
395: [ [THEN] ]
396: r> immediate-mask and flag-sign
397: ;
398:
399: : (name>intn) ( nfa -- xt +-1 )
400: (name>x) tuck (x>int) ( w xt )
401: swap immediate-mask and flag-sign ;
402:
403: const Create ??? 0 , 3 , char ? c, char ? c, char ? c,
404: \ ??? is used by dovar:, must be created/:dovar
405:
406: [IFDEF] forthstart
407: \ if we have a forthstart we can define head? with it
408: \ otherwise leave out the head? check
409:
410: : head? ( addr -- f )
411: \G heuristic check whether addr is a name token; may deliver false
412: \G positives; addr must be a valid address; returns 1 for
413: \G particularly unsafe positives
414: \ we follow the link fields and check for plausibility; two
415: \ iterations should catch most false addresses: on the first
416: \ iteration, we may get an xt, on the second a code address (or
417: \ some code), which is typically not in the dictionary.
418: \ we added a third iteration for working with code and ;code words.
419: 3 0 do
420: dup dup aligned <> if \ protect @ against unaligned accesses
421: drop false unloop exit
422: then
423: dup @ dup
424: if ( addr addr1 )
425: dup rot forthstart within
426: if \ addr1 is outside forthstart..addr, not a head
427: drop false unloop exit
428: then ( addr1 )
429: else \ 0 in the link field, no further checks
430: 2drop 1 unloop exit \ this is very unsure, so return 1
431: then
432: loop
433: \ in dubio pro:
434: drop true ;
435:
436: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
437: \ also heuristic
438: dup forthstart - max-name-length @ float+ cell+ min cell max cell ?do ( cfa )
439: dup i - dup @ [ alias-mask lcount-mask or ] literal
440: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
441: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
442: [ELSE] -1 1 cells 1- times c, [THEN] ]
443: and ( cfa len|alias )
444: swap + cell+ cfaligned over alias-mask + =
445: if ( cfa )
446: dup i - cell - dup head?
447: if
448: nip unloop exit
449: then
450: drop
451: then
452: cell +loop
453: drop ??? ( wouldn't 0 be better? ) ;
454:
455: [ELSE]
456:
457: : >head-noprim ( cfa -- nt ) \ gforth to-head-noprim
458: $25 cell do ( cfa )
459: dup i - dup @ [ alias-mask lcount-mask or ] literal
460: [ 1 bits/char 3 - lshift 1 - 1 bits/char 1 - lshift or
461: -1 cells allot bigendian [IF] c, -1 1 cells 1- times
462: [ELSE] -1 1 cells 1- times c, [THEN] ]
463: and ( cfa len|alias )
464: swap + cell + cfaligned over alias-mask + =
465: if ( cfa ) i - cell - unloop exit
466: then
467: cell +loop
468: drop ??? ( wouldn't 0 be better? ) ;
469:
470: [THEN]
471:
472: cell% 2* 0 0 field >body ( xt -- a_addr ) \ core
473: \G Get the address of the body of the word represented by @i{xt} (the
474: \G address of the word's data field).
475: drop drop
476:
477: cell% -2 * 0 0 field body> ( xt -- a_addr )
478: drop drop
479:
480: has? standardthreading has? compiler and [IF]
481:
482: ' @ alias >code-address ( xt -- c_addr ) \ gforth
483: \G @i{c-addr} is the code address of the word @i{xt}.
484:
485: : >does-code ( xt -- a_addr ) \ gforth
486: \G If @i{xt} is the execution token of a child of a @code{DOES>} word,
487: \G @i{a-addr} is the start of the Forth code after the @code{DOES>};
488: \G Otherwise @i{a-addr} is 0.
489: dup @ dodoes: = if
490: cell+ @
491: else
492: drop 0
493: endif ;
494:
495: ' ! alias code-address! ( c_addr xt -- ) \ gforth
496: \G Create a code field with code address @i{c-addr} at @i{xt}.
497:
498: : does-code! ( a_addr xt -- ) \ gforth
499: \G Create a code field at @i{xt} for a child of a @code{DOES>}-word;
500: \G @i{a-addr} is the start of the Forth code after @code{DOES>}.
501: dodoes: over ! cell+ ! ;
502:
503: ' drop alias does-handler! ( a_addr -- ) \ gforth
504: \G Create a @code{DOES>}-handler at address @i{a-addr}. Normally,
505: \G @i{a-addr} points just behind a @code{DOES>}.
506:
507: 2 cells constant /does-handler ( -- n ) \ gforth
508: \G The size of a @code{DOES>}-handler (includes possible padding).
509:
510: [THEN]
511:
512: : (search-wordlist) ( addr count wid -- nt | false )
513: dup wordlist-map @ find-method perform ;
514:
515: : search-wordlist ( c-addr count wid -- 0 | xt +-1 ) \ search
516: \G Search the word list identified by @i{wid} for the definition
517: \G named by the string at @i{c-addr count}. If the definition is
518: \G not found, return 0. If the definition is found return 1 (if
519: \G the definition is immediate) or -1 (if the definition is not
520: \G immediate) together with the @i{xt}. In Gforth, the @i{xt}
521: \G returned represents the interpretation semantics. ANS Forth
522: \G does not specify clearly what @i{xt} represents.
523: (search-wordlist) dup if
524: (name>intn)
525: then ;
526:
527: : find-name ( c-addr u -- nt | 0 ) \ gforth
528: \g Find the name @i{c-addr u} in the current search
529: \g order. Return its @i{nt}, if found, otherwise 0.
530: lookup @ (search-wordlist) ;
531:
532: : sfind ( c-addr u -- 0 / xt +-1 ) \ gforth-obsolete
533: find-name dup
534: if ( nt )
535: state @
536: if
537: (name>comp)
538: else
539: (name>intn)
540: then
541: then ;
542:
543: : find ( c-addr -- xt +-1 | c-addr 0 ) \ core,search
544: \G Search all word lists in the current search order for the
545: \G definition named by the counted string at @i{c-addr}. If the
546: \G definition is not found, return 0. If the definition is found
547: \G return 1 (if the definition has non-default compilation
548: \G semantics) or -1 (if the definition has default compilation
549: \G semantics). The @i{xt} returned in interpret state represents
550: \G the interpretation semantics. The @i{xt} returned in compile
551: \G state represented either the compilation semantics (for
552: \G non-default compilation semantics) or the run-time semantics
553: \G that the compilation semantics would @code{compile,} (for
554: \G default compilation semantics). The ANS Forth standard does
555: \G not specify clearly what the returned @i{xt} represents (and
556: \G also talks about immediacy instead of non-default compilation
557: \G semantics), so this word is questionable in portable programs.
558: \G If non-portability is ok, @code{find-name} and friends are
559: \G better (@pxref{Name token}).
560: dup count sfind dup
561: if
562: rot drop
563: then ;
564:
565: \ ticks in interpreter
566:
567: : (') ( "name" -- nt ) \ gforth
568: name name-too-short?
569: find-name dup 0=
570: IF
571: drop -&13 throw
572: THEN ;
573:
574: : ' ( "name" -- xt ) \ core tick
575: \g @i{xt} represents @i{name}'s interpretation
576: \g semantics. Perform @code{-14 throw} if the word has no
577: \g interpretation semantics.
578: (') name?int ;
579:
580: has? compiler 0= [IF] \ interpreter only version of IS and TO
581:
582: : IS ' >body ! ;
583: ' IS Alias TO
584:
585: [THEN]
586:
587: \ \ the interpreter loop mar92py
588:
589: \ interpret 10mar92py
590:
591: Defer parser1 ( c-addr u -- ... xt)
592: \ "... xt" is the action to be performed by the text-interpretation of c-addr u
593:
594: : parser ( c-addr u -- ... )
595: \ text-interpret the word/number c-addr u, possibly producing a number
596: parser1 execute ;
597:
598: Defer parse-name ( "name" -- c-addr u ) \ gforth
599: \G Get the next word from the input buffer
600: ' (name) IS parse-name
601:
602: ' parse-name alias parse-word ( -- c-addr u ) \ gforth-obsolete
603: \G old name for @code{parse-name}
604:
605: ' parse-name alias name ( -- c-addr u ) \ gforth-obsolete
606: \G old name for @code{parse-name}
607:
608: Defer compiler-notfound1 ( c-addr count -- ... xt )
609: Defer interpreter-notfound1 ( c-addr count -- ... xt )
610:
611: : no.extensions ( addr u -- )
612: 2drop -&13 throw ;
613: ' no.extensions IS compiler-notfound1
614: ' no.extensions IS interpreter-notfound1
615:
616: Defer before-word ( -- ) \ gforth
617: \ called before the text interpreter parses the next word
618: ' noop IS before-word
619:
620: : interpret1 ( ... -- ... )
621: [ has? backtrace [IF] ]
622: rp@ backtrace-rp0 !
623: [ [THEN] ]
624: BEGIN
625: ?stack before-word name dup
626: WHILE
627: parser1 execute
628: REPEAT
629: 2drop ;
630:
631: : interpret ( ?? -- ?? ) \ gforth
632: \ interpret/compile the (rest of the) input buffer
633: [ has? backtrace [IF] ]
634: backtrace-rp0 @ >r
635: [ [THEN] ]
636: ['] interpret1 catch
637: [ has? backtrace [IF] ]
638: r> backtrace-rp0 !
639: [ [THEN] ]
640: throw ;
641:
642: \ interpreter 30apr92py
643:
644: \ not the most efficient implementations of interpreter and compiler
645: : interpreter1 ( c-addr u -- ... xt )
646: 2dup find-name dup
647: if
648: nip nip name>int
649: else
650: drop
651: 2dup 2>r snumber?
652: IF
653: 2rdrop ['] noop
654: ELSE
655: 2r> interpreter-notfound1
656: THEN
657: then ;
658:
659: ' interpreter1 IS parser1
660:
661: \ \ Query Evaluate 07apr93py
662:
663: has? file 0= [IF]
664: : sourceline# ( -- n ) 1 ;
665: [ELSE]
666: has? new-input 0= [IF]
667: Variable #fill-bytes
668: \G number of bytes read via (read-line) by the last refill
669: [THEN]
670: [THEN]
671:
672: has? new-input 0= [IF]
673: : refill ( -- flag ) \ core-ext,block-ext,file-ext
674: \G Attempt to fill the input buffer from the input source. When
675: \G the input source is the user input device, attempt to receive
676: \G input into the terminal input device. If successful, make the
677: \G result the input buffer, set @code{>IN} to 0 and return true;
678: \G otherwise return false. When the input source is a block, add 1
679: \G to the value of @code{BLK} to make the next block the input
680: \G source and current input buffer, and set @code{>IN} to 0;
681: \G return true if the new value of @code{BLK} is a valid block
682: \G number, false otherwise. When the input source is a text file,
683: \G attempt to read the next line from the file. If successful,
684: \G make the result the current input buffer, set @code{>IN} to 0
685: \G and return true; otherwise, return false. A successful result
686: \G includes receipt of a line containing 0 characters.
687: [ has? file [IF] ]
688: blk @ IF 1 blk +! true 0 >in ! EXIT THEN
689: [ [THEN] ]
690: tib /line
691: [ has? file [IF] ]
692: loadfile @ ?dup
693: IF (read-line) throw #fill-bytes !
694: ELSE
695: [ [THEN] ]
696: sourceline# 0< IF 2drop false EXIT THEN
697: accept true
698: [ has? file [IF] ]
699: THEN
700: 1 loadline +!
701: [ [THEN] ]
702: swap #tib ! 0 >in ! ;
703:
704: : query ( -- ) \ core-ext
705: \G Make the user input device the input source. Receive input into
706: \G the Terminal Input Buffer. Set @code{>IN} to zero. OBSOLESCENT:
707: \G superceeded by @code{accept}.
708: [ has? file [IF] ]
709: blk off loadfile off
710: [ [THEN] ]
711: refill drop ;
712: [THEN]
713:
714: \ save-mem extend-mem
715:
716: has? os [IF]
717: : save-mem ( addr1 u -- addr2 u ) \ gforth
718: \g copy a memory block into a newly allocated region in the heap
719: swap >r
720: dup allocate throw
721: swap 2dup r> -rot move ;
722:
723: : free-mem-var ( addr -- )
724: \ addr is the address of a 2variable containing address and size
725: \ of a memory range; frees memory and clears the 2variable.
726: dup 2@ drop dup
727: if ( addr mem-start )
728: free throw
729: 0 0 rot 2!
730: else
731: 2drop
732: then ;
733:
734: : extend-mem ( addr1 u1 u -- addr addr2 u2 )
735: \ extend memory block allocated from the heap by u aus
736: \ the (possibly reallocated) piece is addr2 u2, the extension is at addr
737: over >r + dup >r resize throw
738: r> over r> + -rot ;
739: [THEN]
740:
741: \ EVALUATE 17may93jaw
742:
743: has? file 0= has? new-input 0= and [IF]
744: : push-file ( -- ) r>
745: tibstack @ >r >tib @ >r #tib @ >r
746: >tib @ tibstack @ = IF r@ tibstack +! THEN
747: tibstack @ >tib ! >in @ >r >r ;
748:
749: : pop-file ( throw-code -- throw-code )
750: r>
751: r> >in ! r> #tib ! r> >tib ! r> tibstack ! >r ;
752: [THEN]
753:
754: has? new-input 0= [IF]
755: : evaluate ( c-addr u -- ) \ core,block
756: \G Save the current input source specification. Store @code{-1} in
757: \G @code{source-id} and @code{0} in @code{blk}. Set @code{>IN} to
758: \G @code{0} and make the string @i{c-addr u} the input source
759: \G and input buffer. Interpret. When the parse area is empty,
760: \G restore the input source specification.
761: [ has? file [IF] ]
762: s" *evaluated string*" loadfilename>r
763: [ [THEN] ]
764: push-file #tib ! >tib !
765: >in off
766: [ has? file [IF] ]
767: blk off loadfile off -1 loadline !
768: [ [THEN] ]
769: ['] interpret catch
770: pop-file
771: [ has? file [IF] ]
772: r>loadfilename
773: [ [THEN] ]
774: throw ;
775: [THEN]
776:
777: \ \ Quit 13feb93py
778:
779: Defer 'quit
780:
781: Defer .status
782:
783: : prompt state @ IF ." compiled" EXIT THEN ." ok" ;
784:
785: : (quit) ( -- )
786: \ exits only through THROW etc.
787: BEGIN
788: .status
789: ['] cr catch if
790: >stderr cr ." Can't print to stdout, leaving" cr
791: \ if stderr does not work either, already DoError causes a hang
792: 2 (bye)
793: endif
794: refill WHILE
795: interpret prompt
796: REPEAT
797: bye ;
798:
799: ' (quit) IS 'quit
800:
801: \ \ DOERROR (DOERROR) 13jun93jaw
802:
803: 8 Constant max-errors
804: 4 has? file 2 and + Constant /error
805: Variable error-stack 0 error-stack !
806: max-errors /error * cells allot
807: \ format of one cell:
808: \ source ( addr u )
809: \ >in
810: \ line-number
811: \ Loadfilename ( addr u )
812:
813: : error> ( -- addr u >in line# [addr u] )
814: -1 error-stack +!
815: error-stack dup @
816: /error * cells + cell+
817: /error cells bounds DO
818: I @
819: cell +LOOP ;
820: : >error ( addr u >in line# [addr u] -- )
821: error-stack dup @ dup 1+
822: max-errors 1- min error-stack !
823: /error * cells + cell+
824: /error 1- cells bounds swap DO
825: I !
826: -1 cells +LOOP ;
827:
828: : dec. ( n -- ) \ gforth
829: \G Display @i{n} as a signed decimal number, followed by a space.
830: \ !! not used...
831: base @ decimal swap . base ! ;
832:
833: : dec.r ( u n -- ) \ gforth
834: \G Display @i{u} as a unsigned decimal number in a field @i{n}
835: \G characters wide.
836: base @ >r decimal .r r> base ! ;
837:
838: : hex. ( u -- ) \ gforth
839: \G Display @i{u} as an unsigned hex number, prefixed with a "$" and
840: \G followed by a space.
841: \ !! not used...
842: [char] $ emit base @ swap hex u. base ! ;
843:
844: : -trailing ( c_addr u1 -- c_addr u2 ) \ string dash-trailing
845: \G Adjust the string specified by @i{c-addr, u1} to remove all
846: \G trailing spaces. @i{u2} is the length of the modified string.
847: BEGIN
848: dup
849: WHILE
850: 1- 2dup + c@ bl <>
851: UNTIL 1+ THEN ;
852:
853: DEFER DOERROR
854:
855: has? backtrace [IF]
856: Defer dobacktrace ( -- )
857: ' noop IS dobacktrace
858: [THEN]
859:
860: : .error-string ( throw-code -- )
861: dup -2 =
862: IF "error @ ?dup IF count type THEN drop
863: ELSE .error
864: THEN ;
865:
866: : umin ( u1 u2 -- u )
867: 2dup u>
868: if
869: swap
870: then
871: drop ;
872:
873: Defer mark-start
874: Defer mark-end
875:
876: :noname ." >>>" ; IS mark-start
877: :noname ." <<<" ; IS mark-end
878:
879: : .error-line ( addr1 u1 n1 -- )
880: \ print error ending at char n1 in line addr1 u1
881: \ should work with UTF-8 (whitespace check looks ok)
882: over umin \ protect against wrong n1
883: swap >r ( addr1 n1 R: u1 )
884: -trailing 1- \ last non-space
885: 0 >r BEGIN \ search for the first non-space
886: 2dup + c@ bl > WHILE
887: r> 1+ >r 1- dup 0< UNTIL THEN 1+
888: ( addr1 n2 r: u1 namelen )
889: 2dup type mark-start
890: r> -rot r> swap /string ( namelen addr2 u2 )
891: >r swap 2dup type mark-end ( addr2 namelen r: u2 )
892: r> swap /string type ;
893:
894: : .error-frame ( throwcode addr1 u1 n1 n2 [addr2 u2] -- throwcode )
895: \ addr2 u2: filename of included file - optional
896: \ n2: line number
897: \ n1: error position in input line
898: \ addr1 u1: input line
899: cr error-stack @
900: IF ( throwcode addr1 u1 n1 n2 [addr2 u2] )
901: [ has? file [IF] ] \ !! unbalanced stack effect
902: ." in file included from "
903: type ." :"
904: [ [THEN] ] ( throwcode addr1 u1 n1 n2 )
905: 0 dec.r drop 2drop
906: ELSE ( throwcode addr1 u1 n1 n2 [addr2 u2] )
907: [ has? file [IF] ]
908: type ." :"
909: [ [THEN] ] ( throwcode addr1 u1 n1 n2 )
910: dup 0 dec.r ." : " 4 pick .error-string
911: IF \ if line# non-zero, there is a line
912: cr .error-line
913: ELSE
914: 2drop drop
915: THEN
916: THEN ;
917:
918: : (DoError) ( throw-code -- )
919: [ has? os [IF] ]
920: >stderr
921: [ [THEN] ]
922: source >in @ sourceline# [ has? file [IF] ] \ !! unbalanced stack effect
923: sourcefilename
924: [ [THEN] ] .error-frame
925: error-stack @ 0 ?DO
926: error>
927: .error-frame
928: LOOP
929: drop
930: [ has? backtrace [IF] ]
931: dobacktrace
932: [ [THEN] ]
933: normal-dp dpp ! ;
934:
935: ' (DoError) IS DoError
936:
937: : quit ( ?? -- ?? ) \ core
938: \G Empty the return stack, make the user input device
939: \G the input source, enter interpret state and start
940: \G the text interpreter.
941: rp0 @ rp! handler off clear-tibstack
942: [ has? new-input 0= [IF] ] >tib @ >r [ [THEN] ]
943: BEGIN
944: [ has? compiler [IF] ]
945: [compile] [
946: [ [THEN] ]
947: \ stack depths may be arbitrary here
948: ['] 'quit CATCH dup
949: WHILE
950: <# \ reset hold area, or we may get another error
951: DoError
952: \ stack depths may be arbitrary still (or again), so clear them
953: clearstacks
954: [ has? new-input [IF] ] clear-tibstack
955: [ [ELSE] ] r@ >tib ! r@ tibstack !
956: [ [THEN] ]
957: REPEAT
958: drop [ has? new-input [IF] ] clear-tibstack
959: [ [ELSE] ] r> >tib !
960: [ [THEN] ] ;
961:
962: \ \ Cold Boot 13feb93py
963:
964: : (bootmessage)
965: ." Gforth " version-string type
966: ." , Copyright (C) 1995-2004,2005 Free Software Foundation, Inc." cr
967: ." Gforth comes with ABSOLUTELY NO WARRANTY; for details type `license'"
968: [ has? os [IF] ]
969: cr ." Type `bye' to exit"
970: [ [THEN] ] ;
971:
972: defer bootmessage
973: defer process-args
974:
975: ' (bootmessage) IS bootmessage
976:
977: Defer 'cold ( -- ) \ gforth tick-cold
978: \ hook (deferred word) for things to do right before interpreting the
979: \ command-line arguments
980: ' noop IS 'cold
981:
982:
983: AVariable init8 NIL init8 !
984:
985: : cold ( -- ) \ gforth
986: [ has? backtrace [IF] ]
987: rp@ backtrace-rp0 !
988: [ [THEN] ]
989: [ has? file [IF] ]
990: os-cold
991: [ [THEN] ]
992: [ has? ec 0= [IF] ]
993: set-encoding-fixed-width
994: [ [THEN] ]
995: 'cold
996: init8 chainperform
997: [ has? file [IF] ]
998: s" *this should go away*" loadfilename 2!
999: process-args
1000: loadline off
1001: [ [THEN] ]
1002: bootmessage
1003: quit ;
1004:
1005: has? new-input 0= [IF]
1006: : clear-tibstack ( -- )
1007: [ has? glocals [IF] ]
1008: lp@ forthstart 7 cells + @ -
1009: [ [ELSE] ]
1010: [ has? os [IF] ]
1011: r0 @ forthstart 6 cells + @ -
1012: [ [ELSE] ]
1013: sp@ $10 cells +
1014: [ [THEN] ]
1015: [ [THEN] ]
1016: dup >tib ! tibstack ! #tib off >in off ;
1017: [THEN]
1018:
1019: : boot ( path n **argv argc -- )
1020: main-task up!
1021: [ has? os [IF] ]
1022: os-boot
1023: [ [THEN] ]
1024: sp@ sp0 !
1025: [ has? peephole [IF] ]
1026: \ only needed for greedy static superinstruction selection
1027: \ primtable prepare-peephole-table TO peeptable
1028: [ [THEN] ]
1029: [ has? new-input [IF] ]
1030: current-input off
1031: [ [THEN] ]
1032: clear-tibstack
1033: 0 0 includefilename 2!
1034: rp@ rp0 !
1035: [ has? floating [IF] ]
1036: fp@ fp0 !
1037: [ [THEN] ]
1038: handler off
1039: ['] cold catch dup -&2049 <> if \ broken pipe?
1040: DoError cr
1041: endif
1042: [ has? os [IF] ]
1043: 1 (bye) \ !! determin exit code from throw code?
1044: [ [THEN] ]
1045: ;
1046:
1047: has? os [IF]
1048: : bye ( -- ) \ tools-ext
1049: [ has? file [IF] ]
1050: script? 0= IF cr THEN
1051: [ [ELSE] ]
1052: cr
1053: [ [THEN] ]
1054: 0 (bye) ;
1055: [THEN]
1056:
1057: \ **argv may be scanned by the C starter to get some important
1058: \ information, as -display and -geometry for an X client FORTH
1059: \ or space and stackspace overrides
1060:
1061: \ 0 arg contains, however, the name of the program.
1062:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to int.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth / kernel