1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20060409],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="April 09, 2006"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(gcc-pr15242-workaround,
57: AC_HELP_STRING([--disable-gcc-pr15242-workaround],[Disables
58: dynamic code generation on some versions of gcc
59: (slowdown~2 on Athlon) and causes slower building
60: of gforth (but gforth speedups) on others.
61: (default enabled)]),
62: ,enable_gcc_pr15242_workaround=yes)
63: test "$enable_gcc_pr15242_workaround" = "no"||
64: AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
65: generation on gccs affected by PR15242])
66:
67: AC_ARG_ENABLE(force-cdiv,
68: AC_HELP_STRING([--enable-force-cdiv],
69: [ Use the native C division - symmetric - instead of
70: floored division (default disabled).]),
71: ,enable_force_cdiv=no)
72: test "$enable_force_cdiv" = "no"||
73: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
74:
75: AC_SUBST(PROFEXES)
76: AC_SUBST(PROFOBJS)
77: AC_ARG_ENABLE(prof,
78: AC_HELP_STRING([--enable-prof],
79: [ Build gforth-prof, which outputs frequently occuring
80: sequences of primitives.]),
81: ,enable_prof=no)
82: if test "$enable_prof" = "no"; then
83: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
84: fi
85:
86: AC_ARG_WITH(debug,
87: [ --with-debug specifies option -g to compile with debug info
88: --without-debug omits the -g switch and creates smaller images on
89: machines where "strip" has problems with gcc style
90: debugging informations.],
91: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
92:
93: dnl PEEPHOLE="yes"
94: dnl AC_ARG_WITH(peephole,
95: dnl [ --with-peephole Enable peephole optimization (default)
96: dnl --without-peephole disables peephole optimization. Creates smaller,
97: dnl but slower images.],
98: dnl PEEPHOLE="$withval")
99:
100: #variables mentioned in INSTALL
101: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
102: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
103: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
104: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
105: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
106: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
107: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
108: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
109: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
110: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
111: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
112: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
113: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
114: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
115: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
116:
117: #set up feature test macros, so the tests get them right:
118: # turn on all POSIX, SUSv3, and GNU features if available
119: AC_GNU_SOURCE
120: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
121:
122: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
123: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
124: dnl but not for _XOPEN_SOURCE)
125: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
126: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
127: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
128: # turn on large file support with 64-bit off_t where available
129: AC_SYS_LARGEFILE
130: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
131: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
132:
133: #currently we force direct threading this way. Eventually we should
134: #setup in the arch and engine files right
135:
136: AC_PROG_CC
137:
138: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
139:
140: AC_SUBST(CC)
141: AC_SUBST(DEBUGFLAG)
142:
143: AC_MSG_CHECKING(make type)
144: make_type=`make -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
145:
146: GNUMAKE='#'
147: test "$make_type" = "GNU Make" && GNUMAKE=''
148:
149: AC_MSG_RESULT($make_type)
150:
151: AC_SUBST(GNUMAKE)
152:
153: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
154: OLDLDFLAGS=$LDFLAGS
155: LDFLAGS="$LDFLAGS -export-dynamic"
156: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
157: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
158: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
159: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
160: AC_MSG_RESULT($ac_export_dynamic)
161:
162: #terminology is a bit unusual here: The host is the system on which
163: #gforth will run; the system on which configure will run is the `build'
164: AC_CANONICAL_HOST
165: case "$host_cpu" in
166: arm*)
167: machine=arm
168: CFLAGS="$CFLAGS -fomit-frame-pointer"
169: if test -z $no_dynamic_default; then
170: no_dynamic_default=1
171: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
172: fi
173: ;;
174: hppa*)
175: machine=hppa
176: $srcdir/mkinstalldirs arch/hppa
177: AC_LIBOBJ(../arch/hppa/cache)
178: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
179: LDFLAGS="$LDFLAGS -Xlinker -N"
180: LIBS="$LIBS -L/lib/pa1.1/"
181: ;;
182: sparc*)
183: machine=sparc
184: ;;
185: i386)
186: machine=386
187: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
188: ;;
189: i486)
190: machine=386
191: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
192: ;;
193: i*86)
194: machine=386
195: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
196: CFLAGS_1="$CFLAGS"
197: CFLAGS="$CFLAGS -march=pentium"
198: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
199: ;;
200: x86_64)
201: machine=amd64
202: ;;
203: ia64*)
204: machine=ia64
205: AC_LIBOBJ(../arch/ia64/flush_icache_block)
206: test "$skipcode" || skipcode="nop.i 0"
207: #".skip 16" passes the test below,
208: # but gives an assembler error in engine
209: ;;
210: m68k)
211: machine=m68k
212: CFLAGS="$CFLAGS -fomit-frame-pointer"
213: if test "$host_os" = "nextstep3"
214: then
215: AC_LIBOBJ(termios)
216: fi
217: ;;
218: mips*)
219: machine=mips
220: #dynamic native code has the following problems on MIPS:
221: #
222: #1) J/JAL seems relocatable, but is are only
223: #relocatable within a 256MB-segment. While we try to
224: #get the linker to arrange this, there is no guarantee
225: #that this will succeed (and if the user uses a lot of
226: #memory, it is likely to fail).
227: #
228: #2) The way we generate dynamic native code may
229: #violate MIPS architectural restrictions (in
230: #particular, the delay slots of LW, MFLO, etc.)
231: #
232: #Therefore we disable dynamic native code by default:
233: if test -z $no_dynamic_default; then
234: no_dynamic_default=1
235: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
236: fi
237: ;;
238: alpha*)
239: machine=alpha
240: #full IEEE FP support for more uniformity across platforms:
241: CFLAGS="$CFLAGS -mieee"
242: ;;
243: power*|rs6000)
244: machine=power
245: $srcdir/mkinstalldirs arch/power
246: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
247: #long long is broken on (at least) gcc-2.95.* for PPC
248: test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
249: ;;
250: *)
251: AC_MSG_WARN([Using a generic machine description])
252: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
253: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
254: machine=generic
255: #I-cache flushing would be needed for dynamic code generation
256: if test -z $no_dynamic_default; then
257: no_dynamic_default=1
258: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
259: fi
260: esac
261: AC_SUBST(host)
262:
263: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
264: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
265: [number of registers in the default stack cache state for gforth-fast and gforth-native])
266:
267: if test "${enable_force_ll+set}" = set; then
268: ac_includes_default="$ac_includes_default
269: #include \"arch/generic/128bit.h\""
270: fi
271:
272: dnl the following macro produces a warning with autoconf-2.1
273: AC_CHECK_SIZEOF(char *)
274: case "$ac_cv_sizeof_char_p" in
275: 2)
276: wordsize=16
277: ;;
278: 4)
279: wordsize=32
280: ;;
281: 8)
282: wordsize=64
283: ;;
284: esac
285:
286: AC_CHECK_SIZEOF(char)
287: AC_CHECK_SIZEOF(short)
288: AC_CHECK_SIZEOF(int)
289: AC_CHECK_SIZEOF(long)
290: AC_CHECK_SIZEOF(long long)
291: AC_CHECK_SIZEOF(intptr_t)
292: AC_CHECK_SIZEOF(int128_t)
293: AC_CHECK_SIZEOF(uint128_t)
294:
295: AC_MSG_CHECKING([for a C type for cells])
296: ac_cv_int_type_cell=none
297: case "$ac_cv_sizeof_char_p" in
298: $ac_cv_sizeof_int)
299: ac_cv_int_type_cell=int
300: ;;
301: $ac_cv_sizeof_short)
302: ac_cv_int_type_cell=short
303: ;;
304: $ac_cv_sizeof_char)
305: ac_cv_int_type_cell=char
306: ;;
307: $ac_cv_sizeof_long)
308: ac_cv_int_type_cell=long
309: ;;
310: $ac_cv_sizeof_long_long)
311: ac_cv_int_type_cell="long long"
312: ;;
313: $ac_cv_sizeof_intptr_t)
314: ac_cv_int_type_cell="intptr_t"
315: ;;
316: $ac_cv_sizeof_int128_t)
317: ac_cv_int_type_cell="int128_t"
318: ;;
319: esac
320: AC_MSG_RESULT($ac_cv_int_type_cell)
321: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
322:
323: AC_MSG_CHECKING([for a C type for wydes])
324: ac_cv_wyde_type_cell=none
325: case 2 in
326: $ac_cv_sizeof_int)
327: ac_cv_wyde_type_cell=int
328: ;;
329: $ac_cv_sizeof_short)
330: ac_cv_wyde_type_cell=short
331: ;;
332: $ac_cv_sizeof_char)
333: ac_cv_wyde_type_cell=char
334: ;;
335: $ac_cv_sizeof_long)
336: ac_cv_wyde_type_cell=long
337: ;;
338: $ac_cv_sizeof_long_long)
339: ac_cv_wyde_type_cell="long long"
340: ;;
341: $ac_cv_sizeof_intptr_t)
342: ac_cv_wyde_type_cell="intptr_t"
343: ;;
344: $ac_cv_sizeof_int128_t)
345: ac_cv_wyde_type_cell="int128_t"
346: ;;
347: esac
348: AC_MSG_RESULT($ac_cv_wyde_type_cell)
349: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
350:
351: AC_MSG_CHECKING([for a C type for tetrabytes])
352: ac_cv_tetrabyte_type_cell=none
353: case 4 in
354: $ac_cv_sizeof_int)
355: ac_cv_tetrabyte_type_cell=int
356: ;;
357: $ac_cv_sizeof_short)
358: ac_cv_tetrabyte_type_cell=short
359: ;;
360: $ac_cv_sizeof_char)
361: ac_cv_tetrabyte_type_cell=char
362: ;;
363: $ac_cv_sizeof_long)
364: ac_cv_tetrabyte_type_cell=long
365: ;;
366: $ac_cv_sizeof_long_long)
367: ac_cv_tetrabyte_type_cell="long long"
368: ;;
369: $ac_cv_sizeof_intptr_t)
370: ac_cv_tetrabyte_type_cell="intptr_t"
371: ;;
372: $ac_cv_sizeof_int128_t)
373: ac_cv_tetrabyte_type_cell="int128_t"
374: ;;
375: esac
376: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
377: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
378:
379: AC_MSG_CHECKING([for a C type for double-cells])
380: ac_cv_int_type_double_cell=none
381: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
382: $ac_cv_sizeof_short)
383: ac_cv_int_type_double_cell=short
384: ;;
385: $ac_cv_sizeof_int)
386: ac_cv_int_type_double_cell=int
387: ;;
388: $ac_cv_sizeof_long)
389: ac_cv_int_type_double_cell=long
390: ;;
391: $ac_cv_sizeof_long_long)
392: ac_cv_int_type_double_cell="long long"
393: ;;
394: $ac_cv_sizeof_intptr_t)
395: ac_cv_int_type_double_cell="intptr_t"
396: ;;
397: $ac_cv_sizeof_int128_t)
398: ac_cv_int_type_double_cell="int128_t"
399: ;;
400: esac
401: AC_MSG_RESULT($ac_cv_int_type_double_cell)
402:
403: AC_MSG_CHECKING([for a C type for unsigned double-cells])
404: ac_cv_int_type_double_ucell=none
405: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
406: $ac_cv_sizeof_short)
407: ac_cv_int_type_double_ucell="unsigned short"
408: ;;
409: $ac_cv_sizeof_int)
410: ac_cv_int_type_double_ucell="unsigned int"
411: ;;
412: $ac_cv_sizeof_long)
413: ac_cv_int_type_double_ucell="unsigned long"
414: ;;
415: $ac_cv_sizeof_long_long)
416: ac_cv_int_type_double_ucell="unsigned long long"
417: ;;
418: $ac_cv_sizeof_intptr_t)
419: ac_cv_int_type_double_ucell="unsigned intptr_t"
420: ;;
421: $ac_cv_sizeof_uint128_t)
422: ac_cv_int_type_double_ucell="uint128_t"
423: ;;
424: esac
425: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
426:
427: if test "$ac_cv_int_type_double_cell" = none || \
428: test "$ac_cv_int_type_double_ucell" = none
429: then
430: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
431: AC_LIBOBJ(dblsub)
432: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
433: else
434: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
435: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
436: fi
437:
438: AC_TYPE_OFF_T
439: AC_CHECK_SIZEOF(off_t)
440: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
441: ac_small_off_t=$?
442: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
443:
444: ENGINE_FLAGS=
445: AC_SUBST(ENGINE_FLAGS)
446:
447: # Try if GCC understands -fno-gcse
448:
449: AC_MSG_CHECKING([if $CC understands -fno-gcse])
450: CFLAGS_1="$CFLAGS"
451: CFLAGS="$CFLAGS -fno-gcse"
452: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
453: CFLAGS="$CFLAGS_1"
454: AC_MSG_RESULT($ac_nogcse)
455:
456: # Try if GCC understands -fno-strict-aliasing
457: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
458: CFLAGS_1="$CFLAGS"
459: CFLAGS="$CFLAGS -fno-strict-aliasing"
460: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
461: CFLAGS="$CFLAGS_1"
462: AC_MSG_RESULT($ac_nostrictaliasing)
463:
464: # Try if GCC understands -fno-crossjumping
465: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
466: CFLAGS_1="$CFLAGS"
467: CFLAGS="$CFLAGS -fno-crossjumping"
468: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
469: CFLAGS="$CFLAGS_1"
470: AC_MSG_RESULT($ac_nocrossjumping)
471:
472: # Try if GCC understands -fno-reorder-blocks
473: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
474: CFLAGS_1="$CFLAGS"
475: CFLAGS="$CFLAGS -fno-reorder-blocks"
476: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
477: CFLAGS="$CFLAGS_1"
478: AC_MSG_RESULT($ac_noreorder_blocks)
479:
480: # Try if GCC understands __attribute__((unused))
481: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
482: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
483: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
484: AC_MSG_RESULT($MAYBE_UNUSED)
485:
486: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
487: AC_SUBST(asm_fs)
488:
489: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
490: AC_SUBST(disasm_fs)
491:
492: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
493:
494: case "$host_os" in
495: *win32*)
496: # !!!FIXME!!! problems with cygwin and ';' as path separator
497: DIRSEP="\\\\"
498: PATHSEP=";"
499: #we want the builtins of command.com/cmd.exe and its
500: # handling of .com files.
501: #$COMSPEC contains the name of the Windows shell;
502: # the ./ is there, because the bash does not recognize
503: # absolute DOS filenames
504: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
505: ;;
506: *darwin*)
507: #Darwin uses some funny preprocessor by default; eliminate it:
508: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
509: CFLAGS="$CFLAGS -no-cpp-precomp"
510: DIRSEP="/"
511: PATHSEP=":"
512: DEFAULTSYSTEMPREFIX=""
513: ;;
514: *)
515: DIRSEP="/"
516: PATHSEP=":"
517: DEFAULTSYSTEMPREFIX=""
518: ;;
519: esac
520: AC_SUBST(DIRSEP)
521: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
522: AC_SUBST(PATHSEP)
523: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
524: AC_SUBST(DEFAULTSYSTEMPREFIX)
525: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
526:
527: dnl Now a little support for DOS/DJGCC
528: AC_SUBST(GFORTH_EXE)
529: GFORTH_EXE=""
530: AC_SUBST(GFORTHFAST_EXE)
531: GFORTHFAST_EXE=""
532: AC_SUBST(GFORTHITC_EXE)
533: GFORTHITC_EXE=""
534: AC_SUBST(GFORTHDITC_EXE)
535: GFORTHDITC_EXE=""
536:
537: AC_SUBST(FORTHSIZES)
538:
539: dnl if test "$PEEPHOLE" = "yes"
540: dnl then
541: dnl PEEPHOLEFLAG="true"
542: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
543: dnl else
544: dnl PEEPHOLEFLAG="false"
545: dnl fi
546: PEEPHOLEFLAG="true"
547: AC_SUBST(PEEPHOLEFLAG)
548:
549: dnl copy commands for systems that don't have links
550: AC_SUBST(LINK_KERNL)
551: LINK_KERNL=""
552:
553: #if test $host_os=dos
554: #then
555: # echo Configuring for DOS!!!
556: # MAKE_EXE="coff2exe gforth"
557: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
558: #fi
559:
560: dnl the following macro produces a warning with autoconf-2.1
561: AC_C_BIGENDIAN
562: AC_SUBST(KERNEL)
563: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
564: if test $ac_cv_c_bigendian = yes; then
565: bytesex=b
566: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
567: else
568: bytesex=l
569: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
570: fi
571:
572: #check how to do asm(".skip 16")
573: echo "CFLAGS=$CFLAGS"
574: echo "ac_link=$ac_link"
575: AC_MSG_CHECKING([if and how we can waste code space])
576: if test -z "$skipcode"; then
577: skipcode=no
578: CFLAGS_1="$CFLAGS"
579: CFLAGS="$CFLAGS $ENGINE_FLAGS"
580: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
581: do
582: AC_TRY_RUN(
583: [int foo(int,int,int);
584: main()
585: {
586: exit(foo(0,0,0)!=16);
587: }
588: int foo(int x, int y, int z)
589: {
590: static void *labels[]={&&label1, &&label2};
591: if (x) {
592: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
593: label1:
594: asm("$i"); /* or ".space 16" or somesuch */
595: label2: ;
596: }
597: {
598: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
599: return labels[1]-labels[0];
600: }
601: }]
602: ,skipcode=$i; break
603: ,,)
604: done
605: CFLAGS=$CFLAGS_1
606: fi
607: AC_MSG_RESULT($skipcode)
608: if test "$skipcode" = no
609: then
610: if test -z $no_dynamic_default; then
611: no_dynamic_default=1
612: AC_MSG_WARN(Disabling default dynamic native code generation)
613: fi
614: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
615: else
616: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
617: fi
618:
619: test "$no_dynamic_default" || no_dynamic_default=0
620: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
621:
622: dnl Checks for programs.
623: AC_PROG_LN_S
624: AC_PROG_INSTALL
625:
626: dnl Checks for library functions
627: dnl This check is just for making later checks link with libm.
628: dnl using sin here is no good idea since it is built-into gcc and typechecked
629: AC_CHECK_LIB(m,asin)
630: AC_CHECK_LIB(dl,dlopen)
631: dnl check for libffi 2.x
632: AC_CHECK_LIB(ffi,ffi_call)
633: if test $ac_cv_lib_ffi_ffi_call = yes
634: then
635: LIBFFIFLAG="true"
636: FFCALLFLAG="false"
637: OLDCALLFLAG="false"
638: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
639: else
640: dnl check for ffcall libraries
641: dnl unfortunately, these four calls are separated out into a library each.
642: AC_CHECK_LIB(avcall,__builtin_avcall)
643: AC_CHECK_LIB(callback,__vacall_r)
644: AC_CHECK_LIB(vacall,vacall)
645: AC_CHECK_LIB(trampoline,alloc_trampoline)
646: LIBFFIFLAG="false"
647: FFCALLFLAG="false"
648: OLDCALLFLAG="true"
649: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
650: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
651: fi
652: AC_SUBST(LIBFFIFLAG)
653: AC_SUBST(FFCALLFLAG)
654: AC_SUBST(OLDCALLFLAG)
655: if test "$host_os" != "nextstep3"
656: then
657: AC_FUNC_MEMCMP
658: fi
659: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
660: AC_FUNC_FSEEKO
661: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
662: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
663: AC_DECL_SYS_SIGLIST
664: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
665: AC_CHECK_FUNCS(expm1 log1p)
666: AC_REPLACE_FUNCS(rint ecvt)
667: dnl No check for select, because our replacement is no good under
668: dnl anything but DOS
669: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
670: AC_FUNC_FNMATCH
671: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
672: AC_CHECK_FUNCS(mmap sysconf getpagesize)
673: AM_PATH_LISPDIR
674:
675: kernel_fi=kernl${wordsize}${bytesex}.fi
676: AC_SUBST(kernel_fi)
677:
678: #this breaks bindists
679: #dnl replace srource directory by absolute value
680: #if test $srcdir = "."; then srcdir=`pwd`
681: #fi
682:
683: AC_SUBST(machine)
684: AC_CONFIG_FILES([
685: Makefile
686: Makedist
687: gforthmi
688: vmgen
689: machpc.fs
690: envos.fs
691: engine/Makefile
692: doc/version.texi
693: build-ec ])
694: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
695: chmod +x gforthmi
696: chmod +x vmgen
697: test -d kernel||mkdir kernel]],[[]])
698: AC_OUTPUT
699:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>