File:
[gforth] /
gforth /
cross.fs
Revision
1.133:
download - view:
text,
annotated -
select for diffs
Wed Jan 1 17:28:29 2003 UTC (21 years, 3 months ago) by
pazsan
Branches:
MAIN
CVS tags:
HEAD
Cleaned up prim file (only one soft of branches, grouping)
Added auto-expanding tib for file reading - the terminal line length remains
limited.
1: \ CROSS.FS The Cross-Compiler 06oct92py
2: \ Idea and implementation: Bernd Paysan (py)
3:
4: \ Copyright (C) 1995,1996,1997,1998,1999,2000 Free Software Foundation, Inc.
5:
6: \ This file is part of Gforth.
7:
8: \ Gforth is free software; you can redistribute it and/or
9: \ modify it under the terms of the GNU General Public License
10: \ as published by the Free Software Foundation; either version 2
11: \ of the License, or (at your option) any later version.
12:
13: \ This program is distributed in the hope that it will be useful,
14: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
15: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: \ GNU General Public License for more details.
17:
18: \ You should have received a copy of the GNU General Public License
19: \ along with this program; if not, write to the Free Software
20: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
21:
22: 0
23: [IF]
24:
25: ToDo:
26: - Crossdoc destination ./doc/crossdoc.fd makes no sense when
27: cross.fs is used seperately. jaw
28: - Do we need this char translation with >address and in branchoffset?
29: (>body also affected) jaw
30:
31: [THEN]
32:
33: s" compat/strcomp.fs" included
34:
35: hex
36:
37: \ debugging for compiling
38:
39: \ print stack at each colon definition
40: \ : : save-input cr bl word count type restore-input throw .s : ;
41:
42: \ print stack at each created word
43: \ : create save-input cr bl word count type restore-input throw .s create ;
44:
45:
46: \ \ ------------- Setup Vocabularies
47:
48: \ Remark: Vocabulary is not ANS, but it should work...
49:
50: Vocabulary Cross
51: Vocabulary Target
52: Vocabulary Ghosts
53: Vocabulary Minimal
54: only Forth also Target also also
55: definitions Forth
56:
57: : T previous Ghosts also Target ; immediate
58: : G Ghosts ; immediate
59: : H previous Forth also Cross ; immediate
60:
61: forth definitions
62:
63: : T previous Ghosts also Target ; immediate
64: : G Ghosts ; immediate
65:
66:
67: : >cross also Cross definitions previous ;
68: : >target also Target definitions previous ;
69: : >minimal also Minimal definitions previous ;
70:
71: H
72:
73: >CROSS
74:
75: \ Test against this definitions to find out whether we are cross-compiling
76: \ may be usefull for assemblers
77: 0 Constant gforth-cross-indicator
78:
79: \ find out whether we are compiling with gforth
80:
81: : defined? bl word find nip ;
82: defined? emit-file defined? toupper and \ drop 0
83: [IF]
84: \ use this in a gforth system
85: : \GFORTH ; immediate
86: : \ANSI postpone \ ; immediate
87: [ELSE]
88: : \GFORTH postpone \ ; immediate
89: : \ANSI ; immediate
90: [THEN]
91:
92: \ANSI : [IFUNDEF] defined? 0= postpone [IF] ; immediate
93: \ANSI : [IFDEF] defined? postpone [IF] ; immediate
94: 0 \ANSI drop 1
95: [IF]
96: : \G postpone \ ; immediate
97: : rdrop postpone r> postpone drop ; immediate
98: : name bl word count ;
99: : bounds over + swap ;
100: : scan >r BEGIN dup WHILE over c@ r@ <> WHILE 1 /string REPEAT THEN rdrop ;
101: : linked here over @ , swap ! ;
102: : alias create , DOES> @ EXECUTE ;
103: : defer ['] noop alias ;
104: : is state @
105: IF ' >body postpone literal postpone !
106: ELSE ' >body ! THEN ; immediate
107: : 0>= 0< 0= ;
108: : d<> rot <> -rot <> or ;
109: : toupper dup [char] a [char] z 1+ within IF [char] A [char] a - + THEN ;
110: Variable ebuf
111: : emit-file ( c fd -- ior ) swap ebuf c! ebuf 1 chars rot write-file ;
112: 0a Constant #lf
113: 0d Constant #cr
114:
115: [IFUNDEF] Warnings Variable Warnings [THEN]
116:
117: \ \ Number parsing 23feb93py
118:
119: \ number? number 23feb93py
120:
121: Variable dpl
122:
123: hex
124: Create bases 10 , 2 , A , 100 ,
125: \ 16 2 10 character
126:
127: \ !! protect BASE saving wrapper against exceptions
128: : getbase ( addr u -- addr' u' )
129: over c@ [char] $ - dup 4 u<
130: IF
131: cells bases + @ base ! 1 /string
132: ELSE
133: drop
134: THEN ;
135:
136: : sign? ( addr u -- addr u flag )
137: over c@ [char] - = dup >r
138: IF
139: 1 /string
140: THEN
141: r> ;
142:
143: : s>unumber? ( addr u -- ud flag )
144: over [char] ' =
145: IF \ a ' alone is rather unusual :-)
146: drop char+ c@ 0 true EXIT
147: THEN
148: base @ >r dpl on getbase
149: 0. 2swap
150: BEGIN ( d addr len )
151: dup >r >number dup
152: WHILE \ there are characters left
153: dup r> -
154: WHILE \ the last >number parsed something
155: dup 1- dpl ! over c@ [char] . =
156: WHILE \ the current char is '.'
157: 1 /string
158: REPEAT THEN \ there are unparseable characters left
159: 2drop false
160: ELSE
161: rdrop 2drop true
162: THEN
163: r> base ! ;
164:
165: \ ouch, this is complicated; there must be a simpler way - anton
166: : s>number? ( addr len -- d f )
167: \ converts string addr len into d, flag indicates success
168: sign? >r
169: s>unumber?
170: 0= IF
171: rdrop false
172: ELSE \ no characters left, all ok
173: r>
174: IF
175: dnegate
176: THEN
177: true
178: THEN ;
179:
180: : s>number ( addr len -- d )
181: \ don't use this, there is no way to tell success
182: s>number? drop ;
183:
184: : snumber? ( c-addr u -- 0 / n -1 / d 0> )
185: s>number? 0=
186: IF
187: 2drop false EXIT
188: THEN
189: dpl @ dup 0< IF
190: nip
191: ELSE
192: 1+
193: THEN ;
194:
195: : number? ( string -- string 0 / n -1 / d 0> )
196: dup >r count snumber? dup if
197: rdrop
198: else
199: r> swap
200: then ;
201:
202: : number ( string -- d )
203: number? ?dup 0= abort" ?" 0<
204: IF
205: s>d
206: THEN ;
207:
208: [THEN]
209:
210: \ this provides assert( and struct stuff
211: \GFORTH [IFUNDEF] assert1(
212: \GFORTH also forth definitions require assert.fs previous
213: \GFORTH [THEN]
214:
215: >CROSS
216:
217: hex \ the defualt base for the cross-compiler is hex !!
218: \ Warnings off
219:
220: \ words that are generaly useful
221:
222: : KB 400 * ;
223: : >wordlist ( vocabulary-xt -- wordlist-struct )
224: also execute get-order swap >r 1- set-order r> ;
225:
226: : umax 2dup u< IF swap THEN drop ;
227: : umin 2dup u> IF swap THEN drop ;
228:
229: : string, ( c-addr u -- )
230: \ puts down string as cstring
231: dup c, here swap chars dup allot move ;
232:
233: : ," [char] " parse string, ;
234:
235: : SetValue ( n -- <name> )
236: \G Same behaviour as "Value" if the <name> is not defined
237: \G Same behaviour as "to" if <name> is defined
238: \G SetValue searches in the current vocabulary
239: save-input bl word >r restore-input throw r> count
240: get-current search-wordlist
241: IF drop >r
242: \ we have to set current to be topmost context wordlist
243: get-order get-order get-current swap 1+ set-order
244: r> ['] to execute
245: set-order
246: ELSE Value THEN ;
247:
248: : DefaultValue ( n -- <name> )
249: \G Same behaviour as "Value" if the <name> is not defined
250: \G DefaultValue searches in the current vocabulary
251: save-input bl word >r restore-input throw r> count
252: get-current search-wordlist
253: IF bl word drop 2drop ELSE Value THEN ;
254:
255: hex
256:
257: \ FIXME delete`
258: \ 1 Constant Cross-Flag \ to check whether assembler compiler plug-ins are
259: \ for cross-compiling
260: \ No! we use "[IFUNDEF]" there to find out whether we are target compiling!!!
261:
262: \ FIXME move down
263: : comment? ( c-addr u -- c-addr u )
264: 2dup s" (" str=
265: IF postpone (
266: ELSE 2dup s" \" str= IF postpone \ THEN
267: THEN ;
268:
269: : X ( -- <name> )
270: \G The next word in the input is a target word.
271: \G Equivalent to T <name> but without permanent
272: \G switch to target dictionary. Used as prefix e.g. for @, !, here etc.
273: bl word count [ ' target >wordlist ] Literal search-wordlist
274: IF state @ IF compile, ELSE execute THEN
275: ELSE -1 ABORT" Cross: access method not supported!"
276: THEN ; immediate
277:
278: \ Begin CROSS COMPILER:
279:
280: \ debugging
281:
282: 0 [IF]
283:
284: This implements debugflags for the cross compiler and the compiled
285: images. It works identical to the has-flags in the environment.
286: The debugflags are defined in a vocabluary. If the word exists and
287: its value is true, the flag is switched on.
288:
289: [THEN]
290:
291: >CROSS
292:
293: Vocabulary debugflags \ debug flags for cross
294: also debugflags get-order over
295: Constant debugflags-wl
296: set-order previous
297:
298: : DebugFlag
299: get-current >r debugflags-wl set-current
300: SetValue
301: r> set-current ;
302:
303: : Debug? ( adr u -- flag )
304: \G return true if debug flag is defined or switched on
305: debugflags-wl search-wordlist
306: IF EXECUTE
307: ELSE false THEN ;
308:
309: : D? ( <name> -- flag )
310: \G return true if debug flag is defined or switched on
311: \G while compiling we do not return the current value but
312: bl word count debug? ;
313:
314: : [d?]
315: \G compile the value-xt so the debug flag can be switched
316: \G the flag must exist!
317: bl word count debugflags-wl search-wordlist
318: IF compile,
319: ELSE -1 ABORT" unknown debug flag"
320: \ POSTPONE false
321: THEN ; immediate
322:
323: : symentry ( adr len taddr -- )
324: \G Produce a symbol table (an optional symbol address
325: \G map) if wanted
326: [ [IFDEF] fd-symbol-table ]
327: base @ swap hex s>d <# 8 0 DO # LOOP #> fd-symbol-table write-file throw base !
328: s" :" fd-symbol-table write-file throw
329: fd-symbol-table write-line throw
330: [ [ELSE] ]
331: 2drop drop
332: [ [THEN] ] ;
333:
334:
335: \ \ -------------------- source file
336:
337: decimal
338:
339: Variable cross-file-list
340: 0 cross-file-list !
341: Variable target-file-list
342: 0 target-file-list !
343: Variable host-file-list
344: 0 host-file-list !
345:
346: cross-file-list Value file-list
347: 0 Value source-desc
348:
349: \ file loading
350:
351: : >fl-id 1 cells + ;
352: : >fl-name 2 cells + ;
353:
354: Variable filelist 0 filelist !
355: Create NoFile ," #load-file#"
356:
357: : loadfile ( -- adr )
358: source-desc ?dup IF >fl-name ELSE NoFile THEN ;
359:
360: : sourcefilename ( -- adr len )
361: loadfile count ;
362:
363: \ANSI : sourceline# 0 ;
364:
365: \ \ -------------------- path handling from kernel/paths.fs
366:
367: \ paths.fs path file handling 03may97jaw
368:
369: \ -Changing the search-path:
370: \ fpath+ <path> adds a directory to the searchpath
371: \ fpath= <path>|<path> makes complete now searchpath
372: \ seperator is |
373: \ .fpath displays the search path
374: \ remark I:
375: \ a ./ in the beginning of filename is expanded to the directory the
376: \ current file comes from. ./ can also be included in the search-path!
377: \ ~+/ loads from the current working directory
378:
379: \ remark II:
380: \ if there is no sufficient space for the search path increase it!
381:
382:
383: \ -Creating custom paths:
384:
385: \ It is possible to use the search mechanism on yourself.
386:
387: \ Make a buffer for the path:
388: \ create mypath 100 chars , \ maximum length (is checked)
389: \ 0 , \ real len
390: \ 100 chars allot \ space for path
391: \ use the same functions as above with:
392: \ mypath path+
393: \ mypath path=
394: \ mypath .path
395:
396: \ do a open with the search path:
397: \ open-path-file ( adr len path -- fd adr len ior )
398: \ the file is opened read-only; if the file is not found an error is generated
399:
400: \ questions to: wilke@jwdt.com
401:
402: [IFUNDEF] +place
403: : +place ( adr len adr )
404: 2dup >r >r
405: dup c@ char+ + swap move
406: r> r> dup c@ rot + swap c! ;
407: [THEN]
408:
409: [IFUNDEF] place
410: : place ( c-addr1 u c-addr2 )
411: 2dup c! char+ swap move ;
412: [THEN]
413:
414: \ if we have path handling, use this and the setup of it
415: [IFUNDEF] open-fpath-file
416:
417: create sourcepath 1024 chars , 0 , 1024 chars allot \ !! make this dynamic
418: sourcepath value fpath
419:
420: : also-path ( adr len path^ -- )
421: >r
422: \ len check
423: r@ cell+ @ over + r@ @ u> ABORT" path buffer too small!"
424: \ copy into
425: tuck r@ cell+ dup @ cell+ + swap cmove
426: \ make delimiter
427: 0 r@ cell+ dup @ cell+ + 2 pick + c! 1 + r> cell+ +!
428: ;
429:
430: : only-path ( adr len path^ -- )
431: dup 0 swap cell+ ! also-path ;
432:
433: : path+ ( path-addr "dir" -- ) \ gforth
434: \G Add the directory @var{dir} to the search path @var{path-addr}.
435: name rot also-path ;
436:
437: : fpath+ ( "dir" ) \ gforth
438: \G Add directory @var{dir} to the Forth search path.
439: fpath path+ ;
440:
441: : path= ( path-addr "dir1|dir2|dir3" ) \ gforth
442: \G Make a complete new search path; the path separator is |.
443: name 2dup bounds ?DO i c@ [char] | = IF 0 i c! THEN LOOP
444: rot only-path ;
445:
446: : fpath= ( "dir1|dir2|dir3" ) \ gforth
447: \G Make a complete new Forth search path; the path separator is |.
448: fpath path= ;
449:
450: : path>counted cell+ dup cell+ swap @ ;
451:
452: : next-path ( adr len -- adr2 len2 )
453: 2dup 0 scan
454: dup 0= IF 2drop 0 -rot 0 -rot EXIT THEN
455: >r 1+ -rot r@ 1- -rot
456: r> - ;
457:
458: : previous-path ( path^ -- )
459: dup path>counted
460: BEGIN tuck dup WHILE repeat ;
461:
462: : .path ( path-addr -- ) \ gforth
463: \G Display the contents of the search path @var{path-addr}.
464: path>counted
465: BEGIN next-path dup WHILE type space REPEAT 2drop 2drop ;
466:
467: : .fpath ( -- ) \ gforth
468: \G Display the contents of the Forth search path.
469: fpath .path ;
470:
471: : absolut-path? ( addr u -- flag ) \ gforth
472: \G A path is absolute if it starts with a / or a ~ (~ expansion),
473: \G or if it is in the form ./*, extended regexp: ^[/~]|./, or if
474: \G it has a colon as second character ("C:..."). Paths simply
475: \G containing a / are not absolute!
476: 2dup 2 u> swap 1+ c@ [char] : = and >r \ dos absoulte: c:/....
477: over c@ [char] / = >r
478: over c@ [char] ~ = >r
479: \ 2dup S" ../" string-prefix? r> or >r \ not catered for in expandtopic
480: S" ./" string-prefix?
481: r> r> r> or or or ;
482:
483: Create ofile 0 c, 255 chars allot
484: Create tfile 0 c, 255 chars allot
485:
486: : pathsep? dup [char] / = swap [char] \ = or ;
487:
488: : need/ ofile dup c@ + c@ pathsep? 0= IF s" /" ofile +place THEN ;
489:
490: : extractpath ( adr len -- adr len2 )
491: BEGIN dup WHILE 1-
492: 2dup + c@ pathsep? IF EXIT THEN
493: REPEAT ;
494:
495: : remove~+ ( -- )
496: ofile count s" ~+/" string-prefix?
497: IF
498: ofile count 3 /string ofile place
499: THEN ;
500:
501: : expandtopic ( -- ) \ stack effect correct? - anton
502: \ expands "./" into an absolute name
503: ofile count s" ./" string-prefix?
504: IF
505: ofile count 1 /string tfile place
506: 0 ofile c! sourcefilename extractpath ofile place
507: ofile c@ IF need/ THEN
508: tfile count over c@ pathsep? IF 1 /string THEN
509: ofile +place
510: THEN ;
511:
512: : compact.. ( adr len -- adr2 len2 )
513: \ deletes phrases like "xy/.." out of our directory name 2dec97jaw
514: over swap
515: BEGIN dup WHILE
516: dup >r '/ scan 2dup s" /../" string-prefix?
517: IF
518: dup r> - >r 4 /string over r> + 4 -
519: swap 2dup + >r move dup r> over -
520: ELSE
521: rdrop dup 1 min /string
522: THEN
523: REPEAT drop over - ;
524:
525: : reworkdir ( -- )
526: remove~+
527: ofile count compact..
528: nip ofile c! ;
529:
530: : open-ofile ( -- fid ior )
531: \G opens the file whose name is in ofile
532: expandtopic reworkdir
533: ofile count r/o open-file ;
534:
535: : check-path ( adr1 len1 adr2 len2 -- fd 0 | 0 <>0 )
536: 0 ofile ! >r >r ofile place need/
537: r> r> ofile +place
538: open-ofile ;
539:
540: : open-path-file ( addr1 u1 path-addr -- wfileid addr2 u2 0 | ior ) \ gforth
541: \G Look in path @var{path-addr} for the file specified by @var{addr1 u1}.
542: \G If found, the resulting path and an open file descriptor
543: \G are returned. If the file is not found, @var{ior} is non-zero.
544: >r
545: 2dup absolut-path?
546: IF rdrop
547: ofile place open-ofile
548: dup 0= IF >r ofile count r> THEN EXIT
549: ELSE r> path>counted
550: BEGIN next-path dup
551: WHILE 5 pick 5 pick check-path
552: 0= IF >r 2drop 2drop r> ofile count 0 EXIT ELSE drop THEN
553: REPEAT
554: 2drop 2drop 2drop -38
555: THEN ;
556:
557: : open-fpath-file ( addr1 u1 -- wfileid addr2 u2 0 | ior ) \ gforth
558: \G Look in the Forth search path for the file specified by @var{addr1 u1}.
559: \G If found, the resulting path and an open file descriptor
560: \G are returned. If the file is not found, @var{ior} is non-zero.
561: fpath open-path-file ;
562:
563: fpath= ~+
564:
565: [THEN]
566:
567: \ \ -------------------- include require 13may99jaw
568:
569: >CROSS
570:
571: : add-included-file ( adr len -- adr )
572: dup >fl-name char+ allocate throw >r
573: file-list @ r@ ! r@ file-list !
574: r@ >fl-name place r> ;
575:
576: : included? ( c-addr u -- f )
577: file-list
578: BEGIN @ dup
579: WHILE >r 2dup r@ >fl-name count str=
580: IF rdrop 2drop true EXIT THEN
581: r>
582: REPEAT
583: 2drop drop false ;
584:
585: false DebugFlag showincludedfiles
586:
587: : included1 ( fd adr u -- )
588: \ include file adr u / fd
589: \ we don't use fd with include-file, because the forth system
590: \ doesn't know the name of the file to get a nice error report
591: [d?] showincludedfiles
592: IF cr ." Including: " 2dup type ." ..." THEN
593: rot close-file throw
594: source-desc >r
595: add-included-file to source-desc
596: sourcefilename
597: ['] included catch
598: r> to source-desc
599: throw ;
600:
601: : included ( adr len -- )
602: cross-file-list to file-list
603: open-fpath-file throw
604: included1 ;
605:
606: : required ( adr len -- )
607: cross-file-list to file-list
608: open-fpath-file throw \ 2dup cr ." R:" type
609: 2dup included?
610: IF 2drop close-file throw
611: ELSE included1
612: THEN ;
613:
614: : include bl word count included ;
615:
616: : require bl word count required ;
617:
618: 0 [IF]
619:
620: also forth definitions previous
621:
622: : included ( adr len -- ) included ;
623:
624: : required ( adr len -- ) required ;
625:
626: : include include ;
627:
628: : require require ;
629:
630: [THEN]
631:
632: >CROSS
633: hex
634:
635: \ \ -------------------- Error Handling 05aug97jaw
636:
637: \ Flags
638:
639: also forth definitions \ these values may be predefined before
640: \ the cross-compiler is loaded
641:
642: false DefaultValue stack-warn \ check on empty stack at any definition
643: false DefaultValue create-forward-warn \ warn on forward declaration of created words
644:
645: previous >CROSS
646:
647: : .dec
648: base @ decimal swap . base ! ;
649:
650: : .sourcepos
651: cr sourcefilename type ." :"
652: sourceline# .dec ;
653:
654: : warnhead
655: \G display error-message head
656: \G perhaps with linenumber and filename
657: .sourcepos ." Warning: " ;
658:
659: : empty? depth IF .sourcepos ." Stack not empty!" THEN ;
660:
661: stack-warn [IF]
662: : defempty? empty? ;
663: [ELSE]
664: : defempty? ; immediate
665: [THEN]
666:
667: \ \ -------------------- Compiler Plug Ins 01aug97jaw
668:
669: >CROSS
670:
671: \ Compiler States
672:
673: Variable comp-state
674: 0 Constant interpreting
675: 1 Constant compiling
676: 2 Constant resolving
677: 3 Constant assembling
678:
679: : compiling? comp-state @ compiling = ;
680:
681: : pi-undefined -1 ABORT" Plugin undefined" ;
682:
683: : Plugin ( -- : pluginname )
684: Create
685: \ for normal cross-compiling only one action
686: \ exists, this fields are identical. For the instant
687: \ simulation environment we need, two actions for each plugin
688: \ the target one and the one that generates the simulation code
689: ['] pi-undefined , \ action
690: ['] pi-undefined , \ target plugin action
691: 8765 , \ plugin magic
692: DOES> perform ;
693:
694: Plugin DummyPlugin
695:
696: : 'PI ( -- addr : pluginname )
697: ' >body dup 2 cells + @ 8765 <> ABORT" not a plugin" ;
698:
699: : plugin-of ( xt -- : pluginname )
700: dup 'PI 2! ;
701:
702: : action-of ( xt -- : plunginname )
703: 'PI cell+ ! ;
704:
705: : TPA ( -- : plugin )
706: \ target plugin action
707: \ executes current target action of plugin
708: 'PI cell+ POSTPONE literal POSTPONE perform ; immediate
709:
710: Variable ppi-temp 0 ppi-temp !
711:
712: : pa:
713: \g define plugin action
714: ppi-temp @ ABORT" pa: definition not closed"
715: 'PI ppi-temp ! :noname ;
716:
717: : ;pa
718: \g end a definition for plugin action
719: POSTPONE ; ppi-temp @ ! 0 ppi-temp ! ; immediate
720:
721:
722: Plugin dlit, ( d -- ) \ compile numerical value the target
723: Plugin lit, ( n -- )
724: Plugin alit, ( n -- )
725:
726: Plugin branch, ( target-addr -- ) \ compiles a branch
727: Plugin ?branch, ( target-addr -- ) \ compiles a ?branch
728: Plugin branchmark, ( -- branch-addr ) \ reserves room for a branch
729: Plugin ?branchmark, ( -- branch-addr ) \ reserves room for a ?branch
730: Plugin ?domark, ( -- branch-addr ) \ reserves room for a ?do branch
731: Plugin branchto, ( -- ) \ actual program position is target of a branch (do e.g. alignment)
732: ' NOOP plugin-of branchto,
733: Plugin branchtoresolve, ( branch-addr -- ) \ resolves a forward reference from branchmark
734: Plugin branchtomark, ( -- target-addr ) \ marks a branch destination
735:
736: Plugin colon, ( tcfa -- ) \ compiles call to tcfa at current position
737: Plugin prim, ( tcfa -- ) \ compiles primitive invocation
738: Plugin colonmark, ( -- addr ) \ marks a colon call
739: Plugin colon-resolve ( tcfa addr -- )
740:
741: Plugin addr-resolve ( target-addr addr -- )
742: Plugin doer-resolve ( ghost res-pnt target-addr addr -- ghost res-pnt )
743:
744: Plugin ncontrols? ( [ xn ... x1 ] n -- ) \ checks wheter n control structures are open
745: Plugin if, ( -- if-token )
746: Plugin else, ( if-token -- if-token )
747: Plugin then, ( if-token -- )
748: Plugin ahead,
749: Plugin begin,
750: Plugin while,
751: Plugin until,
752: Plugin again,
753: Plugin repeat,
754: Plugin cs-swap ( x1 x2 -- x2 x1 )
755:
756: Plugin case, ( -- n )
757: Plugin of, ( n -- x1 n )
758: Plugin endof, ( x1 n -- x2 n )
759: Plugin endcase, ( x1 .. xn n -- )
760:
761: Plugin do, ( -- do-token )
762: Plugin ?do, ( -- ?do-token )
763: Plugin for, ( -- for-token )
764: Plugin loop, ( do-token / ?do-token -- )
765: Plugin +loop, ( do-token / ?do-token -- )
766: Plugin next, ( for-token )
767: Plugin leave, ( -- )
768: Plugin ?leave, ( -- )
769:
770: Plugin ca>native \ Convert a code address to the processors
771: \ native address. This is used in doprim, and
772: \ code/code: primitive definitions word to
773: \ convert the addresses.
774: \ The only target where we need this is the misc
775: \ which is a 16 Bit processor with word addresses
776: \ but the forth system we build has a normal byte
777: \ addressed memory model
778:
779: Plugin doprim, \ compiles start of a primitive
780: Plugin docol, \ compiles start of a colon definition
781: Plugin doer,
782: Plugin fini, \ compiles end of definition ;s
783: Plugin doeshandler,
784: Plugin dodoes,
785:
786: Plugin colon-start
787: ' noop plugin-of colon-start
788: Plugin colon-end
789: ' noop plugin-of colon-end
790:
791: Plugin ]comp \ starts compilation
792: ' noop plugin-of ]comp
793: Plugin comp[ \ ends compilation
794: ' noop plugin-of comp[
795:
796: Plugin t>body \ we need the system >body
797: \ and the target >body
798:
799: >TARGET
800: : >body t>body ;
801:
802:
803: \ Ghost Builder 06oct92py
804:
805: >CROSS
806: hex
807: \ Values for ghost magic
808: 4711 Constant <fwd> 4712 Constant <res>
809: 4713 Constant <imm> 4714 Constant <do:>
810: 4715 Constant <skip>
811:
812: \ Bitmask for ghost flags
813: 1 Constant <unique>
814: 2 Constant <primitive>
815:
816: \ FXIME: move this to general stuff?
817: : set-flag ( addr flag -- )
818: over @ or swap ! ;
819:
820: : reset-flag ( addr flag -- )
821: invert over @ and swap ! ;
822:
823: : get-flag ( addr flag -- f )
824: swap @ and 0<> ;
825:
826:
827: Struct
828:
829: \ link to next ghost (always the first element)
830: cell% field >next-ghost
831:
832: \ type of ghost
833: cell% field >magic
834:
835: \ pointer where ghost is in target, or if unresolved
836: \ points to the where we have to resolve (linked-list)
837: cell% field >link
838:
839: \ execution semantics (while target compiling) of ghost
840: cell% field >exec
841:
842: \ compilation action of this ghost; this is what is
843: \ done to compile a call (or whatever) to this definition.
844: \ E.g. >comp contains the semantic of postpone s"
845: \ whereas >exec-compile contains the semantic of s"
846: cell% field >comp
847:
848: \ Compilation sematics (while parsing) of this ghost. E.g.
849: \ "\" will skip the rest of line.
850: \ These semantics are defined by Cond: and
851: \ if a word is made immediate in instant, then the >exec2 field
852: \ gets copied to here
853: cell% field >exec-compile
854:
855: \ Additional execution semantics of this ghost. This is used
856: \ for code generated by instant and for the doer-xt of created
857: \ words
858: cell% field >exec2
859:
860: cell% field >created
861:
862: \ the xt of the created ghost word itself
863: cell% field >ghost-xt
864:
865: \ pointer to the counted string of the assiciated
866: \ assembler label
867: cell% field >asm-name
868:
869: \ mapped primitives have a special address, so
870: \ we are able to detect them
871: cell% field >asm-dummyaddr
872:
873: \ for builder (create, variable...) words
874: \ the execution symantics of words built are placed here
875: \ this is a doer ghost or a dummy ghost
876: cell% field >do:ghost
877:
878: cell% field >ghost-flags
879:
880: cell% field >ghost-name
881:
882: End-Struct ghost-struct
883:
884: Variable ghost-list
885: 0 ghost-list !
886:
887: Variable executed-ghost \ last executed ghost, needed in tcreate and gdoes>
888: \ Variable last-ghost \ last ghost that is created
889: Variable last-header-ghost \ last ghost definitions with header
890:
891: \ space for ghosts resolve structure
892: \ we create ghosts in a sepearte space
893: \ and not to the current host dp, because this
894: \ gives trouble with instant while compiling and creating
895: \ a ghost for a forward reference
896: \ BTW: we cannot allocate another memory region
897: \ because allot will check the overflow!!
898: Variable cross-space-dp
899: Create cross-space 250000 allot here 100 allot align
900: Constant cross-space-end
901: cross-space cross-space-dp !
902: Variable cross-space-dp-orig
903:
904: : cross-space-used cross-space-dp @ cross-space - ;
905:
906: : >space ( -- )
907: dp @ cross-space-dp-orig !
908: cross-space-dp @ dp ! ;
909:
910: : space> ( -- )
911: dp @ dup cross-space-dp !
912: cross-space-end u> ABORT" CROSS: cross-space overflow"
913: cross-space-dp-orig @ dp ! ;
914:
915: \ this is just for debugging, to see this in the backtrace
916: : execute-exec execute ;
917: : execute-exec2 execute ;
918: : execute-exec-compile execute ;
919:
920: : NoExec
921: executed-ghost @ >exec2 @
922: ?dup
923: IF execute-exec2
924: ELSE true ABORT" CROSS: Don't execute ghost, or immediate target word"
925: THEN ;
926:
927: Defer is-forward
928:
929: : (ghostheader) ( -- )
930: ghost-list linked <fwd> , 0 , ['] NoExec , ['] is-forward ,
931: 0 , 0 , 0 , 0 , 0 , 0 , 0 , 0 , ;
932:
933: : ghostheader ( -- ) (ghostheader) 0 , ;
934:
935: ' Ghosts >wordlist Constant ghosts-wordlist
936:
937: \ the current wordlist for ghost definitions in the host
938: ghosts-wordlist Value current-ghosts
939:
940: : Make-Ghost ( "name" -- ghost )
941: >space
942: \ save current and create in ghost vocabulary
943: get-current >r current-ghosts set-current
944: >in @ Create >in !
945: \ some forth systems like iForth need the immediate directly
946: \ after the word is created
947: \ restore current
948: r> set-current
949: here (ghostheader)
950: bl word count string, align
951: space>
952: \ set ghost-xt field by doing a search
953: dup >ghost-name count
954: current-ghosts search-wordlist
955: 0= ABORT" CROSS: Just created, must be there!"
956: over >ghost-xt !
957: DOES>
958: dup executed-ghost !
959: >exec @ execute-exec ;
960:
961: \ ghost words 14oct92py
962: \ changed: 10may93py/jaw
963:
964: Defer search-ghosts
965:
966: : (search-ghosts) ( adr len -- cfa true | 0 )
967: current-ghosts search-wordlist ;
968:
969: ' (search-ghosts) IS search-ghosts
970:
971: : gsearch ( addr len -- ghost true | 0 )
972: search-ghosts
973: dup IF swap >body swap THEN ;
974:
975: : gfind ( string -- ghost true / string false )
976: \ searches for string in word-list ghosts
977: \ dup count type space
978: dup >r count gsearch
979: dup IF rdrop ELSE r> swap THEN ;
980:
981: : gdiscover ( xt -- ghost true | xt false )
982: >r ghost-list
983: BEGIN @ dup
984: WHILE dup >magic @ <fwd> <>
985: IF dup >link @ r@ =
986: IF rdrop true EXIT THEN
987: THEN
988: REPEAT
989: drop r> false ;
990:
991: : xt>ghost ( xt -- ghost )
992: gdiscover 0= ABORT" CROSS: ghost not found for this xt" ;
993:
994: : Ghost ( "name" -- ghost )
995: >in @ bl word gfind IF nip EXIT THEN
996: drop >in ! Make-Ghost ;
997:
998: : >ghostname ( ghost -- adr len )
999: >ghost-name count ;
1000:
1001: : forward? ( ghost -- flag )
1002: >magic @ <fwd> = ;
1003:
1004: : undefined? ( ghost -- flag )
1005: >magic @ dup <fwd> = swap <skip> = or ;
1006:
1007: : immediate? ( ghost -- flag )
1008: >magic @ <imm> = ;
1009:
1010: Variable TWarnings
1011: TWarnings on
1012: Variable Exists-Warnings
1013: Exists-Warnings on
1014:
1015: : exists-warning ( ghost -- ghost )
1016: TWarnings @ Exists-Warnings @ and
1017: IF dup >ghostname warnhead type ." exists " THEN ;
1018:
1019: \ : HeaderGhost Ghost ;
1020:
1021: Variable reuse-ghosts reuse-ghosts off
1022:
1023: : HeaderGhost ( "name" -- ghost )
1024: >in @
1025: bl word count
1026: \ 2dup type space
1027: current-ghosts search-wordlist
1028: IF >body dup undefined? reuse-ghosts @ or
1029: IF nip EXIT
1030: ELSE exists-warning
1031: THEN
1032: drop >in !
1033: ELSE >in !
1034: THEN
1035: \ we keep the execution semantics of the prviously
1036: \ defined words, this is a workaround
1037: \ for the redefined \ until vocs work
1038: Make-Ghost ;
1039:
1040: : .ghost ( ghost -- ) >ghostname type ;
1041:
1042: \ ' >ghostname ALIAS @name
1043:
1044: : findghost ( "ghostname" -- ghost )
1045: bl word gfind 0= ABORT" CROSS: Ghost don't exists" ;
1046:
1047: : [G'] ( -- ghost : name )
1048: \G ticks a ghost and returns its address
1049: findghost
1050: state @ IF postpone literal THEN ; immediate
1051:
1052: : g>xt ( ghost -- xt )
1053: \G Returns the xt (cfa) of a ghost. Issues a warning if undefined.
1054: dup undefined? ABORT" CROSS: forward " >link @ ;
1055:
1056: : g>body ( ghost -- body )
1057: \G Returns the body-address (pfa) of a ghost.
1058: \G Issues a warning if undefined (a forward-reference).
1059: g>xt X >body ;
1060:
1061: 1 Constant <label>
1062:
1063: Struct
1064: \ bitmask of address type (not used for now)
1065: cell% field addr-type
1066: \ if this address is an xt, this field points to the ghost
1067: cell% field addr-xt-ghost
1068: \ a bit mask that tells as what part of the cell
1069: \ is refenced from an address pointer, used for assembler generation
1070: cell% field addr-refs
1071: End-Struct addr-struct
1072:
1073: : %allocerase ( align size -- addr )
1074: dup >r %alloc dup r> erase ;
1075:
1076: \ returns the addr struct, define it if 0 reference
1077: : define-addr-struct ( addr -- struct-addr )
1078: dup @ ?dup IF nip EXIT THEN
1079: addr-struct %allocerase tuck swap ! ;
1080:
1081: >cross
1082:
1083: \ Predefined ghosts 12dec92py
1084:
1085: Ghost - drop \ need a ghost otherwise "-" would be treated as a number
1086:
1087: Ghost 0= drop
1088: Ghost branch Ghost ?branch 2drop
1089: Ghost unloop Ghost ;S 2drop
1090: Ghost lit Ghost ! 2drop
1091: Ghost noop drop
1092: Ghost over Ghost = Ghost drop 2drop drop
1093: Ghost 2drop drop
1094: Ghost 2dup drop
1095: Ghost call drop
1096: Ghost @ drop
1097: Ghost useraddr drop
1098: Ghost execute drop
1099: Ghost + drop
1100: Ghost decimal drop
1101: Ghost hex drop
1102: Ghost lit@ drop
1103: Ghost lit-perform drop
1104: Ghost lit+ drop
1105: Ghost does-exec drop
1106:
1107: Ghost :docol Ghost :doesjump Ghost :dodoes 2drop drop
1108: Ghost :dovar drop
1109:
1110: \ \ Parameter for target systems 06oct92py
1111:
1112:
1113: \ we define it ans like...
1114: wordlist Constant target-environment
1115:
1116: \ save information of current dictionary to restore with environ>
1117: Variable env-current
1118:
1119: : >ENVIRON get-current env-current ! target-environment set-current ;
1120: : ENVIRON> env-current @ set-current ;
1121:
1122: >TARGET
1123:
1124: : environment? ( addr len -- [ x ] true | false )
1125: \G returns the content of environment variable and true or
1126: \G false if not present
1127: target-environment search-wordlist
1128: IF EXECUTE true ELSE false THEN ;
1129:
1130: : $has? ( addr len -- x | false )
1131: \G returns the content of environment variable
1132: \G or false if not present
1133: T environment? H dup IF drop THEN ;
1134:
1135: : e? ( "name" -- x )
1136: \G returns the content of environment variable.
1137: \G The variable is expected to exist. If not, issue an error.
1138: bl word count T environment? H
1139: 0= ABORT" environment variable not defined!" ;
1140:
1141: : has? ( "name" --- x | false )
1142: \G returns the content of environment variable
1143: \G or false if not present
1144: bl word count T $has? H ;
1145:
1146:
1147: >ENVIRON get-order get-current swap 1+ set-order
1148: true SetValue compiler
1149: true SetValue cross
1150: true SetValue standard-threading
1151: >TARGET previous
1152:
1153: 0
1154: [IFDEF] mach-file drop mach-file count 1 [THEN]
1155: [IFDEF] machine-file drop machine-file 1 [THEN]
1156: [IF] included hex
1157: [ELSE] cr ." No machine description!" ABORT
1158: [THEN]
1159:
1160: >ENVIRON
1161:
1162: T has? ec H
1163: [IF]
1164: false DefaultValue relocate
1165: false DefaultValue file
1166: false DefaultValue OS
1167: false DefaultValue prims
1168: false DefaultValue floating
1169: false DefaultValue glocals
1170: false DefaultValue dcomps
1171: false DefaultValue hash
1172: false DefaultValue xconds
1173: false DefaultValue header
1174: false DefaultValue backtrace
1175: false DefaultValue new-input
1176: false DefaultValue peephole
1177: false DefaultValue abranch
1178: true DefaultValue control-rack
1179: [THEN]
1180:
1181: true DefaultValue interpreter
1182: true DefaultValue ITC
1183: false DefaultValue rom
1184: true DefaultValue standardthreading
1185:
1186: >TARGET
1187: s" relocate" T environment? H
1188: \ JAW why set NIL to this?!
1189: [IF] drop \ SetValue NIL
1190: [ELSE] >ENVIRON X NIL SetValue relocate
1191: [THEN]
1192: >TARGET
1193:
1194: 0 Constant NIL
1195:
1196: >CROSS
1197:
1198: \ \ Create additional parameters 19jan95py
1199:
1200: \ currently cross only works for host machines with address-unit-bits
1201: \ eual to 8 because of s! and sc!
1202: \ but I start to query the environment just to modularize a little bit
1203:
1204: : check-address-unit-bits ( -- )
1205: \ s" ADDRESS-UNIT-BITS" environment?
1206: \ IF 8 <> ELSE true THEN
1207: \ ABORT" ADDRESS-UNIT-BITS unknown or not equal to 8!"
1208:
1209: \ shit, this doesn't work because environment? is only defined for
1210: \ gforth.fi and not kernl???.fi
1211: ;
1212:
1213: check-address-unit-bits
1214: 8 Constant bits/byte \ we define: byte is address-unit
1215:
1216: 1 bits/byte lshift Constant maxbyte
1217: \ this sets byte size for the target machine, (probably right guess) jaw
1218:
1219: T
1220: NIL Constant TNIL
1221: cell Constant tcell
1222: cell<< Constant tcell<<
1223: cell>bit Constant tcell>bit
1224: bits/char Constant tbits/char
1225: bits/char H bits/byte T /
1226: Constant tchar
1227: float Constant tfloat
1228: 1 bits/char lshift Constant tmaxchar
1229: [IFUNDEF] bits/byte
1230: 8 Constant tbits/byte
1231: [ELSE]
1232: bits/byte Constant tbits/byte
1233: [THEN]
1234: H
1235: tbits/char bits/byte / Constant tbyte
1236:
1237:
1238: \ Variables 06oct92py
1239:
1240: Variable image
1241: Variable (tlast)
1242: (tlast) Value tlast TNIL tlast ! \ Last name field
1243: Variable tlastcfa \ Last code field
1244: Variable bit$
1245:
1246: \ statistics 10jun97jaw
1247:
1248: Variable headers-named 0 headers-named !
1249: Variable user-vars 0 user-vars !
1250:
1251: : target>bitmask-size ( u1 -- u2 )
1252: 1- tcell>bit rshift 1+ ;
1253:
1254: : allocatetarget ( size -- adr )
1255: dup allocate ABORT" CROSS: No memory for target"
1256: swap over swap erase ;
1257:
1258: \ \ memregion.fs
1259:
1260:
1261: Variable last-defined-region \ pointer to last defined region
1262: Variable region-link \ linked list with all regions
1263: Variable mirrored-link \ linked list for mirrored regions
1264: 0 dup mirrored-link ! region-link !
1265:
1266: : >rname 8 cells + ;
1267: : >rbm 4 cells + ; \ bitfield per cell witch indicates relocation
1268: : >rmem 5 cells + ;
1269: : >rtype 6 cells + ; \ field per cell witch points to a type struct
1270: : >rrom 7 cells + ; \ a -1 indicates that this region is rom
1271: : >rlink 3 cells + ;
1272: : >rdp 2 cells + ;
1273: : >rlen cell+ ;
1274: : >rstart ;
1275:
1276: : (region) ( addr len region -- )
1277: \G change startaddress and length of an existing region
1278: >r r@ last-defined-region !
1279: r@ >rlen ! dup r@ >rstart ! r> >rdp ! ;
1280:
1281: : region ( addr len -- "name" )
1282: \G create a new region
1283: \ check whether predefined region exists
1284: save-input bl word find >r >r restore-input throw r> r> 0=
1285: IF \ make region
1286: drop
1287: save-input create restore-input throw
1288: here last-defined-region !
1289: over ( startaddr ) , ( length ) , ( dp ) ,
1290: region-link linked 0 , 0 , 0 , 0 , bl word count string,
1291: ELSE \ store new parameters in region
1292: bl word drop
1293: >body (region)
1294: THEN ;
1295:
1296: : borders ( region -- startaddr endaddr )
1297: \G returns lower and upper region border
1298: dup >rstart @ swap >rlen @ over + ;
1299:
1300: : extent ( region -- startaddr len )
1301: \G returns the really used area
1302: dup >rstart @ swap >rdp @ over - ;
1303:
1304: : area ( region -- startaddr totallen )
1305: \G returns the total area
1306: dup >rstart @ swap >rlen @ ;
1307:
1308: : mirrored ( -- )
1309: \G mark last defined region as mirrored
1310: mirrored-link
1311: align linked last-defined-region @ , ;
1312:
1313: : writeprotected
1314: \G mark a region as write protected
1315: -1 last-defined-region @ >rrom ! ;
1316:
1317: : .addr ( u -- )
1318: \G prints a 16 or 32 Bit nice hex value
1319: base @ >r hex
1320: tcell 2 u>
1321: IF s>d <# # # # # [char] . hold # # # # #> type
1322: ELSE s>d <# # # # # # #> type
1323: THEN r> base ! space ;
1324:
1325: : .regions \G display region statistic
1326:
1327: \ we want to list the regions in the right order
1328: \ so first collect all regions on stack
1329: 0 region-link @
1330: BEGIN dup WHILE dup @ REPEAT drop
1331: BEGIN dup
1332: WHILE cr
1333: 0 >rlink - >r
1334: r@ >rname count tuck type
1335: 12 swap - 0 max spaces space
1336: ." Start: " r@ >rstart @ dup .addr space
1337: ." End: " r@ >rlen @ + .addr space
1338: ." DP: " r> >rdp @ .addr
1339: REPEAT drop
1340: s" rom" T $has? H 0= ?EXIT
1341: cr ." Mirrored:"
1342: mirrored-link @
1343: BEGIN dup
1344: WHILE space dup cell+ @ >rname count type @
1345: REPEAT drop cr
1346: ;
1347:
1348: \ -------- predefined regions
1349:
1350: 0 0 region address-space
1351: \ total memory addressed and used by the target system
1352:
1353: 0 0 region dictionary
1354: \ rom area for the compiler
1355:
1356: T has? rom H
1357: [IF]
1358: 0 0 region ram-dictionary mirrored
1359: \ ram area for the compiler
1360: [ELSE]
1361: ' dictionary ALIAS ram-dictionary
1362: [THEN]
1363:
1364: 0 0 region return-stack
1365:
1366: 0 0 region data-stack
1367:
1368: 0 0 region tib-region
1369:
1370: ' dictionary ALIAS rom-dictionary
1371:
1372:
1373: : setup-target ( -- ) \G initialize target's memory space
1374: s" rom" T $has? H
1375: IF \ check for ram and rom...
1376: \ address-space area nip 0<>
1377: ram-dictionary area nip 0<>
1378: rom-dictionary area nip 0<>
1379: and 0=
1380: ABORT" CROSS: define address-space, rom- , ram-dictionary, with rom-support!"
1381: THEN
1382: address-space area nip
1383: IF
1384: address-space area
1385: ELSE
1386: dictionary area
1387: THEN
1388: nip 0=
1389: ABORT" CROSS: define at least address-space or dictionary!!"
1390:
1391: \ allocate target for each region
1392: region-link
1393: BEGIN @ dup
1394: WHILE dup
1395: 0 >rlink - >r
1396: r@ >rlen @
1397: IF \ allocate mem
1398: r@ >rlen @ allocatetarget dup image !
1399: r@ >rmem !
1400:
1401: r@ >rlen @
1402: target>bitmask-size allocatetarget
1403: dup bit$ !
1404: r@ >rbm !
1405:
1406: r@ >rlen @
1407: tcell / 1+ cells allocatetarget r@ >rtype !
1408:
1409: rdrop
1410: ELSE r> drop THEN
1411: REPEAT drop ;
1412:
1413: \ MakeKernel 22feb99jaw
1414:
1415: : makekernel ( targetsize -- )
1416: \G convenience word to setup the memory of the target
1417: \G used by main.fs of the c-engine based systems
1418: 100 swap dictionary (region)
1419: setup-target ;
1420:
1421: >MINIMAL
1422: : makekernel makekernel ;
1423: >CROSS
1424:
1425: \ \ switched tdp for rom support 03jun97jaw
1426:
1427: \ second value is here to store some maximal value for statistics
1428: \ tempdp is also embedded here but has nothing to do with rom support
1429: \ (needs switched dp)
1430:
1431: variable tempdp 0 , \ temporary dp for resolving
1432: variable tempdp-save
1433:
1434: 0 [IF]
1435: variable romdp 0 , \ Dictionary-Pointer for ramarea
1436: variable ramdp 0 , \ Dictionary-Pointer for romarea
1437:
1438: \
1439: variable sramdp \ start of ram-area for forth
1440: variable sromdp \ start of rom-area for forth
1441:
1442: [THEN]
1443:
1444: 0 Value current-region
1445: 0 Value tdp
1446: Variable fixed \ flag: true: no automatic switching
1447: \ false: switching is done automatically
1448:
1449: \ Switch-Policy:
1450: \
1451: \ a header is always compiled into rom
1452: \ after a created word (create and variable) compilation goes to ram
1453: \
1454: \ Be careful: If you want to make the data behind create into rom
1455: \ you have to put >rom before create!
1456:
1457: variable constflag constflag off
1458:
1459: : activate ( region -- )
1460: \G next code goes to this region
1461: dup to current-region >rdp to tdp ;
1462:
1463: : (switchram)
1464: fixed @ ?EXIT s" rom" T $has? H 0= ?EXIT
1465: ram-dictionary activate ;
1466:
1467: : switchram
1468: constflag @
1469: IF constflag off ELSE (switchram) THEN ;
1470:
1471: : switchrom
1472: fixed @ ?EXIT rom-dictionary activate ;
1473:
1474: : >tempdp ( addr -- )
1475: tdp tempdp-save ! tempdp to tdp tdp ! ;
1476: : tempdp> ( -- )
1477: tempdp-save @ to tdp ;
1478:
1479: : >ram fixed off (switchram) fixed on ;
1480: : >rom fixed off switchrom fixed on ;
1481: : >auto fixed off switchrom ;
1482:
1483:
1484:
1485: \ : romstart dup sromdp ! romdp ! ;
1486: \ : ramstart dup sramdp ! ramdp ! ;
1487:
1488: \ default compilation goes to rom
1489: \ when romable support is off, only the rom switch is used (!!)
1490: >auto
1491:
1492: : there tdp @ ;
1493:
1494: >TARGET
1495:
1496: \ \ Target Memory Handling
1497:
1498: \ Byte ordering and cell size 06oct92py
1499:
1500: : cell+ tcell + ;
1501: : cells tcell<< lshift ;
1502: : chars tchar * ;
1503: : char+ tchar + ;
1504: : floats tfloat * ;
1505:
1506: >CROSS
1507: : cell/ tcell<< rshift ;
1508: >TARGET
1509: 20 CONSTANT bl
1510: \ TNIL Constant NIL
1511:
1512: >CROSS
1513:
1514: bigendian
1515: [IF]
1516: : DS! ( d addr -- ) tcell bounds swap 1-
1517: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
1518: : DS@ ( addr -- d ) >r 0 0 r> tcell bounds
1519: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP ;
1520: : Sc! ( n addr -- ) >r s>d r> tchar bounds swap 1-
1521: DO maxbyte ud/mod rot I c! -1 +LOOP 2drop ;
1522: : Sc@ ( addr -- n ) >r 0 0 r> tchar bounds
1523: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap LOOP d>s ;
1524: [ELSE]
1525: : DS! ( d addr -- ) tcell bounds
1526: DO maxbyte ud/mod rot I c! LOOP 2drop ;
1527: : DS@ ( addr -- n ) >r 0 0 r> tcell bounds swap 1-
1528: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP ;
1529: : Sc! ( n addr -- ) >r s>d r> tchar bounds
1530: DO maxbyte ud/mod rot I c! LOOP 2drop ;
1531: : Sc@ ( addr -- n ) >r 0 0 r> tchar bounds swap 1-
1532: DO maxbyte * swap maxbyte um* rot + swap I c@ + swap -1 +LOOP d>s ;
1533: [THEN]
1534:
1535: : S! ( n addr -- ) >r s>d r> DS! ;
1536: : S@ ( addr -- n ) DS@ d>s ;
1537:
1538: : taddr>region ( taddr -- region | 0 )
1539: \G finds for a target-address the correct region
1540: \G returns 0 if taddr is not in range of a target memory region
1541: region-link
1542: BEGIN @ dup
1543: WHILE dup >r
1544: 0 >rlink - >r
1545: r@ >rlen @
1546: IF dup r@ borders within
1547: IF r> r> drop nip EXIT THEN
1548: THEN
1549: r> drop
1550: r>
1551: REPEAT
1552: 2drop 0 ;
1553:
1554: : taddr>region-abort ( taddr -- region | 0 )
1555: \G Same as taddr>region but aborts if taddr is not
1556: \G a valid address in the target address space
1557: dup taddr>region dup 0=
1558: IF drop cr ." Wrong address: " .addr
1559: -1 ABORT" Address out of range!"
1560: THEN nip ;
1561:
1562: : (>regionimage) ( taddr -- 'taddr )
1563: dup
1564: \ find region we want to address
1565: taddr>region-abort
1566: >r
1567: \ calculate offset in region
1568: r@ >rstart @ -
1569: \ add regions real address in our memory
1570: r> >rmem @ + ;
1571:
1572: : (>regionramimage) ( taddr -- 'taddr )
1573: \G same as (>regionimage) but aborts if the region is rom
1574: dup
1575: \ find region we want to address
1576: taddr>region-abort
1577: >r
1578: r@ >rrom @ ABORT" CROSS: region is write-protected!"
1579: \ calculate offset in region
1580: r@ >rstart @ -
1581: \ add regions real address in our memory
1582: r> >rmem @ + ;
1583:
1584: : (>regionbm) ( taddr -- 'taddr bitmaskbaseaddr )
1585: dup
1586: \ find region we want to address
1587: taddr>region-abort
1588: >r
1589: \ calculate offset in region
1590: r@ >rstart @ -
1591: \ add regions real address in our memory
1592: r> >rbm @ ;
1593:
1594: : (>regiontype) ( taddr -- 'taddr )
1595: dup
1596: \ find region we want to address
1597: taddr>region-abort
1598: >r
1599: \ calculate offset in region
1600: r@ >rstart @ - tcell / cells
1601: \ add regions real address in our memory
1602: r> >rtype @ + ;
1603:
1604: \ Bit string manipulation 06oct92py
1605: \ 9may93jaw
1606: CREATE Bittable 80 c, 40 c, 20 c, 10 c, 8 c, 4 c, 2 c, 1 c,
1607: : bits ( n -- n ) chars Bittable + c@ ;
1608:
1609: : >bit ( addr n -- c-addr mask ) 8 /mod rot + swap bits ;
1610: : +bit ( addr n -- ) >bit over c@ or swap c! ;
1611: : -bit ( addr n -- ) >bit invert over c@ and swap c! ;
1612:
1613: : @relbit ( taddr -- f ) (>regionbm) swap cell/ >bit swap c@ and ;
1614:
1615: : (relon) ( taddr -- )
1616: [ [IFDEF] fd-relocation-table ]
1617: s" +" fd-relocation-table write-file throw
1618: dup s>d <# #s #> fd-relocation-table write-line throw
1619: [ [THEN] ]
1620: (>regionbm) swap cell/ +bit ;
1621:
1622: : (reloff) ( taddr -- )
1623: [ [IFDEF] fd-relocation-table ]
1624: s" -" fd-relocation-table write-file throw
1625: dup s>d <# #s #> fd-relocation-table write-line throw
1626: [ [THEN] ]
1627: (>regionbm) swap cell/ -bit ;
1628:
1629: : (>image) ( taddr -- absaddr ) image @ + ;
1630:
1631: DEFER >image
1632: DEFER >ramimage
1633: DEFER relon
1634: DEFER reloff
1635: DEFER correcter
1636:
1637: T has? relocate H
1638: [IF]
1639: ' (relon) IS relon
1640: ' (reloff) IS reloff
1641: ' (>regionimage) IS >image
1642: ' (>regionimage) IS >ramimage
1643: [ELSE]
1644: ' drop IS relon
1645: ' drop IS reloff
1646: ' (>regionimage) IS >image
1647: ' (>regionimage) IS >ramimage
1648: [THEN]
1649:
1650: : enforce-writeprotection ( -- )
1651: ['] (>regionramimage) IS >ramimage ;
1652:
1653: : relax-writeprotection ( -- )
1654: ['] (>regionimage) IS >ramimage ;
1655:
1656: : writeprotection-relaxed? ( -- )
1657: ['] >ramimage >body @ ['] (>regionimage) = ;
1658:
1659: \ Target memory access 06oct92py
1660:
1661: : align+ ( taddr -- rest )
1662: tcell tuck 1- and - [ tcell 1- ] Literal and ;
1663: : cfalign+ ( taddr -- rest )
1664: \ see kernel.fs:cfaligned
1665: /maxalign tuck 1- and - [ /maxalign 1- ] Literal and ;
1666:
1667: >TARGET
1668: : aligned ( taddr -- ta-addr ) dup align+ + ;
1669: \ assumes cell alignment granularity (as GNU C)
1670:
1671: : cfaligned ( taddr1 -- taddr2 )
1672: \ see kernel.fs
1673: dup cfalign+ + ;
1674:
1675: : @ ( taddr -- w ) >image S@ ;
1676: : ! ( w taddr -- ) >ramimage S! ;
1677: : c@ ( taddr -- char ) >image Sc@ ;
1678: : c! ( char taddr -- ) >ramimage Sc! ;
1679: : 2@ ( taddr -- x1 x2 ) T dup cell+ @ swap @ H ;
1680: : 2! ( x1 x2 taddr -- ) T tuck ! cell+ ! H ;
1681:
1682: \ Target compilation primitives 06oct92py
1683: \ included A! 16may93jaw
1684:
1685: : here ( -- there ) there ;
1686: : allot ( n -- ) tdp +! ;
1687: : , ( w -- ) T here H tcell T allot ! H ;
1688: : c, ( char -- ) T here H tchar T allot c! H ;
1689: : align ( -- ) T here H align+ 0 ?DO bl T c, H tchar +LOOP ;
1690: : cfalign ( -- )
1691: T here H cfalign+ 0 ?DO bl T c, H tchar +LOOP ;
1692:
1693: : >address dup 0>= IF tbyte / THEN ; \ ?? jaw
1694: : A! swap >address swap dup relon T ! H ;
1695: : A, ( w -- ) >address T here H relon T , H ;
1696:
1697: \ high-level ghosts
1698:
1699: >CROSS
1700:
1701: Ghost (do) Ghost (?do) 2drop
1702: Ghost (for) drop
1703: Ghost (loop) Ghost (+loop) 2drop
1704: Ghost (next) drop
1705: Ghost (does>) Ghost (compile) 2drop
1706: Ghost (.") Ghost (S") Ghost (ABORT") 2drop drop
1707: Ghost (C") Ghost c(abort") Ghost type 2drop drop
1708: Ghost ' drop
1709:
1710: \ user ghosts
1711:
1712: Ghost state drop
1713:
1714: \ \ -------------------- Host/Target copy etc. 29aug01jaw
1715:
1716:
1717: >CROSS
1718:
1719: : TD! >image DS! ;
1720: : TD@ >image DS@ ;
1721:
1722: : th-count ( taddr -- host-addr len )
1723: \G returns host address of target string
1724: assert1( tbyte 1 = )
1725: dup X c@ swap X char+ >image swap ;
1726:
1727: : ht-move ( haddr taddr len -- )
1728: \G moves data from host-addr to destination in target-addr
1729: \G character by character
1730: swap -rot bounds ?DO I c@ over X c! X char+ LOOP drop ;
1731:
1732: 2Variable last-string
1733:
1734: : ht-string, ( addr count -- )
1735: dup there swap last-string 2!
1736: dup T c, H bounds ?DO I c@ T c, H LOOP ;
1737: : ht-mem, ( addr count )
1738: bounds ?DO I c@ T c, H LOOP ;
1739:
1740: >TARGET
1741:
1742: : count dup X c@ swap X char+ swap ;
1743:
1744: : on -1 -1 rot TD! ;
1745: : off T 0 swap ! H ;
1746:
1747: : tcmove ( source dest len -- )
1748: \G cmove in target memory
1749: tchar * bounds
1750: ?DO dup T c@ H I T c! H 1+
1751: tchar +LOOP drop ;
1752:
1753: : td, ( d -- )
1754: \G Store a host value as one cell into the target
1755: there tcell X allot TD! ;
1756:
1757: \ \ Load Assembler
1758:
1759: >TARGET
1760: H also Forth definitions
1761:
1762: \ FIXME: should we include the assembler really in the forth
1763: \ dictionary?!?!?!? This conflicts with the existing assembler
1764: \ of the host forth system!!
1765: [IFDEF] asm-include asm-include [THEN] hex
1766:
1767: previous
1768:
1769:
1770: >CROSS
1771:
1772: : (cc) T a, H ; ' (cc) plugin-of colon,
1773: : (prim) T a, H ; ' (prim) plugin-of prim,
1774:
1775: : (cr) >tempdp colon, tempdp> ; ' (cr) plugin-of colon-resolve
1776: : (ar) T ! H ; ' (ar) plugin-of addr-resolve
1777: : (dr) ( ghost res-pnt target-addr addr )
1778: >tempdp drop over
1779: dup >magic @ <do:> =
1780: IF doer,
1781: ELSE dodoes,
1782: THEN
1783: tempdp> ; ' (dr) plugin-of doer-resolve
1784:
1785: : (cm) ( -- addr )
1786: there -1 colon, ; ' (cm) plugin-of colonmark,
1787:
1788: >TARGET
1789: : compile, ( xt -- )
1790: dup xt>ghost >comp @ EXECUTE ;
1791: >CROSS
1792:
1793: \ resolve structure
1794:
1795: : >next ; \ link to next field
1796: : >tag cell+ ; \ indecates type of reference: 0: call, 1: address, 2: doer
1797: : >taddr cell+ cell+ ;
1798: : >ghost 3 cells + ;
1799: : >file 4 cells + ;
1800: : >line 5 cells + ;
1801:
1802: : (refered) ( ghost addr tag -- )
1803: \G creates a reference to ghost at address taddr
1804: >space
1805: rot >link linked
1806: ( taddr tag ) ,
1807: ( taddr ) ,
1808: last-header-ghost @ ,
1809: loadfile ,
1810: sourceline# ,
1811: space>
1812: ;
1813:
1814: : refered ( ghost tag -- )
1815: \G creates a resolve structure
1816: T here aligned H swap (refered)
1817: ;
1818:
1819: : killref ( addr ghost -- )
1820: \G kills a forward reference to ghost at position addr
1821: \G this is used to eleminate a :dovar refence after making a DOES>
1822: dup >magic @ <fwd> <> IF 2drop EXIT THEN
1823: swap >r >link
1824: BEGIN dup @ dup ( addr last this )
1825: WHILE dup >taddr @ r@ =
1826: IF @ over !
1827: ELSE nip THEN
1828: REPEAT rdrop 2drop
1829: ;
1830:
1831: Defer resolve-warning
1832:
1833: : reswarn-test ( ghost res-struct -- ghost res-struct )
1834: over cr ." Resolving " .ghost dup ." in " >ghost @ .ghost ;
1835:
1836: : reswarn-forward ( ghost res-struct -- ghost res-struct )
1837: over warnhead .ghost dup ." is referenced in "
1838: >ghost @ .ghost ;
1839:
1840: \ ' reswarn-test IS resolve-warning
1841:
1842: \ resolve 14oct92py
1843:
1844: : resolve-loop ( ghost resolve-list tcfa -- )
1845: >r
1846: BEGIN dup WHILE
1847: \ dup >tag @ 2 = IF reswarn-forward THEN
1848: resolve-warning
1849: r@ over >taddr @
1850: 2 pick >tag @
1851: CASE 0 OF colon-resolve ENDOF
1852: 1 OF addr-resolve ENDOF
1853: 2 OF doer-resolve ENDOF
1854: ENDCASE
1855: @ \ next list element
1856: REPEAT 2drop rdrop
1857: ;
1858:
1859: \ : resolve-loop ( ghost tcfa -- ghost tcfa )
1860: \ >r dup >link @
1861: \ BEGIN dup WHILE dup T @ H r@ rot T ! H REPEAT drop r> ;
1862:
1863: \ exists 9may93jaw
1864:
1865: : exists ( ghost tcfa -- )
1866: \G print warning and set new target link in ghost
1867: swap exists-warning
1868: >link ! ;
1869:
1870: : colon-resolved ( ghost -- )
1871: \ compiles a call to a colon definition,
1872: \ compile action for >comp field
1873: >link @ colon, ;
1874:
1875: : prim-resolved ( ghost -- )
1876: \ compiles a call to a primitive
1877: >link @ prim, ;
1878:
1879: : (is-forward) ( ghost -- )
1880: colonmark, 0 (refered) ; \ compile space for call
1881: ' (is-forward) IS is-forward
1882:
1883: 0 Value resolved
1884:
1885: : resolve-forward-references ( ghost resolve-list -- )
1886: \ loop through forward referencies
1887: comp-state @ >r Resolving comp-state !
1888: over >link @ resolve-loop
1889: r> comp-state !
1890:
1891: ['] noop IS resolve-warning ;
1892:
1893:
1894: : (resolve) ( ghost tcfa -- ghost resolve-list )
1895: \ check for a valid address, it is a primitive reference
1896: \ otherwise
1897: dup taddr>region 0<> IF
1898: \ define this address in the region address type table
1899: 2dup (>regiontype) define-addr-struct addr-xt-ghost
1900: \ we define new address only if empty
1901: \ this is for not to take over the alias ghost
1902: \ (different ghost, but identical xt)
1903: \ but the very first that really defines it
1904: dup @ 0= IF ! ELSE 2drop THEN
1905: THEN
1906: swap >r
1907: r@ to resolved
1908:
1909: \ r@ >comp @ ['] is-forward =
1910: \ ABORT" >comp action not set on a resolved ghost"
1911:
1912: \ copmile action defaults to colon-resolved
1913: \ if this is not right something must be set before
1914: \ calling resolve
1915: r@ >comp @ ['] is-forward = IF
1916: ['] colon-resolved r@ >comp !
1917: THEN
1918: r@ >link @ swap \ ( list tcfa R: ghost )
1919: \ mark ghost as resolved
1920: r@ >link ! <res> r@ >magic !
1921: r> swap ;
1922:
1923: : resolve ( ghost tcfa -- )
1924: \G resolve referencies to ghost with tcfa
1925: \ is ghost resolved?, second resolve means another
1926: \ definition with the same name
1927: over undefined? 0= IF exists EXIT THEN
1928: (resolve)
1929: ( ghost resolve-list )
1930: resolve-forward-references ;
1931:
1932: : resolve-noforwards ( ghost tcfa -- )
1933: \G Same as resolve but complain if there are any
1934: \G forward references on this ghost
1935: \ is ghost resolved?, second resolve means another
1936: \ definition with the same name
1937: over undefined? 0= IF exists EXIT THEN
1938: (resolve)
1939: IF cr ." No forward references allowed on: " .ghost cr
1940: -1 ABORT" Illegal forward reference"
1941: THEN
1942: drop ;
1943:
1944: \ gexecute ghost, 01nov92py
1945:
1946: : (gexecute) ( ghost -- )
1947: dup >comp @ EXECUTE ;
1948:
1949: : gexecute ( ghost -- )
1950: dup >magic @ <imm> = ABORT" CROSS: gexecute on immediate word"
1951: (gexecute) ;
1952:
1953: : addr, ( ghost -- )
1954: dup forward? IF 1 refered 0 T a, H ELSE >link @ T a, H THEN ;
1955:
1956: \ .unresolved 11may93jaw
1957:
1958: variable ResolveFlag
1959:
1960: \ ?touched 11may93jaw
1961:
1962: : ?touched ( ghost -- flag ) dup forward? swap >link @
1963: 0 <> and ;
1964:
1965: : .forwarddefs ( ghost -- )
1966: ." appeared in:"
1967: >link
1968: BEGIN @ dup
1969: WHILE cr 5 spaces
1970: dup >ghost @ .ghost
1971: ." file " dup >file @ ?dup IF count type ELSE ." CON" THEN
1972: ." line " dup >line @ .dec
1973: REPEAT
1974: drop ;
1975:
1976: : ?resolved ( ghost -- )
1977: dup ?touched
1978: IF ResolveFlag on
1979: dup cr .ghost .forwarddefs
1980: ELSE drop
1981: THEN ;
1982:
1983: : .unresolved ( -- )
1984: ResolveFlag off cr ." Unresolved: "
1985: ghost-list
1986: BEGIN @ dup
1987: WHILE dup ?resolved
1988: REPEAT drop ResolveFlag @
1989: IF
1990: -1 abort" Unresolved words!"
1991: ELSE
1992: ." Nothing!"
1993: THEN
1994: cr ;
1995:
1996: : .stats
1997: base @ >r decimal
1998: cr ." named Headers: " headers-named @ .
1999: r> base ! ;
2000:
2001: >MINIMAL
2002:
2003: : .unresolved .unresolved ;
2004:
2005: >CROSS
2006: \ Header states 12dec92py
2007:
2008: \ : flag! ( 8b -- ) tlast @ dup >r T c@ xor r> c! H ;
2009: bigendian [IF] 0 [ELSE] tcell 1- [THEN] Constant flag+
2010: : flag! ( w -- ) tlast @ flag+ + dup >r T c@ xor r> c! H ;
2011:
2012: VARIABLE ^imm
2013:
2014: \ !! should be target wordsize specific
2015: $80 constant alias-mask
2016: $40 constant immediate-mask
2017: $20 constant restrict-mask
2018:
2019: >TARGET
2020: : immediate immediate-mask flag!
2021: ^imm @ @ dup <imm> = IF drop EXIT THEN
2022: <res> <> ABORT" CROSS: Cannot immediate a unresolved word"
2023: <imm> ^imm @ ! ;
2024: : restrict restrict-mask flag! ;
2025:
2026: : isdoer
2027: \G define a forth word as doer, this makes obviously only sence on
2028: \G forth processors such as the PSC1000
2029: <do:> last-header-ghost @ >magic ! ;
2030: >CROSS
2031:
2032: \ Target Header Creation 01nov92py
2033:
2034: : ht-lstring, ( addr count -- )
2035: dup T , H bounds ?DO I c@ T c, H LOOP ;
2036:
2037: >TARGET
2038: : name, ( "name" -- ) bl word count ht-lstring, X cfalign ;
2039: : view, ( -- ) ( dummy ) ;
2040: >CROSS
2041:
2042: \ Target Document Creation (goes to crossdoc.fd) 05jul95py
2043:
2044: s" ./doc/crossdoc.fd" r/w create-file throw value doc-file-id
2045: \ contains the file-id of the documentation file
2046:
2047: : T-\G ( -- )
2048: source >in @ /string doc-file-id write-line throw
2049: postpone \ ;
2050:
2051: Variable to-doc to-doc on
2052:
2053: : cross-doc-entry ( -- )
2054: to-doc @ tlast @ 0<> and \ not an anonymous (i.e. noname) header
2055: IF
2056: s" " doc-file-id write-line throw
2057: s" make-doc " doc-file-id write-file throw
2058:
2059: Last-Header-Ghost @ >ghostname doc-file-id write-file throw
2060: >in @
2061: [char] ( parse 2drop
2062: [char] ) parse doc-file-id write-file throw
2063: s" )" doc-file-id write-file throw
2064: [char] \ parse 2drop
2065: T-\G
2066: >in !
2067: THEN ;
2068:
2069: \ Target TAGS creation
2070:
2071: s" kernel.TAGS" r/w create-file throw value tag-file-id
2072: s" kernel.tags" r/w create-file throw value vi-tag-file-id
2073: \ contains the file-id of the tags file
2074:
2075: Create tag-beg 2 c, 7F c, bl c,
2076: Create tag-end 2 c, bl c, 01 c,
2077: Create tag-bof 1 c, 0C c,
2078: Create tag-tab 1 c, 09 c,
2079:
2080: 2variable last-loadfilename 0 0 last-loadfilename 2!
2081:
2082: : put-load-file-name ( -- )
2083: sourcefilename last-loadfilename 2@ d<>
2084: IF
2085: tag-bof count tag-file-id write-line throw
2086: sourcefilename 2dup
2087: tag-file-id write-file throw
2088: last-loadfilename 2!
2089: s" ,0" tag-file-id write-line throw
2090: THEN ;
2091:
2092: : cross-gnu-tag-entry ( -- )
2093: tlast @ 0<> \ not an anonymous (i.e. noname) header
2094: IF
2095: put-load-file-name
2096: source >in @ min tag-file-id write-file throw
2097: tag-beg count tag-file-id write-file throw
2098: Last-Header-Ghost @ >ghostname tag-file-id write-file throw
2099: tag-end count tag-file-id write-file throw
2100: base @ decimal sourceline# 0 <# #s #> tag-file-id write-file throw
2101: \ >in @ 0 <# #s [char] , hold #> tag-file-id write-line throw
2102: s" ,0" tag-file-id write-line throw
2103: base !
2104: THEN ;
2105:
2106: : cross-vi-tag-entry ( -- )
2107: tlast @ 0<> \ not an anonymous (i.e. noname) header
2108: IF
2109: sourcefilename vi-tag-file-id write-file throw
2110: tag-tab count vi-tag-file-id write-file throw
2111: Last-Header-Ghost @ >ghostname vi-tag-file-id write-file throw
2112: tag-tab count vi-tag-file-id write-file throw
2113: s" /^" vi-tag-file-id write-file throw
2114: source vi-tag-file-id write-file throw
2115: s" $/" vi-tag-file-id write-line throw
2116: THEN ;
2117:
2118: : cross-tag-entry ( -- )
2119: cross-gnu-tag-entry
2120: cross-vi-tag-entry ;
2121:
2122: \ Check for words
2123:
2124: Defer skip? ' false IS skip?
2125:
2126: : skipdef ( "name" -- )
2127: \G skip definition of an undefined word in undef-words and
2128: \G all-words mode
2129: Ghost dup forward?
2130: IF >magic <skip> swap !
2131: ELSE drop THEN ;
2132:
2133: : tdefined? ( "name" -- flag )
2134: Ghost undefined? 0= ;
2135:
2136: : defined2? ( "name" -- flag )
2137: \G return true for anything else than forward, even for <skip>
2138: \G that's what we want
2139: Ghost forward? 0= ;
2140:
2141: : forced? ( "name" -- flag )
2142: \G return ture if it is a foreced skip with defskip
2143: Ghost >magic @ <skip> = ;
2144:
2145: : needed? ( -- flag ) \ name
2146: \G returns a false flag when
2147: \G a word is not defined
2148: \G a forward reference exists
2149: \G so the definition is not skipped!
2150: bl word gfind
2151: IF dup undefined?
2152: nip
2153: 0=
2154: ELSE drop true THEN ;
2155:
2156: : doer? ( -- flag ) \ name
2157: Ghost >magic @ <do:> = ;
2158:
2159: : skip-defs ( -- )
2160: BEGIN refill WHILE source -trailing nip 0= UNTIL THEN ;
2161:
2162: \ Target header creation
2163:
2164: Variable NoHeaderFlag
2165: NoHeaderFlag off
2166:
2167: : 0.r ( n1 n2 -- )
2168: base @ >r hex
2169: 0 swap <# 0 ?DO # LOOP #> type
2170: r> base ! ;
2171:
2172: : .sym ( adr len -- )
2173: \G escapes / and \ to produce sed output
2174: bounds
2175: DO I c@ dup
2176: CASE [char] / OF drop ." \/" ENDOF
2177: [char] \ OF drop ." \\" ENDOF
2178: dup OF emit ENDOF
2179: ENDCASE
2180: LOOP ;
2181:
2182: Defer setup-execution-semantics
2183: 0 Value lastghost
2184:
2185: : (THeader ( "name" -- ghost )
2186: \ >in @ bl word count type 2 spaces >in !
2187: \ wordheaders will always be compiled to rom
2188: switchrom
2189: \ build header in target
2190: NoHeaderFlag @
2191: IF NoHeaderFlag off
2192: ELSE
2193: T align H view,
2194: tlast @ dup 0> IF tcell - THEN T A, H there tlast !
2195: 1 headers-named +! \ Statistic
2196: >in @ T name, H >in !
2197: THEN
2198: T cfalign here H tlastcfa !
2199: \ Old Symbol table sed-script
2200: \ >in @ cr ." sym:s/CFA=" there 4 0.r ." /" bl word count .sym ." /g" cr >in !
2201: HeaderGhost
2202: \ output symbol table to extra file
2203: dup >ghostname there symentry
2204: dup Last-Header-Ghost ! dup to lastghost
2205: dup >magic ^imm ! \ a pointer for immediate
2206: alias-mask flag!
2207: cross-doc-entry cross-tag-entry
2208: setup-execution-semantics
2209: ;
2210:
2211: \ this is the resolver information from ":"
2212: \ resolving is done by ";"
2213: Variable ;Resolve 1 cells allot
2214:
2215: : hereresolve ( ghost -- )
2216: there resolve 0 ;Resolve ! ;
2217:
2218: : Theader ( "name" -- ghost )
2219: (THeader dup hereresolve ;
2220:
2221: Variable aprim-nr -20 aprim-nr !
2222:
2223: : copy-execution-semantics ( ghost-from ghost-dest -- )
2224: >r
2225: dup >exec @ r@ >exec !
2226: dup >comp @ r@ >comp !
2227: dup >exec2 @ r@ >exec2 !
2228: dup >exec-compile @ r@ >exec-compile !
2229: dup >ghost-xt @ r@ >ghost-xt !
2230: dup >created @ r@ >created !
2231: rdrop drop ;
2232:
2233: >TARGET
2234:
2235: : Alias ( cfa -- ) \ name
2236: >in @ skip? IF 2drop EXIT THEN >in !
2237: (THeader ( S xt ghost )
2238: 2dup swap xt>ghost swap copy-execution-semantics
2239: over resolve T A, H alias-mask flag! ;
2240:
2241: Variable last-prim-ghost
2242: 0 last-prim-ghost !
2243:
2244: : asmprimname, ( ghost -- : name )
2245: dup last-prim-ghost !
2246: >r
2247: here bl word count string, r@ >asm-name !
2248: aprim-nr @ r> >asm-dummyaddr ! ;
2249:
2250: Defer setup-prim-semantics
2251:
2252: : mapprim ( "forthname" "asmlabel" -- )
2253: THeader -1 aprim-nr +! aprim-nr @ T A, H
2254: asmprimname,
2255: setup-prim-semantics ;
2256:
2257: : mapprim: ( "forthname" "asmlabel" -- )
2258: -1 aprim-nr +! aprim-nr @
2259: Ghost tuck swap resolve-noforwards <do:> swap tuck >magic !
2260: asmprimname, ;
2261:
2262: : Doer: ( cfa -- ) \ name
2263: >in @ skip? IF 2drop EXIT THEN >in !
2264: dup 0< s" prims" T $has? H 0= and
2265: IF
2266: .sourcepos ." needs doer: " >in @ bl word count type >in ! cr
2267: THEN
2268: Ghost
2269: tuck swap resolve-noforwards <do:> swap >magic ! ;
2270:
2271: Variable prim#
2272: : first-primitive ( n -- ) prim# ! ;
2273: : group 0 word drop prim# @ 1- -$200 and prim# ! ;
2274: : Primitive ( -- ) \ name
2275: >in @ skip? IF drop EXIT THEN >in !
2276: s" prims" T $has? H 0=
2277: IF
2278: .sourcepos ." needs prim: " >in @ bl word count type >in ! cr
2279: THEN
2280: prim# @ (THeader ( S xt ghost )
2281: ['] prim-resolved over >comp !
2282: dup >ghost-flags <primitive> set-flag
2283: over resolve-noforwards T A, H alias-mask flag!
2284: -1 prim# +! ;
2285: >CROSS
2286:
2287: \ Conditionals and Comments 11may93jaw
2288:
2289: \G saves the existing cond action, this is used for redefining in
2290: \G instant
2291: Variable cond-xt-old
2292:
2293: : cond-target ( -- )
2294: \G Compiles semantic of redefined cond into new one
2295: cond-xt-old @ compile, ; immediate restrict
2296:
2297: : ;Cond
2298: postpone ;
2299: swap ! ; immediate
2300:
2301: : Cond: ( "name" -- )
2302: \g defines a conditional or another word that must
2303: \g be executed directly while compiling
2304: \g these words have no interpretative semantics by default
2305: Ghost
2306: >exec-compile
2307: dup @ cond-xt-old !
2308: :NONAME ;
2309:
2310:
2311: : Comment ( -- )
2312: >in @ Ghost swap >in ! ' swap
2313: 2dup >exec-compile ! >exec ! ;
2314:
2315: Comment ( Comment \
2316:
2317: \ compile 10may93jaw
2318:
2319: : compile ( "name" -- ) \ name
2320: findghost
2321: dup >exec-compile @ ?dup
2322: IF nip compile,
2323: ELSE postpone literal postpone gexecute THEN ; immediate restrict
2324:
2325: >TARGET
2326:
2327: : ' ( -- xt )
2328: \G returns the target-cfa of a ghost
2329: bl word gfind 0= ABORT" CROSS: Ghost don't exists"
2330: g>xt ;
2331:
2332: \ FIXME: this works for the current use cases, but is not
2333: \ in all cases correct ;-)
2334: : comp' X ' 0 ;
2335:
2336: Cond: ['] T ' H alit, ;Cond
2337:
2338: >CROSS
2339:
2340: : [T']
2341: \ returns the target-cfa of a ghost, or compiles it as literal
2342: postpone [G']
2343: state @ IF postpone g>xt ELSE g>xt THEN ; immediate
2344:
2345: \ \ threading modell 13dec92py
2346: \ modularized 14jun97jaw
2347:
2348: T 2 cells H Value xt>body
2349:
2350: : (>body) ( cfa -- pfa )
2351: xt>body + ; ' (>body) plugin-of t>body
2352:
2353: : fillcfa ( usedcells -- )
2354: T cells H xt>body swap -
2355: assert1( dup 0 >= )
2356: 0 ?DO 0 X c, tchar +LOOP ;
2357:
2358: : (doer,) ( ghost -- )
2359: addr, 1 fillcfa ; ' (doer,) plugin-of doer,
2360:
2361: : (docol,) ( -- ) [G'] :docol (doer,) ; ' (docol,) plugin-of docol,
2362:
2363: ' NOOP plugin-of ca>native
2364:
2365: : (doprim,) ( -- )
2366: there xt>body + ca>native T a, H 1 fillcfa ; ' (doprim,) plugin-of doprim,
2367:
2368: : (doeshandler,) ( -- )
2369: T cfalign H [G'] :doesjump addr, T 0 , H ; ' (doeshandler,) plugin-of doeshandler,
2370:
2371: : (dodoes,) ( does-action-ghost -- )
2372: ]comp [G'] :dodoes addr, comp[
2373: addr,
2374: \ the relocator in the c engine, does not like the
2375: \ does-address to marked for relocation
2376: [ T e? ec H 0= [IF] ] T here H tcell - reloff [ [THEN] ]
2377: 2 fillcfa ; ' (dodoes,) plugin-of dodoes,
2378:
2379: : (dlit,) ( n -- ) compile lit td, ; ' (dlit,) plugin-of dlit,
2380:
2381: : (lit,) ( n -- ) s>d dlit, ; ' (lit,) plugin-of lit,
2382:
2383: \ if we dont produce relocatable code alit, defaults to lit, jaw
2384: \ this is just for convenience, so we don't have to define alit,
2385: \ seperately for embedded systems....
2386: T has? relocate H
2387: [IF]
2388: : (alit,) ( n -- ) compile lit T a, H ; ' (alit,) plugin-of alit,
2389: [ELSE]
2390: : (alit,) ( n -- ) lit, ; ' (alit,) plugin-of alit,
2391: [THEN]
2392:
2393: : (fini,) compile ;s ; ' (fini,) plugin-of fini,
2394:
2395: [IFUNDEF] (code)
2396: Defer (code)
2397: Defer (end-code)
2398: [THEN]
2399:
2400: >TARGET
2401: : Code
2402: defempty?
2403: (THeader ( ghost )
2404: ['] prim-resolved over >comp !
2405: there resolve-noforwards
2406:
2407: [ T e? prims H 0= [IF] T e? ITC H [ELSE] true [THEN] ] [IF]
2408: doprim,
2409: [THEN]
2410: depth (code) ;
2411:
2412: \ FIXME : no-compile -1 ABORT" this ghost is not for compilation" ;
2413:
2414: : Code:
2415: defempty?
2416: Ghost >r
2417: r@ >ghostname there symentry
2418: r@ there ca>native resolve-noforwards
2419: <do:> r@ >magic !
2420: r> drop
2421: depth (code) ;
2422:
2423: : end-code
2424: (end-code)
2425: depth ?dup IF 1- <> ABORT" CROSS: Stack changed"
2426: ELSE true ABORT" CROSS: Stack empty" THEN
2427: ;
2428:
2429: >CROSS
2430:
2431: \ tLiteral 12dec92py
2432:
2433: >TARGET
2434: Cond: \G T-\G ;Cond
2435:
2436: Cond: Literal ( n -- ) lit, ;Cond
2437: Cond: ALiteral ( n -- ) alit, ;Cond
2438:
2439: : Char ( "<char>" -- ) bl word char+ c@ ;
2440: Cond: [Char] ( "<char>" -- ) Char lit, ;Cond
2441:
2442: tchar 1 = [IF]
2443: Cond: chars ;Cond
2444: [THEN]
2445:
2446: \ some special literals 27jan97jaw
2447:
2448: Cond: MAXU
2449: -1 s>d dlit,
2450: ;Cond
2451:
2452: tcell 2 = tcell 4 = or tcell 8 = or 0=
2453: [IF]
2454: .( Warning: MINI and MAXI may not work with this host) cr
2455: [THEN]
2456:
2457: Cond: MINI
2458: tcell 2 = IF $8000 ELSE $80000000 THEN 0
2459: tcell 8 = IF swap THEN dlit,
2460: ;Cond
2461:
2462: Cond: MAXI
2463: tcell 2 = IF $7fff ELSE $7fffffff THEN 0
2464: tcell 8 = IF drop -1 swap THEN dlit,
2465: ;Cond
2466:
2467: >CROSS
2468:
2469: \ Target compiling loop 12dec92py
2470: \ ">tib trick thrown out 10may93jaw
2471: \ number? defined at the top 11may93jaw
2472: \ replaced >in by save-input
2473:
2474: : discard 0 ?DO drop LOOP ;
2475:
2476: \ compiled word might leave items on stack!
2477: : tcom ( x1 .. xn n name -- )
2478: \ dup count type space
2479: gfind
2480: IF >r ( discard saved input state ) discard r>
2481: dup >exec-compile @ ?dup
2482: IF nip execute-exec-compile ELSE gexecute THEN
2483: EXIT
2484: THEN
2485: number? dup
2486: IF 0> IF swap lit, THEN lit, discard
2487: ELSE 2drop restore-input throw Ghost gexecute THEN ;
2488:
2489: \ : ; DOES> 13dec92py
2490: \ ] 9may93py/jaw
2491:
2492: >CROSS
2493:
2494: : compiling-state ( -- )
2495: \G set states to compililng
2496: Compiling comp-state !
2497: \ if we have a state in target, change it with the compile state
2498: [G'] state dup undefined? 0=
2499: IF >ghost-xt @ execute X on ELSE drop THEN ;
2500:
2501: : interpreting-state ( -- )
2502: \G set states to interpreting
2503: \ if target has a state variable, change it according to our state
2504: [G'] state dup undefined? 0=
2505: IF >ghost-xt @ execute X off ELSE drop THEN
2506: Interpreting comp-state ! ;
2507:
2508: >TARGET
2509:
2510: : ]
2511: compiling-state
2512: BEGIN
2513: BEGIN save-input bl word
2514: dup c@ 0= WHILE drop discard refill 0=
2515: ABORT" CROSS: End of file while target compiling"
2516: REPEAT
2517: tcom
2518: compiling? 0=
2519: UNTIL ;
2520:
2521: \ by the way: defining a second interpreter (a compiler-)loop
2522: \ is not allowed if a system should be ans conform
2523:
2524: : (:) ( ghost -- )
2525: \ common factor of : and :noname. Prepare ;Resolve and start definition
2526: ;Resolve ! there ;Resolve cell+ !
2527: docol, ]comp colon-start depth T ] H ;
2528:
2529: : : ( -- colon-sys ) \ Name
2530: defempty?
2531: constflag off \ don't let this flag work over colon defs
2532: \ just to go sure nothing unwanted happens
2533: >in @ skip? IF drop skip-defs EXIT THEN >in !
2534: (THeader (:) ;
2535:
2536: : :noname ( -- colon-sys )
2537: X cfalign there
2538: \ define a nameless ghost
2539: here ghostheader dup last-header-ghost ! dup to lastghost
2540: (:) ;
2541:
2542: Cond: EXIT ( -- ) compile ;S ;Cond
2543:
2544: Cond: ?EXIT ( -- ) 1 abort" CROSS: using ?exit" ;Cond
2545:
2546: >CROSS
2547: : LastXT ;Resolve @ 0= abort" CROSS: no definition for LastXT"
2548: ;Resolve cell+ @ ;
2549:
2550: >TARGET
2551:
2552: Cond: recurse ( -- ) Last-Header-Ghost @ gexecute ;Cond
2553:
2554: Cond: ; ( -- )
2555: depth ?dup
2556: IF 1- <> ABORT" CROSS: Stack changed"
2557: ELSE true ABORT" CROSS: Stack empty"
2558: THEN
2559: colon-end
2560: fini,
2561: comp[
2562: ;Resolve @
2563: IF ['] colon-resolved ;Resolve @ >comp !
2564: ;Resolve @ ;Resolve cell+ @ resolve
2565: THEN
2566: interpreting-state
2567: ;Cond
2568:
2569: Cond: [ ( -- ) interpreting-state ;Cond
2570:
2571: >CROSS
2572:
2573: 0 Value created
2574:
2575: : !does ( does-action -- )
2576: tlastcfa @ [G'] :dovar killref
2577: >space here >r ghostheader space>
2578: ['] colon-resolved r@ >comp !
2579: r@ created >do:ghost ! r@ swap resolve
2580: r> tlastcfa @ >tempdp dodoes, tempdp> ;
2581:
2582: Defer instant-interpret-does>-hook
2583:
2584: : does-resolved ( ghost -- )
2585: compile does-exec g>xt T a, H ;
2586:
2587: : resolve-does>-part ( -- )
2588: \ resolve words made by builders
2589: Last-Header-Ghost @ >do:ghost @ ?dup
2590: IF there resolve THEN ;
2591:
2592: >TARGET
2593: Cond: DOES>
2594: compile (does>) doeshandler,
2595: resolve-does>-part
2596: ;Cond
2597:
2598: : DOES>
2599: ['] does-resolved created >comp !
2600: switchrom doeshandler, T here H !does
2601: instant-interpret-does>-hook
2602: depth T ] H ;
2603:
2604: >CROSS
2605: \ Creation 01nov92py
2606:
2607: \ Builder 11may93jaw
2608:
2609: 0 Value built
2610:
2611: : Builder ( Create-xt do-ghost "name" -- )
2612: \ builds up a builder in current vocabulary
2613: \ create-xt is executed when word is interpreted
2614: \ do:-xt is executed when the created word from builder is executed
2615: \ for do:-xt an additional entry after the normal ghost-entrys is used
2616:
2617: ghost to built
2618: built >created @ 0= IF
2619: built >created on
2620: THEN ;
2621:
2622: : gdoes, ( ghost -- )
2623: \ makes the codefield for a word that is built
2624: >do:ghost @ dup undefined? 0=
2625: IF
2626: dup >magic @ <do:> =
2627: IF doer,
2628: ELSE dodoes,
2629: THEN
2630: EXIT
2631: THEN
2632: \ compile :dodoes gexecute
2633: \ T here H tcell - reloff
2634: 2 refered
2635: 0 fillcfa
2636: ;
2637:
2638: : takeover-x-semantics ( S constructor-ghost new-ghost -- )
2639: \g stores execution semantic and compilation semantic in the built word
2640: swap >do:ghost @ 2dup swap >do:ghost !
2641: \ we use the >exec2 field for the semantic of a created word,
2642: \ using exec or exec2 makes no difference for normal cross-compilation
2643: \ but is usefull for instant where the exec field is already
2644: \ defined (e.g. Vocabularies)
2645: 2dup >exec @ swap >exec2 !
2646: >comp @ swap >comp ! ;
2647:
2648: 0 Value createhere
2649:
2650: : create-resolve ( -- )
2651: created createhere resolve 0 ;Resolve ! ;
2652: : create-resolve-immediate ( -- )
2653: create-resolve T immediate H ;
2654:
2655: : TCreate ( <name> -- )
2656: create-forward-warn
2657: IF ['] reswarn-forward IS resolve-warning THEN
2658: executed-ghost @ (Theader
2659: dup >created on dup to created
2660: 2dup takeover-x-semantics
2661: there to createhere drop gdoes, ;
2662:
2663: : RTCreate ( <name> -- )
2664: \ creates a new word with code-field in ram
2665: create-forward-warn
2666: IF ['] reswarn-forward IS resolve-warning THEN
2667: \ make Alias
2668: executed-ghost @ (THeader
2669: dup >created on dup to created
2670: 2dup takeover-x-semantics
2671: there 0 T a, H alias-mask flag!
2672: \ store poiter to code-field
2673: switchram T cfalign H
2674: there swap T ! H
2675: there tlastcfa !
2676: there to createhere drop gdoes, ;
2677:
2678: : Build: ( -- [xt] [colon-sys] )
2679: :noname postpone TCreate ;
2680:
2681: : BuildSmart: ( -- [xt] [colon-sys] )
2682: :noname
2683: [ T has? rom H [IF] ]
2684: postpone RTCreate
2685: [ [ELSE] ]
2686: postpone TCreate
2687: [ [THEN] ] ;
2688:
2689: : ;Build
2690: postpone create-resolve postpone ; built >exec ! ; immediate
2691:
2692: : ;Build-immediate
2693: postpone create-resolve-immediate
2694: postpone ; built >exec ! ; immediate
2695:
2696: : gdoes> ( ghost -- addr flag )
2697: executed-ghost @ g>body ;
2698:
2699: \ DO: ;DO 11may93jaw
2700:
2701: : do:ghost! ( ghost -- ) built >do:ghost ! ;
2702: : doexec! ( xt -- ) built >do:ghost @ >exec ! ;
2703:
2704: : DO: ( -- [xt] [colon-sys] )
2705: here ghostheader do:ghost!
2706: :noname postpone gdoes> ;
2707:
2708: : by: ( -- [xt] [colon-sys] ) \ name
2709: Ghost do:ghost!
2710: :noname postpone gdoes> ;
2711:
2712: : ;DO ( [xt] [colon-sys] -- )
2713: postpone ; doexec! ; immediate
2714:
2715: : by ( -- ) \ Name
2716: Ghost >do:ghost @ do:ghost! ;
2717:
2718: : compile: ( --[xt] [colon-sys] )
2719: \G defines a compile time action for created words
2720: \G by this builder
2721: :noname ;
2722:
2723: : ;compile ( [xt] [colon-sys] -- )
2724: postpone ; built >do:ghost @ >comp ! ; immediate
2725:
2726: \ Variables and Constants 05dec92py
2727:
2728: Builder (Constant)
2729: Build: ( n -- ) ;Build
2730: by: :docon ( target-body-addr -- n ) T @ H ;DO
2731:
2732: Builder Constant
2733: Build: ( n -- ) T , H ;Build
2734: by (Constant)
2735:
2736: Builder AConstant
2737: Build: ( n -- ) T A, H ;Build
2738: by (Constant)
2739:
2740: Builder 2Constant
2741: Build: ( d -- ) T , , H ;Build
2742: DO: ( ghost -- d ) T dup cell+ @ swap @ H ;DO
2743:
2744: Builder Create
2745: BuildSmart: ;Build
2746: by: :dovar ( target-body-addr -- addr ) ;DO
2747:
2748: Builder Variable
2749: T has? rom H [IF]
2750: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , H ( switchrom ) ;Build
2751: by (Constant)
2752: [ELSE]
2753: Build: T 0 , H ;Build
2754: by Create
2755: [THEN]
2756:
2757: Builder 2Variable
2758: T has? rom H [IF]
2759: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 , 0 , H ( switchrom ) ;Build
2760: by (Constant)
2761: [ELSE]
2762: Build: T 0 , 0 , H ;Build
2763: by Create
2764: [THEN]
2765:
2766: Builder AVariable
2767: T has? rom H [IF]
2768: Build: ( -- ) T here 0 A, H switchram T align here swap ! 0 A, H ( switchrom ) ;Build
2769: by (Constant)
2770: [ELSE]
2771: Build: T 0 A, H ;Build
2772: by Create
2773: [THEN]
2774:
2775: \ User variables 04may94py
2776:
2777: Variable tup 0 tup !
2778: Variable tudp 0 tudp !
2779:
2780: : u, ( n -- udp )
2781: tup @ tudp @ + T ! H
2782: tudp @ dup T cell+ H tudp ! ;
2783:
2784: : au, ( n -- udp )
2785: tup @ tudp @ + T A! H
2786: tudp @ dup T cell+ H tudp ! ;
2787:
2788: Builder User
2789: Build: 0 u, X , ;Build
2790: by: :douser ( ghost -- up-addr ) X @ tup @ + ;DO
2791:
2792: Builder 2User
2793: Build: 0 u, X , 0 u, drop ;Build
2794: by User
2795:
2796: Builder AUser
2797: Build: 0 au, X , ;Build
2798: by User
2799:
2800: Builder (Value)
2801: Build: ( n -- ) ;Build
2802: by: :docon ( target-body-addr -- n ) T @ H ;DO
2803:
2804: Builder Value
2805: BuildSmart: T , H ;Build
2806: by (Value)
2807:
2808: Builder AValue
2809: BuildSmart: T A, H ;Build
2810: by (Value)
2811:
2812: Defer texecute
2813:
2814: Builder Defer
2815: BuildSmart: ( -- ) [T'] noop T A, H ;Build
2816: by: :dodefer ( ghost -- ) X @ texecute ;DO
2817:
2818: Builder interpret/compile:
2819: Build: ( inter comp -- ) swap T A, A, H ;Build-immediate
2820: DO: ( ghost -- ) ABORT" CROSS: Don't execute" ;DO
2821:
2822: \ Sturctures 23feb95py
2823:
2824: : nalign ( addr1 n -- addr2 )
2825: \ addr2 is the aligned version of addr1 wrt the alignment size n
2826: 1- tuck + swap invert and ;
2827:
2828:
2829: Builder (Field)
2830: Build: ;Build
2831: by: :dofield T @ H + ;DO
2832:
2833: Builder Field
2834: Build: ( align1 offset1 align size "name" -- align2 offset2 )
2835: rot dup T , H ( align1 align size offset1 )
2836: + >r nalign r> ;Build
2837: by (Field)
2838:
2839: >TARGET
2840: : struct T 1 chars 0 H ;
2841: : end-struct T 2Constant H ;
2842:
2843: : cell% ( n -- size align )
2844: T 1 cells H dup ;
2845: >CROSS
2846:
2847: \ Input-Methods 01py
2848:
2849: Builder input-method
2850: Build: ( m v -- m' v ) dup T , cell+ H ;Build
2851: DO: abort" Not in cross mode" ;DO
2852:
2853: Builder input-var
2854: Build: ( m v size -- m v' ) over T , H + ;Build
2855: DO: abort" Not in cross mode" ;DO
2856:
2857: \ Peephole optimization 05sep01jaw
2858:
2859: \ this section defines different compilation
2860: \ actions for created words
2861: \ this will help the peephole optimizer
2862: \ I (jaw) took this from bernds latest cross-compiler
2863: \ changes but seperated it from the original
2864: \ Builder words. The final plan is to put this
2865: \ into a seperate file, together with the peephole
2866: \ optimizer for cross
2867:
2868:
2869: T has? peephole H [IF]
2870:
2871: >CROSS
2872:
2873: : (callc) compile call T >body a, H ; ' (callc) plugin-of colon,
2874: : (callcm) T here 0 a, 0 a, H ; ' (callcm) plugin-of colonmark,
2875: : (call-res) >tempdp resolved gexecute tempdp> drop ;
2876: ' (call-res) plugin-of colon-resolve
2877: : (pprim) dup 0< IF $4000 - ELSE
2878: cr ." wrong usage of (prim) "
2879: dup gdiscover IF .ghost ELSE . THEN cr -1 throw THEN
2880: T a, H ; ' (pprim) plugin-of prim,
2881:
2882: \ if we want this, we have to spilt aconstant
2883: \ and constant!!
2884: \ Builder (Constant)
2885: \ compile: g>body X @ lit, ;compile
2886:
2887: Builder (Constant)
2888: compile: g>body compile lit@ T a, H ;compile
2889:
2890: Builder (Value)
2891: compile: g>body compile lit@ T a, H ;compile
2892:
2893: \ this changes also Variable, AVariable and 2Variable
2894: Builder Create
2895: compile: g>body alit, ;compile
2896:
2897: Builder User
2898: compile: g>body compile useraddr T @ , H ;compile
2899:
2900: Builder Defer
2901: compile: g>body compile lit-perform T A, H ;compile
2902:
2903: Builder (Field)
2904: compile: g>body T @ H compile lit+ T , H ;compile
2905:
2906: Builder interpret/compile:
2907: compile: does-resolved ;compile
2908:
2909: Builder input-method
2910: compile: does-resolved ;compile
2911:
2912: Builder input-var
2913: compile: does-resolved ;compile
2914:
2915: [THEN]
2916:
2917: \ structural conditionals 17dec92py
2918:
2919: >CROSS
2920: : (ncontrols?) ( n -- )
2921: \g We expect n open control structures
2922: depth over u<=
2923: ABORT" CROSS: unstructured, stack underflow"
2924: 0 ?DO I pick 0=
2925: ABORT" CROSS: unstructured"
2926: LOOP ; ' (ncontrols?) plugin-of ncontrols?
2927:
2928: \ : ?struc ( flag -- ) ABORT" CROSS: unstructured " ;
2929: \ : sys? ( sys -- sys ) dup 0= ?struc ;
2930:
2931: : >mark ( -- sys ) T here ( dup ." M" hex. ) 0 , H ;
2932:
2933: X has? abranch [IF]
2934: : branchoffset ( src dest -- ) drop ;
2935: : offset, ( n -- ) X A, ;
2936: [ELSE]
2937: : branchoffset ( src dest -- ) - tchar / ; \ ?? jaw
2938: : offset, ( n -- ) X , ;
2939: [THEN]
2940:
2941: :noname compile branch X here branchoffset offset, ;
2942: IS branch, ( target-addr -- )
2943: :noname compile ?branch X here branchoffset offset, ;
2944: IS ?branch, ( target-addr -- )
2945: :noname compile branch T here 0 H offset, ;
2946: IS branchmark, ( -- branchtoken )
2947: :noname compile ?branch T here 0 H offset, ;
2948: IS ?branchmark, ( -- branchtoken )
2949: :noname T here 0 H offset, ;
2950: IS ?domark, ( -- branchtoken )
2951: :noname dup X @ ?struc X here over branchoffset swap X ! ;
2952: IS branchtoresolve, ( branchtoken -- )
2953: :noname branchto, X here ;
2954: IS branchtomark, ( -- target-addr )
2955:
2956: >TARGET
2957:
2958: \ Structural Conditionals 12dec92py
2959:
2960: \ CLEANUP Cond: BUT sys? swap ;Cond
2961: \ CLEANUP Cond: YET sys? dup ;Cond
2962:
2963: >CROSS
2964:
2965: Variable tleavings 0 tleavings !
2966:
2967: : (done) ( do-addr -- )
2968: \G resolve branches of leave and ?leave and ?do
2969: \G do-addr is the address of the beginning of our
2970: \G loop so we can take care of nested loops
2971: tleavings @
2972: BEGIN dup
2973: WHILE
2974: >r dup r@ cell+ @ \ address of branch
2975: u> 0= \ lower than DO?
2976: WHILE
2977: r@ 2 cells + @ \ branch token
2978: branchtoresolve,
2979: r@ @ r> free throw
2980: REPEAT r> THEN
2981: tleavings ! drop ;
2982:
2983: >TARGET
2984:
2985: \ What for? ANS? JAW Cond: DONE ( addr -- ) (done) ;Cond
2986:
2987: >CROSS
2988: : (leave) ( branchtoken -- )
2989: 3 cells allocate throw >r
2990: T here H r@ cell+ !
2991: r@ 2 cells + !
2992: tleavings @ r@ !
2993: r> tleavings ! ;
2994: >TARGET
2995:
2996: : (leave,) ( -- )
2997: branchmark, (leave) ; ' (leave,) plugin-of leave,
2998:
2999: : (?leave,) ( -- )
3000: compile 0= ?branchmark, (leave) ; ' (?leave,) plugin-of ?leave,
3001:
3002: Cond: LEAVE leave, ;Cond
3003: Cond: ?LEAVE ?leave, ;Cond
3004:
3005: >CROSS
3006: \ !!JW ToDo : Move to general tools section
3007:
3008: : to1 ( x1 x2 xn n -- addr )
3009: \G packs n stack elements in am allocated memory region
3010: dup dup 1+ cells allocate throw dup >r swap 1+
3011: 0 DO tuck ! cell+ LOOP
3012: drop r> ;
3013:
3014: : 1to ( addr -- x1 x2 xn )
3015: \G unpacks the elements saved by to1
3016: dup @ swap over cells + swap
3017: 0 DO dup @ swap 1 cells - LOOP
3018: free throw ;
3019:
3020: : loop] ( target-addr -- )
3021: branchto,
3022: dup X here branchoffset offset,
3023: tcell - (done) ;
3024:
3025: : skiploop] ?dup IF branchto, branchtoresolve, THEN ;
3026:
3027: >TARGET
3028:
3029: \ Structural Conditionals 12dec92py
3030:
3031: : (cs-swap) ( x1 x2 -- x2 x1 )
3032: swap ; ' (cs-swap) plugin-of cs-swap
3033:
3034: : (ahead,) branchmark, ; ' (ahead,) plugin-of ahead,
3035:
3036: : (if,) ?branchmark, ; ' (if,) plugin-of if,
3037:
3038: : (then,) branchto, branchtoresolve, ; ' (then,) plugin-of then,
3039:
3040: : (else,) ( ahead ) branchmark,
3041: swap
3042: ( then ) branchto, branchtoresolve, ; ' (else,) plugin-of else,
3043:
3044: : (begin,) branchtomark, ; ' (begin,) plugin-of begin,
3045:
3046: : (while,) ( if ) ?branchmark,
3047: swap ; ' (while,) plugin-of while,
3048:
3049: : (again,) branch, ; ' (again,) plugin-of again,
3050:
3051: : (until,) ?branch, ; ' (until,) plugin-of until,
3052:
3053: : (repeat,) ( again ) branch,
3054: ( then ) branchto, branchtoresolve, ; ' (repeat,) plugin-of repeat,
3055:
3056: : (case,) ( -- n )
3057: 0 ; ' (case,) plugin-of case,
3058:
3059: : (of,) ( n -- x1 n )
3060: 1+ >r
3061: compile over compile =
3062: if, compile drop r> ; ' (of,) plugin-of of,
3063:
3064: : (endof,) ( x1 n -- x2 n )
3065: >r 1 ncontrols? else, r> ; ' (endof,) plugin-of endof,
3066:
3067: : (endcase,) ( x1 .. xn n -- )
3068: compile drop 0 ?DO 1 ncontrols? then, LOOP ; ' (endcase,) plugin-of endcase,
3069:
3070: >TARGET
3071: Cond: AHEAD ahead, ;Cond
3072: Cond: IF if, ;Cond
3073: Cond: THEN 1 ncontrols? then, ;Cond
3074: Cond: ENDIF 1 ncontrols? then, ;Cond
3075: Cond: ELSE 1 ncontrols? else, ;Cond
3076:
3077: Cond: BEGIN begin, ;Cond
3078: Cond: WHILE 1 ncontrols? while, ;Cond
3079: Cond: AGAIN 1 ncontrols? again, ;Cond
3080: Cond: UNTIL 1 ncontrols? until, ;Cond
3081: Cond: REPEAT 2 ncontrols? repeat, ;Cond
3082:
3083: Cond: CASE case, ;Cond
3084: Cond: OF of, ;Cond
3085: Cond: ENDOF endof, ;Cond
3086: Cond: ENDCASE endcase, ;Cond
3087:
3088: \ Structural Conditionals 12dec92py
3089:
3090: : (do,) ( -- target-addr )
3091: \ ?? i think 0 is too much! jaw
3092: 0 compile (do)
3093: branchtomark, 2 to1 ; ' (do,) plugin-of do,
3094:
3095: \ alternative for if no ?do
3096: \ : (do,)
3097: \ compile 2dup compile = compile IF
3098: \ compile 2drop compile ELSE
3099: \ compile (do) branchtomark, 2 to1 ;
3100:
3101: : (?do,) ( -- target-addr )
3102: 0 compile (?do) ?domark, (leave)
3103: branchtomark, 2 to1 ; ' (?do,) plugin-of ?do,
3104:
3105: : (for,) ( -- target-addr )
3106: compile (for) branchtomark, ; ' (for,) plugin-of for,
3107:
3108: : (loop,) ( target-addr -- )
3109: 1to compile (loop) loop]
3110: compile unloop skiploop] ; ' (loop,) plugin-of loop,
3111:
3112: : (+loop,) ( target-addr -- )
3113: 1to compile (+loop) loop]
3114: compile unloop skiploop] ; ' (+loop,) plugin-of +loop,
3115:
3116: : (next,)
3117: compile (next) loop] compile unloop ; ' (next,) plugin-of next,
3118:
3119: Cond: DO do, ;Cond
3120: Cond: ?DO ?do, ;Cond
3121: Cond: FOR for, ;Cond
3122:
3123: Cond: LOOP 1 ncontrols? loop, ;Cond
3124: Cond: +LOOP 1 ncontrols? +loop, ;Cond
3125: Cond: NEXT 1 ncontrols? next, ;Cond
3126:
3127: \ String words 23feb93py
3128:
3129: : ," [char] " parse ht-string, X align ;
3130:
3131: X has? control-rack [IF]
3132: Cond: ." compile (.") T ," H ;Cond
3133: Cond: S" compile (S") T ," H ;Cond
3134: Cond: C" compile (C") T ," H ;Cond
3135: Cond: ABORT" compile (ABORT") T ," H ;Cond
3136: [ELSE]
3137: Cond: ." '" parse tuck 2>r ahead, there 2r> ht-mem, X align
3138: >r then, r> compile ALiteral compile Literal compile type ;Cond
3139: Cond: S" '" parse tuck 2>r ahead, there 2r> ht-mem, X align
3140: >r then, r> compile ALiteral compile Literal ;Cond
3141: Cond: C" ahead, there [char] " parse ht-string, X align
3142: >r then, r> compile ALiteral ;Cond
3143: Cond: ABORT" if, ahead, there [char] " parse ht-string, X align
3144: >r then, r> compile ALiteral compile c(abort") then, ;Cond
3145: [THEN]
3146:
3147: Cond: IS T ' >body H compile ALiteral compile ! ;Cond
3148: : IS T >address ' >body ! H ;
3149: Cond: TO T ' >body H compile ALiteral compile ! ;Cond
3150: : TO T ' >body ! H ;
3151:
3152: Cond: defers T ' >body @ compile, H ;Cond
3153:
3154: \ LINKED ERR" ENV" 2ENV" 18may93jaw
3155:
3156: \ linked list primitive
3157: : linked X here over X @ X A, swap X ! ;
3158: : chained T linked A, H ;
3159:
3160: : err" s" ErrLink linked" evaluate T , H
3161: [char] " parse ht-string, X align ;
3162:
3163: : env" [char] " parse s" EnvLink linked" evaluate
3164: ht-string, X align X , ;
3165:
3166: : 2env" [char] " parse s" EnvLink linked" evaluate
3167: here >r ht-string, X align X , X ,
3168: r> dup T c@ H 80 and swap T c! H ;
3169:
3170: \ compile must be last 22feb93py
3171:
3172: Cond: [compile] ( -- ) \ name
3173: \g For immediate words, works even if forward reference
3174: bl word gfind 0= ABORT" CROSS: Can't compile"
3175: (gexecute) ;Cond
3176:
3177: Cond: postpone ( -- ) \ name
3178: bl word gfind 0= ABORT" CROSS: Can't compile"
3179: dup >magic @ <fwd> =
3180: ABORT" CROSS: Can't postpone on forward declaration"
3181: dup >magic @ <imm> =
3182: IF (gexecute)
3183: ELSE compile (compile) addr, THEN ;Cond
3184:
3185: \ save-cross 17mar93py
3186:
3187: hex
3188:
3189: >CROSS
3190: Create magic s" Gforth3x" here over allot swap move
3191:
3192: bigendian 1+ \ strangely, in magic big=0, little=1
3193: tcell 1 = 0 and or
3194: tcell 2 = 2 and or
3195: tcell 4 = 4 and or
3196: tcell 8 = 6 and or
3197: tchar 1 = 00 and or
3198: tchar 2 = 28 and or
3199: tchar 4 = 50 and or
3200: tchar 8 = 78 and or
3201: magic 7 + c!
3202:
3203: : save-cross ( "image-name" "binary-name" -- )
3204: bl parse ." Saving to " 2dup type cr
3205: w/o bin create-file throw >r
3206: s" header" X $has? IF
3207: s" #! " r@ write-file throw
3208: bl parse r@ write-file throw
3209: s" --image-file" r@ write-file throw
3210: #lf r@ emit-file throw
3211: r@ dup file-position throw drop 8 mod 8 swap ( file-id limit index )
3212: ?do
3213: bl over emit-file throw
3214: loop
3215: drop
3216: magic 8 r@ write-file throw \ write magic
3217: ELSE
3218: bl parse 2drop
3219: THEN
3220: image @ there
3221: r@ write-file throw \ write image
3222: s" relocate" X $has? IF
3223: bit$ @ there 1- tcell>bit rshift 1+
3224: r@ write-file throw \ write tags
3225: THEN
3226: r> close-file throw ;
3227:
3228: : save-region ( addr len -- )
3229: bl parse w/o bin create-file throw >r
3230: swap >image swap r@ write-file throw
3231: r> close-file throw ;
3232:
3233: \ save-asm-region 29aug01jaw
3234:
3235: Variable name-ptr
3236: Create name-buf 200 chars allot
3237: : init-name-buf name-buf name-ptr ! ;
3238: : nb, name-ptr @ c! 1 chars name-ptr +! ;
3239: : $nb, ( adr len -- ) bounds ?DO I c@ nb, LOOP ;
3240: : @nb name-ptr @ name-buf tuck - ;
3241:
3242: \ stores a usefull string representation of the character
3243: \ in the name buffer
3244: : name-char, ( c -- )
3245: dup 'a 'z 1+ within IF nb, EXIT THEN
3246: dup 'A 'Z 1+ within IF $20 + nb, EXIT THEN
3247: dup '0 '9 1+ within IF nb, EXIT THEN
3248: CASE '+ OF s" _PLUS" $nb, ENDOF
3249: '- OF s" _MINUS" $nb, ENDOF
3250: '* OF s" _STAR" $nb, ENDOF
3251: '/ OF s" _SLASH" $nb, ENDOF
3252: '' OF s" _TICK" $nb, ENDOF
3253: '( OF s" _OPAREN" $nb, ENDOF
3254: ') OF s" _CPAREN" $nb, ENDOF
3255: '[ OF s" _OBRACKET" $nb, ENDOF
3256: '] OF s" _CBRACKET" $nb, ENDOF
3257: '! OF s" _STORE" $nb, ENDOF
3258: '@ OF s" _FETCH" $nb, ENDOF
3259: '> OF s" _GREATER" $nb, ENDOF
3260: '< OF s" _LESS" $nb, ENDOF
3261: '= OF s" _EQUAL" $nb, ENDOF
3262: '# OF s" _HASH" $nb, ENDOF
3263: '? OF s" _QUEST" $nb, ENDOF
3264: ': OF s" _COL" $nb, ENDOF
3265: '; OF s" _SEMICOL" $nb, ENDOF
3266: ', OF s" _COMMA" $nb, ENDOF
3267: '. OF s" _DOT" $nb, ENDOF
3268: '" OF s" _DQUOT" $nb, ENDOF
3269: dup
3270: base @ >r hex s>d <# #s 'X hold '_ hold #> $nb, r> base !
3271: ENDCASE ;
3272:
3273: : label-from-ghostname ( ghost -- addr len )
3274: dup >ghostname init-name-buf 'L nb, bounds
3275: ?DO I c@ name-char, LOOP
3276: \ we add the address to a name to make in unique
3277: \ because one name may appear more then once
3278: \ there are names (e.g. boot) that may be reference from other
3279: \ assembler source files, so we declare them as unique
3280: \ and don't add the address suffix
3281: dup >ghost-flags @ <unique> and 0=
3282: IF s" __" $nb, >link @ base @ >r hex 0 <# #s 'L hold #> r> base ! $nb,
3283: ELSE drop
3284: THEN
3285: @nb ;
3286:
3287: \ FIXME why disabled?!
3288: : label-from-ghostnameXX ( ghost -- addr len )
3289: \ same as (label-from-ghostname) but caches generated names
3290: dup >asm-name @ ?dup IF nip count EXIT THEN
3291: \ dup >r (label-from-ghostname) 2dup
3292: align here >r string, align
3293: r> r> >asm-name ! ;
3294:
3295: : primghostdiscover ( xt -- ghost true | xt false )
3296: dup 0= IF false EXIT THEN
3297: >r last-prim-ghost
3298: BEGIN @ dup
3299: WHILE dup >asm-dummyaddr @ r@ =
3300: IF rdrop true EXIT THEN
3301: REPEAT
3302: drop r> false ;
3303:
3304: : gdiscover2 ( xt -- ghost true | xt false )
3305: dup taddr>region 0= IF false EXIT THEN
3306: dup (>regiontype) @ dup 0= IF drop false EXIT THEN
3307: addr-xt-ghost @ dup 0= IF drop false EXIT THEN
3308: nip true ;
3309: \ dup >ghost-name @ IF nip true ELSE drop false THEN ;
3310:
3311: \ generates a label name for the target address
3312: : generate-label-name ( taddr -- addr len )
3313: gdiscover2
3314: IF dup >magic @ <do:> =
3315: IF >asm-name @ count EXIT THEN
3316: label-from-ghostname
3317: ELSE
3318: primghostdiscover
3319: IF >asm-name @ count
3320: ELSE base @ >r hex 0 <# #s 'L hold #> r> base !
3321: THEN
3322: THEN ;
3323:
3324: Variable outfile-fd
3325:
3326: : $out ( adr len -- ) outfile-fd @ write-file throw ;
3327: : nlout newline $out ;
3328: : .ux ( n -- )
3329: base @ hex swap 0 <# #S #> $out base ! ;
3330:
3331: : save-asm-region-part-aligned ( taddr len -- 'taddr 'len )
3332: dup cell/ 0
3333: ?DO nlout s" .word " $out over @relbit
3334: IF over X @ generate-label-name $out
3335: ELSE over X @ s" 0x0" $out .ux
3336: THEN
3337: tcell /string
3338: LOOP ;
3339:
3340: : print-bytes ( taddr len n -- taddr' len' )
3341: over min dup 0>
3342: IF nlout s" .byte " $out 0
3343: ?DO I 0> IF s" , " $out THEN
3344: over X c@ s" 0x0" $out .ux 1 /string
3345: LOOP
3346: THEN ;
3347:
3348: : save-asm-region-part ( addr len -- )
3349: over dup X aligned swap - ?dup
3350: IF print-bytes THEN
3351: save-asm-region-part-aligned
3352: dup dup X aligned swap - ?dup
3353: IF 2 pick @relbit ABORT" relocated field splitted"
3354: print-bytes
3355: THEN
3356: 2drop ;
3357:
3358: : print-label ( taddr -- )
3359: nlout generate-label-name $out s" :" $out ;
3360:
3361: : snl-calc ( taddr taddr2 -- )
3362: tuck over - ;
3363:
3364: : skip-nolables ( taddr -- taddr2 taddr len )
3365: \G skips memory region where no lables are defined
3366: \G starting from taddr+1
3367: \G Labels will be introduced for each reference mark
3368: \G in addr-refs.
3369: \G This word deals with lables at byte addresses as well.
3370: \G The main idea is to have an intro part which
3371: \G skips until the next cell boundary, the middle part
3372: \G which skips whole cells very efficiently and the third
3373: \G part which skips the bytes to the label in a cell
3374: dup 1+ dup (>regiontype)
3375: ( S taddr taddr-realstart type-addr )
3376: dup @ dup IF addr-refs @ THEN
3377: swap >r
3378: over align+ tuck tcell swap - rshift swap 0
3379: ?DO dup 1 and
3380: IF drop rdrop snl-calc UNLOOP EXIT THEN
3381: 2/ swap 1+ swap
3382: LOOP
3383: drop r> cell+
3384: ( S .. taddr2 type-addr ) dup
3385: BEGIN dup @ dup IF addr-refs @ THEN 0= WHILE cell+ REPEAT
3386: dup >r swap - 1 cells / tcell * + r>
3387: ( S .. taddr2+skiplencells type-addr )
3388: @ addr-refs @ 1 tcell lshift or
3389: BEGIN dup 1 and 0= WHILE swap 1+ swap 2/ REPEAT drop
3390: ( S .. taddr2+skiplencells+skiplenbytes )
3391: snl-calc ;
3392:
3393: : insert-label ( taddr -- )
3394: dup 0= IF drop EXIT THEN
3395: \ ignore everything which points outside our memory regions
3396: \ maybe a primitive pointer or whatever
3397: dup taddr>region 0= IF drop EXIT THEN
3398: dup >r (>regiontype) define-addr-struct addr-refs dup @
3399: r> tcell 1- and 1 swap lshift or swap ! ;
3400:
3401: \ this generates a sorted list of addresses which must be labels
3402: \ it scans therefore a whole region
3403: : generate-label-list-region ( taddr len -- )
3404: BEGIN over @relbit IF over X @ insert-label THEN
3405: tcell /string dup 0<
3406: UNTIL 2drop ;
3407:
3408: : generate-label-list ( -- )
3409: region-link
3410: BEGIN @ dup WHILE
3411: dup 0 >rlink - extent
3412: ?dup IF generate-label-list-region ELSE drop THEN
3413: REPEAT drop ;
3414:
3415: : create-outfile ( addr len -- )
3416: w/o bin create-file throw outfile-fd ! ;
3417:
3418: : close-outfile ( -- )
3419: outfile-fd @ close-file throw ;
3420:
3421: : (save-asm-region) ( region -- )
3422: \ ." label list..."
3423: generate-label-list
3424: \ ." ok!" cr
3425: extent ( S taddr len )
3426: over insert-label
3427: 2dup + dup insert-label >r ( R end-label )
3428: ( S taddr len ) drop
3429: BEGIN
3430: dup print-label
3431: dup r@ <> WHILE
3432: skip-nolables save-asm-region-part
3433: REPEAT drop rdrop ;
3434:
3435: : lineout ( addr len -- )
3436: outfile-fd @ write-line throw ;
3437:
3438: : save-asm-region ( region adr len -- )
3439: create-outfile (save-asm-region) close-outfile ;
3440:
3441: \ \ minimal definitions
3442:
3443: >MINIMAL also minimal
3444:
3445: \ Usefull words 13feb93py
3446:
3447: : KB 400 * ;
3448:
3449: \ \ [IF] [ELSE] [THEN] ... 14sep97jaw
3450:
3451: \ it is useful to define our own structures and not to rely
3452: \ on the words in the host system
3453: \ The words in the host system might be defined with vocabularies
3454: \ this doesn't work with our self-made compile-loop
3455:
3456: Create parsed 20 chars allot \ store word we parsed
3457:
3458: : upcase
3459: parsed count bounds
3460: ?DO I c@ toupper I c! LOOP ;
3461:
3462: : [ELSE]
3463: 1 BEGIN
3464: BEGIN bl word count dup WHILE
3465: comment? 20 umin parsed place upcase parsed count
3466: 2dup s" [IF]" str= >r
3467: 2dup s" [IFUNDEF]" str= >r
3468: 2dup s" [IFDEF]" str= r> or r> or
3469: IF 2drop 1+
3470: ELSE 2dup s" [ELSE]" str=
3471: IF 2drop 1- dup
3472: IF 1+
3473: THEN
3474: ELSE
3475: 2dup s" [ENDIF]" str= >r
3476: s" [THEN]" str= r> or
3477: IF 1- THEN
3478: THEN
3479: THEN
3480: ?dup 0= ?EXIT
3481: REPEAT
3482: 2drop refill 0=
3483: UNTIL drop ; immediate
3484:
3485: : [THEN] ( -- ) ; immediate
3486:
3487: : [ENDIF] ( -- ) ; immediate
3488:
3489: : [IF] ( flag -- )
3490: 0= IF postpone [ELSE] THEN ; immediate
3491:
3492: Cond: [IF] postpone [IF] ;Cond
3493: Cond: [THEN] postpone [THEN] ;Cond
3494: Cond: [ELSE] postpone [ELSE] ;Cond
3495:
3496: \ define new [IFDEF] and [IFUNDEF] 20may93jaw
3497:
3498: : defined? tdefined? ;
3499: : needed? needed? ;
3500: : doer? doer? ;
3501:
3502: \ we want to use IFDEF on compiler directives (e.g. E?) in the source, too
3503:
3504: : directive?
3505: bl word count [ ' target >wordlist ] literal search-wordlist
3506: dup IF nip THEN ;
3507:
3508: : [IFDEF] >in @ directive? swap >in !
3509: 0= IF tdefined? ELSE name 2drop true THEN
3510: postpone [IF] ;
3511:
3512: : [IFUNDEF] tdefined? 0= postpone [IF] ;
3513:
3514: Cond: [IFDEF] postpone [IFDEF] ;Cond
3515:
3516: Cond: [IFUNDEF] postpone [IFUNDEF] ;Cond
3517:
3518: \ C: \- \+ Conditional Compiling 09jun93jaw
3519:
3520: : C: >in @ tdefined? 0=
3521: IF >in ! X :
3522: ELSE drop
3523: BEGIN bl word dup c@
3524: IF count comment? s" ;" str= ?EXIT
3525: ELSE refill 0= ABORT" CROSS: Out of Input while C:"
3526: THEN
3527: AGAIN
3528: THEN ;
3529:
3530: : d? d? ;
3531:
3532: : \D ( -- "debugswitch" )
3533: \G doesn't skip line when debug switch is on
3534: D? 0= IF postpone \ THEN ;
3535:
3536: : \- ( -- "wordname" )
3537: \G interprets the line if word is not defined
3538: tdefined? IF postpone \ THEN ;
3539:
3540: : \+ ( -- "wordname" )
3541: \G interprets the line if word is defined
3542: tdefined? 0= IF postpone \ THEN ;
3543:
3544: : \? ( -- "envorinstring" )
3545: \G Skip line if environmental variable evaluates to false
3546: X has? 0= IF postpone \ THEN ;
3547:
3548: Cond: \- \- ;Cond
3549: Cond: \+ \+ ;Cond
3550: Cond: \D \D ;Cond
3551: Cond: \? \? ;Cond
3552:
3553: : ?? bl word find IF execute ELSE drop 0 THEN ;
3554:
3555: : needed:
3556: \G defines ghost for words that we want to be compiled
3557: BEGIN >in @ bl word c@ WHILE >in ! Ghost drop REPEAT drop ;
3558:
3559: \ words that should be in minimal
3560:
3561: create s-buffer 50 chars allot
3562:
3563: bigendian Constant bigendian
3564:
3565: : here there ;
3566: : equ constant ;
3567: : mark there constant ;
3568:
3569: \ compiler directives
3570: : >ram >ram ;
3571: : >rom >rom ;
3572: : >auto >auto ;
3573: : >tempdp >tempdp ;
3574: : tempdp> tempdp> ;
3575: : const constflag on ;
3576:
3577: : Redefinitions-start
3578: \G Starts a redefinition section. Warnings are disabled and
3579: \G existing ghosts are reused. This is used in the kernel
3580: \G where ( and \ and the like are redefined
3581: twarnings off warnings off reuse-ghosts on ;
3582:
3583: : Redefinitions-end
3584: \G Ends a redefinition section. Warnings are enabled again.
3585: twarnings on warnings on reuse-ghosts off ;
3586:
3587: : warnings name 3 =
3588: IF twarnings off warnings off ELSE twarnings on warnings on THEN drop ;
3589:
3590: : | ;
3591: \ : | NoHeaderFlag on ; \ This is broken (damages the last word)
3592:
3593: : save-cross save-cross ;
3594: : save-region save-region ;
3595: : tdump swap >image swap dump ;
3596:
3597: also forth
3598: [IFDEF] Label : Label defempty? Label ; [THEN]
3599: [IFDEF] start-macros : start-macros defempty? start-macros ; [THEN]
3600: \ [IFDEF] builttag : builttag builttag ; [THEN]
3601: previous
3602:
3603: : s" [char] " parse s-buffer place s-buffer count ; \ for environment?
3604: : + + ;
3605: : 1+ 1 + ;
3606: : 2+ 2 + ;
3607: : 1- 1- ;
3608: : - - ;
3609: : and and ;
3610: : or or ;
3611: : 2* 2* ;
3612: : * * ;
3613: : / / ;
3614: : dup dup ;
3615: : over over ;
3616: : swap swap ;
3617: : rot rot ;
3618: : drop drop ;
3619: : = = ;
3620: : <> <> ;
3621: : 0= 0= ;
3622: : lshift lshift ;
3623: : 2/ 2/ ;
3624: \ : . . ;
3625:
3626: : all-words ['] forced? IS skip? ;
3627: : needed-words ['] needed? IS skip? ;
3628: : undef-words ['] defined2? IS skip? ;
3629: : skipdef skipdef ;
3630:
3631: : \ postpone \ ; immediate
3632: : \G T-\G ; immediate
3633: : ( postpone ( ; immediate
3634: : include bl word count included ;
3635: : included swap >image swap included ;
3636: : require require ;
3637: : needs require ;
3638: : .( [char] ) parse type ;
3639: : ." [char] " parse type ;
3640: : cr cr ;
3641:
3642: : times 0 ?DO dup X c, LOOP drop ; \ used for space table creation
3643:
3644: \ only forth also cross also minimal definitions order
3645:
3646: \ cross-compiler words
3647:
3648: : decimal decimal [g'] decimal >exec2 @ ?dup IF EXECUTE THEN ;
3649: : hex hex [g'] hex >exec2 @ ?dup IF EXECUTE THEN ;
3650:
3651: \ : tudp X tudp ;
3652: \ : tup X tup ;
3653:
3654: : doc-off false to-doc ! ;
3655: : doc-on true to-doc ! ;
3656:
3657: : declareunique ( "name" -- )
3658: \ Sets the unique flag for a ghost. The assembler output
3659: \ generates labels with the ghostname concatenated with the address
3660: \ while cross-compiling. The address is concatenated
3661: \ because we have double occurences of the same name.
3662: \ If we want to reference the labels from the assembler or C
3663: \ code we declare them unique, so the address is skipped.
3664: Ghost >ghost-flags dup @ <unique> or swap ! ;
3665:
3666: \ [IFDEF] dbg : dbg dbg ; [THEN]
3667:
3668: \ for debugging...
3669: \ : dbg dbg ;
3670: : horder order ;
3671: : hwords words ;
3672: \ : words also ghosts
3673: \ words previous ;
3674: : .s .s ;
3675: : depth depth ;
3676: : bye bye ;
3677:
3678: \ dummy
3679:
3680: \ turnkey direction
3681: : H forth ; immediate
3682: : T minimal ; immediate
3683: : G ghosts ; immediate
3684:
3685:
3686: \ these ones are pefered:
3687:
3688: : unlock previous forth also cross ;
3689:
3690: \ also minimal
3691: >cross
3692:
3693: : turnkey
3694: ghosts-wordlist 1 set-order
3695: also target definitions
3696: also Minimal also ;
3697:
3698: >minimal
3699:
3700: : [[+++
3701: turnkey unlock ;
3702:
3703: unlock definitions also minimal
3704:
3705: : lock turnkey ;
3706:
3707: Defer +++]]-hook
3708: : +++]] +++]]-hook lock ;
3709:
3710: LOCK
3711: \ load cross compiler extension defined in mach file
3712:
3713: UNLOCK >CROSS
3714:
3715: [IFDEF] extend-cross extend-cross [THEN]
3716:
3717: LOCK
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>