1: \ High level floating point 14jan94py
2:
3: \ Copyright (C) 1995,1997 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: \ 1 cells 4 = [IF]
22: \ ' cells Alias sfloats
23: \ ' cell+ Alias sfloat+
24: \ ' align Alias sfalign
25: \ ' aligned Alias sfaligned
26: \ [ELSE]
27: \ : sfloats 2* 2* ;
28: \ : sfloat+ 4 + ;
29: \ : sfaligned ( addr -- addr' ) 3 + -4 and ;
30: \ : sfalign ( -- ) here dup sfaligned swap ?DO bl c, LOOP ;
31: \ [THEN]
32:
33: \ 1 floats 8 = [IF]
34: \ ' floats Alias dfloats
35: \ ' float+ Alias dfloat+
36: \ ' falign Alias dfalign
37: \ ' faligned Alias dfaligned
38: \ [ELSE]
39: \ : dfloats 2* 2* 2* ;
40: \ : dfloat+ 8 + ;
41: \ : dfaligned ( addr -- addr' ) 7 + -8 and ;
42: \ : dfalign ( -- ) here dup dfaligned swap ?DO bl c, LOOP ;
43: \ [THEN]
44:
45: : sfalign ( -- ) \ float-ext s-f-align
46: \G If the data-space pointer is not single-float-aligned, reserve
47: \G enough space to align it.
48: here dup sfaligned swap ?DO bl c, LOOP ;
49: : dfalign ( -- ) \ float-ext d-f-align
50: \G If the data-space pointer is not double-float-aligned, reserve
51: \G enough space to align it.
52: here dup dfaligned swap ?DO bl c, LOOP ;
53:
54: 1 sfloats (Field) sfloat+ , ( sf-addr1 -- sf-addr2 ) \ float-ext s-float-plus
55: \G Increment @i{sf-addr1} by the number of address units corresponding to the size of
56: \G a single-precision IEEE floating-point number, to give @i{sf-addr2}.""
57:
58: 1 dfloats (Field) dfloat+ , ( df-addr1 -- df-addr2 ) \ float-ext d-float-plus
59: \G Increment @i{df-addr1} by the number of address units corresponding to the size of
60: \G a double-precision IEEE floating-point number, to give @i{df-addr2}.""
61:
62: : f, ( f -- ) \ gforth
63: \G Reserve data space for one floating-point number and store
64: \G @i{f} in the space.
65: here 1 floats allot f! ;
66:
67: : fconstant ( r "name" -- ) \ float f-constant
68: Create f,
69: DOES> ( -- r )
70: f@ ;
71:
72: : fdepth ( -- +n ) \ float f-depth
73: \G @i{+n} is the current number of (floating-point) values on the
74: \G floating-point stack.
75: fp0 @ fp@ - [ 1 floats ] Literal / ;
76:
77: : FLit ( -- r ) r> dup f@ float+ >r ;
78: : FLiteral ( compilation r -- ; run-time -- r ) \ float f-literal
79: \G Compile appropriate code such that, at run-time, @i{r} is placed
80: \G on the (floating-point) stack. Interpretation semantics are undefined.
81: BEGIN here cell+ dup faligned <> WHILE postpone noop REPEAT
82: postpone FLit f, ; immediate
83:
84: &15 Value precision ( -- u ) \ float-ext
85: \G @i{u} is the number of significant digits currently used by
86: \G @code{F.} @code{FE.} and @code{FS.}
87: : set-precision ( u -- ) \ float-ext
88: \G Set the number of significant digits currently used by
89: \G @code{F.} @code{FE.} and @code{FS.} to @i{u}.
90: to precision ;
91:
92: : scratch ( r -- addr len )
93: pad precision - precision ;
94:
95: : zeros ( n -- ) 0 max 0 ?DO '0 emit LOOP ;
96:
97: : -zeros ( addr u -- addr' u' )
98: BEGIN dup WHILE 1- 2dup + c@ '0 <> UNTIL 1+ THEN ;
99:
100: : f$ ( f -- n ) scratch represent 0=
101: IF 2drop scratch 3 min type rdrop EXIT THEN
102: IF '- emit THEN ;
103:
104: : f. ( r -- ) \ float-ext f-dot
105: \G Display (the floating-point number) @i{r} using fixed-point notation,
106: \G followed by a space.
107: f$ dup >r 0<
108: IF '0 emit
109: ELSE scratch r@ min type r@ precision - zeros THEN
110: '. emit r@ negate zeros
111: scratch r> 0 max /string 0 max -zeros type space ;
112: \ I'm afraid this does not really implement ansi semantics wrt precision.
113: \ Shouldn't precision indicate the number of places shown after the point?
114:
115: : fe. ( r -- ) \ float-ext f-e-dot
116: \G Display @i{r} using engineering notation, followed by a space.
117: f$ 1- s>d 3 fm/mod 3 * >r 1+ >r
118: scratch r@ min type '. emit scratch r> /string type
119: 'E emit r> . ;
120:
121: : fs. ( r -- ) \ float-ext f-s-dot
122: \G Display @i{r} using scientific notation, followed by a space.
123: f$ 1-
124: scratch over c@ emit '. emit 1 /string type
125: 'E emit . ;
126:
127: require debugs.fs
128:
129: : sfnumber ( c-addr u -- r true | false )
130: 2dup [CHAR] e scan ( c-addr u c-addr2 u2 )
131: dup 0=
132: IF
133: 2drop 2dup [CHAR] E scan ( c-addr u c-addr3 u3 )
134: THEN
135: nip
136: IF
137: >float
138: ELSE
139: 2drop false
140: THEN ;
141:
142: :noname ( c-addr u -- )
143: 2dup sfnumber
144: IF
145: 2drop POSTPONE FLiteral
146: ELSE
147: defers compiler-notfound
148: ENDIF ;
149: IS compiler-notfound
150:
151: :noname ( c-addr u -- r )
152: 2dup sfnumber
153: IF
154: 2drop
155: ELSE
156: defers interpreter-notfound
157: ENDIF ;
158: IS interpreter-notfound
159:
160: : fvariable ( "name" -- ) \ float f-variable
161: Create 0.0E0 f, ;
162: \ does> ( -- f-addr )
163:
164: 1.0e0 fasin 2.0e0 f* fconstant pi ( -- r ) \ gforth
165: \G @code{Fconstant} -- @i{r} is the value pi; the ratio of a circle's area
166: \G to its diameter.
167:
168: : f2* ( r1 -- r2 ) \ gforth
169: \G Multiply @i{r1} by 2.0e0
170: 2.0e0 f* ;
171:
172: : f2/ ( r1 -- r2 ) \ gforth
173: \G Multiply @i{r1} by 0.5e0
174: 0.5e0 f* ;
175:
176: : 1/f ( r1 -- r2 ) \ gforth
177: \G Divide 1.0e0 by @i{r1}.
178: 1.0e0 fswap f/ ;
179:
180:
181: \ We now have primitives for these, so we need not define them
182:
183: \ : falog ( f -- 10^f ) [ 10.0e0 fln ] FLiteral f* fexp ;
184:
185: \ : fsinh fexpm1 fdup fdup 1.0e0 f+ f/ f+ f2/ ;
186: \ : fcosh fexp fdup 1/f f+ f2/ ;
187: \ : ftanh f2* fexpm1 fdup 2.0e0 f+ f/ ;
188:
189: \ : fatanh fdup f0< >r fabs 1.0e0 fover f- f/ f2* flnp1 f2/
190: \ r> IF fnegate THEN ;
191: \ : facosh fdup fdup f* 1.0e0 f- fsqrt f+ fln ;
192: \ : fasinh fdup fdup f* 1.0e0 f+ fsqrt f/ fatanh ;
193:
194: : f~abs ( r1 r2 r3 -- flag ) \ gforth
195: \G Approximate equality with absolute error: |r1-r2|<r3.
196: frot frot f- fabs fswap f< ;
197:
198: : f~rel ( r1 r2 r3 -- flag ) \ gforth
199: \G Approximate equality with relative error: |r1-r2|<r3*|r1+r2|.
200: frot frot fover fabs fover fabs f+ frot frot
201: f- fabs frot frot f* f< ;
202:
203: : f~ ( r1 r2 r3 -- flag ) \ float-ext f-proximate
204: \G ANS Forth medley: r3>0: @code{f~abs}; r3=0: r1=r2; r3<0: @code{fnegate f~rel}.
205: fdup f0=
206: IF
207: fdrop f= \ !! this does not work, because 0=-0 with f= on Linux-Intel
208: \ the standard says they should compare unequal
209: \ the comparison should be done with COMPARE
210: EXIT
211: THEN
212: fdup f0>
213: IF
214: f~abs
215: ELSE
216: fnegate f~rel
217: THEN ;
218:
219: : f.s ( -- ) \ gforth f-dot-s
220: \G Display the number of items on the floating-point stack,
221: \G followed by a list of the items; TOS is the right-most item.
222: ." <" fdepth 0 .r ." > " fdepth 0 max maxdepth-.s @ min dup 0
223: ?DO dup i - 1- floats fp@ + f@ f. LOOP drop ;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to float.fs CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [gforth] / gforth