1: \ compiler definitions 14sep97jaw
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: \ \ Revisions-Log
22:
23: \ put in seperate file 14sep97jaw
24:
25: \ \ here allot , c, A, 17dec92py
26:
27: [IFUNDEF] allot
28: [IFUNDEF] forthstart
29: : allot ( n -- ) \ core
30: dup unused u> -8 and throw
31: dp +! ;
32: [THEN]
33: [THEN]
34:
35: \ we default to this version if we have nothing else 05May99jaw
36: [IFUNDEF] allot
37: : allot ( n -- ) \ core
38: \G Reserve @i{n} address units of data space without
39: \G initialization. @i{n} is a signed number, passing a negative
40: \G @i{n} releases memory. In ANS Forth you can only deallocate
41: \G memory from the current contiguous region in this way. In
42: \G Gforth you can deallocate anything in this way but named words.
43: \G The system does not check this restriction.
44: here +
45: dup 1- usable-dictionary-end forthstart within -8 and throw
46: dp ! ;
47: [THEN]
48:
49: : c, ( c -- ) \ core c-comma
50: \G Reserve data space for one char and store @i{c} in the space.
51: here 1 chars allot c! ;
52:
53: : , ( w -- ) \ core comma
54: \G Reserve data space for one cell and store @i{w} in the space.
55: here cell allot ! ;
56:
57: : 2, ( w1 w2 -- ) \ gforth
58: \G Reserve data space for two cells and store the double @i{w1
59: \G w2} there, @i{w2} first (lower address).
60: here 2 cells allot 2! ;
61:
62: \ : aligned ( addr -- addr' ) \ core
63: \ [ cell 1- ] Literal + [ -1 cells ] Literal and ;
64:
65: : align ( -- ) \ core
66: \G If the data-space pointer is not aligned, reserve enough space to align it.
67: here dup aligned swap ?DO bl c, LOOP ;
68:
69: \ : faligned ( addr -- f-addr ) \ float f-aligned
70: \ [ 1 floats 1- ] Literal + [ -1 floats ] Literal and ;
71:
72: : falign ( -- ) \ float f-align
73: \G If the data-space pointer is not float-aligned, reserve
74: \G enough space to align it.
75: here dup faligned swap
76: ?DO
77: bl c,
78: LOOP ;
79:
80: : maxalign ( -- ) \ gforth
81: \G Align data-space pointer for all alignment requirements.
82: here dup maxaligned swap
83: ?DO
84: bl c,
85: LOOP ;
86:
87: \ the code field is aligned if its body is maxaligned
88: ' maxalign Alias cfalign ( -- ) \ gforth
89: \G Align data-space pointer for code field requirements (i.e., such
90: \G that the corresponding body is maxaligned).
91:
92: ' , alias A, ( addr -- ) \ gforth
93:
94: ' NOOP ALIAS const
95:
96: \ \ Header 23feb93py
97:
98: \ input-stream, nextname and noname are quite ugly (passing
99: \ information through global variables), but they are useful for dealing
100: \ with existing/independent defining words
101:
102: defer (header)
103: defer header ( -- ) \ gforth
104: ' (header) IS header
105:
106: : string, ( c-addr u -- ) \ gforth
107: \G puts down string as cstring
108: dup c, here swap chars dup allot move ;
109:
110: : longstring, ( c-addr u -- ) \ gforth
111: \G puts down string as longcstring
112: dup , here swap chars dup allot move ;
113:
114: : header, ( c-addr u -- ) \ gforth
115: name-too-long?
116: dup max-name-length @ max max-name-length !
117: align here last !
118: current @ 1 or A, \ link field; before revealing, it contains the
119: \ tagged reveal-into wordlist
120: longstring, cfalign
121: alias-mask lastflags cset ;
122:
123: : input-stream-header ( "name" -- )
124: name name-too-short? header, ;
125:
126: : input-stream ( -- ) \ general
127: \G switches back to getting the name from the input stream ;
128: ['] input-stream-header IS (header) ;
129:
130: ' input-stream-header IS (header)
131:
132: 2variable nextname-string
133:
134: has? OS [IF]
135: : nextname-header ( -- )
136: nextname-string 2@ header,
137: nextname-string free-mem-var
138: input-stream ;
139: [THEN]
140:
141: \ the next name is given in the string
142:
143: has? OS [IF]
144: : nextname ( c-addr u -- ) \ gforth
145: \g The next defined word will have the name @var{c-addr u}; the
146: \g defining word will leave the input stream alone.
147: name-too-long?
148: nextname-string free-mem-var
149: save-mem nextname-string 2!
150: ['] nextname-header IS (header) ;
151: [THEN]
152:
153: : noname-header ( -- )
154: 0 last ! cfalign
155: input-stream ;
156:
157: : noname ( -- ) \ gforth
158: \g The next defined word will be anonymous. The defining word will
159: \g leave the input stream alone. The xt of the defined word will
160: \g be given by @code{latestxt}.
161: ['] noname-header IS (header) ;
162:
163: : latestxt ( -- xt ) \ gforth
164: \G @i{xt} is the execution token of the last word defined.
165: \ The main purpose of this word is to get the xt of words defined using noname
166: lastcfa @ ;
167:
168: ' latestxt alias lastxt \ gforth-obsolete
169: \G old name for @code{latestxt}.
170:
171: : latest ( -- nt ) \ gforth
172: \G @var{nt} is the name token of the last word defined; it is 0 if the
173: \G last word has no name.
174: last @ ;
175:
176: \ \ literals 17dec92py
177:
178: : Literal ( compilation n -- ; run-time -- n ) \ core
179: \G Compilation semantics: compile the run-time semantics.@*
180: \G Run-time Semantics: push @i{n}.@*
181: \G Interpretation semantics: undefined.
182: [ [IFDEF] lit, ]
183: lit,
184: [ [ELSE] ]
185: postpone lit ,
186: [ [THEN] ] ; immediate restrict
187:
188: : ALiteral ( compilation addr -- ; run-time -- addr ) \ gforth
189: [ [IFDEF] alit, ]
190: alit,
191: [ [ELSE] ]
192: postpone lit A,
193: [ [THEN] ] ; immediate restrict
194:
195: : char ( '<spaces>ccc' -- c ) \ core
196: \G Skip leading spaces. Parse the string @i{ccc} and return @i{c}, the
197: \G display code representing the first character of @i{ccc}.
198: bl word char+ c@ ;
199:
200: : [char] ( compilation '<spaces>ccc' -- ; run-time -- c ) \ core bracket-char
201: \G Compilation: skip leading spaces. Parse the string
202: \G @i{ccc}. Run-time: return @i{c}, the display code
203: \G representing the first character of @i{ccc}. Interpretation
204: \G semantics for this word are undefined.
205: char postpone Literal ; immediate restrict
206:
207: \ \ threading 17mar93py
208:
209: : cfa, ( code-address -- ) \ gforth cfa-comma
210: here
211: dup lastcfa !
212: 0 A, 0 , code-address! ;
213:
214: [IFUNDEF] compile,
215: defer compile, ( xt -- ) \ core-ext compile-comma
216: \G Compile the word represented by the execution token @i{xt}
217: \G into the current definition.
218:
219: ' , is compile,
220: [THEN]
221:
222: defer basic-block-end ( -- )
223:
224: :noname ( -- )
225: 0 last-compiled ! ;
226: is basic-block-end
227:
228: has? peephole [IF]
229:
230: \ dynamic only
231: : peephole-compile, ( xt -- )
232: \ compile xt, appending its code to the current dynamic superinstruction
233: here swap , compile-prim1 ;
234:
235: \ static only
236: \ : peephole-compile, ( xt -- )
237: \ \ compile xt, possibly combining it with the previous compiled xt
238: \ \ into a superinstruction (static superinstructions)
239: \ last-compiled @ ?dup if
240: \ @ over peeptable peephole-opt ?dup if
241: \ last-compiled @ ! drop EXIT
242: \ then
243: \ then
244: \ here last-compiled !
245: \ dyn-compile, ;
246:
247: \ combine greedy static with dynamic
248: \ : dyn-compile! ( xt -- )
249: \ \ compile xt, appending its code to the current dynamic superinstruction
250: \ last-compiled-here @ tuck ! compile-prim1 ;
251:
252: \ :noname ( -- )
253: \ last-compiled @ if
254: \ last-compiled @ dyn-compile!
255: \ 0 last-compiled !
256: \ then ;
257: \ is basic-block-end
258:
259: \ : peephole-compile, ( xt -- )
260: \ \ compile xt, possibly combining it with the previous compiled xt
261: \ \ into a superinstruction (static superinstructions)
262: \ last-compiled @ ?dup if
263: \ over peeptable peephole-opt ?dup if ( xt comb-xt )
264: \ last-compiled ! drop EXIT
265: \ then ( xt )
266: \ last-compiled @ dyn-compile!
267: \ then ( xt )
268: \ last-compiled !
269: \ here last-compiled-here ! 0 , ;
270:
271: : compile-to-prims, ( xt -- )
272: \G compile xt to use primitives (and their peephole optimization)
273: \G instead of ","-ing the xt.
274: \ !! all POSTPONEs here postpone primitives; this can be optimized
275: dup >does-code if
276: POSTPONE does-exec , EXIT
277: \ dup >body POSTPONE literal POSTPONE call >does-code , EXIT
278: then
279: dup >code-address CASE
280: docon: OF >body POSTPONE lit@ , EXIT ENDOF
281: \ docon: OF >body POSTPONE literal POSTPONE @ EXIT ENDOF
282: \ docon is also used by VALUEs, so don't @ at compile time
283: docol: OF >body POSTPONE call , EXIT ENDOF
284: dovar: OF >body POSTPONE literal EXIT ENDOF
285: douser: OF >body @ POSTPONE useraddr , EXIT ENDOF
286: dodefer: OF >body POSTPONE lit-perform , EXIT ENDOF
287: dofield: OF >body @ POSTPONE lit+ , EXIT ENDOF
288: \ dofield: OF >body @ POSTPONE literal POSTPONE + EXIT ENDOF
289: \ code words and ;code-defined words (code words could be optimized):
290: dup in-dictionary? IF drop POSTPONE literal POSTPONE execute EXIT THEN
291: ENDCASE
292: peephole-compile, ;
293:
294: ' compile-to-prims, IS compile,
295: [ELSE]
296: ' , is compile,
297: [THEN]
298:
299: : !does ( addr -- ) \ gforth store-does
300: latestxt does-code! ;
301:
302: : (does>) ( R: addr -- )
303: r> cfaligned /does-handler + !does ;
304:
305: : dodoes, ( -- )
306: cfalign here /does-handler allot does-handler! ;
307:
308: : (compile) ( -- ) \ gforth
309: r> dup cell+ >r @ compile, ;
310:
311: \ \ ticks
312:
313: : name>comp ( nt -- w xt ) \ gforth
314: \G @i{w xt} is the compilation token for the word @i{nt}.
315: (name>comp)
316: 1 = if
317: ['] execute
318: else
319: ['] compile,
320: then ;
321:
322: : [(')] ( compilation "name" -- ; run-time -- nt ) \ gforth bracket-paren-tick
323: (') postpone ALiteral ; immediate restrict
324:
325: : ['] ( compilation. "name" -- ; run-time. -- xt ) \ core bracket-tick
326: \g @i{xt} represents @i{name}'s interpretation
327: \g semantics. Perform @code{-14 throw} if the word has no
328: \g interpretation semantics.
329: ' postpone ALiteral ; immediate restrict
330:
331: : COMP' ( "name" -- w xt ) \ gforth comp-tick
332: \g Compilation token @i{w xt} represents @i{name}'s compilation semantics.
333: (') name>comp ;
334:
335: : [COMP'] ( compilation "name" -- ; run-time -- w xt ) \ gforth bracket-comp-tick
336: \g Compilation token @i{w xt} represents @i{name}'s compilation semantics.
337: COMP' swap POSTPONE Aliteral POSTPONE ALiteral ; immediate restrict
338:
339: : postpone, ( w xt -- ) \ gforth postpone-comma
340: \g Compile the compilation semantics represented by the
341: \g compilation token @i{w xt}.
342: dup ['] execute =
343: if
344: drop compile,
345: else
346: dup ['] compile, =
347: if
348: drop POSTPONE (compile) a,
349: else
350: swap POSTPONE aliteral compile,
351: then
352: then ;
353:
354: : POSTPONE ( "name" -- ) \ core
355: \g Compiles the compilation semantics of @i{name}.
356: COMP' postpone, ; immediate
357:
358: \ \ recurse 17may93jaw
359:
360: : recurse ( compilation -- ; run-time ?? -- ?? ) \ core
361: \g Call the current definition.
362: latestxt compile, ; immediate restrict
363:
364: \ \ compiler loop
365:
366: : compiler ( c-addr u -- )
367: 2dup find-name dup
368: if ( c-addr u nt )
369: nip nip name>comp execute
370: else
371: drop
372: 2dup snumber? dup
373: IF
374: 0>
375: IF
376: swap postpone Literal
377: THEN
378: postpone Literal
379: 2drop
380: ELSE
381: drop compiler-notfound
382: THEN
383: then ;
384:
385: : [ ( -- ) \ core left-bracket
386: \G Enter interpretation state. Immediate word.
387: ['] interpreter IS parser state off ; immediate
388:
389: : ] ( -- ) \ core right-bracket
390: \G Enter compilation state.
391: ['] compiler IS parser state on ;
392:
393: \ \ Strings 22feb93py
394:
395: : S, ( addr u -- )
396: \ allot string as counted string
397: here over char+ allot place align ;
398:
399: : mem, ( addr u -- )
400: \ allot the memory block HERE (do alignment yourself)
401: here over allot swap move ;
402:
403: : ," ( "string"<"> -- )
404: [char] " parse s, ;
405:
406: \ \ Header states 23feb93py
407:
408: : cset ( bmask c-addr -- )
409: tuck @ or swap ! ;
410:
411: : creset ( bmask c-addr -- )
412: tuck @ swap invert and swap ! ;
413:
414: : ctoggle ( bmask c-addr -- )
415: tuck @ xor swap ! ;
416:
417: : lastflags ( -- c-addr )
418: \ the address of the flags byte in the last header
419: \ aborts if the last defined word was headerless
420: latest dup 0= abort" last word was headerless" cell+ ;
421:
422: : immediate ( -- ) \ core
423: \G Make the compilation semantics of a word be to @code{execute}
424: \G the execution semantics.
425: immediate-mask lastflags cset ;
426:
427: : restrict ( -- ) \ gforth
428: \G A synonym for @code{compile-only}
429: restrict-mask lastflags cset ;
430:
431: ' restrict alias compile-only ( -- ) \ gforth
432: \G Remove the interpretation semantics of a word.
433:
434: \ \ Create Variable User Constant 17mar93py
435:
436: : Alias ( xt "name" -- ) \ gforth
437: Header reveal
438: alias-mask lastflags creset
439: dup A, lastcfa ! ;
440:
441: doer? :dovar [IF]
442:
443: : Create ( "name" -- ) \ core
444: Header reveal dovar: cfa, ;
445: [ELSE]
446:
447: : Create ( "name" -- ) \ core
448: Header reveal here lastcfa ! 0 A, 0 , DOES> ;
449: [THEN]
450:
451: : Variable ( "name" -- ) \ core
452: Create 0 , ;
453:
454: : AVariable ( "name" -- ) \ gforth
455: Create 0 A, ;
456:
457: : 2Variable ( "name" -- ) \ double two-variable
458: create 0 , 0 , ;
459:
460: : uallot ( n -- ) \ gforth
461: udp @ swap udp +! ;
462:
463: doer? :douser [IF]
464:
465: : User ( "name" -- ) \ gforth
466: Header reveal douser: cfa, cell uallot , ;
467:
468: : AUser ( "name" -- ) \ gforth
469: User ;
470: [ELSE]
471:
472: : User Create cell uallot , DOES> @ up @ + ;
473:
474: : AUser User ;
475: [THEN]
476:
477: doer? :docon [IF]
478: : (Constant) Header reveal docon: cfa, ;
479: [ELSE]
480: : (Constant) Create DOES> @ ;
481: [THEN]
482:
483: : Constant ( w "name" -- ) \ core
484: \G Define a constant @i{name} with value @i{w}.
485: \G
486: \G @i{name} execution: @i{-- w}
487: (Constant) , ;
488:
489: : AConstant ( addr "name" -- ) \ gforth
490: (Constant) A, ;
491:
492: : Value ( w "name" -- ) \ core-ext
493: (Constant) , ;
494:
495: : AValue ( w "name" -- ) \ core-ext
496: (Constant) A, ;
497:
498: : 2Constant ( w1 w2 "name" -- ) \ double two-constant
499: Create ( w1 w2 "name" -- )
500: 2,
501: DOES> ( -- w1 w2 )
502: 2@ ;
503:
504: doer? :dofield [IF]
505: : (Field) Header reveal dofield: cfa, ;
506: [ELSE]
507: : (Field) Create DOES> @ + ;
508: [THEN]
509:
510: \ \ interpret/compile:
511:
512: struct
513: >body
514: cell% field interpret/compile-int
515: cell% field interpret/compile-comp
516: end-struct interpret/compile-struct
517:
518: : interpret/compile: ( interp-xt comp-xt "name" -- ) \ gforth
519: Create immediate swap A, A,
520: DOES>
521: abort" executed primary cfa of an interpret/compile: word" ;
522: \ state @ IF cell+ THEN perform ;
523:
524: \ IS Defer What's Defers TO 24feb93py
525:
526: doer? :dodefer [IF]
527:
528: : Defer ( "name" -- ) \ gforth
529: \ !! shouldn't it be initialized with abort or something similar?
530: Header Reveal dodefer: cfa,
531: ['] noop A, ;
532:
533: [ELSE]
534:
535: : Defer ( "name" -- ) \ gforth
536: Create ['] noop A,
537: DOES> @ execute ;
538:
539: [THEN]
540:
541: : Defers ( compilation "name" -- ; run-time ... -- ... ) \ gforth
542: \G Compiles the present contents of the deferred word @i{name}
543: \G into the current definition. I.e., this produces static
544: \G binding as if @i{name} was not deferred.
545: ' >body @ compile, ; immediate
546:
547: :noname
548: dodoes, here !does ]
549: defstart :-hook ;
550: :noname
551: ;-hook ?struc
552: [ has? xconds [IF] ] exit-like [ [THEN] ]
553: postpone (does>) dodoes,
554: defstart :-hook ;
555: interpret/compile: DOES> ( compilation colon-sys1 -- colon-sys2 ; run-time nest-sys -- ) \ core does
556:
557: : <IS> ( "name" xt -- ) \ gforth
558: \g Changes the @code{defer}red word @var{name} to execute @var{xt}.
559: ' >body ! ;
560:
561: : [IS] ( compilation "name" -- ; run-time xt -- ) \ gforth bracket-is
562: \g At run-time, changes the @code{defer}red word @var{name} to
563: \g execute @var{xt}.
564: ' >body postpone ALiteral postpone ! ; immediate restrict
565:
566: ' <IS>
567: ' [IS]
568: interpret/compile: IS ( xt "name" -- ) \ gforth
569: \G A combined word made up from @code{<IS>} and @code{[IS]}.
570:
571: ' <IS>
572: ' [IS]
573: interpret/compile: TO ( w "name" -- ) \ core-ext
574:
575: :noname ' >body @ ;
576: :noname ' >body postpone ALiteral postpone @ ;
577: interpret/compile: What's ( interpretation "name" -- xt; compilation "name" -- ; run-time -- xt ) \ gforth
578: \G @i{Xt} is the XT that is currently assigned to @i{name}.
579:
580: : interpret/compile? ( xt -- flag )
581: >does-code ['] DOES> >does-code = ;
582:
583: \ \ : ; 24feb93py
584:
585: defer :-hook ( sys1 -- sys2 )
586:
587: defer ;-hook ( sys2 -- sys1 )
588:
589: 0 Constant defstart
590:
591: [IFDEF] docol,
592: : (:noname) ( -- colon-sys )
593: \ common factor of : and :noname
594: docol, ]comp
595: [ELSE]
596: : (:noname) ( -- colon-sys )
597: \ common factor of : and :noname
598: docol: cfa,
599: [THEN]
600: defstart ] :-hook ;
601:
602: : : ( "name" -- colon-sys ) \ core colon
603: Header (:noname) ;
604:
605: : :noname ( -- xt colon-sys ) \ core-ext colon-no-name
606: 0 last !
607: cfalign here (:noname) ;
608:
609: [IFDEF] fini,
610: : ; ( compilation colon-sys -- ; run-time nest-sys ) \ core semicolon
611: ;-hook ?struc fini, comp[ reveal postpone [ ; immediate restrict
612: [ELSE]
613: : ; ( compilation colon-sys -- ; run-time nest-sys ) \ core semicolon
614: ;-hook ?struc [compile] exit
615: [ has? peephole [IF] ] finish-code [ [THEN] ]
616: reveal postpone [ ; immediate restrict
617: [THEN]
618:
619: \ \ Search list handling: reveal words, recursive 23feb93py
620:
621: : last? ( -- false / nfa nfa )
622: latest ?dup ;
623:
624: : (reveal) ( nt wid -- )
625: wordlist-id dup >r
626: @ over ( name>link ) !
627: r> ! ;
628:
629: \ make entry in wordlist-map
630: ' (reveal) f83search reveal-method !
631:
632: Variable warnings ( -- addr ) \ gforth
633: G -1 warnings T !
634:
635: : check-shadow ( addr count wid -- )
636: \G prints a warning if the string is already present in the wordlist
637: >r 2dup 2dup r> (search-wordlist) warnings @ and ?dup if
638: >stderr
639: ." redefined " name>string 2dup type
640: str= 0= if
641: ." with " type
642: else
643: 2drop
644: then
645: space space EXIT
646: then
647: 2drop 2drop ;
648:
649: : reveal ( -- ) \ gforth
650: last?
651: if \ the last word has a header
652: dup ( name>link ) @ 1 and
653: if \ it is still hidden
654: dup ( name>link ) @ 1 xor ( nt wid )
655: 2dup >r name>string r> check-shadow ( nt wid )
656: dup wordlist-map @ reveal-method perform
657: else
658: drop
659: then
660: then ;
661:
662: : rehash ( wid -- )
663: dup wordlist-map @ rehash-method perform ;
664:
665: ' reveal alias recursive ( compilation -- ; run-time -- ) \ gforth
666: \g Make the current definition visible, enabling it to call itself
667: \g recursively.
668: immediate restrict
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to comp.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth / kernel