1: \ command line edit and history support 16oct94py
2:
3: \ Copyright (C) 1995 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: :noname
22: char [char] @ - ;
23: :noname
24: char [char] @ - postpone Literal ;
25: interpret/compile: ctrl ( "<char>" -- ctrl-code )
26:
27: \ command line editing 16oct94py
28:
29: : >string ( span addr pos1 -- span addr pos1 addr2 len )
30: over 3 pick 2 pick chars /string ;
31: : type-rest ( span addr pos1 -- span addr pos1 back )
32: >string tuck type ;
33: : (del) ( max span addr pos1 -- max span addr pos2 )
34: 1- >string over 1+ -rot move
35: rot 1- -rot #bs emit type-rest bl emit 1+ backspaces ;
36: : (ins) ( max span addr pos1 char -- max span addr pos2 )
37: >r >string over 1+ swap move 2dup chars + r> swap c!
38: rot 1+ -rot type-rest 1- backspaces 1+ ;
39: : ?del ( max span addr pos1 -- max span addr pos2 0 )
40: dup IF (del) THEN 0 ;
41: : (ret) type-rest drop true space ;
42: : back dup IF 1- #bs emit ELSE #bell emit THEN 0 ;
43: : forw 2 pick over <> IF 2dup + c@ emit 1+ ELSE #bell emit THEN 0 ;
44: : eof 2 pick over or 0= IF
45: bye
46: ELSE 2 pick over <>
47: IF forw drop (del) ELSE #bell emit THEN 0
48: THEN ;
49:
50: ' forw ctrl F cells ctrlkeys + !
51: ' back ctrl B cells ctrlkeys + !
52: ' ?del ctrl H cells ctrlkeys + !
53: ' eof ctrl D cells ctrlkeys + !
54:
55: ' (ins) IS insert-char
56:
57: \ history support 16oct94py
58:
59: 0 Value history \ history file fid
60:
61: 2Variable forward^
62: 2Variable backward^
63: 2Variable end^
64:
65: : force-open ( addr len -- fid )
66: 2dup r/w open-file 0<
67: IF drop r/w create-file throw ELSE nip nip THEN ;
68:
69: : get-history ( addr len -- )
70: force-open to history
71: history file-size throw
72: 2dup forward^ 2! 2dup backward^ 2! end^ 2! ;
73:
74: s" GFORTHHIST" getenv dup 0= [IF]
75: 2drop s" ~/.gforth-history"
76: [THEN] get-history
77:
78: : history-cold
79: Defers 'cold
80: s" GFORTHHIST" getenv dup 0= IF
81: 2drop s" ~/.gforth-history"
82: THEN get-history ;
83:
84: ' history-cold IS 'cold
85:
86: \ moving in history file 16oct94py
87:
88: : clear-line ( max span addr pos1 -- max addr )
89: backspaces over spaces swap backspaces ;
90:
91: : clear-tib ( max span addr pos -- max 0 addr 0 false )
92: clear-line 0 tuck dup ;
93:
94: : hist-pos ( -- ud ) history file-position throw ;
95: : hist-setpos ( ud -- ) history reposition-file throw ;
96:
97: : get-line ( addr len -- len' flag )
98: swap history read-line throw ;
99:
100: : next-line ( max span addr pos1 -- max span addr pos2 false )
101: clear-line
102: forward^ 2@ 2dup hist-setpos backward^ 2!
103: 2dup get-line drop
104: hist-pos forward^ 2!
105: tuck 2dup type 0 ;
106:
107: : prev-line ( max span addr pos1 -- max span addr pos2 false )
108: clear-line backward^ 2@ forward^ 2!
109: over 2 + negate s>d backward^ 2@ d+ 0. dmax 2dup hist-setpos
110: BEGIN
111: backward^ 2! 2dup get-line WHILE
112: hist-pos 2dup forward^ 2@ d< WHILE
113: rot drop
114: REPEAT 2drop THEN
115: tuck 2dup type 0 ;
116:
117: Create lfpad #lf c,
118:
119: : (enter) ( max span addr pos1 -- max span addr pos2 true )
120: >r end^ 2@ hist-setpos
121: 2dup swap history write-line throw
122: hist-pos 2dup backward^ 2! end^ 2!
123: r> (ret) ;
124:
125: \ some other key commands 16oct94py
126:
127: : first-pos ( max span addr pos1 -- max span addr 0 0 )
128: backspaces 0 0 ;
129: : end-pos ( max span addr pos1 -- max span addr span 0 )
130: type-rest 2drop over 0 ;
131:
132: : extract-word ( addr len -- addr' len' ) dup >r
133: BEGIN 1- dup 0>= WHILE 2dup + c@ bl = UNTIL THEN 1+
134: tuck + r> rot - ;
135:
136: Create prefix-found 0 , 0 ,
137:
138: : word-lex ( nfa1 nfa2 -- -1/0/1 )
139: dup 0=
140: IF
141: 2drop 1 EXIT
142: THEN
143: name>string 2>r name>string
144: dup r@ =
145: IF
146: rdrop r> capscomp 0<= EXIT
147: THEN
148: r> <
149: nip rdrop ;
150:
151: : search-voc ( addr len nfa1 nfa2 -- addr len nfa3 )
152: >r
153: BEGIN
154: dup
155: WHILE
156: >r dup r@ name>string nip <=
157: IF
158: 2dup r@ name>string drop capscomp 0=
159: IF
160: r> dup r@ word-lex
161: IF
162: dup prefix-found @ word-lex
163: 0>=
164: IF
165: rdrop dup >r
166: THEN
167: THEN
168: >r
169: THEN
170: THEN
171: r> @
172: REPEAT
173: drop r> ;
174:
175: : prefix-string ( addr len nfa -- addr' len' )
176: dup prefix-found ! ?dup
177: IF
178: name>string rot /string rot drop
179: dup 1+ prefix-found cell+ !
180: ELSE
181: 2drop s" " prefix-found cell+ off
182: THEN ;
183:
184: : search-prefix ( addr1 len1 -- addr2 len2 )
185: 0 vp dup @ 1- cells over +
186: DO I 2@ <>
187: IF I cell+ @ @ swap search-voc THEN
188: [ -1 cells ] Literal +LOOP
189: prefix-string ;
190:
191: : kill-expand ( max span addr pos1 -- max span addr pos2 )
192: prefix-found cell+ @ 0 ?DO (del) LOOP ;
193:
194: : tib-full? ( max span addr pos addr' len' -- max span addr pos addr1 u flag )
195: 5 pick over 4 pick + prefix-found @ 0<> - < ;
196:
197: : tab-expand ( max span addr pos1 -- max span addr pos2 0 )
198: kill-expand 2dup extract-word search-prefix
199: tib-full?
200: IF 7 emit 2drop 0 0 prefix-found 2!
201: ELSE bounds ?DO I c@ (ins) LOOP THEN
202: prefix-found @ IF bl (ins) THEN 0 ;
203:
204: : kill-prefix ( key -- key )
205: dup #tab <> IF 0 0 prefix-found 2! THEN ;
206:
207: ' kill-prefix IS everychar
208:
209: ' next-line ctrl N cells ctrlkeys + !
210: ' prev-line ctrl P cells ctrlkeys + !
211: ' clear-tib ctrl K cells ctrlkeys + !
212: ' first-pos ctrl A cells ctrlkeys + !
213: ' end-pos ctrl E cells ctrlkeys + !
214: ' (enter) #lf cells ctrlkeys + !
215: ' (enter) #cr cells ctrlkeys + !
216: ' tab-expand #tab cells ctrlkeys + !
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to history.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth