1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.1-20030806],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="August 6, 2003"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: #default setting that may be changed later:
37: test "$no_dynamic_default" || no_dynamic_default=0
38:
39: AC_ARG_ENABLE(force-reg,
40: [ --enable-force-reg Use explicit register declarations if they appear in
41: the machine.h file. This can cause a good speedup,
42: but also incorrect code with some gcc versions on
43: some processors (default disabled).],
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
45:
46: AC_ARG_WITH(debug,
47: [ --with-debug specifies option -g to compile with debug info
48: --without-debug omits the -g switch and creates smaller images on
49: machines where "strip" has problems with gcc style
50: debugging informations.],
51: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
52:
53: dnl PEEPHOLE="yes"
54: dnl AC_ARG_WITH(peephole,
55: dnl [ --with-peephole Enable peephole optimization (default)
56: dnl --without-peephole disables peephole optimization. Creates smaller,
57: dnl but slower images.],
58: dnl PEEPHOLE="$withval")
59:
60: #variables mentioned in INSTALL
61: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
62: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
63: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
64: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
65: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
66: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
67: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
68: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
69: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
70: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
71: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
72: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
73:
74: #set up feature test macros, so the tests get them right:
75: # turn on all POSIX, SUSv3, and GNU features if available
76: AC_GNU_SOURCE
77: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
78:
79: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
80: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
81: dnl but not for _XOPEN_SOURCE)
82: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
83: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
84: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
85: # turn on large file support with 64-bit off_t where available
86: AC_SYS_LARGEFILE
87: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
88: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
89:
90: #currently we force direct threading this way. Eventually we should
91: #setup in the arch and engine files right
92:
93: AC_PROG_CC
94:
95: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
96:
97: AC_SUBST(CC)
98: AC_SUBST(DEBUGFLAG)
99:
100: AC_MSG_CHECKING(make type)
101: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
102:
103: GNUMAKE='#'
104: test "$make_type" = "GNU Make" && GNUMAKE=''
105:
106: AC_MSG_RESULT($make_type)
107:
108: AC_SUBST(GNUMAKE)
109:
110: dnl gcc-3.2 seems to work fine now
111: dnl AC_MSG_CHECKING(gcc version)
112: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
113: dnl AC_MSG_RESULT($gcc_version)
114: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
115: dnl then
116: dnl no_dynamic_default=1
117: dnl AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
118: dnl fi
119:
120: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
121: OLDLDFLAGS=$LDFLAGS
122: LDFLAGS="$LDFLAGS -export-dynamic"
123: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
124: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
125: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
126: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
127: AC_MSG_RESULT($ac_export_dynamic)
128:
129: #terminology is a bit unusual here: The host is the system on which
130: #gforth will run; the system on which configure will run is the `build'
131: AC_CANONICAL_HOST
132: case "$host_cpu" in
133: hppa*)
134: machine=hppa
135: $srcdir/mkinstalldirs arch/hppa
136: AC_LIBOBJ(../arch/hppa/cache)
137: #LDFLAGS="$LDFLAGS -Xlinker -N"
138: LIBS="$LIBS -L/lib/pa1.1/"
139: #executing dynamically generated code produced segfaults on
140: #the only HPPA machine that could waste code space, so
141: #disable it by default
142: no_dynamic_default=1
143: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
144: ;;
145: sparc*)
146: machine=sparc
147: ;;
148: i386)
149: machine=386
150: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
151: ;;
152: i486)
153: machine=386
154: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
155: ;;
156: i*86)
157: machine=386
158: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
159: CFLAGS_1="$CFLAGS"
160: CFLAGS="$CFLAGS -march=pentium"
161: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
162: ;;
163: #generic should work for IA64
164: # ia64*)
165: # machine=ia64
166: # ;;
167: m68k)
168: machine=m68k
169: CFLAGS="$CFLAGS -fomit-frame-pointer"
170: if test "$host_os" = "nextstep3"
171: then
172: AC_LIBOBJ(termios)
173: fi
174: ;;
175: mips*)
176: machine=mips
177: #dynamic native code has the following problems on MIPS:
178: #
179: #1) J/JAL seems relocatable, but is are only
180: #relocatable within a 256MB-segment. While we try to
181: #get the linker to arrange this, there is no guarantee
182: #that this will succeed (and if the user uses a lot of
183: #memory, it is likely to fail).
184: #
185: #2) The way we generate dynamic native code may
186: #violate MIPS architectural restrictions (in
187: #particular, the delay slots of LW, MFLO, etc.)
188: #
189: #Therefore we disable dynamic native code by default:
190: no_dynamic_default=1
191: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
192: ;;
193: alpha*)
194: machine=alpha
195: #full IEEE FP support for more uniformity across platforms:
196: CFLAGS="$CFLAGS -mieee"
197: ;;
198: power*|rs6000)
199: machine=power
200: $srcdir/mkinstalldirs arch/power
201: AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
202: #long long is broken on (at least) gcc-2.95.* for PPC
203: test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
204: ;;
205: *)
206: AC_MSG_WARN([Using a generic machine description])
207: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
208: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
209: machine=generic
210: #I-cache flushing would be needed for dynamic code generation
211: no_dynamic_default=1
212: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
213: esac
214: AC_SUBST(host)
215:
216: dnl the following macro produces a warning with autoconf-2.1
217: AC_CHECK_SIZEOF(char *)
218: case "$ac_cv_sizeof_char_p" in
219: 2)
220: wordsize=16
221: ;;
222: 4)
223: wordsize=32
224: ;;
225: 8)
226: wordsize=64
227: ;;
228: esac
229:
230: AC_CHECK_SIZEOF(char)
231: AC_CHECK_SIZEOF(short)
232: AC_CHECK_SIZEOF(int)
233: AC_CHECK_SIZEOF(long)
234: AC_CHECK_SIZEOF(long long)
235: AC_CHECK_SIZEOF(intptr_t)
236: AC_CHECK_SIZEOF(int128_t)
237:
238: AC_MSG_CHECKING([for a C type for cells])
239: ac_cv_int_type_cell=none
240: case "$ac_cv_sizeof_char_p" in
241: $ac_cv_sizeof_int)
242: ac_cv_int_type_cell=int
243: ;;
244: $ac_cv_sizeof_short)
245: ac_cv_int_type_cell=short
246: ;;
247: $ac_cv_sizeof_char)
248: ac_cv_int_type_cell=char
249: ;;
250: $ac_cv_sizeof_long)
251: ac_cv_int_type_cell=long
252: ;;
253: $ac_cv_sizeof_long_long)
254: ac_cv_int_type_cell="long long"
255: ;;
256: $ac_cv_sizeof_intptr_t)
257: ac_cv_int_type_cell="intptr_t"
258: ;;
259: $ac_cv_sizeof_int128_t)
260: ac_cv_int_type_cell="int128_t"
261: ;;
262: esac
263: AC_MSG_RESULT($ac_cv_int_type_cell)
264: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
265:
266: AC_MSG_CHECKING([for a C type for double-cells])
267: ac_cv_int_type_double_cell=none
268: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
269: $ac_cv_sizeof_short)
270: ac_cv_int_type_double_cell=short
271: ;;
272: $ac_cv_sizeof_int)
273: ac_cv_int_type_double_cell=int
274: ;;
275: $ac_cv_sizeof_long)
276: ac_cv_int_type_double_cell=long
277: ;;
278: $ac_cv_sizeof_long_long)
279: ac_cv_int_type_double_cell="long long"
280: ;;
281: $ac_cv_sizeof_intptr_t)
282: ac_cv_int_type_double_cell="intptr_t"
283: ;;
284: $ac_cv_sizeof_int128_t)
285: ac_cv_int_type_double_cell="int128_t"
286: ;;
287: esac
288: AC_MSG_RESULT($ac_cv_int_type_double_cell)
289: if test "$ac_cv_int_type_double_cell" = none; then
290: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
291: AC_LIBOBJ(dblsub)
292: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
293: else
294: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
295: fi
296:
297: AC_TYPE_OFF_T
298: AC_CHECK_SIZEOF(off_t)
299: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
300: ac_small_off_t=$?
301: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
302:
303: ENGINE_FLAGS=
304: AC_SUBST(ENGINE_FLAGS)
305:
306: # Try if GCC understands -fno-gcse
307:
308: AC_MSG_CHECKING([if $CC understands -fno-gcse])
309: CFLAGS_1="$CFLAGS"
310: CFLAGS="$CFLAGS -fno-gcse"
311: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
312: CFLAGS="$CFLAGS_1"
313: AC_MSG_RESULT($ac_nogcse)
314:
315: # Try if GCC understands -fno-strict-aliasing
316: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
317: CFLAGS_1="$CFLAGS"
318: CFLAGS="$CFLAGS -fno-strict-aliasing"
319: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
320: CFLAGS="$CFLAGS_1"
321: AC_MSG_RESULT($ac_nostrictaliasing)
322:
323: # Try if GCC understands -fno-crossjumping
324: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
325: CFLAGS_1="$CFLAGS"
326: CFLAGS="$CFLAGS -fno-crossjumping"
327: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
328: CFLAGS="$CFLAGS_1"
329: AC_MSG_RESULT($ac_nocrossjumping)
330:
331: # Try if GCC understands __attribute__((unused))
332: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
333: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
334: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
335: AC_MSG_RESULT($MAYBE_UNUSED)
336:
337: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
338: AC_SUBST(asm_fs)
339:
340: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
341: AC_SUBST(disasm_fs)
342:
343: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
344:
345: case "$host_os" in
346: *win32|cygwin)
347: DIRSEP="\\\\"
348: PATHSEP=";"
349: ;;
350: *darwin*)
351: #Darwin uses some funny preprocessor by default; eliminate it:
352: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
353: CFLAGS="$CFLAGS -no-cpp-precomp"
354: DIRSEP="/"
355: PATHSEP=":"
356: ;;
357: *)
358: DIRSEP="/"
359: PATHSEP=":"
360: ;;
361: esac
362: AC_SUBST(DIRSEP)
363: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
364: AC_SUBST(PATHSEP)
365: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
366:
367:
368: dnl Now a little support for DOS/DJGCC
369: AC_SUBST(GFORTH_EXE)
370: GFORTH_EXE=""
371: AC_SUBST(GFORTHFAST_EXE)
372: GFORTHFAST_EXE=""
373: AC_SUBST(GFORTHITC_EXE)
374: GFORTHITC_EXE=""
375: AC_SUBST(GFORTHDITC_EXE)
376: GFORTHDITC_EXE=""
377:
378: AC_SUBST(FORTHSIZES)
379:
380: dnl if test "$PEEPHOLE" = "yes"
381: dnl then
382: dnl PEEPHOLEFLAG="true"
383: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
384: dnl else
385: dnl PEEPHOLEFLAG="false"
386: dnl fi
387: PEEPHOLEFLAG="true"
388: AC_SUBST(PEEPHOLEFLAG)
389:
390: dnl copy commands for systems that don't have links
391: AC_SUBST(LINK_KERNL)
392: LINK_KERNL=""
393:
394: #if test $host_os=dos
395: #then
396: # echo Configuring for DOS!!!
397: # MAKE_EXE="coff2exe gforth"
398: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
399: #fi
400:
401: dnl the following macro produces a warning with autoconf-2.1
402: AC_C_BIGENDIAN
403: AC_SUBST(KERNEL)
404: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
405: if test $ac_cv_c_bigendian = yes; then
406: bytesex=b
407: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
408: else
409: bytesex=l
410: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
411: fi
412:
413: #check how to do asm(".skip 16")
414: AC_MSG_CHECKING([if and how we can waste code space])
415: skipcode=no
416: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
417: do
418: AC_TRY_RUN(
419: int foo(int);
420: main()
421: {
422: exit(foo(0)!=16);
423: }
424: int foo(int x)
425: {
426: if (x) {
427: label1:
428: asm("$i");
429: label2:
430: }
431: return (&&label2)-(&&label1);
432: }
433: ,skipcode=$i; break
434: ,,)
435: done
436: AC_MSG_RESULT($skipcode)
437: if test "$skipcode" = no
438: then
439: no_dynamic_default=1
440: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
441: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
442: else
443: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
444: fi
445:
446: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
447:
448: dnl Checks for programs.
449: AC_PROG_LN_S
450: AC_PROG_INSTALL
451:
452: dnl Checks for library functions
453: dnl This check is just for making later checks link with libm.
454: dnl using sin here is no good idea since it is built-into gcc and typechecked
455: AC_CHECK_LIB(m,asin)
456: AC_CHECK_LIB(dl,dlopen)
457: dnl check for ffcall libraries
458: dnl unfortunately, these four calls are separated out into a library each.
459: AC_CHECK_LIB(avcall,__builtin_avcall)
460: AC_CHECK_LIB(callback,__vacall_r)
461: AC_CHECK_LIB(vacall,vacall)
462: AC_CHECK_LIB(trampoline,alloc_trampoline)
463: FFCALLFLAG="false"
464: OLDCALLFLAG="true"
465: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
466: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
467: AC_SUBST(FFCALLFLAG)
468: AC_SUBST(OLDCALLFLAG)
469: if test "$host_os" != "nextstep3"
470: then
471: AC_FUNC_MEMCMP
472: fi
473: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
474: AC_FUNC_FSEEKO
475: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
476: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
477: AC_DECL_SYS_SIGLIST
478: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
479: AC_CHECK_FUNCS(expm1 log1p)
480: AC_REPLACE_FUNCS(rint ecvt)
481: dnl No check for select, because our replacement is no good under
482: dnl anything but DOS
483: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
484: AC_FUNC_FNMATCH
485: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
486: AC_CHECK_FUNCS(mmap sysconf getpagesize)
487: AM_PATH_LISPDIR
488:
489: kernel_fi=kernl${wordsize}${bytesex}.fi
490: AC_SUBST(kernel_fi)
491:
492: #this breaks bindists
493: #dnl replace srource directory by absolute value
494: #if test $srcdir = "."; then srcdir=`pwd`
495: #fi
496:
497: AC_SUBST(machine)
498: AC_CONFIG_FILES([
499: Makefile
500: Makedist
501: gforthmi
502: vmgen
503: machpc.fs
504: engine/Makefile
505: doc/version.texi ])
506: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
507: chmod +x gforthmi
508: chmod +x vmgen
509: test -d kernel||mkdir kernel]],[[]])
510: AC_OUTPUT
511:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>