1: \ command line edit and history support 16oct94py
2:
3: \ Copyright (C) 1995 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: :noname
22: char [char] @ - ;
23: :noname
24: char [char] @ - postpone Literal ;
25: interpret/compile: ctrl ( "<char>" -- ctrl-code )
26:
27: \ command line editing 16oct94py
28:
29: : >string ( span addr pos1 -- span addr pos1 addr2 len )
30: over 3 pick 2 pick chars /string ;
31: : type-rest ( span addr pos1 -- span addr pos1 back )
32: >string tuck type ;
33: : (del) ( max span addr pos1 -- max span addr pos2 )
34: 1- >string over 1+ -rot move
35: rot 1- -rot #bs emit type-rest bl emit 1+ backspaces ;
36: : (ins) ( max span addr pos1 char -- max span addr pos2 )
37: >r >string over 1+ swap move 2dup chars + r> swap c!
38: rot 1+ -rot type-rest 1- backspaces 1+ ;
39: : ?del ( max span addr pos1 -- max span addr pos2 0 )
40: dup IF (del) THEN 0 ;
41: : (ret) type-rest drop true space ;
42: : back dup IF 1- #bs emit ELSE #bell emit THEN 0 ;
43: : forw 2 pick over <> IF 2dup + c@ emit 1+ ELSE #bell emit THEN 0 ;
44: : eof 2 pick over or 0= IF
45: bye
46: ELSE 2 pick over <>
47: IF forw drop (del) ELSE #bell emit THEN 0
48: THEN ;
49:
50: ' forw ctrl F cells ctrlkeys + !
51: ' back ctrl B cells ctrlkeys + !
52: ' ?del ctrl H cells ctrlkeys + !
53: ' eof ctrl D cells ctrlkeys + !
54:
55: ' (ins) IS insert-char
56:
57: \ history support 16oct94py
58:
59: 0 Value history \ history file fid
60:
61: 2Variable forward^
62: 2Variable backward^
63: 2Variable end^
64:
65: : force-open ( addr len -- fid )
66: 2dup r/w open-file
67: IF
68: drop r/w create-file throw
69: ELSE
70: nip nip
71: THEN ;
72:
73: s" os-class" environment? [IF] s" unix" compare 0= [ELSE] true [THEN]
74: [IF]
75: : history-file ( -- addr u )
76: s" GFORTHHIST" getenv dup 0= IF
77: 2drop s" ~/.gforth-history"
78: THEN ;
79: [ELSE]
80:
81: : history-dir ( -- addr u )
82: s" TMP" getenv ?dup ?EXIT drop
83: s" TEMP" getenv ?dup ?EXIT drop
84: s" c:/" ;
85:
86: : history-file ( -- addr u )
87: s" GFORTHHIST" getenv ?dup ?EXIT
88: drop
89: history-dir pad place
90: s" /ghist.fs" pad +place pad count ;
91: [THEN]
92:
93: \ moving in history file 16oct94py
94:
95: : clear-line ( max span addr pos1 -- max addr )
96: backspaces over spaces swap backspaces ;
97:
98: : clear-tib ( max span addr pos -- max 0 addr 0 false )
99: clear-line 0 tuck dup ;
100:
101: : hist-pos ( -- ud ) history file-position throw ;
102: : hist-setpos ( ud -- ) history reposition-file throw ;
103:
104: : get-line ( addr len -- len' flag )
105: swap history read-line throw ;
106:
107: : next-line ( max span addr pos1 -- max span addr pos2 false )
108: clear-line
109: forward^ 2@ 2dup hist-setpos backward^ 2!
110: 2dup get-line drop
111: hist-pos forward^ 2!
112: tuck 2dup type 0 ;
113:
114: : find-prev-line ( max addr -- max span addr pos2 )
115: backward^ 2@ forward^ 2!
116: over 2 + negate s>d backward^ 2@ d+ 0. dmax 2dup hist-setpos
117: BEGIN
118: backward^ 2! 2dup get-line WHILE
119: hist-pos 2dup forward^ 2@ d< WHILE
120: rot drop
121: REPEAT 2drop THEN tuck ;
122:
123: : prev-line ( max span addr pos1 -- max span addr pos2 false )
124: clear-line find-prev-line 2dup type 0 ;
125:
126: Create lfpad #lf c,
127:
128: : (enter) ( max span addr pos1 -- max span addr pos2 true )
129: >r end^ 2@ hist-setpos
130: 2dup swap history write-line throw
131: hist-pos 2dup backward^ 2! end^ 2!
132: r> (ret) ;
133:
134: \ some other key commands 16oct94py
135:
136: : first-pos ( max span addr pos1 -- max span addr 0 0 )
137: backspaces 0 0 ;
138: : end-pos ( max span addr pos1 -- max span addr span 0 )
139: type-rest 2drop over 0 ;
140:
141: : extract-word ( addr len -- addr' len' ) dup >r
142: BEGIN 1- dup 0>= WHILE 2dup + c@ bl = UNTIL THEN 1+
143: tuck + r> rot - ;
144:
145: Create prefix-found 0 , 0 ,
146:
147: : word-lex ( nfa1 nfa2 -- -1/0/1 )
148: dup 0=
149: IF
150: 2drop 1 EXIT
151: THEN
152: name>string 2>r name>string
153: dup r@ =
154: IF
155: rdrop r> capscomp 0<= EXIT
156: THEN
157: r> <
158: nip rdrop ;
159:
160: : search-voc ( addr len nfa1 nfa2 -- addr len nfa3 )
161: >r
162: BEGIN
163: dup
164: WHILE
165: >r dup r@ name>string nip <=
166: IF
167: 2dup r@ name>string drop capscomp 0=
168: IF
169: r> dup r@ word-lex
170: IF
171: dup prefix-found @ word-lex
172: 0>=
173: IF
174: rdrop dup >r
175: THEN
176: THEN
177: >r
178: THEN
179: THEN
180: r> @
181: REPEAT
182: drop r> ;
183:
184: : prefix-string ( addr len nfa -- addr' len' )
185: dup prefix-found ! ?dup
186: IF
187: name>string rot /string rot drop
188: dup 1+ prefix-found cell+ !
189: ELSE
190: 2drop s" " prefix-found cell+ off
191: THEN ;
192:
193: : search-prefix ( addr1 len1 -- addr2 len2 )
194: 0 vp dup @ 1- cells over +
195: DO I 2@ <>
196: IF I cell+ @ wordlist-id @ swap search-voc THEN
197: [ -1 cells ] Literal +LOOP
198: prefix-string ;
199:
200: : kill-expand ( max span addr pos1 -- max span addr pos2 )
201: prefix-found cell+ @ 0 ?DO (del) LOOP ;
202:
203: : tib-full? ( max span addr pos addr' len' -- max span addr pos addr1 u flag )
204: 5 pick over 4 pick + prefix-found @ 0<> - < ;
205:
206: : tab-expand ( max span addr pos1 -- max span addr pos2 0 )
207: kill-expand 2dup extract-word search-prefix
208: tib-full?
209: IF 7 emit 2drop 0 0 prefix-found 2!
210: ELSE bounds ?DO I c@ (ins) LOOP THEN
211: prefix-found @ IF bl (ins) THEN 0 ;
212:
213: : kill-prefix ( key -- key )
214: dup #tab <> IF 0 0 prefix-found 2! THEN ;
215:
216: ' kill-prefix IS everychar
217:
218: ' next-line ctrl N cells ctrlkeys + !
219: ' prev-line ctrl P cells ctrlkeys + !
220: ' clear-tib ctrl K cells ctrlkeys + !
221: ' first-pos ctrl A cells ctrlkeys + !
222: ' end-pos ctrl E cells ctrlkeys + !
223: ' (enter) #lf cells ctrlkeys + !
224: ' (enter) #cr cells ctrlkeys + !
225: ' tab-expand #tab cells ctrlkeys + !
226:
227: \ initializing history
228:
229: : get-history ( addr len -- )
230: ['] force-open catch
231: ?dup-if
232: \ !! >stderr
233: \ history-file type ." : " .error cr
234: drop 2drop
235: ['] false ['] false ['] (ret)
236: else
237: to history
238: history file-size throw
239: 2dup forward^ 2! 2dup backward^ 2! end^ 2!
240: ['] next-line ['] prev-line ['] (enter)
241: endif
242: dup
243: [ #lf cells ctrlkeys + ]L !
244: [ #cr cells ctrlkeys + ]L !
245: [ ctrl P cells ctrlkeys + ]L !
246: [ ctrl N cells ctrlkeys + ]L !
247: ;
248:
249: : history-cold ( -- )
250: history-file get-history ;
251:
252: ' history-cold INIT8 chained
253: history-cold
254:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to history.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth