Return to glocals.fs CVS log

Up to [gforth] / gforth

New "docclean" target for makefile (removes glossary dependencies when
rebuilding documentation). Changes to .fs files and prim are restricted
to glossary (\G) additions for the documentation; this has necessitated
the addition of new white-space in places to stop the \G stuff from
obscuring the code. Many additions to doc/gforth.ds - new sections
added, a few things moved and some sections re-written slightly. There
are a set of things to tidy up before this rev. is suitable for
release, and those will be my highest priority. I have also used
"@comment TODO" to highlight other sections I plan to work on, and
added a set of comments at the start to indicate other things I plan
to modify in the medium-term.

    1: \ A powerful locals implementation
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: 
   22: \ More documentation can be found in the manual and in
   23: \ http://www.complang.tuwien.ac.at/papers/ertl94l.ps.gz
   24: 
   25: \ Local variables are quite important for writing readable programs, but
   26: \ IMO (anton) they are the worst part of the standard. There they are very
   27: \ restricted and have an ugly interface.
   28: 
   29: \ So, we implement the locals wordset, but do not recommend using
   30: \ locals-ext (which is a really bad user interface for locals).
   31: 
   32: \ We also have a nice and powerful user-interface for locals: locals are
   33: \ defined with
   34: 
   35: \ { local1 local2 ... }
   36: \ or
   37: \ { local1 local2 ... -- ... }
   38: \ (anything after the -- is just a comment)
   39: 
   40: \ Every local in this list consists of an optional type specification
   41: \ and a name. If there is only the name, it stands for a cell-sized
   42: \ value (i.e., you get the value of the local variable, not it's
   43: \ address). The following type specifiers stand before the name:
   44: 
   45: \ Specifier	Type	Access
   46: \ W:		Cell	value
   47: \ W^		Cell	address
   48: \ D:		Double	value
   49: \ D^		Double	address
   50: \ F:		Float	value
   51: \ F^		Float	address
   52: \ C:		Char	value
   53: \ C^		Char	address
   54: 
   55: \ The local variables are initialized with values from the appropriate
   56: \ stack. In contrast to the examples in the standard document our locals
   57: \ take the arguments in the expected way: The last local gets the top of
   58: \ stack, the second last gets the second stack item etc. An example:
   59: 
   60: \ : CX* { F: Ar  F: Ai  F: Br  F: Bi -- Cr Ci }
   61: \ \ complex multiplication
   62: \  Ar Br f* Ai Bi f* f-
   63: \  Ar Bi f* Ai Br f* f+ ;
   64: 
   65: \ There will also be a way to add user types, but it is not yet decided,
   66: \ how. Ideas are welcome.
   67: 
   68: \ Locals defined in this manner live until (!! see below). 
   69: \ Their names can be used during this time to get
   70: \ their value or address; The addresses produced in this way become
   71: \ invalid at the end of the lifetime.
   72: 
   73: \ Values can be changed with TO, but this is not recomended (TO is a
   74: \ kludge and words lose the single-assignment property, which makes them
   75: \ harder to analyse).
   76: 
   77: \ As for the internals, we use a special locals stack. This eliminates
   78: \ the problems and restrictions of reusing the return stack and allows
   79: \ to store floats as locals: the return stack is not guaranteed to be
   80: \ aligned correctly, but our locals stack must be float-aligned between
   81: \ words.
   82: 
   83: \ Other things about the internals are pretty unclear now.
   84: 
   85: \ Currently locals may only be
   86: \ defined at the outer level and TO is not supported.
   87: 
   88: require search.fs
   89: require float.fs
   90: 
   91: : compile-@local ( n -- ) \ gforth compile-fetch-local
   92:  case
   93:     0       of postpone @local0 endof
   94:     1 cells of postpone @local1 endof
   95:     2 cells of postpone @local2 endof
   96:     3 cells of postpone @local3 endof
   97:    ( otherwise ) dup postpone @local# ,
   98:  endcase ;
   99: 
  100: : compile-f@local ( n -- ) \ gforth compile-f-fetch-local
  101:  case
  102:     0        of postpone f@local0 endof
  103:     1 floats of postpone f@local1 endof
  104:    ( otherwise ) dup postpone f@local# ,
  105:  endcase ;
  106: 
  107: \ locals stuff needed for control structures
  108: 
  109: : compile-lp+! ( n -- ) \ gforth	compile-l-p-plus-store
  110:     dup negate locals-size +!
  111:     0 over = if
  112:     else -1 cells  over = if postpone lp-
  113:     else  1 floats over = if postpone lp+
  114:     else  2 floats over = if postpone lp+2
  115:     else postpone lp+!# dup ,
  116:     then then then then drop ;
  117: 
  118: : adjust-locals-size ( n -- ) \ gforth
  119:     \ sets locals-size to n and generates an appropriate lp+!
  120:     locals-size @ swap - compile-lp+! ;
  121: 
  122: \ the locals stack grows downwards (see primitives)
  123: \ of the local variables of a group (in braces) the leftmost is on top,
  124: \ i.e. by going onto the locals stack the order is reversed.
  125: \ there are alignment gaps if necessary.
  126: \ lp must have the strictest alignment (usually float) across calls;
  127: \ for simplicity we align it strictly for every group.
  128: 
  129: slowvoc @
  130: slowvoc on \ we want a linked list for the vocabulary locals
  131: vocabulary locals \ this contains the local variables
  132: ' locals >body wordlist-id ' locals-list >body !
  133: slowvoc !
  134: 
  135: create locals-buffer 1000 allot \ !! limited and unsafe
  136:     \ here the names of the local variables are stored
  137:     \ we would have problems storing them at the normal dp
  138: 
  139: variable locals-dp \ so here's the special dp for locals.
  140: 
  141: : alignlp-w ( n1 -- n2 )
  142:     \ cell-align size and generate the corresponding code for aligning lp
  143:     aligned dup adjust-locals-size ;
  144: 
  145: : alignlp-f ( n1 -- n2 )
  146:     faligned dup adjust-locals-size ;
  147: 
  148: \ a local declaration group (the braces stuff) is compiled by calling
  149: \ the appropriate compile-pushlocal for the locals, starting with the
  150: \ righmost local; the names are already created earlier, the
  151: \ compile-pushlocal just inserts the offsets from the frame base.
  152: 
  153: : compile-pushlocal-w ( a-addr -- ) ( run-time: w -- )
  154: \ compiles a push of a local variable, and adjusts locals-size
  155: \ stores the offset of the local variable to a-addr
  156:     locals-size @ alignlp-w cell+ dup locals-size !
  157:     swap !
  158:     postpone >l ;
  159: 
  160: \ locals list operations
  161: 
  162: : common-list ( list1 list2 -- list3 ) \ gforth-internal
  163: \ list1 and list2 are lists, where the heads are at higher addresses than
  164: \ the tail. list3 is the largest sublist of both lists.
  165:  begin
  166:    2dup u<>
  167:  while
  168:    2dup u>
  169:    if
  170:      swap
  171:    then
  172:    @
  173:  repeat
  174:  drop ;
  175: 
  176: : sub-list? ( list1 list2 -- f ) \ gforth-internal
  177: \ true iff list1 is a sublist of list2
  178:  begin
  179:    2dup u<
  180:  while
  181:    @
  182:  repeat
  183:  = ;
  184: 
  185: : list-size ( list -- u ) \ gforth-internal
  186:     \ size of the locals frame represented by list
  187:     0 ( list n )
  188:     begin
  189: 	over 0<>
  190:     while
  191: 	over
  192: 	((name>)) >body @ max
  193: 	swap @ swap ( get next )
  194:     repeat
  195:     faligned nip ;
  196: 
  197: : set-locals-size-list ( list -- )
  198:     dup locals-list !
  199:     list-size locals-size ! ;
  200: 
  201: : check-begin ( list -- )
  202: \ warn if list is not a sublist of locals-list
  203:  locals-list @ sub-list? 0= if
  204:    \ !! print current position
  205:    ." compiler was overly optimistic about locals at a BEGIN" cr
  206:    \ !! print assumption and reality
  207:  then ;
  208: 
  209: : compile-pushlocal-f ( a-addr -- ) ( run-time: f -- )
  210:     locals-size @ alignlp-f float+ dup locals-size !
  211:     swap !
  212:     postpone f>l ;
  213: 
  214: : compile-pushlocal-d ( a-addr -- ) ( run-time: w1 w2 -- )
  215:     locals-size @ alignlp-w cell+ cell+ dup locals-size !
  216:     swap !
  217:     postpone swap postpone >l postpone >l ;
  218: 
  219: : compile-pushlocal-c ( a-addr -- ) ( run-time: w -- )
  220:     -1 chars compile-lp+!
  221:     locals-size @ swap !
  222:     postpone lp@ postpone c! ;
  223: 
  224: : create-local ( " name" -- a-addr )
  225:     \ defines the local "name"; the offset of the local shall be
  226:     \ stored in a-addr
  227:     create
  228: 	immediate restrict
  229: 	here 0 , ( place for the offset ) ;
  230: 
  231: : lp-offset ( n1 -- n2 )
  232: \ converts the offset from the frame start to an offset from lp and
  233: \ i.e., the address of the local is lp+locals_size-offset
  234:   locals-size @ swap - ;
  235: 
  236: : lp-offset, ( n -- )
  237: \ converts the offset from the frame start to an offset from lp and
  238: \ adds it as inline argument to a preceding locals primitive
  239:   lp-offset , ;
  240: 
  241: vocabulary locals-types \ this contains all the type specifyers, -- and }
  242: locals-types definitions
  243: 
  244: : W: ( "name" -- a-addr xt ) \ gforth w-colon
  245:     create-local
  246: 	\ xt produces the appropriate locals pushing code when executed
  247: 	['] compile-pushlocal-w
  248:     does> ( Compilation: -- ) ( Run-time: -- w )
  249:         \ compiles a local variable access
  250: 	@ lp-offset compile-@local ;
  251: 
  252: : W^ ( "name" -- a-addr xt ) \ gforth w-caret
  253:     create-local
  254: 	['] compile-pushlocal-w
  255:     does> ( Compilation: -- ) ( Run-time: -- w )
  256: 	postpone laddr# @ lp-offset, ;
  257: 
  258: : F: ( "name" -- a-addr xt ) \ gforth f-colon
  259:     create-local
  260: 	['] compile-pushlocal-f
  261:     does> ( Compilation: -- ) ( Run-time: -- w )
  262: 	@ lp-offset compile-f@local ;
  263: 
  264: : F^ ( "name" -- a-addr xt ) \ gforth f-caret
  265:     create-local
  266: 	['] compile-pushlocal-f
  267:     does> ( Compilation: -- ) ( Run-time: -- w )
  268: 	postpone laddr# @ lp-offset, ;
  269: 
  270: : D: ( "name" -- a-addr xt ) \ gforth d-colon
  271:     create-local
  272: 	['] compile-pushlocal-d
  273:     does> ( Compilation: -- ) ( Run-time: -- w )
  274: 	postpone laddr# @ lp-offset, postpone 2@ ;
  275: 
  276: : D^ ( "name" -- a-addr xt ) \ gforth d-caret
  277:     create-local
  278: 	['] compile-pushlocal-d
  279:     does> ( Compilation: -- ) ( Run-time: -- w )
  280: 	postpone laddr# @ lp-offset, ;
  281: 
  282: : C: ( "name" -- a-addr xt ) \ gforth c-colon
  283:     create-local
  284: 	['] compile-pushlocal-c
  285:     does> ( Compilation: -- ) ( Run-time: -- w )
  286: 	postpone laddr# @ lp-offset, postpone c@ ;
  287: 
  288: : C^ ( "name" -- a-addr xt ) \ gforth c-caret
  289:     create-local
  290: 	['] compile-pushlocal-c
  291:     does> ( Compilation: -- ) ( Run-time: -- w )
  292: 	postpone laddr# @ lp-offset, ;
  293: 
  294: \ you may want to make comments in a locals definitions group:
  295: ' \ alias \ ( -- ) \ core-ext,block-ext backslash
  296: \G Line comment: if @code{BLK} contains 0, parse and discard the remainder
  297: \G of the parse area. Otherwise, parse and discard all subsequent characters in the
  298: \G parse area corresponding to the current line.
  299: immediate 
  300: 
  301: ' ( alias ( ( compilation 'ccc<close-paren>' -- ; run-time -- ) \ core,file	paren
  302: \G Comment: parse and discard all subsequent characters in the parse
  303: \G area until ")" is encountered. During interactive input, an end-of-line
  304: \G also acts as a comment terminator. For file input, it does not; if the
  305: \G end-of-file is encountered whilst parsing for the ")" delimiter, Gforth
  306: \G will generate a warning.
  307: immediate
  308: 
  309: forth definitions
  310: 
  311: \ the following gymnastics are for declaring locals without type specifier.
  312: \ we exploit a feature of our dictionary: every wordlist
  313: \ has it's own methods for finding words etc.
  314: \ So we create a vocabulary new-locals, that creates a 'w:' local named x
  315: \ when it is asked if it contains x.
  316: 
  317: also locals-types
  318: 
  319: : new-locals-find ( caddr u w -- nfa )
  320: \ this is the find method of the new-locals vocabulary
  321: \ make a new local with name caddr u; w is ignored
  322: \ the returned nfa denotes a word that produces what W: produces
  323: \ !! do the whole thing without nextname
  324:     drop nextname
  325:     ['] W: >name ;
  326: 
  327: previous
  328: 
  329: : new-locals-reveal ( -- )
  330:   true abort" this should not happen: new-locals-reveal" ;
  331: 
  332: create new-locals-map ( -- wordlist-map )
  333: ' new-locals-find A,
  334: ' new-locals-reveal A,
  335: ' drop A, \ rehash method
  336: ' drop A,
  337: 
  338: slowvoc @
  339: slowvoc on
  340: vocabulary new-locals
  341: slowvoc !
  342: new-locals-map ' new-locals >body wordlist-map A! \ !! use special access words
  343: 
  344: variable old-dpp
  345: 
  346: \ and now, finally, the user interface words
  347: : { ( -- lastxt wid 0 ) \ gforth open-brace
  348:     dp old-dpp !
  349:     locals-dp dpp !
  350:     lastxt get-current
  351:     also new-locals
  352:     also locals definitions locals-types
  353:     0 TO locals-wordlist
  354:     0 postpone [ ; immediate
  355: 
  356: locals-types definitions
  357: 
  358: : } ( lastxt wid 0 a-addr1 xt1 ... -- ) \ gforth close-brace
  359:     \ ends locals definitions
  360:     ] old-dpp @ dpp !
  361:     begin
  362: 	dup
  363:     while
  364: 	execute
  365:     repeat
  366:     drop
  367:     locals-size @ alignlp-f locals-size ! \ the strictest alignment
  368:     previous previous
  369:     set-current lastcfa !
  370:     locals-list 0 wordlist-id - TO locals-wordlist ;
  371: 
  372: : -- ( addr wid 0 ... -- ) \ gforth dash-dash
  373:     }
  374:     [char] } parse 2drop ;
  375: 
  376: forth definitions
  377: 
  378: \ A few thoughts on automatic scopes for locals and how they can be
  379: \ implemented:
  380: 
  381: \ We have to combine locals with the control structures. My basic idea
  382: \ was to start the life of a local at the declaration point. The life
  383: \ would end at any control flow join (THEN, BEGIN etc.) where the local
  384: \ is lot live on both input flows (note that the local can still live in
  385: \ other, later parts of the control flow). This would make a local live
  386: \ as long as you expected and sometimes longer (e.g. a local declared in
  387: \ a BEGIN..UNTIL loop would still live after the UNTIL).
  388: 
  389: \ The following example illustrates the problems of this approach:
  390: 
  391: \ { z }
  392: \ if
  393: \   { x }
  394: \ begin
  395: \   { y }
  396: \ [ 1 cs-roll ] then
  397: \   ...
  398: \ until
  399: 
  400: \ x lives only until the BEGIN, but the compiler does not know this
  401: \ until it compiles the UNTIL (it can deduce it at the THEN, because at
  402: \ that point x lives in no thread, but that does not help much). This is
  403: \ solved by optimistically assuming at the BEGIN that x lives, but
  404: \ warning at the UNTIL that it does not. The user is then responsible
  405: \ for checking that x is only used where it lives.
  406: 
  407: \ The produced code might look like this (leaving out alignment code):
  408: 
  409: \ >l ( z )
  410: \ ?branch <then>
  411: \ >l ( x )
  412: \ <begin>:
  413: \ >l ( y )
  414: \ lp+!# 8 ( RIP: x,y )
  415: \ <then>:
  416: \ ...
  417: \ lp+!# -4 ( adjust lp to <begin> state )
  418: \ ?branch <begin>
  419: \ lp+!# 4 ( undo adjust )
  420: 
  421: \ The BEGIN problem also has another incarnation:
  422: 
  423: \ AHEAD
  424: \ BEGIN
  425: \   x
  426: \ [ 1 CS-ROLL ] THEN
  427: \   { x }
  428: \   ...
  429: \ UNTIL
  430: 
  431: \ should be legal: The BEGIN is not a control flow join in this case,
  432: \ since it cannot be entered from the top; therefore the definition of x
  433: \ dominates the use. But the compiler processes the use first, and since
  434: \ it does not look ahead to notice the definition, it will complain
  435: \ about it. Here's another variation of this problem:
  436: 
  437: \ IF
  438: \   { x }
  439: \ ELSE
  440: \   ...
  441: \ AHEAD
  442: \ BEGIN
  443: \   x
  444: \ [ 2 CS-ROLL ] THEN
  445: \   ...
  446: \ UNTIL
  447: 
  448: \ In this case x is defined before the use, and the definition dominates
  449: \ the use, but the compiler does not know this until it processes the
  450: \ UNTIL. So what should the compiler assume does live at the BEGIN, if
  451: \ the BEGIN is not a control flow join? The safest assumption would be
  452: \ the intersection of all locals lists on the control flow
  453: \ stack. However, our compiler assumes that the same variables are live
  454: \ as on the top of the control flow stack. This covers the following case:
  455: 
  456: \ { x }
  457: \ AHEAD
  458: \ BEGIN
  459: \   x
  460: \ [ 1 CS-ROLL ] THEN
  461: \   ...
  462: \ UNTIL
  463: 
  464: \ If this assumption is too optimistic, the compiler will warn the user.
  465: 
  466: \ Implementation:
  467: 
  468: \ explicit scoping
  469: 
  470: : scope ( compilation  -- scope ; run-time  -- ) \ gforth
  471:     cs-push-part scopestart ; immediate
  472: 
  473: : adjust-locals-list ( wid -- )
  474:     locals-list @ common-list
  475:     dup list-size adjust-locals-size
  476:     locals-list ! ;
  477: 
  478: : endscope ( compilation scope -- ; run-time  -- ) \ gforth
  479:     scope?
  480:     drop  adjust-locals-list ; immediate
  481: 
  482: \ adapt the hooks
  483: 
  484: : locals-:-hook ( sys -- sys addr xt n )
  485:     \ addr is the nfa of the defined word, xt its xt
  486:     DEFERS :-hook
  487:     last @ lastcfa @
  488:     clear-leave-stack
  489:     0 locals-size !
  490:     locals-buffer locals-dp !
  491:     0 locals-list !
  492:     dead-code off
  493:     defstart ;
  494: 
  495: : locals-;-hook ( sys addr xt sys -- sys )
  496:     def?
  497:     0 TO locals-wordlist
  498:     0 adjust-locals-size ( not every def ends with an exit )
  499:     lastcfa ! last !
  500:     DEFERS ;-hook ;
  501: 
  502: \ THEN (another control flow from before joins the current one):
  503: \ The new locals-list is the intersection of the current locals-list and
  504: \ the orig-local-list. The new locals-size is the (alignment-adjusted)
  505: \ size of the new locals-list. The following code is generated:
  506: \ lp+!# (current-locals-size - orig-locals-size)
  507: \ <then>:
  508: \ lp+!# (orig-locals-size - new-locals-size)
  509: 
  510: \ Of course "lp+!# 0" is not generated. Still this is admittedly a bit
  511: \ inefficient, e.g. if there is a locals declaration between IF and
  512: \ ELSE. However, if ELSE generates an appropriate "lp+!#" before the
  513: \ branch, there will be none after the target <then>.
  514: 
  515: : (then-like) ( orig -- )
  516:     dead-orig =
  517:     if
  518: 	>resolve drop
  519:     else
  520:         dead-code @
  521:         if
  522: 	    >resolve set-locals-size-list dead-code off
  523: 	else \ both live
  524: 	    over list-size adjust-locals-size
  525: 	    >resolve
  526: 	    adjust-locals-list
  527: 	then
  528:     then ;
  529: 
  530: : (begin-like) ( -- )
  531:     dead-code @ if
  532: 	\ set up an assumption of the locals visible here.  if the
  533: 	\ users want something to be visible, they have to declare
  534: 	\ that using ASSUME-LIVE
  535: 	backedge-locals @ set-locals-size-list
  536:     then
  537:     dead-code off ;
  538: 
  539: \ AGAIN (the current control flow joins another, earlier one):
  540: \ If the dest-locals-list is not a subset of the current locals-list,
  541: \ issue a warning (see below). The following code is generated:
  542: \ lp+!# (current-local-size - dest-locals-size)
  543: \ branch <begin>
  544: 
  545: : (again-like) ( dest -- addr )
  546:     over list-size adjust-locals-size
  547:     swap check-begin  POSTPONE unreachable ;
  548: 
  549: \ UNTIL (the current control flow may join an earlier one or continue):
  550: \ Similar to AGAIN. The new locals-list and locals-size are the current
  551: \ ones. The following code is generated:
  552: \ ?branch-lp+!# <begin> (current-local-size - dest-locals-size)
  553: 
  554: : (until-like) ( list addr xt1 xt2 -- )
  555:     \ list and addr are a fragment of a cs-item
  556:     \ xt1 is the conditional branch without lp adjustment, xt2 is with
  557:     >r >r
  558:     locals-size @ 2 pick list-size - dup if ( list dest-addr adjustment )
  559: 	r> drop r> compile,
  560: 	swap <resolve ( list adjustment ) ,
  561:     else ( list dest-addr adjustment )
  562: 	drop
  563: 	r> compile, <resolve
  564: 	r> drop
  565:     then ( list )
  566:     check-begin ;
  567: 
  568: : (exit-like) ( -- )
  569:     0 adjust-locals-size ;
  570: 
  571: ' locals-:-hook IS :-hook
  572: ' locals-;-hook IS ;-hook
  573: 
  574: ' (then-like)  IS then-like
  575: ' (begin-like) IS begin-like
  576: ' (again-like) IS again-like
  577: ' (until-like) IS until-like
  578: ' (exit-like)  IS exit-like
  579: 
  580: \ The words in the locals dictionary space are not deleted until the end
  581: \ of the current word. This is a bit too conservative, but very simple.
  582: 
  583: \ There are a few cases to consider: (see above)
  584: 
  585: \ after AGAIN, AHEAD, EXIT (the current control flow is dead):
  586: \ We have to special-case the above cases against that. In this case the
  587: \ things above are not control flow joins. Everything should be taken
  588: \ over from the live flow. No lp+!# is generated.
  589: 
  590: \ About warning against uses of dead locals. There are several options:
  591: 
  592: \ 1) Do not complain (After all, this is Forth;-)
  593: 
  594: \ 2) Additional restrictions can be imposed so that the situation cannot
  595: \ arise; the programmer would have to introduce explicit scoping
  596: \ declarations in cases like the above one. I.e., complain if there are
  597: \ locals that are live before the BEGIN but not before the corresponding
  598: \ AGAIN (replace DO etc. for BEGIN and UNTIL etc. for AGAIN).
  599: 
  600: \ 3) The real thing: i.e. complain, iff a local lives at a BEGIN, is
  601: \ used on a path starting at the BEGIN, and does not live at the
  602: \ corresponding AGAIN. This is somewhat hard to implement. a) How does
  603: \ the compiler know when it is working on a path starting at a BEGIN
  604: \ (consider "{ x } if begin [ 1 cs-roll ] else x endif again")? b) How
  605: \ is the usage info stored?
  606: 
  607: \ For now I'll resort to alternative 2. When it produces warnings they
  608: \ will often be spurious, but warnings should be rare. And better
  609: \ spurious warnings now and then than days of bug-searching.
  610: 
  611: \ Explicit scoping of locals is implemented by cs-pushing the current
  612: \ locals-list and -size (and an unused cell, to make the size equal to
  613: \ the other entries) at the start of the scope, and restoring them at
  614: \ the end of the scope to the intersection, like THEN does.
  615: 
  616: 
  617: \ And here's finally the ANS standard stuff
  618: 
  619: : (local) ( addr u -- ) \ local paren-local-paren
  620:     \ a little space-inefficient, but well deserved ;-)
  621:     \ In exchange, there are no restrictions whatsoever on using (local)
  622:     \ as long as you use it in a definition
  623:     dup
  624:     if
  625: 	nextname POSTPONE { [ also locals-types ] W: } [ previous ]
  626:     else
  627: 	2drop
  628:     endif ;
  629: 
  630: : >definer ( xt -- definer )
  631:     \ this gives a unique identifier for the way the xt was defined
  632:     \ words defined with different does>-codes have different definers
  633:     \ the definer can be used for comparison and in definer!
  634:     dup >does-code
  635:     ?dup-if
  636: 	nip 1 or
  637:     else
  638: 	>code-address
  639:     then ;
  640: 
  641: : definer! ( definer xt -- )
  642:     \ gives the word represented by xt the behaviour associated with definer
  643:     over 1 and if
  644: 	swap [ 1 invert ] literal and does-code!
  645:     else
  646: 	code-address!
  647:     then ;
  648: 
  649: :noname
  650:     ' dup >definer [ ' locals-wordlist ] literal >definer =
  651:     if
  652: 	>body !
  653:     else
  654: 	-&32 throw
  655:     endif ;
  656: :noname
  657:     0 0 0. 0.0e0 { c: clocal w: wlocal d: dlocal f: flocal }
  658:     comp' drop dup >definer
  659:     case
  660: 	[ ' locals-wordlist ] literal >definer \ value
  661: 	OF >body POSTPONE Aliteral POSTPONE ! ENDOF
  662: 	\ !! dependent on c: etc. being does>-defining words
  663: 	\ this works, because >definer uses >does-code in this case,
  664: 	\ which produces a relocatable address
  665: 	[ comp' clocal drop >definer ] literal
  666: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE c! ENDOF
  667: 	[ comp' wlocal drop >definer ] literal
  668: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE ! ENDOF
  669: 	[ comp' dlocal drop >definer ] literal
  670: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE 2! ENDOF
  671: 	[ comp' flocal drop >definer ] literal
  672: 	OF POSTPONE laddr# >body @ lp-offset, POSTPONE f! ENDOF
  673: 	-&32 throw
  674:     endcase ;
  675: interpret/compile: TO ( c|w|d|r "name" -- ) \ core-ext,local
  676: 
  677: : locals|
  678:     \ don't use 'locals|'! use '{'! A portable and free '{'
  679:     \ implementation is compat/anslocals.fs
  680:     BEGIN
  681: 	name 2dup s" |" compare 0<>
  682:     WHILE
  683: 	(local)
  684:     REPEAT
  685:     drop 0 (local) ; immediate restrict