1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.6.9-20080405],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="February 23, 2008"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #ltdl stuff:
33: AC_CONFIG_MACRO_DIR([libltdl/m4])
34: LT_CONFIG_LTDL_DIR([libltdl])
35: LT_INIT([dlopen])
36: LTDL_INIT([subproject],[convenience])
37: AC_CONFIG_AUX_DIR([libltdl/config])
38:
39: # check for ltdl features we need
40: # The lt_dladvise_init symbol was added with libtool-2.2
41: if test "x$with_included_ltdl" != "xyes"; then
42: save_CFLAGS="$CFLAGS"
43: save_LDFLAGS="$LDFLAGS"
44: CFLAGS="$CFLAGS $LTDLINCL"
45: LDFLAGS="$LDFLAGS $LIBLTDL"
46: AC_CHECK_LIB([ltdl], [lt_dladvise_init],
47: [],
48: [AC_MSG_ERROR([libltdl-2.2 or later needed; configure with --with-included-ltdl])])
49: LDFLAGS="$save_LDFLAGS"
50: CFLAGS="$save_CFLAGS"
51: fi
52:
53: #how to link with libltdl
54: if test "x$with_included_ltdl" = "xyes"; then
55: #hard-code it (hopefully portable); the official way is to use automake :-(
56: LTDL_LDLIBS='-L$(top_builddir)/libltdl/.libs -lltdlc'
57: else
58: LTDL_LDLIBS='$(LIBLTDL)'
59: fi
60: AC_SUBST(LTDL_LDLIBS)
61:
62: #suppress the "-g -O2" default
63: test "$CFLAGS" || CFLAGS=-O2
64:
65: AC_ARG_ENABLE(force-cdiv,
66: AC_HELP_STRING([--enable-force-cdiv],
67: [ Use the native C division - symmetric - instead of
68: floored division (default disabled).]),
69: ,enable_force_cdiv=no)
70: test "$enable_force_cdiv" = "no"||
71: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
72:
73: AC_SUBST(PROFEXES)
74: AC_SUBST(PROFOBJS)
75: AC_ARG_ENABLE(prof,
76: AC_HELP_STRING([--enable-prof],
77: [ Build gforth-prof, which outputs frequently occuring
78: sequences of primitives.]),
79: ,enable_prof=no)
80: if test "$enable_prof" != "no"; then
81: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
82: fi
83:
84: AC_ARG_WITH(debug,
85: [ --with-debug specifies option -g to compile with debug info
86: --without-debug omits the -g switch and creates smaller images on
87: machines where "strip" has problems with gcc style
88: debugging informations.],
89: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
90:
91: GCC_LD="\$(GCC)"
92: EC_MODE="false"
93: EC=""
94: engine2='engine2$(OPT).o'
95: engine_fast2='engine-fast2$(OPT).o'
96: no_dynamic=""
97: image_i=""
98: signals_o="io.o signals.o"
99:
100: AC_ARG_WITH(ec,
101: AC_HELP_STRING([--with-ec=<arch>],
102: [ Build gforth for systems without OS.]),
103: [if test "$withval" = "no"; then
104: echo "defining hosted system"
105: else
106: echo "defining standalone system (${withval})"
107: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
108: EC_MODE="true"
109: EC="-ec"
110: engine2=""
111: engine_fast2=""
112: no_dynamic="-DNO_DYNAMIC"
113: image_i="image.i"
114: if test "$withval" != "yes"; then
115: signals_o="io-${withval}.o"
116: else
117: signals_o="io.o"
118: fi
119: GCC_PATH=$(which $CC)
120: LIB_PATH=${GCC_PATH%/*/*}
121: GCC_LD="\$(LD)"
122: platform=${withval}
123: fi])
124:
125: #variables mentioned in INSTALL
126: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
127: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
128: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
129: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
130: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
131:
132: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
133: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
134: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
135: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
136: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
137: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
138: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
139: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
140: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
141: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
142: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
143: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
144: AC_ARG_VAR(asmcomment, [assembler comment start string])
145: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
146:
147: #set up feature test macros, so the tests get them right:
148: # turn on all POSIX, SUSv3, and GNU features if available
149: AC_GNU_SOURCE
150: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
151:
152: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
153: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
154: dnl but not for _XOPEN_SOURCE)
155: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
156: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
157: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
158: # turn on large file support with 64-bit off_t where available
159: AC_SYS_LARGEFILE
160: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
161: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
162:
163: #currently we force direct threading this way. Eventually we should
164: #setup in the arch and engine files right
165:
166: AC_PROG_CC
167:
168: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
169:
170: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
171: test x$condbranch_opt = x &&
172: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
173: condbranch_opt=0
174: else
175: condbranch_opt=1
176: fi
177: AC_MSG_RESULT($condbranch_opt)
178: AC_SUBST(condbranch_opt)
179:
180: AC_SUBST(CC)
181: AC_SUBST(GCC_LD)
182: AC_SUBST(DEBUGFLAG)
183: AC_SUBST(EC)
184: AC_SUBST(EC_MODE)
185: AC_SUBST(engine2)
186: AC_SUBST(engine_fast2)
187: AC_SUBST(no_dynamic)
188: AC_SUBST(image_i)
189: AC_SUBST(signals_o)
190:
191: #this is used to disable some (not generally essential) part of the
192: #Makefile that some makes don't grok. It would be better to test for
193: #this specific Makefile feature than the make version.
194: AC_MSG_CHECKING(make type)
195: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
196: GNUMAKE='#'
197: test "$make_type" = "GNU Make" && GNUMAKE=''
198: AC_MSG_RESULT($make_type)
199: AC_SUBST(GNUMAKE)
200:
201: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
202: OLDLDFLAGS=$LDFLAGS
203: LDFLAGS="$LDFLAGS -export-dynamic"
204: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
205: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
206: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
207: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
208: AC_MSG_RESULT($ac_export_dynamic)
209:
210: #terminology is a bit unusual here: The host is the system on which
211: #gforth will run; the system on which configure will run is the `build'
212: AC_CANONICAL_HOST
213: case "$host_cpu" in
214: arm*)
215: machine=arm
216: CFLAGS="$CFLAGS -fomit-frame-pointer"
217: if test x$platform = xnxt; then
218: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
219: fi
220: if test -z $arm_cacheflush; then
221: case "$host_os" in
222: *linux*)
223: arm_cacheflush=arch/arm/cacheflush-linux
224: ;;
225: *)
226: no_dynamic_default=1
227: arm_cacheflush=arch/arm/cacheflush0
228: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
229: ;;
230: esac
231: fi
232: AC_LIBSOURCES([../arch/arm/cacheflush0, dnl
233: ../arch/arm/cacheflush-linux])
234: AC_LIBOBJ(../$arm_cacheflush)
235: #longer skipcodes lead to problems on ARM, and it uses
236: #only 4-byte alignment anyway
237: test "$skipcode" || skipcode="nop"
238: ;;
239: hppa*)
240: machine=hppa
241: $srcdir/mkinstalldirs arch/hppa
242: AC_LIBOBJ(../arch/hppa/cache)
243: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
244: LDFLAGS="$LDFLAGS -Xlinker -N"
245: LIBS="$LIBS -L/lib/pa1.1/"
246: ;;
247: sparc*)
248: machine=sparc
249: ;;
250: i386)
251: machine=386
252: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
253: ;;
254: i486)
255: machine=386
256: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
257: ;;
258: i*86)
259: machine=386
260: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
261: CFLAGS_1="$CFLAGS"
262: CFLAGS="$CFLAGS -march=pentium"
263: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
264: ;;
265: x86_64)
266: case $CC
267: in
268: *-m32*)
269: machine=386
270: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
271: CFLAGS_1="$CFLAGS"
272: CFLAGS="$CFLAGS -march=athlon64"
273: ;;
274: *)
275: machine=amd64
276: ;;
277: esac
278: ;;
279: ia64*)
280: machine=ia64
281: AC_LIBOBJ(../arch/ia64/flush_icache_block)
282: test "$skipcode" || skipcode="nop.i 0"
283: #".skip 16" passes the test below,
284: # but gives an assembler error in engine
285: ;;
286: m68k)
287: machine=m68k
288: CFLAGS="$CFLAGS -fomit-frame-pointer"
289: if test "$host_os" = "nextstep3"
290: then
291: AC_LIBOBJ(termios)
292: fi
293: ;;
294: mips*)
295: machine=mips
296: #dynamic native code has the following problems on MIPS:
297: #
298: #1) J/JAL seems relocatable, but is are only
299: #relocatable within a 256MB-segment. While we try to
300: #get the linker to arrange this, there is no guarantee
301: #that this will succeed (and if the user uses a lot of
302: #memory, it is likely to fail).
303: #
304: #2) The way we generate dynamic native code may
305: #violate MIPS architectural restrictions (in
306: #particular, the delay slots of LW, MFLO, etc.)
307: #
308: #Therefore we disable dynamic native code by default:
309: if test -z $no_dynamic_default; then
310: no_dynamic_default=1
311: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
312: fi
313: ;;
314: alpha*)
315: machine=alpha
316: #full IEEE FP support for more uniformity across platforms:
317: CFLAGS="$CFLAGS -mieee"
318: ;;
319: power*|rs6000)
320: machine=power
321: $srcdir/mkinstalldirs arch/power
322: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
323: #long long is broken on (at least) gcc-2.95.* for PPC
324: test x$ac_cv_sizeof_long_long = x &&
325: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
326: ac_cv_sizeof_long_long=0
327: #The only architecture with enough callee-saved registers
328: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
329: #or use 2, hardly slower at run-time and starts up faster
330: ;;
331: *)
332: AC_MSG_WARN([Using a generic machine description])
333: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
334: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
335: machine=generic
336: #I-cache flushing would be needed for dynamic code generation
337: if test -z $no_dynamic_default; then
338: no_dynamic_default=1
339: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
340: fi
341: esac
342: AC_SUBST(host)
343:
344: MAKEINC=""
345:
346: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
347: if test x$EC_MODE = xtrue
348: then
349: echo "Check for arch/$machine/$platform/gforth.ld"
350: if test -f arch/$machine/$platform/gforth.ld
351: then
352: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
353: if test x$platform = xnxt; then
354: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
355: fi
356: fi
357: if test -f arch/$machine/$platform/make.inc
358: then
359: MAKEINC="include ../arch/$machine/$platform/make.inc"
360: fi
361: fi
362: AC_SUBST(MAKEINC)
363:
364: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
365:
366: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
367: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
368: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
369: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
370: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
371: [number of registers in the default stack cache state for gforth-fast and gforth-native])
372:
373: test x$GCC_PR15242_WORKAROUND = x ||
374: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
375: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
376:
377: dnl the following macro produces a warning with autoconf-2.1
378: AC_CHECK_SIZEOF(char *)
379: case "$ac_cv_sizeof_char_p" in
380: 2)
381: wordsize=16
382: ;;
383: 4)
384: wordsize=32
385: ;;
386: 8)
387: wordsize=64
388: ;;
389: esac
390:
391: AC_CHECK_SIZEOF(void *)
392: case "$ac_cv_sizeof_void_p" in
393: 2)
394: vwordsize=16
395: ;;
396: 4)
397: vwordsize=32
398: ;;
399: 8)
400: vwordsize=64
401: ;;
402: esac
403:
404: AC_CHECK_SIZEOF(char)
405: AC_CHECK_SIZEOF(short)
406: AC_CHECK_SIZEOF(int)
407: AC_CHECK_SIZEOF(long)
408: AC_CHECK_SIZEOF(long long)
409: AC_CHECK_SIZEOF(intptr_t)
410: AC_CHECK_SIZEOF(int128_t)
411: AC_CHECK_SIZEOF(uint128_t)
412:
413: AC_MSG_CHECKING([for a C type for cells])
414: ac_cv_int_type_cell=none
415: case "$ac_cv_sizeof_char_p" in
416: $ac_cv_sizeof_int)
417: ac_cv_int_type_cell=int
418: ;;
419: $ac_cv_sizeof_short)
420: ac_cv_int_type_cell=short
421: ;;
422: $ac_cv_sizeof_char)
423: ac_cv_int_type_cell=char
424: ;;
425: $ac_cv_sizeof_long)
426: ac_cv_int_type_cell=long
427: ;;
428: $ac_cv_sizeof_long_long)
429: ac_cv_int_type_cell="long long"
430: ;;
431: $ac_cv_sizeof_intptr_t)
432: ac_cv_int_type_cell="intptr_t"
433: ;;
434: esac
435: AC_MSG_RESULT($ac_cv_int_type_cell)
436: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
437:
438: AC_MSG_CHECKING([for a C type for wydes])
439: ac_cv_wyde_type_cell=none
440: case 2 in
441: $ac_cv_sizeof_int)
442: ac_cv_wyde_type_cell=int
443: ;;
444: $ac_cv_sizeof_short)
445: ac_cv_wyde_type_cell=short
446: ;;
447: $ac_cv_sizeof_char)
448: ac_cv_wyde_type_cell=char
449: ;;
450: $ac_cv_sizeof_long)
451: ac_cv_wyde_type_cell=long
452: ;;
453: $ac_cv_sizeof_long_long)
454: ac_cv_wyde_type_cell="long long"
455: ;;
456: $ac_cv_sizeof_intptr_t)
457: ac_cv_wyde_type_cell="intptr_t"
458: ;;
459: esac
460: AC_MSG_RESULT($ac_cv_wyde_type_cell)
461: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
462:
463: AC_MSG_CHECKING([for a C type for tetrabytes])
464: ac_cv_tetrabyte_type_cell=none
465: case 4 in
466: $ac_cv_sizeof_int)
467: ac_cv_tetrabyte_type_cell=int
468: ;;
469: $ac_cv_sizeof_short)
470: ac_cv_tetrabyte_type_cell=short
471: ;;
472: $ac_cv_sizeof_char)
473: ac_cv_tetrabyte_type_cell=char
474: ;;
475: $ac_cv_sizeof_long)
476: ac_cv_tetrabyte_type_cell=long
477: ;;
478: $ac_cv_sizeof_long_long)
479: ac_cv_tetrabyte_type_cell="long long"
480: ;;
481: $ac_cv_sizeof_intptr_t)
482: ac_cv_tetrabyte_type_cell="intptr_t"
483: ;;
484: esac
485: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
486: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
487:
488: AC_MSG_CHECKING([for a C type for double-cells])
489: ac_cv_int_type_double_cell=none
490: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
491: $ac_cv_sizeof_short)
492: ac_cv_int_type_double_cell=short
493: ;;
494: $ac_cv_sizeof_int)
495: ac_cv_int_type_double_cell=int
496: ;;
497: $ac_cv_sizeof_long)
498: ac_cv_int_type_double_cell=long
499: ;;
500: $ac_cv_sizeof_long_long)
501: ac_cv_int_type_double_cell="long long"
502: ;;
503: $ac_cv_sizeof_intptr_t)
504: ac_cv_int_type_double_cell="intptr_t"
505: ;;
506: $ac_cv_sizeof_int128_t)
507: ac_cv_int_type_double_cell="int128_t"
508: ;;
509: esac
510: AC_MSG_RESULT($ac_cv_int_type_double_cell)
511:
512: AC_MSG_CHECKING([for a C type for unsigned double-cells])
513: ac_cv_int_type_double_ucell=none
514: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
515: $ac_cv_sizeof_short)
516: ac_cv_int_type_double_ucell="unsigned short"
517: ;;
518: $ac_cv_sizeof_int)
519: ac_cv_int_type_double_ucell="unsigned int"
520: ;;
521: $ac_cv_sizeof_long)
522: ac_cv_int_type_double_ucell="unsigned long"
523: ;;
524: $ac_cv_sizeof_long_long)
525: ac_cv_int_type_double_ucell="unsigned long long"
526: ;;
527: $ac_cv_sizeof_intptr_t)
528: ac_cv_int_type_double_ucell="unsigned intptr_t"
529: ;;
530: $ac_cv_sizeof_uint128_t)
531: ac_cv_int_type_double_ucell="uint128_t"
532: ;;
533: esac
534: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
535:
536: if test "$ac_cv_int_type_double_cell" != none && \
537: test "$ac_cv_int_type_double_ucell" != none
538: then
539: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
540: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
541: OPTS=-ll
542: else
543: if test "$ac_cv_sizeof_char_p" = 8; then
544: OPTS="-ll -noll"
545: else
546: OPTS=-noll
547: fi
548: fi
549:
550: if grep -q FORCE_REG arch/$machine/machine.h; then
551: OPTS=`for i in $OPTS; do echo -n "$i-reg "; done`$OPTS
552: fi
553: AC_SUBST(OPTS)
554:
555: AC_TYPE_OFF_T
556: AC_CHECK_SIZEOF(off_t)
557: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
558: ac_small_off_t=$?
559: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
560:
561: ENGINE_FLAGS=
562: AC_SUBST(ENGINE_FLAGS)
563:
564: # Try if GCC understands -fno-gcse
565:
566: AC_MSG_CHECKING([if $CC understands -fno-gcse])
567: CFLAGS_1="$CFLAGS"
568: CFLAGS="$CFLAGS -fno-gcse"
569: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
570: CFLAGS="$CFLAGS_1"
571: AC_MSG_RESULT($ac_nogcse)
572:
573: # Try if GCC understands -fno-strict-aliasing
574: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
575: CFLAGS_1="$CFLAGS"
576: CFLAGS="$CFLAGS -fno-strict-aliasing"
577: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
578: CFLAGS="$CFLAGS_1"
579: AC_MSG_RESULT($ac_nostrictaliasing)
580:
581: # Try if GCC understands -fno-crossjumping
582: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
583: CFLAGS_1="$CFLAGS"
584: CFLAGS="$CFLAGS -fno-crossjumping"
585: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
586: CFLAGS="$CFLAGS_1"
587: AC_MSG_RESULT($ac_nocrossjumping)
588:
589: # Try if GCC understands -fno-reorder-blocks
590: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
591: CFLAGS_1="$CFLAGS"
592: CFLAGS="$CFLAGS -fno-reorder-blocks"
593: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
594: CFLAGS="$CFLAGS_1"
595: AC_MSG_RESULT($ac_noreorder_blocks)
596:
597: # Try if GCC understands -falign-labels=1
598: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
599: CFLAGS_1="$CFLAGS"
600: CFLAGS="$CFLAGS -falign-labels=1"
601: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
602: CFLAGS="$CFLAGS_1"
603: AC_MSG_RESULT($ac_align_labels)
604:
605: # Try if GCC understands -falign-loops=1
606: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
607: CFLAGS_1="$CFLAGS"
608: CFLAGS="$CFLAGS -falign-loops=1"
609: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
610: CFLAGS="$CFLAGS_1"
611: AC_MSG_RESULT($ac_align_loops)
612:
613: # Try if GCC understands -falign-jumps=1
614: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
615: CFLAGS_1="$CFLAGS"
616: CFLAGS="$CFLAGS -falign-jumps=1"
617: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
618: CFLAGS="$CFLAGS_1"
619: AC_MSG_RESULT($ac_align_jumps)
620:
621: # Try if GCC understands __attribute__((unused))
622: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
623: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
624: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
625: AC_MSG_RESULT($MAYBE_UNUSED)
626:
627: #try if m4 understands -s
628: AC_MSG_CHECKING([how to invoke m4])
629: if m4 -s /dev/null >/dev/null 2>&1; then
630: M4="m4 -s"
631: else
632: M4=m4
633: fi
634: AC_SUBST(M4)
635: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
636: AC_MSG_RESULT($M4)
637:
638: # Find installed Gforth
639: AC_MSG_CHECKING([for gforth])
640: GFORTH="`cd / && which gforth 2>/dev/null`"
641: if test -z "$GFORTH"; then
642: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
643: else
644: PREFORTH="$GFORTH -i `cd / && gforth --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
645: fi
646: AC_SUBST(PREFORTH)
647: AC_DEFINE_UNQUOTED(PREFORTH,"$PREFORTH",[How to invoke the pre-installed gforth])
648: AC_MSG_RESULT($PREFORTH)
649:
650: #echo "machine='$machine'"
651:
652: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
653: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
654: AC_SUBST(asm_fs)
655:
656: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
657: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
658: AC_SUBST(disasm_fs)
659:
660: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
661:
662: case "$host_os" in
663: *win32*)
664: # !!!FIXME!!! problems with cygwin and ';' as path separator
665: DIRSEP="\\\\"
666: PATHSEP=";"
667: #we want the builtins of command.com/cmd.exe and its
668: # handling of .com files.
669: #$COMSPEC contains the name of the Windows shell;
670: # the ./ is there, because the bash does not recognize
671: # absolute DOS filenames
672: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
673: ;;
674: *darwin*)
675: #Darwin uses some funny preprocessor by default; eliminate it:
676: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
677: CFLAGS="$CFLAGS -no-cpp-precomp"
678: DIRSEP="/"
679: PATHSEP=":"
680: DEFAULTSYSTEMPREFIX=""
681: ;;
682: *)
683: DIRSEP="/"
684: PATHSEP=":"
685: DEFAULTSYSTEMPREFIX=""
686: ;;
687: esac
688: AC_SUBST(DIRSEP)
689: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
690: AC_SUBST(PATHSEP)
691: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
692: AC_SUBST(DEFAULTSYSTEMPREFIX)
693: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
694:
695: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
696: #This magic incantation seems to be completely undocumented.
697: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
698:
699: dnl Now a little support for DOS/DJGCC
700: AC_SUBST(GFORTH_EXE)
701: GFORTH_EXE="true"
702: AC_SUBST(GFORTHFAST_EXE)
703: GFORTHFAST_EXE="true"
704: AC_SUBST(GFORTHITC_EXE)
705: GFORTHITC_EXE="true"
706: AC_SUBST(GFORTHDITC_EXE)
707: GFORTHDITC_EXE="true"
708:
709: AC_SUBST(FORTHSIZES)
710:
711: dnl if test "$PEEPHOLE" = "yes"
712: dnl then
713: dnl PEEPHOLEFLAG="true"
714: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
715: dnl else
716: dnl PEEPHOLEFLAG="false"
717: dnl fi
718: PEEPHOLEFLAG="true"
719: AC_SUBST(PEEPHOLEFLAG)
720:
721: dnl copy commands for systems that don't have links
722: AC_SUBST(LINK_KERNL)
723: LINK_KERNL=""
724:
725: #if test $host_os=dos
726: #then
727: # echo Configuring for DOS!!!
728: # MAKE_EXE="coff2exe gforth"
729: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
730: #fi
731:
732: dnl the following macro produces a warning with autoconf-2.1
733: AC_C_BIGENDIAN
734: AC_SUBST(KERNEL)
735: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
736: if test $ac_cv_c_bigendian = yes; then
737: bytesex=b
738: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
739: else
740: bytesex=l
741: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
742: fi
743:
744: #check how to do asm(".skip 16")
745: #echo "CFLAGS=$CFLAGS"
746: #echo "ac_link=$ac_link"
747: AC_MSG_CHECKING([if and how we can waste code space])
748: if test -z "$skipcode"; then
749: skipcode=no
750: CFLAGS_1="$CFLAGS"
751: CFLAGS="$CFLAGS $ENGINE_FLAGS"
752: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
753: do
754: AC_TRY_RUN(
755: [int foo(int,int,int);
756: main()
757: {
758: exit(foo(0,0,0)!=16);
759: }
760: int foo(int x, int y, int z)
761: {
762: static void *labels[]={&&label1, &&label2};
763: if (x) {
764: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
765: label1:
766: asm("$i"); /* or ".space 16" or somesuch */
767: label2: ;
768: }
769: {
770: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
771: return labels[1]-labels[0];
772: }
773: }]
774: ,skipcode=$i; break
775: ,,)
776: done
777: CFLAGS=$CFLAGS_1
778: fi
779: AC_MSG_RESULT($skipcode)
780: if test "$skipcode" = no
781: then
782: if test -z $no_dynamic_default; then
783: no_dynamic_default=1
784: AC_MSG_WARN(Disabling default dynamic native code generation)
785: fi
786: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
787: else
788: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
789: fi
790:
791: AC_MSG_CHECKING([if and how we can do comments in asm statements])
792: #the point here is to get asm statements that look different to
793: #gcc's "optimizer"
794: if test -z "$asmcomment"; then
795: asmcomment=no
796: CFLAGS_1="$CFLAGS"
797: CFLAGS="$CFLAGS $ENGINE_FLAGS"
798: for i in '"# "' '"! "' '"; "'; do
799: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
800: done
801: CFLAGS=$CFLAGS_1
802: fi
803: AC_MSG_RESULT($asmcomment)
804: if test "$asmcomment" != no
805: then
806: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
807: fi
808:
809: test "$no_dynamic_default" || no_dynamic_default=0
810: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
811:
812: dnl Checks for programs.
813: AC_PROG_LN_S
814: AC_PROG_INSTALL
815: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
816:
817: dnl MacOS X has a libtool that does something else
818: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
819:
820: dnl Checks for library functions
821: dnl This check is just for making later checks link with libm.
822: dnl using sin here is no good idea since it is built-into gcc and typechecked
823: AC_CHECK_LIB(m,asin)
824: AC_CHECK_LIB(dl,dlopen)
825: dnl check for libffi 2.x
826: AC_CHECK_LIB(ffi,ffi_call)
827: if test $ac_cv_lib_ffi_ffi_call = yes
828: then
829: LIBFFIFLAG="true"
830: FFCALLFLAG="false"
831: OLDCALLFLAG="false"
832: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
833: else
834: dnl check for ffcall libraries
835: dnl unfortunately, these four calls are separated out into a library each.
836: AC_CHECK_LIB(avcall,__builtin_avcall)
837: AC_CHECK_LIB(callback,__vacall_r)
838: AC_CHECK_LIB(vacall,vacall)
839: AC_CHECK_LIB(trampoline,alloc_trampoline)
840: LIBFFIFLAG="false"
841: FFCALLFLAG="false"
842: OLDCALLFLAG="true"
843: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
844: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
845: fi
846: AC_SUBST(LIBFFIFLAG)
847: AC_SUBST(FFCALLFLAG)
848: AC_SUBST(OLDCALLFLAG)
849: if test "$host_os" != "nextstep3"
850: then
851: AC_FUNC_MEMCMP
852: fi
853: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
854: AC_FUNC_FSEEKO
855: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
856: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
857: AC_DECL_SYS_SIGLIST
858: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
859: AC_CHECK_FUNCS(expm1 log1p)
860: AC_REPLACE_FUNCS(rint ecvt)
861: dnl No check for select, because our replacement is no good under
862: dnl anything but DOS
863: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
864: AC_FUNC_FNMATCH
865: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
866: AC_CHECK_FUNCS(mmap sysconf getpagesize)
867: AM_PATH_LISPDIR
868:
869: kernel_fi=kernl${vwordsize}${bytesex}.fi
870: include_fi=kernl${wordsize}${bytesex}${EC}.fi
871: AC_SUBST(kernel_fi)
872: AC_SUBST(include_fi)
873:
874: #this breaks bindists
875: #dnl replace srource directory by absolute value
876: #if test $srcdir = "."; then srcdir=`pwd`
877: #fi
878:
879: AC_SUBST(machine)
880: AC_CONFIG_FILES([
881: Makefile
882: Makedist
883: gforthmi
884: vmgen
885: machpc.fs
886: envos.fs
887: engine/Makefile
888: engine/libcc.h
889: doc/version.texi
890: build-ec ])
891: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
892: chmod +x gforthmi
893: chmod +x vmgen
894: chmod +x build-ec
895: test -d kernel||mkdir kernel
896: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
897: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
898: AC_OUTPUT
899:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>