1: \ Structural Conditionals, loops part 12dec92py
3: \ Copyright (C) 1995,1996,1997,1999,2001,2003,2006,2007 Free Software Foundation, Inc.
5: \ This file is part of Gforth.
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation, either version 3
10: \ of the License, or (at your option) any later version.
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program. If not, see http://www.gnu.org/licenses/.
20: \ Structural Conditionals 12dec92py
22: \ this works with flash
24: : (leave) -1 , ;
25: : LEAVE postpone branch (leave) ; immediate restrict
26: : ?LEAVE postpone 0= postpone ?branch (leave) ;
27: immediate restrict
29: : DONE ( addr -- ) here swap ?DO
30: I @ ['] branch = I @ ['] ?branch = or I @ ['] (?do) = or
31: I cell+ @ -1 = and IF I cell+ >resolve THEN
32: cell +LOOP ; immediate restrict
34: \ Structural Conditionals 12dec92py
36: : DO postpone (do) here ; immediate restrict
38: : ?DO postpone (?do) (leave) here ;
39: immediate restrict
40: : FOR postpone (for) here ; immediate restrict
42: : loop] dup <resolve 2 cells - postpone done postpone unloop ;
44: : LOOP sys? postpone (loop) loop] ; immediate restrict
45: : +LOOP sys? postpone (+loop) loop] ; immediate restrict
46: : NEXT sys? postpone (next) loop] ; immediate restrict
48: : EXIT postpone ;s ; immediate restrict
49: : ?EXIT postpone IF postpone EXIT postpone THEN ; immediate restrict