Return to extend.fs CVS log

Up to [gforth] / gforth

Added section talking about different memory regions, and glossed
associated words. Glossed words associated with user input; the
manual still needs a bunch of examples for these.

    1: \ EXTEND.FS    CORE-EXT Word not fully tested!         12may93jaw
    2: 
    3: \ Copyright (C) 1995,1998 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: 
   22: \ May be cross-compiled
   23: 
   24: decimal
   25: 
   26: \ .(                                                    12may93jaw
   27: 
   28: : .(   ( "ccc<paren>" -- ) \ core-ext dot-paren
   29:   \G Parse a string @var{ccc} delimited by a @code{)} (right
   30:   \G parenthesis). Display the string. This is often used to display
   31:   \G progress information during compilation; see examples below.
   32:   [char] ) parse type ; immediate
   33: 
   34: \ VALUE 2>R 2R> 2R@                                     17may93jaw
   35: 
   36: \ !! 2value
   37: 
   38: : 2Literal ( compilation w1 w2 -- ; run-time  -- w1 w2 ) \ double two-literal
   39:     \G Compile appropriate code such that, at run-time, cell pair @var{w1, w2} are
   40:     \G placed on the stack. Interpretation semantics are undefined.
   41:     swap postpone Literal  postpone Literal ; immediate restrict
   42: 
   43: ' drop alias d>s ( d -- n ) \ double		d_to_s
   44: 
   45: : m*/ ( d1 n2 u3 -- dqout ) \ double m-star-slash
   46:     >r s>d >r abs -rot
   47:     s>d r> xor r> swap >r >r dabs rot tuck um* 2swap um*
   48:     swap >r 0 d+ r> -rot r@ um/mod -rot r> um/mod nip swap
   49:     r> IF dnegate THEN ;
   50: 
   51: \ CASE OF ENDOF ENDCASE                                 17may93jaw
   52: 
   53: \ just as described in dpANS5
   54: 
   55: 0 CONSTANT case ( compilation  -- case-sys ; run-time  -- ) \ core-ext
   56:     immediate
   57: 
   58: : of ( compilation  -- of-sys ; run-time x1 x2 -- |x1 ) \ core-ext
   59:     \ !! the implementation does not match the stack effect
   60:     1+ >r
   61:     postpone over postpone = postpone if postpone drop
   62:     r> ; immediate
   63: 
   64: : endof ( compilation case-sys1 of-sys -- case-sys2 ; run-time  -- ) \ core-ext end-of
   65:     >r postpone else r> ; immediate
   66: 
   67: : endcase ( compilation case-sys -- ; run-time x -- ) \ core-ext end-case
   68:     postpone drop
   69:     0 ?do postpone then loop ; immediate
   70: 
   71: \ C"                                                    17may93jaw
   72: 
   73: : (c")     "lit ;
   74: 
   75: : CLiteral
   76:     postpone (c") here over char+ allot  place align ; immediate restrict
   77: 
   78: : C" ( compilation "ccc<quote>" -- ; run-time  -- c-addr ) \ core-ext c-quote
   79:     \G Compilation: parse a string @var{ccc} delimited by a @code{"}
   80:     \G (double quote). At run-time, return @var{c-addr} which
   81:     \G specifies the counted string @var{ccc}.  Interpretation
   82:     \G semantics are undefined.
   83:     [char] " parse postpone CLiteral ; immediate restrict
   84: 
   85: \ [COMPILE]                                             17may93jaw
   86: 
   87: : [compile] ( compilation "name" -- ; run-time ? -- ? ) \ core-ext bracket-compile
   88:     comp' drop compile, ; immediate
   89: 
   90: \ CONVERT                                               17may93jaw
   91: 
   92: : convert ( ud1 c-addr1 -- ud2 c-addr2 ) \ core-ext
   93:     \G OBSOLESCENT: superseded by @code{>number}.
   94:     char+ true >number drop ;
   95: 
   96: \ ERASE                                                 17may93jaw
   97: 
   98: : erase ( addr len -- ) \ core-ext
   99:     \G If @var{len}>0, clear all bits in each location of a memory region
  100:     \G of @var{len} address units starting at address @var{addr}.
  101:     \ !! dependence on "1 chars 1 ="
  102:     ( 0 1 chars um/mod nip )  0 fill ;
  103: : blank ( c-addr u -- ) \ string
  104:     \G If @var{u}>0, store the character value for a space in each
  105:     \G location of a memory region
  106:     \G of @var{u} character units starting at address @var{c-addr}.
  107:     bl fill ;
  108: 
  109: \ SEARCH                                                02sep94py
  110: 
  111: : search ( c-addr1 u1 c-addr2 u2 -- c-addr3 u3 flag ) \ string
  112:     \G Search the string specified by @var{c-addr1, u1} for the string
  113:     \G specified by @var{c-addr2, u2}. If @var{flag} is true: match was found
  114:     \G at @var{c-addr3} with @var{u3} characters remaining. If @var{flag} is false:
  115:     \G no match was found; @var{c-addr3, u3} are equal to @var{c-addr1, u1}.
  116:     \ not very efficient; but if we want efficiency, we'll do it as primitive
  117:     2>r 2dup
  118:     begin
  119: 	dup r@ >=
  120:     while
  121: 	over 2r@ swap -text 0= if
  122: 	    2swap 2drop 2r> 2drop true exit
  123: 	endif
  124: 	1 /string
  125:     repeat
  126:     2drop 2r> 2drop false ;
  127: 
  128: \ SOURCE-ID SAVE-INPUT RESTORE-INPUT                    11jun93jaw
  129: 
  130: : source-id ( -- 0 | -1 | fileid ) \ core-ext,file source-i-d
  131:     \G Return 0 (the input source is the user input device), -1 (the
  132:     \G input source is a string being processed by @code{evaluate}) or
  133:     \G a @var{fileid} (the input source is the file specified by
  134:     \G @var{fileid}).
  135:     loadfile @ dup 0= IF  drop sourceline# 0 min  THEN ;
  136: 
  137: : save-input ( -- xn .. x1 n ) \ core-ext
  138:     \G The @var{n} entries @var{xn - x1} describe the current state of the
  139:     \G input source specification, in some platform-dependent way that can
  140:     \G be used by @code{restore-input}.
  141:     >in @
  142:     loadfile @
  143:     if
  144: 	loadfile @ file-position throw
  145:     else
  146: 	blk @
  147: 	linestart @
  148:     then
  149:     sourceline#
  150:     >tib @
  151:     source-id
  152:     6 ;
  153: 
  154: : restore-input ( xn .. x1 n -- flag ) \ core-ext
  155:     \G Attempt to restore the input source specification to the state
  156:     \G described by the @var{n} entries @var{xn - x1}. @var{flag} is
  157:     \G true if the restore fails.
  158:     6 <> -12 and throw
  159:     source-id <> -12 and throw
  160:     >tib !
  161:     >r ( line# )
  162:     loadfile @ 0<>
  163:     if
  164: 	loadfile @ reposition-file throw
  165:     else
  166: 	linestart !
  167: 	blk !
  168: 	sourceline# r@ <> blk @ 0= and loadfile @ 0= and
  169: 	if
  170: 	    drop rdrop true EXIT
  171: 	then
  172:     then
  173:     r> loadline !
  174:     >in !
  175:     false ;
  176: 
  177: \ This things we don't need, but for being complete... jaw
  178: 
  179: \ EXPECT SPAN                                           17may93jaw
  180: 
  181: variable span ( -- c-addr ) \ core-ext
  182: \ VARIABLE: @var{c-addr} is the address of a cell that stores the
  183: \ length of the last string received by @code{expect}. OBSOLESCENT.
  184: 
  185: : expect ( c-addr +n -- ) \ core-ext
  186:     \G Receive a string of at most @var{+n} characters, and store it
  187:     \G in memory starting at @var{c-addr}. The string is
  188:     \G displayed. Input terminates when the <return> key is pressed or
  189:     \G @var{+n} characters have been received. The normal Gforth line
  190:     \G editing capabilites are available. The length of the string is
  191:     \G stored in @code{span}; it does not include the <return>
  192:     \G character. OBSOLESCENT: superceeded by @code{accept}.
  193:     0 rot over
  194:     BEGIN ( maxlen span c-addr pos1 )
  195: 	key decode ( maxlen span c-addr pos2 flag )
  196: 	>r 2over = r> or
  197:     UNTIL
  198:     2 pick swap /string type
  199:     nip span ! ;
  200: 
  201: \ marker                                               18dec94py
  202: 
  203: \ Marker creates a mark that is removed (including everything 
  204: \ defined afterwards) when executing the mark.
  205: 
  206: : included-files-mark ( -- u )
  207:     included-files 2@ nip
  208:     blk @ 0=
  209:     if \ not input from blocks
  210: 	source-id 1 -1 within
  211: 	if \ input from file
  212: 	    1- \ do not include the last file (hopefully this is the
  213: 	       \ currently included file)
  214: 	then
  215:     then ;  
  216: 
  217: \ hmm, most of the saving appears to be pretty unnecessary: we could
  218: \ derive the wordlists and the words that have to be kept from the
  219: \ saved value of dp value. - anton
  220: 
  221: : marker, ( -- mark )
  222:     here
  223:     included-files-mark ,
  224:     dup A, \ here
  225:     voclink @ A, \ vocabulary list start
  226:     \ for all wordlists, remember wordlist-id (the linked list)
  227:     voclink
  228:     BEGIN
  229: 	@ dup
  230:     WHILE
  231: 	dup 0 wordlist-link - wordlist-id @ A,
  232:     REPEAT
  233:     drop
  234:     \ remember udp
  235:     udp @ , ;
  236: 
  237: : marker! ( mark -- )
  238:     \ reset included files count; resize will happen on next add-included-file
  239:     included-files 2@ drop over @ included-files 2! cell+
  240:     \ rest of marker!
  241:     dup @ swap cell+ ( here rest-of-marker )
  242:     dup @ voclink ! cell+
  243:     \ restore wordlists to former words
  244:     voclink
  245:     BEGIN
  246: 	@ dup 
  247:     WHILE
  248: 	over @ over 0 wordlist-link - wordlist-id !
  249: 	swap cell+ swap
  250:     REPEAT
  251:     drop
  252:     \ rehash wordlists to remove forgotten words
  253:     \ why don't we do this in a single step? - anton
  254:     voclink
  255:     BEGIN
  256: 	@ dup
  257:     WHILE
  258: 	dup 0 wordlist-link - rehash
  259:     REPEAT
  260:     drop
  261:     \ restore udp and dp
  262:     @ udp !  dp !
  263:     \ clean up vocabulary stack
  264:     0 vp @ 0
  265:     ?DO
  266: 	vp cell+ I cells + @ dup here >
  267: 	IF  drop  ELSE  swap 1+  THEN
  268:     LOOP
  269:     dup 0= or set-order \ -1 set-order if order is empty
  270:     get-current here > IF
  271: 	forth-wordlist set-current
  272:     THEN ;
  273: 
  274: : marker ( "<spaces> name" -- ) \ core-ext
  275:     \G Create a definition, @var{name} (called a @var{mark}) whose
  276:     \G execution semantics are to remove itself and everything 
  277:     \G defined after it.
  278:     marker, Create A,
  279: DOES> ( -- )
  280:     @ marker! ;
  281: