1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007,2008,2009,2010,2011 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.7.9-20121007],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="October 7, 2012"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #remnants from having ltdl as convenience library
33: LTDLDEPS=""
34: LTDLINCL=""
35: LIBLTDL=""
36: LTDL_LDLIBS=""
37: AC_SUBST(LTDLDEPS)
38: AC_SUBST(LTDLINCL)
39: AC_SUBST(LIBLTDL)
40: AC_SUBST(LTDL_LDLIBS)
41:
42: #suppress the "-g -O2" default
43: test "$CFLAGS" || CFLAGS=-O2
44:
45: AC_ARG_ENABLE(force-cdiv,
46: AC_HELP_STRING([--enable-force-cdiv],
47: [ Use the native C division - symmetric - instead of
48: floored division (default disabled).]),
49: ,enable_force_cdiv=no)
50: test "$enable_force_cdiv" = "no"||
51: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
52:
53: AC_SUBST(PROFEXES)
54: AC_SUBST(PROFOBJS)
55: AC_ARG_ENABLE(prof,
56: AC_HELP_STRING([--enable-prof],
57: [ Build gforth-prof, which outputs frequently occuring
58: sequences of primitives.]),
59: ,enable_prof=no)
60: if test "$enable_prof" != "no"; then
61: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
62: fi
63:
64: AC_ARG_WITH(debug,
65: [ --with-debug specifies option -g to compile with debug info
66: --without-debug omits the -g switch and creates smaller images on
67: machines where "strip" has problems with gcc style
68: debugging informations.],
69: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
70:
71: GCC_LD="\$(GCC)"
72: EC_MODE="false"
73: NO_EC=""
74: NO_CROSS=""
75: EC=""
76: engine2='engine2$(OPT).o'
77: engine_fast2='engine-fast2$(OPT).o'
78: no_dynamic=""
79: image_i=""
80: signals_o="io.o signals.o"
81:
82: AC_CANONICAL_HOST
83: AC_ARG_WITH(ec,
84: AC_HELP_STRING([--with-ec=<arch>],
85: [ Build gforth for systems without OS.]),
86: [if test "$withval" = "no"; then
87: echo "defining hosted system"
88: else
89: echo "defining standalone system (${withval})"
90: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
91: EC_MODE="true"
92: EC="-ec"
93: NO_EC="#"
94: NO_CROSS="#"
95: engine2=""
96: engine_fast2=""
97: no_dynamic="-DNO_DYNAMIC"
98: image_i="image.i"
99: if test "$withval" != "yes"; then
100: signals_o="io-${withval}.o"
101: else
102: signals_o="io.o"
103: fi
104: if test -f "arch/$host_cpu/${withval}/config.sh"; then
105: source "arch/$host_cpu/${withval}/config.sh"
106: fi
107: GCC_PATH=$(which $CC)
108: LIB_PATH=${GCC_PATH%/*/*}
109: GCC_LD="\$(LD)"
110: platform=${withval}
111: fi])
112:
113: AC_ARG_ENABLE(lib,
114: AC_HELP_STRING([--enable-lib],
115: [ Compile Gforth as shared library (default disabled).]),
116: ,enable_lib=no)
117: if test "$enable_lib" != "no"; then
118: AC_DEFINE(HAS_LIB,,[Define if you want to build as shared library])
119: libengines=libgforths
120: libinstall=libinstall
121: LIB_VERSION=0:8:0
122: fi
123: AC_SUBST(libengines)
124: AC_SUBST(libinstall)
125: AC_SUBST(LIB_VERSION)
126:
127: AC_ARG_WITH(cross,
128: AC_HELP_STRING([--with-cross=<arch>],
129: [ Build gforth using a cross compiler.]),
130: [if test "$withval" = "no"; then
131: echo "defining hosted system"
132: else
133: echo "defining cross compiled system (${withval})"
134: if test -f "arch/$host_cpu/${withval}/config.sh"; then
135: source "arch/$host_cpu/${withval}/config.sh"
136: fi
137: GCC_PATH=$(which $CC)
138: LIB_PATH=${GCC_PATH%/*/*}
139: platform=${withval}
140: NO_EC=""
141: NO_CROSS="#"
142: fi])
143:
144: AC_ARG_WITH(arch,
145: AC_HELP_STRING([--with-arch=<arch>],
146: [ Build gforth binaries with <arch> postfix]),
147: [if test "$withval" = "no"; then
148: ARCH=""
149: else
150: ARCH=-${withval}
151: fi])
152: AC_SUBST(ARCH)
153:
154: #variables mentioned in INSTALL
155: AC_ARG_VAR(SH, [The shell])
156: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
157: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
158: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
159: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
160: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
161: AC_ARG_VAR(LIBCC_BUILD_SRC, [(Additional) libcc interface source files that should be processed on building and installation (default none)])
162:
163: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
164: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
165: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
166: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
167: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
168: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
169: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
170: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
171: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
172: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
173: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
174: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
175: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
176: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
177: AC_ARG_VAR(asmcomment, [assembler comment start string])
178: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
179: AC_ARG_VAR(LTDL_LIBRARY_PATH, [additional directories for libltdl (for some 64-bit platforms)])
180:
181: #set up feature test macros, so the tests get them right:
182: # turn on all POSIX, SUSv3, and GNU features if available
183: AC_GNU_SOURCE
184: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
185:
186: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
187: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
188: dnl but not for _XOPEN_SOURCE)
189: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
190: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
191: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
192: # turn on large file support with 64-bit off_t where available
193: AC_SYS_LARGEFILE
194: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
195: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
196:
197: #currently we force direct threading this way. Eventually we should
198: #setup in the arch and engine files right
199:
200: AC_PROG_CC
201:
202: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
203:
204: test "x$SH" = "x" && SH="/bin/sh"
205:
206: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
207: test x$condbranch_opt = x &&
208: if ($CC -v 2>&1 |grep 'gcc version 3' >/dev/null); then
209: condbranch_opt=0
210: else
211: condbranch_opt=1
212: fi
213: AC_MSG_RESULT($condbranch_opt)
214: AC_SUBST(condbranch_opt)
215: AC_SUBST(host_cpu)
216:
217: AC_SUBST(SH)
218: AC_SUBST(CC)
219: AC_SUBST(GCC_LD)
220: AC_SUBST(DEBUGFLAG)
221: AC_SUBST(EC)
222: AC_SUBST(NO_EC)
223: AC_SUBST(NO_CROSS)
224: AC_SUBST(EC_MODE)
225: AC_SUBST(engine2)
226: AC_SUBST(engine_fast2)
227: AC_SUBST(no_dynamic)
228: AC_SUBST(image_i)
229: AC_SUBST(signals_o)
230: AC_SUBST(mi_prefix)
231:
232: #this is used to disable some (not generally essential) part of the
233: #Makefile that some makes don't grok. It would be better to test for
234: #this specific Makefile feature than the make version.
235: AC_MSG_CHECKING(make type)
236: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
237: GNUMAKE='#'
238: test "$make_type" = "GNU Make" && GNUMAKE=''
239: AC_MSG_RESULT($make_type)
240: AC_SUBST(GNUMAKE)
241:
242: if test "$ac_export_dynamic" != yes; then
243: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
244: OLDLDFLAGS=$LDFLAGS
245: LDFLAGS="$LDFLAGS -export-dynamic"
246: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
247: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
248: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
249: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
250: AC_MSG_RESULT($ac_export_dynamic)
251: else
252: LDFLAGS="$LDFLAGS -export-dynamic"
253: fi
254:
255: #terminology is a bit unusual here: The host is the system on which
256: #gforth will run; the system on which configure will run is the `build'
257: case "$host_cpu" in
258: arm*)
259: machine=arm
260: CFLAGS="$CFLAGS -fomit-frame-pointer"
261: if test x$platform = xnxt; then
262: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
263: fi
264: if test -z $arm_cacheflush; then
265: case "$host_os" in
266: *linux*)
267: AC_LIBOBJ(../arch/arm/cacheflush-linux)
268: ;;
269: *)
270: no_dynamic_default=1
271: AC_LIBOBJ(../arch/arm/cacheflush0)
272: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
273: ;;
274: esac
275: else
276: AC_LIBOBJ(../$arm_cacheflush)
277: test $srcdir = . || AC_MSG_WARN([setting arm_cacheflush requires building in the source directory])
278: fi
279: #longer skipcodes lead to problems on ARM, and it uses
280: #only 4-byte alignment anyway
281: test "$skipcode" || skipcode="nop"
282: ;;
283: hppa*)
284: machine=hppa
285: AC_LIBOBJ(../arch/hppa/cache)
286: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
287: LDFLAGS="$LDFLAGS -Xlinker -N"
288: LIBS="$LIBS -L/lib/pa1.1/"
289: ;;
290: sparc*)
291: machine=sparc
292: ;;
293: i386)
294: machine=386
295: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
296: ;;
297: i486)
298: machine=386
299: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
300: CFLAGS_1="$CFLAGS"
301: CFLAGS="$CFLAGS -march=i486"
302: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
303: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
304: ;;
305: i*86)
306: machine=386
307: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
308: CFLAGS_1="$CFLAGS"
309: CFLAGS="$CFLAGS -march=pentium -mtune=generic"
310: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -march=pentium")
311: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
312: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
313: ;;
314: x86_64)
315: case $CC
316: in
317: *-m32*)
318: machine=386
319: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
320: CFLAGS_1="$CFLAGS"
321: CFLAGS="$CFLAGS -march=athlon64"
322: ;;
323: *)
324: machine=amd64
325: ;;
326: esac
327: ;;
328: ia64*)
329: machine=ia64
330: AC_LIBOBJ(../arch/ia64/flush_icache_block)
331: test "$skipcode" || skipcode="nop.i 0"
332: #".skip 16" passes the test below,
333: # but gives an assembler error in engine
334: ;;
335: m68k)
336: machine=m68k
337: CFLAGS="$CFLAGS -fomit-frame-pointer"
338: if test "$host_os" = "nextstep3"
339: then
340: AC_LIBOBJ(termios)
341: fi
342: ;;
343: mips*)
344: machine=mips
345: AC_LIBOBJ(../arch/mips/check_prim)
346: #dynamic native code has the following problems on MIPS:
347: #
348: #1) J/JAL seems relocatable, but is are only
349: #relocatable within a 256MB-segment. While we try to
350: #get the linker to arrange this, there is no guarantee
351: #that this will succeed (and if the user uses a lot of
352: #memory, it is likely to fail).
353: #
354: #2) The way we generate dynamic native code may
355: #violate MIPS architectural restrictions (in
356: #particular, the delay slots of LW, MFLO, etc.)
357: #
358: #Therefore we disable dynamic native code by default:
359: if test -z "$no_dynamic_default"; then
360: no_dynamic_default=1
361: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
362: fi
363: ;;
364: alpha*)
365: machine=alpha
366: #full IEEE FP support for more uniformity across platforms:
367: CFLAGS="$CFLAGS -mieee"
368: ;;
369: power*|rs6000)
370: machine=power
371: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
372: #long long is broken on (at least) gcc-2.95.* for PPC
373: test x$ac_cv_sizeof_long_long = x &&
374: ($CC -v 2>&1 |grep 'gcc version 2.95' >/dev/null) &&
375: ac_cv_sizeof_long_long=0
376: #The only architecture with enough callee-saved registers
377: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
378: #or use 2, hardly slower at run-time and starts up faster
379:
380: #the skipcode that is normally selected below does not
381: #work with gcc-3.[34]
382: test "$skipcode" || skipcode="nop\nnop\nnop\nnop"
383: ;;
384: *)
385: AC_MSG_WARN([Using a generic machine description])
386: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
387: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
388: machine=generic
389: #I-cache flushing would be needed for dynamic code generation
390: if test -z $no_dynamic_default; then
391: no_dynamic_default=1
392: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
393: fi
394: esac
395: AC_SUBST(host)
396:
397: MAKEINC=""
398: GFORTH_EXE="true"
399:
400: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
401: if test x$EC_MODE = xtrue
402: then
403: echo "Check for arch/$machine/$platform/gforth.ld"
404: if test -f arch/$machine/$platform/gforth.ld
405: then
406: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
407: if test x$platform = xnxt; then
408: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
409: fi
410: fi
411: if test -f arch/$machine/$platform/make.inc
412: then
413: MAKEINC="include ../arch/$machine/$platform/make.inc"
414: GFORTH_EXE="\$(MAKE) -f arch/$machine/$platform/make.inc \$@.exe"
415: fi
416: fi
417: AC_SUBST(MAKEINC)
418:
419: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
420:
421: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
422: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
423: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
424: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
425: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
426: [number of registers in the default stack cache state for gforth-fast and gforth-native])
427:
428: test x$GCC_PR15242_WORKAROUND = x ||
429: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
430: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
431:
432: dnl the following macro produces a warning with autoconf-2.1
433: AC_CHECK_SIZEOF(char *)
434: case "$ac_cv_sizeof_char_p" in
435: 2)
436: wordsize=16
437: ;;
438: 4)
439: wordsize=32
440: ;;
441: 8)
442: wordsize=64
443: ;;
444: esac
445:
446: AC_CHECK_SIZEOF(void *)
447: case "$ac_cv_sizeof_void_p" in
448: 2)
449: vwordsize=16
450: ;;
451: 4)
452: vwordsize=32
453: ;;
454: 8)
455: vwordsize=64
456: ;;
457: esac
458:
459: AC_CHECK_SIZEOF(char)
460: AC_CHECK_SIZEOF(short)
461: AC_CHECK_SIZEOF(int)
462: AC_CHECK_SIZEOF(long)
463: AC_CHECK_SIZEOF(long long)
464: AC_CHECK_SIZEOF(intptr_t)
465: AC_CHECK_SIZEOF(int128_t)
466: AC_CHECK_SIZEOF(uint128_t)
467:
468: AC_MSG_CHECKING([for a C type for cells])
469: ac_cv_int_type_cell=none
470: case "$ac_cv_sizeof_char_p" in
471: $ac_cv_sizeof_int)
472: ac_cv_int_type_cell=int
473: ;;
474: $ac_cv_sizeof_short)
475: ac_cv_int_type_cell=short
476: ;;
477: $ac_cv_sizeof_char)
478: ac_cv_int_type_cell=char
479: ;;
480: $ac_cv_sizeof_long)
481: ac_cv_int_type_cell=long
482: ;;
483: $ac_cv_sizeof_long_long)
484: ac_cv_int_type_cell="long long"
485: ;;
486: $ac_cv_sizeof_intptr_t)
487: ac_cv_int_type_cell="intptr_t"
488: ;;
489: esac
490: AC_MSG_RESULT($ac_cv_int_type_cell)
491: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
492:
493: AC_MSG_CHECKING([for a C type for wydes])
494: ac_cv_wyde_type_cell=none
495: case 2 in
496: $ac_cv_sizeof_int)
497: ac_cv_wyde_type_cell=int
498: ;;
499: $ac_cv_sizeof_short)
500: ac_cv_wyde_type_cell=short
501: ;;
502: $ac_cv_sizeof_char)
503: ac_cv_wyde_type_cell=char
504: ;;
505: $ac_cv_sizeof_long)
506: ac_cv_wyde_type_cell=long
507: ;;
508: $ac_cv_sizeof_long_long)
509: ac_cv_wyde_type_cell="long long"
510: ;;
511: $ac_cv_sizeof_intptr_t)
512: ac_cv_wyde_type_cell="intptr_t"
513: ;;
514: esac
515: AC_MSG_RESULT($ac_cv_wyde_type_cell)
516: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
517:
518: AC_MSG_CHECKING([for a C type for tetrabytes])
519: ac_cv_tetrabyte_type_cell=none
520: case 4 in
521: $ac_cv_sizeof_int)
522: ac_cv_tetrabyte_type_cell=int
523: ;;
524: $ac_cv_sizeof_short)
525: ac_cv_tetrabyte_type_cell=short
526: ;;
527: $ac_cv_sizeof_char)
528: ac_cv_tetrabyte_type_cell=char
529: ;;
530: $ac_cv_sizeof_long)
531: ac_cv_tetrabyte_type_cell=long
532: ;;
533: $ac_cv_sizeof_long_long)
534: ac_cv_tetrabyte_type_cell="long long"
535: ;;
536: $ac_cv_sizeof_intptr_t)
537: ac_cv_tetrabyte_type_cell="intptr_t"
538: ;;
539: esac
540: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
541: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
542:
543: AC_MSG_CHECKING([for a C type for octabytes])
544: ac_cv_octabyte_type_cell=none
545: case 8 in
546: $ac_cv_sizeof_int)
547: ac_cv_octabyte_type_cell=int
548: ;;
549: $ac_cv_sizeof_short)
550: ac_cv_octabyte_type_cell=short
551: ;;
552: $ac_cv_sizeof_char)
553: ac_cv_octabyte_type_cell=char
554: ;;
555: $ac_cv_sizeof_long)
556: ac_cv_octabyte_type_cell=long
557: ;;
558: $ac_cv_sizeof_long_long)
559: ac_cv_octabyte_type_cell="long long"
560: ;;
561: $ac_cv_sizeof_intptr_t)
562: ac_cv_octabyte_type_cell="intptr_t"
563: ;;
564: esac
565: AC_MSG_RESULT($ac_cv_octabyte_type_cell)
566: AC_DEFINE_UNQUOTED(OCTABYTE_TYPE,$ac_cv_octabyte_type_cell,[an integer type that is 8 bytes long])
567:
568: AC_MSG_CHECKING([for a C type for double-cells])
569: ac_cv_int_type_double_cell=none
570: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
571: $ac_cv_sizeof_short)
572: ac_cv_int_type_double_cell=short
573: ;;
574: $ac_cv_sizeof_int)
575: ac_cv_int_type_double_cell=int
576: ;;
577: $ac_cv_sizeof_long)
578: ac_cv_int_type_double_cell=long
579: ;;
580: $ac_cv_sizeof_long_long)
581: ac_cv_int_type_double_cell="long long"
582: ;;
583: $ac_cv_sizeof_intptr_t)
584: ac_cv_int_type_double_cell="intptr_t"
585: ;;
586: $ac_cv_sizeof_int128_t)
587: ac_cv_int_type_double_cell="int128_t"
588: ;;
589: esac
590: AC_MSG_RESULT($ac_cv_int_type_double_cell)
591:
592: AC_MSG_CHECKING([for a C type for unsigned double-cells])
593: ac_cv_int_type_double_ucell=none
594: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
595: $ac_cv_sizeof_short)
596: ac_cv_int_type_double_ucell="unsigned short"
597: ;;
598: $ac_cv_sizeof_int)
599: ac_cv_int_type_double_ucell="unsigned int"
600: ;;
601: $ac_cv_sizeof_long)
602: ac_cv_int_type_double_ucell="unsigned long"
603: ;;
604: $ac_cv_sizeof_long_long)
605: ac_cv_int_type_double_ucell="unsigned long long"
606: ;;
607: $ac_cv_sizeof_intptr_t)
608: ac_cv_int_type_double_ucell="unsigned intptr_t"
609: ;;
610: $ac_cv_sizeof_uint128_t)
611: ac_cv_int_type_double_ucell="uint128_t"
612: ;;
613: esac
614: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
615:
616: if test "$ac_cv_int_type_double_cell" != none && \
617: test "$ac_cv_int_type_double_ucell" != none
618: then
619: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
620: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
621: OPTS=-ll
622: else
623: if test "$ac_cv_sizeof_char_p" = 8; then
624: OPTS="-ll -noll"
625: else
626: OPTS=-noll
627: fi
628: fi
629:
630: if grep FORCE_REG $srcdir/arch/$machine/machine.h >/dev/null; then
631: OPTS2=''
632: for i in $OPTS; do OPTS2="$OPTS2 $i-reg"; done
633: OPTS="$OPTS2 $OPTS"
634: else
635: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
636: fi
637: AC_SUBST(OPTS)
638:
639: AC_TYPE_OFF_T
640: AC_CHECK_SIZEOF(off_t)
641: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
642: ac_small_off_t=$?
643: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
644:
645: ENGINE_FLAGS=
646: AC_SUBST(ENGINE_FLAGS)
647:
648: # Try if GCC understands -fno-gcse
649:
650: AC_MSG_CHECKING([if $CC understands -fno-gcse])
651: CFLAGS_1="$CFLAGS"
652: CFLAGS="$CFLAGS -fno-gcse"
653: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
654: CFLAGS="$CFLAGS_1"
655: AC_MSG_RESULT($ac_nogcse)
656:
657: # Try if GCC understands -fno-strict-aliasing
658: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
659: CFLAGS_1="$CFLAGS"
660: CFLAGS="$CFLAGS -fno-strict-aliasing"
661: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
662: CFLAGS="$CFLAGS_1"
663: AC_MSG_RESULT($ac_nostrictaliasing)
664:
665: # Try if GCC understands -fno-crossjumping
666: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
667: CFLAGS_1="$CFLAGS"
668: CFLAGS="$CFLAGS -fno-crossjumping"
669: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
670: CFLAGS="$CFLAGS_1"
671: AC_MSG_RESULT($ac_nocrossjumping)
672:
673: # Try if GCC understands -fno-reorder-blocks
674: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
675: CFLAGS_1="$CFLAGS"
676: CFLAGS="$CFLAGS -fno-reorder-blocks"
677: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
678: CFLAGS="$CFLAGS_1"
679: AC_MSG_RESULT($ac_noreorder_blocks)
680:
681: # Try if GCC understands -falign-labels=1
682: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
683: CFLAGS_1="$CFLAGS"
684: CFLAGS="$CFLAGS -falign-labels=1"
685: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
686: CFLAGS="$CFLAGS_1"
687: AC_MSG_RESULT($ac_align_labels)
688:
689: # Try if GCC understands -falign-loops=1
690: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
691: CFLAGS_1="$CFLAGS"
692: CFLAGS="$CFLAGS -falign-loops=1"
693: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
694: CFLAGS="$CFLAGS_1"
695: AC_MSG_RESULT($ac_align_loops)
696:
697: # Try if GCC understands -falign-jumps=1
698: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
699: CFLAGS_1="$CFLAGS"
700: CFLAGS="$CFLAGS -falign-jumps=1"
701: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
702: CFLAGS="$CFLAGS_1"
703: AC_MSG_RESULT($ac_align_jumps)
704:
705: if test -z "$LIBTOOL_CC"
706: then
707: LIBTOOL_CC="$CC"
708: # Try if GCC understands -Wimplicit-function-declaration
709: AC_MSG_CHECKING([if $CC understands -Wimplicit-function-declaration])
710: CFLAGS_1="$CFLAGS"
711: CFLAGS="$CFLAGS -Wimplicit-function-declaration"
712: AC_TRY_COMPILE(,,LIBTOOL_CC="$CC -Wimplicit-function-declaration",)
713: CFLAGS="$CFLAGS_1"
714: AC_MSG_RESULT($ac_align_jumps)
715: fi
716: AC_SUBST(LIBTOOL_CC)
717:
718:
719:
720: # Try if GCC understands __attribute__((unused))
721: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
722: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
723: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
724: AC_MSG_RESULT($MAYBE_UNUSED)
725:
726: # Try if GCC understands __thread
727: AC_CACHE_CHECK([whether gcc understands '__thread'], [ac_cv_thread],
728: [AC_TRY_COMPILE(,[extern __thread int foo;],
729: [ac_cv_thread=yes],
730: [ac_cv_thread=no])])
731: test x$ac_cv_thread = xyes && PER_THREAD='__thread'
732: AC_DEFINE_UNQUOTED(PER_THREAD,$PER_THREAD,[storage class for thread-local variables])
733:
734: #try if m4 understands -s
735: AC_MSG_CHECKING([how to invoke m4])
736: if m4 -s /dev/null >/dev/null 2>&1; then
737: M4="m4 -s"
738: else
739: M4=m4
740: fi
741: AC_SUBST(M4)
742: AC_MSG_RESULT($M4)
743:
744: #echo "machine='$machine'"
745:
746: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
747: if test x$EC_MODE = xfalse
748: then
749: AS_IF([test -f $srcdir/arch/$machine/asm.fs],
750: [asm_fs=arch/$machine/asm.fs])
751: fi
752: AC_SUBST(asm_fs)
753:
754: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
755: if test x$EC_MODE = xfalse
756: then
757: AS_IF([test -f $srcdir/arch/$machine/disasm.fs],
758: [disasm_fs=arch/$machine/disasm.fs])
759: fi
760: AC_SUBST(disasm_fs)
761:
762: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
763:
764: case "$host_os" in
765: *darwin*)
766: #dar*win* must be first, not to confuse with cygwin, win32 or similar
767: #Darwin uses some funny preprocessor by default; eliminate it:
768: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
769: CFLAGS="$CFLAGS -no-cpp-precomp"
770: DIRSEP="/"
771: PATHSEP=":"
772: DEFAULTSYSTEMPREFIX=""
773: #the following magic value was suggested by
774: #http://mail.python.org/pipermail/pythonmac-sig/2005-October/015190.html
775: AC_DEFINE_UNQUOTED(MACOSX_DEPLOYMENT_TARGET,"10.3",[an environment variable value needed by libtool on some MacOS X versions])
776: ;;
777: *win*)
778: # !!!FIXME!!! problems with cygwin and ';' as path separator
779: DIRSEP="/" # normal dirsep
780: PATHSEP=";" # semicolon as pathsep
781: #we want the builtins of command.com/cmd.exe and its
782: # handling of .com files.
783: #$COMSPEC contains the name of the Windows shell;
784: # the ./ is there, because the bash does not recognize
785: # absolute DOS filenames
786: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
787: ;;
788: *linux*)
789: DIRSEP="/"
790: PATHSEP=":"
791: DEFAULTSYSTEMPREFIX=""
792: if test -z "$LTDL_LIBRARY_PATH" -a "$wordsize" = 64; then
793: LTDL_LIBRARY_PATH=`/sbin/ldconfig -p |tail -n +2 |sed 's/^.* => //'|sed 's|/[[^/]]*$||'| grep 64 | sort -u | tr '\n' : | sed -e 's/:$//'`
794: fi
795: ;;
796: *)
797: DIRSEP="/"
798: PATHSEP=":"
799: DEFAULTSYSTEMPREFIX=""
800: ;;
801: esac
802: AC_SUBST(DIRSEP)
803: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
804: AC_SUBST(PATHSEP)
805: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
806: AC_SUBST(DEFAULTSYSTEMPREFIX)
807: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
808: if test -n "$LTDL_LIBRARY_PATH"; then
809: AC_DEFINE_UNQUOTED(LTDL_LIBRARY_PATH,"$LTDL_LIBRARY_PATH",[Define LTDL_LIBRARY_PATH for 64 bit Linux])
810: fi
811:
812: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
813: #This magic incantation seems to be completely undocumented.
814: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
815:
816: dnl Now a little support for DOS/DJGCC
817: GFORTHFAST_EXE="$GFORTH_EXE"
818: GFORTHITC_EXE="$GFORTH_EXE"
819: GFORTHDITC_EXE="$GFORTH_EXE"
820: AC_SUBST(GFORTH_EXE)
821: AC_SUBST(GFORTHFAST_EXE)
822: AC_SUBST(GFORTHITC_EXE)
823: AC_SUBST(GFORTHDITC_EXE)
824:
825: AC_SUBST(FORTHSIZES)
826:
827: dnl if test "$PEEPHOLE" = "yes"
828: dnl then
829: dnl PEEPHOLEFLAG="true"
830: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
831: dnl else
832: dnl PEEPHOLEFLAG="false"
833: dnl fi
834: PEEPHOLEFLAG="true"
835: AC_SUBST(PEEPHOLEFLAG)
836:
837: dnl copy commands for systems that don't have links
838: AC_SUBST(LINK_KERNL)
839: LINK_KERNL=""
840:
841: #if test $host_os=dos
842: #then
843: # echo Configuring for DOS!!!
844: # MAKE_EXE="coff2exe gforth"
845: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
846: #fi
847:
848: dnl the following macro produces a warning with autoconf-2.1
849: AC_C_BIGENDIAN
850: AC_SUBST(KERNEL)
851: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
852: if test $ac_cv_c_bigendian != no; then
853: bytesex=b
854: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
855: else
856: bytesex=l
857: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
858: fi
859:
860: #check how to do asm(".skip 16")
861: #echo "CFLAGS=$CFLAGS"
862: #echo "ac_link=$ac_link"
863: AC_MSG_CHECKING([if and how we can waste code space])
864: if test -z "$skipcode" && test x$cross_compiling = xyes; then
865: # we cannot perform the AC_TRY_RUN check when cross-compiling.
866: skipcode=no
867: AC_MSG_RESULT([$skipcode, can't run checks since cross-compiling])
868: elif test -z "$skipcode"; then
869: skipcode=no
870: CFLAGS_1="$CFLAGS"
871: CFLAGS="$CFLAGS $ENGINE_FLAGS"
872: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
873: do
874: AC_TRY_RUN(
875: [int foo(int,int,int);
876: main()
877: {
878: exit(foo(0,0,0)!=16);
879: }
880: int foo(int x, int y, int z)
881: {
882: static void *labels[]={&&label1, &&label2};
883: if (x) {
884: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
885: label1:
886: asm("$i"); /* or ".space 16" or somesuch */
887: label2: ;
888: }
889: {
890: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
891: return labels[1]-labels[0];
892: }
893: }]
894: ,skipcode=$i; break
895: ,,)
896: done
897: CFLAGS=$CFLAGS_1
898: fi
899: AC_MSG_RESULT($skipcode)
900: if test "$skipcode" = no
901: then
902: if test -z $no_dynamic_default; then
903: no_dynamic_default=1
904: AC_MSG_WARN(Disabling default dynamic native code generation)
905: fi
906: AC_DEFINE_UNQUOTED(SKIP16,asm(""),statement for skipping 16 bytes)
907: else
908: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
909: fi
910:
911: AC_MSG_CHECKING([if and how we can do comments in asm statements])
912: #the point here is to get asm statements that look different to
913: #gcc's "optimizer"
914: if test -z "$asmcomment"; then
915: asmcomment=no
916: CFLAGS_1="$CFLAGS"
917: CFLAGS="$CFLAGS $ENGINE_FLAGS"
918: for i in '"# "' '"! "' '"; "'; do
919: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
920: done
921: CFLAGS=$CFLAGS_1
922: fi
923: AC_MSG_RESULT($asmcomment)
924: if test "$asmcomment" != no
925: then
926: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
927: fi
928:
929: test "$no_dynamic_default" || no_dynamic_default=0
930: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
931:
932: dnl Checks for programs.
933: AC_PROG_LN_S
934: AC_PROG_INSTALL
935: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
936:
937: dnl check for the presence of Emacs
938: AC_CHECK_PROGS(EMACS,emacs xemacs)
939: test -n "$EMACS" && gforth_elc=gforth.elc
940: AC_SUBST(gforth_elc)
941:
942: dnl MacOS X has a libtool that does something else
943: AC_CHECK_PROGS(GNU_LIBTOOL,"glibtool --tag=CC" libtool)
944:
945: dnl Checks for library functions
946: dnl This check is just for making later checks link with libm.
947: dnl using sin here is no good idea since it is built-into gcc and typechecked
948: AC_CHECK_LIB(m,asin)
949: AC_CHECK_LIB(ltdl,lt_dlinit)
950: dnl ,LIB_SUFFIX=.la,LIB_SUFFIX=.so)
951: if test "x$ac_cv_lib_ltdl_lt_dlinit" = xyes; then
952: LIB_SUFFIX=.la
953: else
954: LIB_SUFFIX=.so
955: fi
956: AC_SUBST(LIB_SUFFIX)
957: AC_CHECK_LIB(rt,clock_gettime)
958:
959: if test -n "$GNU_LIBTOOL" -a $ac_cv_lib_ltdl_lt_dlinit = yes; then
960: build_libcc_named=build-libcc-named
961: else
962: AC_MSG_WARN([No GNU_LIBTOOL found, skip pre-building libcc-based libraries])
963: fi
964: AC_SUBST(build_libcc_named)
965:
966:
967: if test -z "$GNU_LIBTOOL"; then
968: AC_MSG_WARN([No GNU_LIBTOOL found, using "libtool" as name.])
969: AC_MSG_WARN([libcc.fs won't work until you have installed (GNU) libtool.])
970: GNU_LIBTOOL=libtool
971: fi
972:
973: #check for libffi 2.x
974: AC_CHECK_HEADER(ffi.h,FFI_H_NAME=ffi.h,)
975: if test -z "$FFI_H_NAME"; then
976: AC_CHECK_HEADER(ffi/ffi.h,FFI_H_NAME=ffi/ffi.h,)
977: fi
978: AC_SUBST(FFI_H_NAME)
979: AC_CHECK_LIB(ffi,ffi_call,LIBS="$LIBS")
980: if test -n "$FFI_H_NAME" -a $ac_cv_lib_ffi_ffi_call = yes
981: then
982: LIBFFIFLAG="true"
983: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC libffi.fs"
984: else
985: LIBFFIFLAG="false"
986: fi
987: #check for ffcall libraries
988: #unfortunately, these four calls are separated out into a library each.
989: AC_CHECK_LIB(avcall,__builtin_avcall,LIBS="$LIBS")
990: dnl AC_CHECK_LIB(callback,__vacall_r)
991: dnl AC_CHECK_LIB(vacall,vacall)
992: dnl AC_CHECK_LIB(trampoline,alloc_trampoline)
993: if test $ac_cv_lib_avcall___builtin_avcall = yes; then
994: FFCALLFLAG="true"
995: LIBCC_BUILD_SRC="$LIBCC_BUILD_SRC fflib.fs"
996: else
997: FFCALLFLAG="false"
998: fi
999: if test $LIBFFIFLAG = false -a $FFCALLFLAG = false; then
1000: AC_MSG_WARN([The (old) lib.fs foreign function interface needs either libffi or the ffcall libraries])
1001: fi
1002: AC_SUBST(LIBFFIFLAG)
1003: AC_SUBST(FFCALLFLAG)
1004: AC_SUBST(LIBCC_BUILD_SRC)
1005: if test "$host_os" != "nextstep3"
1006: then
1007: AC_FUNC_MEMCMP
1008: fi
1009: AC_REPLACE_FUNCS(memmove strtoul pow10 sincos strerror strsignal atanh)
1010: AC_FUNC_FSEEKO
1011: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep clock_gettime)
1012: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
1013: AC_DECL_SYS_SIGLIST
1014: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
1015: AC_CHECK_FUNCS(expm1 log1p)
1016: AC_REPLACE_FUNCS(rint ecvt)
1017: dnl No check for select, because our replacement is no good under
1018: dnl anything but DOS
1019: AC_CHECK_HEADERS(sys/mman.h fnmatch.h alloca.h wchar.h endian.h)
1020: AC_FUNC_FNMATCH
1021: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
1022: AC_CHECK_FUNCS(mmap sysconf getpagesize wcwidth)
1023: AM_PATH_LISPDIR
1024:
1025: kernel_fi=kernl${vwordsize}${bytesex}.fi
1026: include_fi=kernl${wordsize}${bytesex}${EC}.fi
1027: AC_SUBST(kernel_fi)
1028: AC_SUBST(include_fi)
1029:
1030: # Find installed Gforth
1031: AC_MSG_CHECKING([for gforth])
1032: GFORTH="`cd / && which gforth 2>/dev/null`"
1033: #the "$srcdir" = "." test defends agains the "../" bug in gforth-0.6.2
1034: (cd / && $GFORTH -e bye >/dev/null 2>/dev/null && test "$srcdir" = ".") || GFORTH=""
1035: if test -z "$GFORTH"; then
1036: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
1037: GFORTHKER='echo "You need to configure with a gforth in \$PATH to build this part" && false'
1038: kernel_anti_dependence=''
1039: else
1040: GFORTH_FI=`cd / && $GFORTH --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`
1041: PREFORTH="$GFORTH -i $GFORTH_FI" ;
1042: KERNLX_FI1=`echo $GFORTH_FI | sed -e s/lib[64]*/share/g -e s/gforth.fi/kernl*.fi/g`
1043: KERNLX_FI2=`echo $GFORTH_FI | sed -e s/gforth.fi/kernl*.fi/g`
1044: test -f $KERNLX_FI1 && KERNLX_FI=$KERNLX_FI1
1045: test -f $KERNLX_FI2 && KERNLX_FI=$KERNLX_FI2
1046: GFORTHKER="$GFORTH -i `echo $KERNLX_FI`" ;
1047: kernel_anti_dependence='$(kernel_fi)'
1048: fi
1049: AC_SUBST(PREFORTH)
1050: AC_SUBST(GFORTHKER)
1051: AC_SUBST(kernel_anti_dependence)
1052: AC_MSG_RESULT($PREFORTH)
1053: AC_DEFINE_UNQUOTED(KERNEL, "$kernel_fi", [The kernel to load in the image])
1054: AC_DEFINE_UNQUOTED(ARCH, "$machine", [architecture to run on ])
1055:
1056: #this breaks bindists
1057: #dnl replace srource directory by absolute value
1058: #if test $srcdir = "."; then srcdir=`pwd`
1059: #fi
1060:
1061: AC_SUBST(machine)
1062: AC_CONFIG_FILES([
1063: Makefile
1064: Makedist
1065: gforthmi
1066: gforthmi.sh
1067: vmgen
1068: machpc.fs
1069: envos.fs
1070: preforth
1071: libforth
1072: gforthker
1073: engine/Makefile
1074: engine/libcc.h
1075: doc/version.texi
1076: build-ec ])
1077: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
1078: chmod +x gforthmi
1079: chmod +x vmgen
1080: chmod +x build-ec
1081: chmod +x preforth
1082: chmod +x libforth
1083: chmod +x gforthker
1084: test -d kernel||mkdir kernel
1085: if test $srcdir != "."; then ln -sf $srcdir/gforth.el .; fi
1086: $srcdir/mkinstalldirs include/gforth$ARCH/$PACKAGE_VERSION
1087: $srcdir/mkinstalldirs arch/$machine
1088: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth$ARCH/$PACKAGE_VERSION]],
1089: [PACKAGE_VERSION=$PACKAGE_VERSION
1090: machine=$machine
1091: ARCH=$ARCH])
1092: AC_OUTPUT
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>