1: \ compiler definitions 14sep97jaw
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ \ Revisions-Log
22:
23: \ put in seperate file 14sep97jaw
24:
25: \ \ here allot , c, A, 17dec92py
26:
27: [IFUNDEF] allot
28: [IFUNDEF] forthstart
29: : allot ( n -- ) \ core
30: dup unused u> -8 and throw
31: dp +! ;
32: [THEN]
33: [THEN]
34:
35: \ we default to this version if we have nothing else 05May99jaw
36: [IFUNDEF] allot
37: : allot ( n -- ) \ core
38: \G Reserve @i{n} address units of data space without
39: \G initialization. @i{n} is a signed number, passing a negative
40: \G @i{n} releases memory. In ANS Forth you can only deallocate
41: \G memory from the current contiguous region in this way. In
42: \G Gforth you can deallocate anything in this way but named words.
43: \G The system does not check this restriction.
44: here +
45: dup 1- usable-dictionary-end forthstart within -8 and throw
46: dp ! ;
47: [THEN]
48:
49: : c, ( c -- ) \ core c-comma
50: \G Reserve data space for one char and store @i{c} in the space.
51: here 1 chars allot [ has? flash [IF] ] flashc! [ [ELSE] ] c! [ [THEN] ] ;
52:
53: : , ( w -- ) \ core comma
54: \G Reserve data space for one cell and store @i{w} in the space.
55: here cell allot [ has? flash [IF] ] flash! [ [ELSE] ] ! [ [THEN] ] ;
56:
57: : 2, ( w1 w2 -- ) \ gforth
58: \G Reserve data space for two cells and store the double @i{w1
59: \G w2} there, @i{w2} first (lower address).
60: here 2 cells allot [ has? flash [IF] ] tuck flash! cell+ flash!
61: [ [ELSE] ] 2! [ [THEN] ] ;
62:
63: \ : aligned ( addr -- addr' ) \ core
64: \ [ cell 1- ] Literal + [ -1 cells ] Literal and ;
65:
66: : align ( -- ) \ core
67: \G If the data-space pointer is not aligned, reserve enough space to align it.
68: here dup aligned swap ?DO bl c, LOOP ;
69:
70: \ : faligned ( addr -- f-addr ) \ float f-aligned
71: \ [ 1 floats 1- ] Literal + [ -1 floats ] Literal and ;
72:
73: : falign ( -- ) \ float f-align
74: \G If the data-space pointer is not float-aligned, reserve
75: \G enough space to align it.
76: here dup faligned swap
77: ?DO
78: bl c,
79: LOOP ;
80:
81: : maxalign ( -- ) \ gforth
82: \G Align data-space pointer for all alignment requirements.
83: here dup maxaligned swap
84: ?DO
85: bl c,
86: LOOP ;
87:
88: \ the code field is aligned if its body is maxaligned
89: ' maxalign Alias cfalign ( -- ) \ gforth
90: \G Align data-space pointer for code field requirements (i.e., such
91: \G that the corresponding body is maxaligned).
92:
93: ' , alias A, ( addr -- ) \ gforth
94:
95: ' NOOP ALIAS const
96:
97: \ \ Header 23feb93py
98:
99: \ input-stream, nextname and noname are quite ugly (passing
100: \ information through global variables), but they are useful for dealing
101: \ with existing/independent defining words
102:
103: defer (header)
104: defer header ( -- ) \ gforth
105: ' (header) IS header
106:
107: : string, ( c-addr u -- ) \ gforth
108: \G puts down string as cstring
109: dup [ has? rom [IF] ] $E0 [ [ELSE] ] alias-mask [ [THEN] ] or c,
110: [ has? flash [IF] ]
111: bounds ?DO I c@ c, LOOP
112: [ [ELSE] ]
113: here swap chars dup allot move
114: [ [THEN] ] ;
115:
116: : longstring, ( c-addr u -- ) \ gforth
117: \G puts down string as longcstring
118: dup , here swap chars dup allot move ;
119:
120: : header, ( c-addr u -- ) \ gforth
121: name-too-long?
122: dup max-name-length @ max max-name-length !
123: align here last !
124: [ has? flash [IF] ]
125: -1 A,
126: [ [ELSE] ]
127: current @ 1 or A, \ link field; before revealing, it contains the
128: \ tagged reveal-into wordlist
129: [ [THEN] ]
130: [ has? f83headerstring [IF] ]
131: string,
132: [ [ELSE] ]
133: longstring, alias-mask lastflags cset
134: [ [THEN] ]
135: cfalign ;
136:
137: : input-stream-header ( "name" -- )
138: parse-name name-too-short? header, ;
139:
140: : input-stream ( -- ) \ general
141: \G switches back to getting the name from the input stream ;
142: ['] input-stream-header IS (header) ;
143:
144: ' input-stream-header IS (header)
145:
146: 2variable nextname-string
147:
148: has? OS [IF]
149: : nextname-header ( -- )
150: nextname-string 2@ header,
151: nextname-string free-mem-var
152: input-stream ;
153: [THEN]
154:
155: \ the next name is given in the string
156:
157: has? OS [IF]
158: : nextname ( c-addr u -- ) \ gforth
159: \g The next defined word will have the name @var{c-addr u}; the
160: \g defining word will leave the input stream alone.
161: name-too-long?
162: nextname-string free-mem-var
163: save-mem nextname-string 2!
164: ['] nextname-header IS (header) ;
165: [THEN]
166:
167: : noname-header ( -- )
168: 0 last ! cfalign
169: input-stream ;
170:
171: : noname ( -- ) \ gforth
172: \g The next defined word will be anonymous. The defining word will
173: \g leave the input stream alone. The xt of the defined word will
174: \g be given by @code{latestxt}.
175: ['] noname-header IS (header) ;
176:
177: : latestxt ( -- xt ) \ gforth
178: \G @i{xt} is the execution token of the last word defined.
179: \ The main purpose of this word is to get the xt of words defined using noname
180: lastcfa @ ;
181:
182: ' latestxt alias lastxt \ gforth-obsolete
183: \G old name for @code{latestxt}.
184:
185: : latest ( -- nt ) \ gforth
186: \G @var{nt} is the name token of the last word defined; it is 0 if the
187: \G last word has no name.
188: last @ ;
189:
190: \ \ literals 17dec92py
191:
192: : Literal ( compilation n -- ; run-time -- n ) \ core
193: \G Compilation semantics: compile the run-time semantics.@*
194: \G Run-time Semantics: push @i{n}.@*
195: \G Interpretation semantics: undefined.
196: [ [IFDEF] lit, ]
197: lit,
198: [ [ELSE] ]
199: postpone lit ,
200: [ [THEN] ] ; immediate restrict
201:
202: : 2Literal ( compilation w1 w2 -- ; run-time -- w1 w2 ) \ double two-literal
203: \G Compile appropriate code such that, at run-time, @i{w1 w2} are
204: \G placed on the stack. Interpretation semantics are undefined.
205: swap postpone Literal postpone Literal ; immediate restrict
206:
207: : ALiteral ( compilation addr -- ; run-time -- addr ) \ gforth
208: [ [IFDEF] alit, ]
209: alit,
210: [ [ELSE] ]
211: postpone lit A,
212: [ [THEN] ] ; immediate restrict
213:
214: Defer char@ ( addr u -- char addr' u' )
215: :noname over c@ -rot 1 /string ; IS char@
216:
217: : char ( '<spaces>ccc' -- c ) \ core
218: \G Skip leading spaces. Parse the string @i{ccc} and return @i{c}, the
219: \G display code representing the first character of @i{ccc}.
220: parse-name char@ 2drop ;
221:
222: : [char] ( compilation '<spaces>ccc' -- ; run-time -- c ) \ core bracket-char
223: \G Compilation: skip leading spaces. Parse the string
224: \G @i{ccc}. Run-time: return @i{c}, the display code
225: \G representing the first character of @i{ccc}. Interpretation
226: \G semantics for this word are undefined.
227: char postpone Literal ; immediate restrict
228:
229: \ \ threading 17mar93py
230:
231: : cfa, ( code-address -- ) \ gforth cfa-comma
232: here
233: dup lastcfa !
234: [ has? rom [IF] ] 2 cells allot [ [ELSE] ] 0 A, 0 , [ [THEN] ]
235: code-address! ;
236:
237: [IFUNDEF] compile,
238: defer compile, ( xt -- ) \ core-ext compile-comma
239: \G Compile the word represented by the execution token @i{xt}
240: \G into the current definition.
241:
242: ' , is compile,
243: [THEN]
244:
245: has? ec 0= [IF]
246: defer basic-block-end ( -- )
247:
248: :noname ( -- )
249: 0 compile-prim1 ;
250: is basic-block-end
251: [THEN]
252:
253: has? peephole [IF]
254:
255: \ dynamic only
256: : peephole-compile, ( xt -- )
257: \ compile xt, appending its code to the current dynamic superinstruction
258: here swap , compile-prim1 ;
259:
260: : compile-to-prims, ( xt -- )
261: \G compile xt to use primitives (and their peephole optimization)
262: \G instead of ","-ing the xt.
263: \ !! all POSTPONEs here postpone primitives; this can be optimized
264: dup >does-code if
265: ['] does-exec peephole-compile, , EXIT
266: \ dup >body POSTPONE literal ['] call peephole-compile, >does-code , EXIT
267: then
268: dup >code-address CASE
269: docon: OF >body ['] lit@ peephole-compile, , EXIT ENDOF
270: \ docon: OF >body POSTPONE literal ['] @ peephole-compile, EXIT ENDOF
271: \ docon is also used by VALUEs, so don't @ at compile time
272: docol: OF >body ['] call peephole-compile, , EXIT ENDOF
273: dovar: OF >body ['] lit peephole-compile, , EXIT ENDOF
274: douser: OF >body @ ['] useraddr peephole-compile, , EXIT ENDOF
275: dodefer: OF >body ['] lit-perform peephole-compile, , EXIT ENDOF
276: dofield: OF >body @ ['] lit+ peephole-compile, , EXIT ENDOF
277: \ dofield: OF >body @ POSTPONE literal ['] + peephole-compile, EXIT ENDOF
278: \ code words and ;code-defined words (code words could be optimized):
279: dup in-dictionary? IF drop POSTPONE literal ['] execute peephole-compile, EXIT THEN
280: ENDCASE
281: peephole-compile, ;
282:
283: ' compile-to-prims, IS compile,
284: [ELSE]
285: ' , is compile,
286: [THEN]
287:
288: : !does ( addr -- ) \ gforth store-does
289: latestxt does-code! ;
290:
291: \ !! unused, but ifdefed/gosted in some places
292: : (does>) ( R: addr -- )
293: r> cfaligned /does-handler + !does ; \ !! no gforth-native
294:
295: : (does>2) ( addr -- )
296: cfaligned /does-handler + !does ;
297:
298: : dodoes, ( -- )
299: cfalign here /does-handler allot does-handler! ;
300:
301: : (compile) ( -- ) \ gforth-obsolete: dummy
302: true abort" (compile) doesn't work, use POSTPONE instead" ;
303:
304: \ \ ticks
305:
306: : name>comp ( nt -- w xt ) \ gforth
307: \G @i{w xt} is the compilation token for the word @i{nt}.
308: (name>comp)
309: 1 = if
310: ['] execute
311: else
312: ['] compile,
313: then ;
314:
315: : [(')] ( compilation "name" -- ; run-time -- nt ) \ gforth bracket-paren-tick
316: (') postpone ALiteral ; immediate restrict
317:
318: : ['] ( compilation. "name" -- ; run-time. -- xt ) \ core bracket-tick
319: \g @i{xt} represents @i{name}'s interpretation
320: \g semantics. Perform @code{-14 throw} if the word has no
321: \g interpretation semantics.
322: ' postpone ALiteral ; immediate restrict
323:
324: : COMP' ( "name" -- w xt ) \ gforth comp-tick
325: \g Compilation token @i{w xt} represents @i{name}'s compilation semantics.
326: (') name>comp ;
327:
328: : [COMP'] ( compilation "name" -- ; run-time -- w xt ) \ gforth bracket-comp-tick
329: \g Compilation token @i{w xt} represents @i{name}'s compilation semantics.
330: COMP' swap POSTPONE Aliteral POSTPONE ALiteral ; immediate restrict
331:
332: : postpone, ( w xt -- ) \ gforth postpone-comma
333: \g Compile the compilation semantics represented by the
334: \g compilation token @i{w xt}.
335: dup ['] execute =
336: if
337: drop compile,
338: else
339: swap POSTPONE aliteral compile,
340: then ;
341:
342: : POSTPONE ( "name" -- ) \ core
343: \g Compiles the compilation semantics of @i{name}.
344: COMP' postpone, ; immediate
345:
346: \ \ recurse 17may93jaw
347:
348: : recurse ( compilation -- ; run-time ?? -- ?? ) \ core
349: \g Call the current definition.
350: latestxt compile, ; immediate restrict
351:
352: \ \ compiler loop
353:
354: : compiler1 ( c-addr u -- ... xt )
355: 2dup find-name dup
356: if ( c-addr u nt )
357: nip nip name>comp
358: else
359: drop
360: 2dup 2>r snumber? dup
361: IF
362: 0>
363: IF
364: ['] 2literal
365: ELSE
366: ['] literal
367: THEN
368: 2rdrop
369: ELSE
370: drop 2r> compiler-notfound1
371: THEN
372: then ;
373:
374: : [ ( -- ) \ core left-bracket
375: \G Enter interpretation state. Immediate word.
376: ['] interpreter1 IS parser1 state off ; immediate
377:
378: : ] ( -- ) \ core right-bracket
379: \G Enter compilation state.
380: ['] compiler1 IS parser1 state on ;
381:
382: \ \ Strings 22feb93py
383:
384: : S, ( addr u -- )
385: \ allot string as counted string
386: [ has? flash [IF] ]
387: dup c, bounds ?DO I c@ c, LOOP
388: [ [ELSE] ]
389: here over char+ allot place align
390: [ [THEN] ] ;
391:
392: : mem, ( addr u -- )
393: \ allot the memory block HERE (do alignment yourself)
394: [ has? flash [IF] ]
395: bounds ?DO I c@ c, LOOP
396: [ [ELSE] ]
397: here over allot swap move
398: [ [THEN] ] ;
399:
400: : ," ( "string"<"> -- )
401: [char] " parse s, ;
402:
403: \ \ Header states 23feb93py
404:
405: \ problematic only for big endian machines
406:
407: has? f83headerstring [IF]
408: : cset ( bmask c-addr -- )
409: tuck c@ or swap c! ;
410:
411: : creset ( bmask c-addr -- )
412: tuck c@ swap invert and swap c! ;
413:
414: : ctoggle ( bmask c-addr -- )
415: tuck c@ xor swap c! ;
416: [ELSE]
417: : cset ( bmask c-addr -- )
418: tuck @ or swap ! ;
419:
420: : creset ( bmask c-addr -- )
421: tuck @ swap invert and swap ! ;
422:
423: : ctoggle ( bmask c-addr -- )
424: tuck @ xor swap ! ;
425: [THEN]
426:
427: : lastflags ( -- c-addr )
428: \ the address of the flags byte in the last header
429: \ aborts if the last defined word was headerless
430: latest dup 0= abort" last word was headerless" cell+ ;
431:
432: : immediate ( -- ) \ core
433: \G Make the compilation semantics of a word be to @code{execute}
434: \G the execution semantics.
435: immediate-mask lastflags [ has? rom [IF] ] creset [ [ELSE] ] cset [ [THEN] ] ;
436:
437: : restrict ( -- ) \ gforth
438: \G A synonym for @code{compile-only}
439: restrict-mask lastflags [ has? rom [IF] ] creset [ [ELSE] ] cset [ [THEN] ] ;
440:
441: ' restrict alias compile-only ( -- ) \ gforth
442: \G Remove the interpretation semantics of a word.
443:
444: \ \ Create Variable User Constant 17mar93py
445:
446: : Alias ( xt "name" -- ) \ gforth
447: Header reveal
448: alias-mask lastflags creset
449: dup A, lastcfa ! ;
450:
451: doer? :dovar [IF]
452:
453: : Create ( "name" -- ) \ core
454: Header reveal dovar: cfa, ;
455: [ELSE]
456:
457: : Create ( "name" -- ) \ core
458: Header reveal here lastcfa ! 0 A, 0 , DOES> ;
459: [THEN]
460:
461: has? flash [IF]
462: : (variable) dpp @ normal-dp = IF Create dpp @
463: ELSE normal-dp @ Constant dpp @ ram THEN ;
464: : Variable ( "name" -- ) \ core
465: (Variable) 0 , dpp ! ;
466:
467: : AVariable ( "name" -- ) \ gforth
468: (Variable) 0 A, dpp ! ;
469:
470: : 2Variable ( "name" -- ) \ double two-variable
471: (Variable) 0 , 0 , dpp ! ;
472: [ELSE]
473: : Variable ( "name" -- ) \ core
474: Create 0 , ;
475:
476: : AVariable ( "name" -- ) \ gforth
477: Create 0 A, ;
478:
479: : 2Variable ( "name" -- ) \ double two-variable
480: Create 0 , 0 , ;
481: [THEN]
482:
483: has? no-userspace 0= [IF]
484: : uallot ( n -- ) \ gforth
485: udp @ swap udp +! ;
486:
487: doer? :douser [IF]
488:
489: : User ( "name" -- ) \ gforth
490: Header reveal douser: cfa, cell uallot , ;
491:
492: : AUser ( "name" -- ) \ gforth
493: User ;
494: [ELSE]
495:
496: : User Create cell uallot , DOES> @ up @ + ;
497:
498: : AUser User ;
499: [THEN]
500: [THEN]
501:
502: doer? :docon [IF]
503: : (Constant) Header reveal docon: cfa, ;
504: [ELSE]
505: : (Constant) Create DOES> @ ;
506: [THEN]
507:
508: doer? :dovalue [IF]
509: : (Value) Header reveal dovalue: cfa, ;
510: [ELSE]
511: has? rom [IF]
512: : (Value) Create DOES> @ @ ;
513: [ELSE]
514: : (Value) Create DOES> @ ;
515: [THEN]
516: [THEN]
517:
518: : Constant ( w "name" -- ) \ core
519: \G Define a constant @i{name} with value @i{w}.
520: \G
521: \G @i{name} execution: @i{-- w}
522: (Constant) , ;
523:
524: : AConstant ( addr "name" -- ) \ gforth
525: (Constant) A, ;
526:
527: has? flash [IF]
528: : Value ( w "name" -- ) \ core-ext
529: (Value) dpp @ >r here cell allot >r
530: ram here >r , r> r> flash! r> dpp ! ;
531:
532: ' Value alias AValue
533: [ELSE]
534: : Value ( w "name" -- ) \ core-ext
535: (Value) , ;
536:
537: : AValue ( w "name" -- ) \ core-ext
538: (Value) A, ;
539: [THEN]
540:
541: : 2Constant ( w1 w2 "name" -- ) \ double two-constant
542: Create ( w1 w2 "name" -- )
543: 2,
544: DOES> ( -- w1 w2 )
545: 2@ ;
546:
547: doer? :dofield [IF]
548: : (Field) Header reveal dofield: cfa, ;
549: [ELSE]
550: : (Field) Create DOES> @ + ;
551: [THEN]
552:
553: \ \ interpret/compile:
554:
555: struct
556: >body
557: cell% field interpret/compile-int
558: cell% field interpret/compile-comp
559: end-struct interpret/compile-struct
560:
561: : interpret/compile: ( interp-xt comp-xt "name" -- ) \ gforth
562: Create immediate swap A, A,
563: DOES>
564: abort" executed primary cfa of an interpret/compile: word" ;
565: \ state @ IF cell+ THEN perform ;
566:
567: \ IS Defer What's Defers TO 24feb93py
568:
569: defer defer-default ( -- )
570: ' abort is defer-default
571: \ default action for deferred words (overridden by a warning later)
572:
573: doer? :dodefer [IF]
574:
575: : Defer ( "name" -- ) \ gforth
576: \G Define a deferred word @i{name}; its execution semantics can be
577: \G set with @code{defer!} or @code{is} (and they have to, before first
578: \G executing @i{name}.
579: Header Reveal dodefer: cfa,
580: [ has? rom [IF] ] here >r cell allot
581: dpp @ ram here r> flash! ['] defer-default A, dpp !
582: [ [ELSE] ] ['] defer-default A, [ [THEN] ] ;
583:
584: [ELSE]
585:
586: has? rom [IF]
587: : Defer ( "name" -- ) \ gforth
588: Create here >r cell allot
589: dpp @ ram here r> flash! ['] defer-default A, dpp !
590: DOES> @ @ execute ;
591: [ELSE]
592: : Defer ( "name" -- ) \ gforth
593: Create ['] defer-default A,
594: DOES> @ execute ;
595: [THEN]
596: [THEN]
597:
598: : defer@ ( xt-deferred -- xt ) \ gforth defer-fetch
599: \G @i{xt} represents the word currently associated with the deferred
600: \G word @i{xt-deferred}.
601: >body @ [ has? rom [IF] ] @ [ [THEN] ] ;
602:
603: : Defers ( compilation "name" -- ; run-time ... -- ... ) \ gforth
604: \G Compiles the present contents of the deferred word @i{name}
605: \G into the current definition. I.e., this produces static
606: \G binding as if @i{name} was not deferred.
607: ' defer@ compile, ; immediate
608:
609: :noname
610: dodoes, here !does ]
611: defstart :-hook ;
612: :noname
613: ;-hook ?struc
614: [ has? xconds [IF] ] exit-like [ [THEN] ]
615: here [ has? peephole [IF] ] 5 [ [ELSE] ] 4 [ [THEN] ] cells +
616: postpone aliteral postpone (does>2) [compile] exit
617: [ has? peephole [IF] ] finish-code [ [THEN] ] dodoes,
618: defstart :-hook ;
619: interpret/compile: DOES> ( compilation colon-sys1 -- colon-sys2 ; run-time nest-sys -- ) \ core does
620:
621: : defer! ( xt xt-deferred -- ) \ gforth defer-store
622: \G Changes the @code{defer}red word @var{xt-deferred} to execute @var{xt}.
623: >body [ has? rom [IF] ] @ [ [THEN] ] ! ;
624:
625: : <IS> ( "name" xt -- ) \ gforth
626: \g Changes the @code{defer}red word @var{name} to execute @var{xt}.
627: ' defer! ;
628:
629: : [IS] ( compilation "name" -- ; run-time xt -- ) \ gforth bracket-is
630: \g At run-time, changes the @code{defer}red word @var{name} to
631: \g execute @var{xt}.
632: ' postpone ALiteral postpone defer! ; immediate restrict
633:
634: ' <IS>
635: ' [IS]
636: interpret/compile: IS ( compilation/interpretation "name-deferred" -- ; run-time xt -- ) \ gforth
637: \G Changes the @code{defer}red word @var{name} to execute @var{xt}.
638: \G Its compilation semantics parses at compile time.
639:
640: ' <IS>
641: ' [IS]
642: interpret/compile: TO ( w "name" -- ) \ core-ext
643:
644: : interpret/compile? ( xt -- flag )
645: >does-code ['] DOES> >does-code = ;
646:
647: \ \ : ; 24feb93py
648:
649: defer :-hook ( sys1 -- sys2 )
650:
651: defer ;-hook ( sys2 -- sys1 )
652:
653: 0 Constant defstart
654:
655: [IFDEF] docol,
656: : (:noname) ( -- colon-sys )
657: \ common factor of : and :noname
658: docol, ]comp
659: [ELSE]
660: : (:noname) ( -- colon-sys )
661: \ common factor of : and :noname
662: docol: cfa,
663: [THEN]
664: defstart ] :-hook ;
665:
666: : : ( "name" -- colon-sys ) \ core colon
667: Header (:noname) ;
668:
669: : :noname ( -- xt colon-sys ) \ core-ext colon-no-name
670: 0 last !
671: cfalign here (:noname) ;
672:
673: [IFDEF] fini,
674: : ; ( compilation colon-sys -- ; run-time nest-sys ) \ core semicolon
675: ;-hook ?struc fini, comp[ reveal postpone [ ; immediate restrict
676: [ELSE]
677: : ; ( compilation colon-sys -- ; run-time nest-sys ) \ core semicolon
678: ;-hook ?struc [compile] exit
679: [ has? peephole [IF] ] finish-code [ [THEN] ]
680: reveal postpone [ ; immediate restrict
681: [THEN]
682:
683: \ \ Search list handling: reveal words, recursive 23feb93py
684:
685: : last? ( -- false / nfa nfa )
686: latest ?dup ;
687:
688: Variable warnings ( -- addr ) \ gforth
689: G -1 warnings T !
690:
691: has? ec [IF]
692: : reveal ( -- ) \ gforth
693: last?
694: if \ the last word has a header
695: dup ( name>link ) @ -1 =
696: if \ it is still hidden
697: current @ dup >r @ over
698: [ has? flash [IF] ] flash! [ [ELSE] ] ! [ [THEN] ] r> !
699: else
700: drop
701: then
702: then ;
703: [ELSE]
704: : (reveal) ( nt wid -- )
705: wordlist-id dup >r
706: @ over ( name>link ) !
707: r> ! ;
708:
709: \ make entry in wordlist-map
710: ' (reveal) f83search reveal-method !
711:
712: : check-shadow ( addr count wid -- )
713: \G prints a warning if the string is already present in the wordlist
714: >r 2dup 2dup r> (search-wordlist) warnings @ and ?dup if
715: >stderr
716: ." redefined " name>string 2dup type
717: str= 0= if
718: ." with " type
719: else
720: 2drop
721: then
722: space space EXIT
723: then
724: 2drop 2drop ;
725:
726: : reveal ( -- ) \ gforth
727: last?
728: if \ the last word has a header
729: dup ( name>link ) @ 1 and
730: if \ it is still hidden
731: dup ( name>link ) @ 1 xor ( nt wid )
732: 2dup >r name>string r> check-shadow ( nt wid )
733: dup wordlist-map @ reveal-method perform
734: else
735: drop
736: then
737: then ;
738:
739: : rehash ( wid -- )
740: dup wordlist-map @ rehash-method perform ;
741: [THEN]
742:
743: ' reveal alias recursive ( compilation -- ; run-time -- ) \ gforth
744: \g Make the current definition visible, enabling it to call itself
745: \g recursively.
746: immediate restrict
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>