File:  [gforth] / gforth / configure.in
Revision 1.146: download - view: text, annotated - select for diffs
Sat Jan 22 16:39:58 2005 UTC (19 years, 2 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Added --diag switch, diagnostics output.
Fixed "broken link" bug when referring to current file

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.2-20030910],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="September 10, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: [  --enable-force-reg	  Use explicit register declarations if they appear in
   38: 			  the machine.h file. This can cause a good speedup,
   39: 			  but also incorrect code with some gcc versions on
   40: 			  some processors (default disabled).],
   41: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   42: AC_ARG_ENABLE(force-ll,
   43: [  --enable-force-ll	  Use explicit long long declarations if they appear in
   44: 			  the machine.h file. This can cause a good speedup,
   45: 			  but also incorrect code with some gcc versions on
   46: 			  some processors (default disabled).],
   47: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)]))
   48: AC_SUBST(PROFEXES)
   49: AC_SUBST(PROFOBJS)
   50: AC_ARG_ENABLE(prof,
   51: [  --enable-prof          Build gforth-prof, which outputs frequently occuring
   52:                           sequences of primitives.],
   53: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o")
   54: 
   55: AC_ARG_WITH(debug,
   56: [  --with-debug		  specifies option -g to compile with debug info
   57:   --without-debug	  omits the -g switch and creates smaller images on
   58: 			  machines where "strip" has problems with gcc style
   59: 			  debugging informations.],
   60: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   61: 
   62: dnl PEEPHOLE="yes"
   63: dnl AC_ARG_WITH(peephole,
   64: dnl [  --with-peephole	Enable peephole optimization (default)
   65: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   66: dnl 			but slower images.],
   67: dnl PEEPHOLE="$withval")
   68: 
   69: #variables mentioned in INSTALL
   70: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
   71: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   72: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   73: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   74: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   75: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   76: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   77: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   78: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   79: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   80: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
   81: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
   82: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
   83: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
   84: 
   85: #set up feature test macros, so the tests get them right:
   86: # turn on all POSIX, SUSv3, and GNU features if available
   87: AC_GNU_SOURCE
   88: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   89: 
   90: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   91: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   92: dnl but not for _XOPEN_SOURCE)
   93: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   94: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   95: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   96: # turn on large file support with 64-bit off_t where available
   97: AC_SYS_LARGEFILE
   98: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   99: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  100: 
  101: #currently we force direct threading this way.  Eventually we should
  102: #setup in the arch and engine files right
  103: 
  104: AC_PROG_CC
  105: 
  106: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  107: 
  108: AC_SUBST(CC)
  109: AC_SUBST(DEBUGFLAG)
  110: 
  111: AC_MSG_CHECKING(make type)
  112: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
  113: 
  114: GNUMAKE='#'
  115: test "$make_type" = "GNU Make" && GNUMAKE=''
  116: 
  117: AC_MSG_RESULT($make_type)
  118: 
  119: AC_SUBST(GNUMAKE)
  120: 
  121: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  122: OLDLDFLAGS=$LDFLAGS
  123: LDFLAGS="$LDFLAGS -export-dynamic"
  124: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  125: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  126: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  127: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  128: AC_MSG_RESULT($ac_export_dynamic)
  129: 
  130: #terminology is a bit unusual here: The host is the system on which
  131: #gforth will run; the system on which configure will run is the `build'
  132: AC_CANONICAL_HOST
  133: case "$host_cpu" in
  134: 	arm*)
  135: 		machine=arm
  136: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  137: 		if test -z $no_dynamic_default; then
  138: 		    no_dynamic_default=1
  139: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  140: 		fi
  141: 		;;
  142: 	hppa*)
  143: 		machine=hppa
  144: 		$srcdir/mkinstalldirs arch/hppa
  145: 		AC_LIBOBJ(../arch/hppa/cache)
  146: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  147: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  148: 		LIBS="$LIBS -L/lib/pa1.1/"
  149: 		;;
  150: 	sparc*)
  151: 		machine=sparc
  152: 		;;
  153: 	i386)
  154: 		machine=386
  155: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  156: 		;;
  157: 	i486)
  158: 		machine=386
  159: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  160: 		;;
  161: 	i*86)
  162: 		machine=386
  163: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  164: 		CFLAGS_1="$CFLAGS"
  165: 		CFLAGS="$CFLAGS -march=pentium"
  166: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  167: 		;;
  168: 	x86_64)
  169: 		machine=amd64
  170: 		;;
  171: 	ia64*)
  172: 		machine=ia64
  173: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  174: 		test "$skipcode" || skipcode="nop.i 0"
  175: 		#".skip 16" passes the test below,
  176: 		# but gives an assembler error in engine
  177: 		;;
  178:         m68k)
  179: 		machine=m68k
  180: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  181: 		if test "$host_os" = "nextstep3"
  182: 		then
  183: 			AC_LIBOBJ(termios)
  184: 		fi
  185: 		;;
  186: 	mips*)
  187: 		machine=mips
  188: 		#dynamic native code has the following problems on MIPS:
  189: 		#
  190: 		#1) J/JAL seems relocatable, but is are only
  191: 		#relocatable within a 256MB-segment.  While we try to
  192: 		#get the linker to arrange this, there is no guarantee
  193: 		#that this will succeed (and if the user uses a lot of
  194: 		#memory, it is likely to fail).
  195: 		#
  196: 		#2) The way we generate dynamic native code may
  197: 		#violate MIPS architectural restrictions (in
  198: 		#particular, the delay slots of LW, MFLO, etc.)
  199: 		#
  200: 		#Therefore we disable dynamic native code by default:
  201: 		if test -z $no_dynamic_default; then
  202: 		    no_dynamic_default=1
  203: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  204: 		fi
  205: 		;;
  206: 	alpha*)
  207: 		machine=alpha
  208: 		#full IEEE FP support for more uniformity across platforms:
  209: 		CFLAGS="$CFLAGS -mieee"
  210: 		;;
  211: 	power*|rs6000)
  212: 		machine=power
  213: 		$srcdir/mkinstalldirs arch/power
  214: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  215: 		#long long is broken on (at least) gcc-2.95.* for PPC
  216: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  217: 		;;
  218: 	*)
  219: 		AC_MSG_WARN([Using a generic machine description])
  220: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  221: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  222: 		machine=generic
  223: 		#I-cache flushing would be needed for dynamic code generation
  224: 		if test -z $no_dynamic_default; then
  225: 		    no_dynamic_default=1
  226: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  227: 		fi
  228: esac
  229: AC_SUBST(host)
  230: 
  231: if test "${enable_force_ll+set}" = set; then
  232:    ac_includes_default="$ac_includes_default
  233: #include \"arch/generic/128bit.h\""
  234: fi
  235: 
  236: dnl the following macro produces a warning with autoconf-2.1
  237: AC_CHECK_SIZEOF(char *)
  238: case "$ac_cv_sizeof_char_p" in
  239:   2)
  240:     wordsize=16
  241:     ;;
  242:   4)
  243:     wordsize=32
  244:     ;;
  245:   8)
  246:     wordsize=64
  247:     ;;
  248: esac
  249: 
  250: AC_CHECK_SIZEOF(char)
  251: AC_CHECK_SIZEOF(short)
  252: AC_CHECK_SIZEOF(int)
  253: AC_CHECK_SIZEOF(long)
  254: AC_CHECK_SIZEOF(long long)
  255: AC_CHECK_SIZEOF(intptr_t)
  256: AC_CHECK_SIZEOF(int128_t)
  257: AC_CHECK_SIZEOF(uint128_t)
  258: 
  259: AC_MSG_CHECKING([for a C type for cells])
  260: ac_cv_int_type_cell=none
  261: case "$ac_cv_sizeof_char_p" in
  262:   $ac_cv_sizeof_int)
  263:     ac_cv_int_type_cell=int
  264:     ;;
  265:   $ac_cv_sizeof_short)
  266:     ac_cv_int_type_cell=short
  267:     ;;
  268:   $ac_cv_sizeof_char)
  269:     ac_cv_int_type_cell=char
  270:     ;;
  271:   $ac_cv_sizeof_long)
  272:     ac_cv_int_type_cell=long
  273:     ;;
  274:   $ac_cv_sizeof_long_long)
  275:     ac_cv_int_type_cell="long long"
  276:     ;;
  277:   $ac_cv_sizeof_intptr_t)
  278:     ac_cv_int_type_cell="intptr_t"
  279:     ;;
  280:   $ac_cv_sizeof_int128_t)
  281:     ac_cv_int_type_cell="int128_t"
  282:     ;;
  283: esac
  284: AC_MSG_RESULT($ac_cv_int_type_cell)
  285: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  286: 
  287: AC_MSG_CHECKING([for a C type for double-cells])
  288: ac_cv_int_type_double_cell=none
  289: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  290:   $ac_cv_sizeof_short)
  291:     ac_cv_int_type_double_cell=short
  292:     ;;
  293:   $ac_cv_sizeof_int)
  294:     ac_cv_int_type_double_cell=int
  295:     ;;
  296:   $ac_cv_sizeof_long)
  297:     ac_cv_int_type_double_cell=long
  298:     ;;
  299:   $ac_cv_sizeof_long_long)
  300:     ac_cv_int_type_double_cell="long long"
  301:     ;;
  302:   $ac_cv_sizeof_intptr_t)
  303:     ac_cv_int_type_double_cell="intptr_t"
  304:     ;;
  305:   $ac_cv_sizeof_int128_t)
  306:     ac_cv_int_type_double_cell="int128_t"
  307:     ;;
  308: esac
  309: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  310: 
  311: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  312: ac_cv_int_type_double_ucell=none
  313: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  314:   $ac_cv_sizeof_short)
  315:     ac_cv_int_type_double_ucell="unsigned short"
  316:     ;;
  317:   $ac_cv_sizeof_int)
  318:     ac_cv_int_type_double_ucell="unsigned int"
  319:     ;;
  320:   $ac_cv_sizeof_long)
  321:     ac_cv_int_type_double_ucell="unsigned long"
  322:     ;;
  323:   $ac_cv_sizeof_long_long)
  324:     ac_cv_int_type_double_ucell="unsigned long long"
  325:     ;;
  326:   $ac_cv_sizeof_intptr_t)
  327:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  328:     ;;
  329:   $ac_cv_sizeof_uint128_t)
  330:     ac_cv_int_type_double_ucell="uint128_t"
  331:     ;;
  332: esac
  333: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  334: 
  335: if test "$ac_cv_int_type_double_cell" = none || \
  336:    test "$ac_cv_int_type_double_ucell" = none
  337: then
  338: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  339: 	AC_LIBOBJ(dblsub)
  340: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  341: else
  342: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  343: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  344: fi
  345: 
  346: AC_TYPE_OFF_T
  347: AC_CHECK_SIZEOF(off_t)
  348: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  349: ac_small_off_t=$?
  350: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  351: 
  352: ENGINE_FLAGS=
  353: AC_SUBST(ENGINE_FLAGS)
  354: 
  355: # Try if GCC understands -fno-gcse
  356: 
  357: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  358: CFLAGS_1="$CFLAGS"
  359: CFLAGS="$CFLAGS -fno-gcse"
  360: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  361: CFLAGS="$CFLAGS_1"
  362: AC_MSG_RESULT($ac_nogcse)
  363: 
  364: # Try if GCC understands -fno-strict-aliasing
  365: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  366: CFLAGS_1="$CFLAGS"
  367: CFLAGS="$CFLAGS -fno-strict-aliasing"
  368: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  369: CFLAGS="$CFLAGS_1"
  370: AC_MSG_RESULT($ac_nostrictaliasing)
  371: 
  372: # Try if GCC understands -fno-crossjumping
  373: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  374: CFLAGS_1="$CFLAGS"
  375: CFLAGS="$CFLAGS -fno-crossjumping"
  376: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  377: CFLAGS="$CFLAGS_1"
  378: AC_MSG_RESULT($ac_nocrossjumping)
  379: 
  380: # Try if GCC understands -fno-reorder-blocks
  381: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  382: CFLAGS_1="$CFLAGS"
  383: CFLAGS="$CFLAGS -fno-reorder-blocks"
  384: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  385: CFLAGS="$CFLAGS_1"
  386: AC_MSG_RESULT($ac_noreorder_blocks)
  387: 
  388: # Try if GCC understands __attribute__((unused))
  389: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  390: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  391: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  392: AC_MSG_RESULT($MAYBE_UNUSED)
  393: 
  394: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  395: AC_SUBST(asm_fs)
  396: 
  397: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  398: AC_SUBST(disasm_fs)
  399: 
  400: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  401: 
  402: case "$host_os" in
  403: 	*win32|cygwin)
  404: 		DIRSEP="\\\\"
  405: 		PATHSEP=";"
  406: 		#we want the builtins of command.com/cmd.exe and its
  407: 		# handling of .com files.
  408: 		#$COMSPEC contains the name of the Windows shell;
  409: 		# the ./ is there, because the bash does not recognize
  410: 		# absolute DOS filenames
  411: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  412: 		;;
  413: 	*darwin*)
  414: 		#Darwin uses some funny preprocessor by default; eliminate it:
  415: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  416: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  417: 		DIRSEP="/"
  418: 		PATHSEP=":"
  419: 		DEFAULTSYSTEMPREFIX=""
  420: 		;;
  421: 	*)
  422: 		DIRSEP="/"
  423: 		PATHSEP=":"
  424: 		DEFAULTSYSTEMPREFIX=""
  425: 		;;
  426: esac
  427: AC_SUBST(DIRSEP)
  428: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  429: AC_SUBST(PATHSEP)
  430: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  431: AC_SUBST(DEFAULTSYSTEMPREFIX)
  432: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  433: 
  434: dnl Now a little support for DOS/DJGCC
  435: AC_SUBST(GFORTH_EXE)
  436: GFORTH_EXE=""
  437: AC_SUBST(GFORTHFAST_EXE)
  438: GFORTHFAST_EXE=""
  439: AC_SUBST(GFORTHITC_EXE)
  440: GFORTHITC_EXE=""
  441: AC_SUBST(GFORTHDITC_EXE)
  442: GFORTHDITC_EXE=""
  443: 
  444: AC_SUBST(FORTHSIZES)
  445: 
  446: dnl if test "$PEEPHOLE" = "yes"
  447: dnl then
  448: dnl    PEEPHOLEFLAG="true"
  449: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  450: dnl else
  451: dnl    PEEPHOLEFLAG="false"
  452: dnl fi
  453: PEEPHOLEFLAG="true"
  454: AC_SUBST(PEEPHOLEFLAG)
  455: 
  456: dnl copy commands for systems that don't have links
  457: AC_SUBST(LINK_KERNL)
  458: LINK_KERNL=""
  459: 
  460: #if test $host_os=dos
  461: #then
  462: #  echo Configuring for DOS!!!
  463: #  MAKE_EXE="coff2exe gforth"
  464: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  465: #fi
  466: 
  467: dnl the following macro produces a warning with autoconf-2.1
  468: AC_C_BIGENDIAN
  469: AC_SUBST(KERNEL)
  470: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  471: if test $ac_cv_c_bigendian = yes; then
  472:   bytesex=b
  473:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  474: else
  475:   bytesex=l
  476:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  477: fi
  478: 
  479: #check how to do asm(".skip 16")
  480: AC_MSG_CHECKING([if and how we can waste code space])
  481: if test -z "$skipcode"; then
  482:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  483:     do
  484: 	AC_TRY_RUN(
  485: [int foo(int,int,int);
  486: main()
  487: {
  488:   exit(foo(0,0,0)!=16);
  489: }
  490: int foo(int x, int y, int z)
  491: {
  492:   static void *labels[]={&&label1, &&label2};
  493:   if (x) {
  494:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  495:   label1:
  496:     asm(".skip 16"); /* or ".space 16" or somesuch */
  497:   label2: ;
  498:   }
  499:   {
  500:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  501:   return labels[1]-labels[0];
  502:   }
  503: }]
  504: 	,skipcode=$i; break
  505: 	,,)
  506:     done
  507: fi
  508: AC_MSG_RESULT($skipcode)
  509: if test "$skipcode" = no
  510: then 
  511:     if test -z $no_dynamic_default; then
  512: 	no_dynamic_default=1
  513: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  514:     fi
  515:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  516: else
  517:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  518: fi
  519: 
  520: test "$no_dynamic_default" || no_dynamic_default=0
  521: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  522: 
  523: dnl Checks for programs.
  524: AC_PROG_LN_S
  525: AC_PROG_INSTALL
  526: 
  527: dnl Checks for library functions
  528: dnl This check is just for making later checks link with libm.
  529: dnl using sin here is no good idea since it is built-into gcc and typechecked
  530: AC_CHECK_LIB(m,asin)
  531: AC_CHECK_LIB(dl,dlopen)
  532: dnl check for ffcall libraries
  533: dnl unfortunately, these four calls are separated out into a library each.
  534: AC_CHECK_LIB(avcall,__builtin_avcall)
  535: AC_CHECK_LIB(callback,__vacall_r)
  536: AC_CHECK_LIB(vacall,vacall)
  537: AC_CHECK_LIB(trampoline,alloc_trampoline)
  538: FFCALLFLAG="false"
  539: OLDCALLFLAG="true"
  540: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  541: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  542: AC_SUBST(FFCALLFLAG)
  543: AC_SUBST(OLDCALLFLAG)
  544: if test "$host_os" != "nextstep3"
  545: then
  546: 	AC_FUNC_MEMCMP
  547: fi
  548: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  549: AC_FUNC_FSEEKO
  550: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  551: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  552: AC_DECL_SYS_SIGLIST
  553: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  554: AC_CHECK_FUNCS(expm1 log1p)
  555: AC_REPLACE_FUNCS(rint ecvt)
  556: dnl No check for select, because our replacement is no good under
  557: dnl anything but DOS
  558: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  559: AC_FUNC_FNMATCH
  560: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  561: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  562: AM_PATH_LISPDIR
  563: 
  564: kernel_fi=kernl${wordsize}${bytesex}.fi
  565: AC_SUBST(kernel_fi)
  566: 
  567: #this breaks bindists
  568: #dnl replace srource directory by absolute value
  569: #if test $srcdir = "."; then srcdir=`pwd` 
  570: #fi
  571: 
  572: AC_SUBST(machine)
  573: AC_CONFIG_FILES([
  574: Makefile
  575: Makedist
  576: gforthmi
  577: vmgen
  578: machpc.fs
  579: engine/Makefile
  580: doc/version.texi ])
  581: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  582: chmod +x gforthmi
  583: chmod +x vmgen
  584: test -d kernel||mkdir kernel]],[[]])
  585: AC_OUTPUT
  586: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>