1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: AC_INIT(engine/engine.c)
22:
23: dnl We use some automake macros here,
24: dnl but don't use automake for creating Makefile.in
25: AM_INIT_AUTOMAKE(gforth,0.5.0)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering bust be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: AM_CONFIG_HEADER(engine/config.h)
30: #AM_CYGWIN32
31:
32: AC_ARG_ENABLE(force-reg,
33: [ --enable-force-reg Use explicit register declarations if they appear in
34: the machine.h file. This can cause a good speedup,
35: but also incorrect code with some gcc versions on
36: some processors (default disabled).],
37:
38: AC_DEFINE(FORCE_REG))
39: dnl this is not quite according to the autoconf manual, it causes a replacement
40: AC_ARG_ENABLE(direct-threaded,
41: [ --enable-direct-threaded Force direct threading. This may not work on
42: some machines and may cause slowdown on others.
43: (default processor-dependent)],
44: AC_DEFINE(DIRECT_THREADED))
45: AC_ARG_ENABLE(indirect-threaded,
46: [ --enable-indirect-threaded Force indirect threading. This can cause a
47: slowdown on some machines.
48: (default processor-dependent)],
49: AC_DEFINE(INDIRECT_THREADED))
50:
51: AC_ARG_WITH(debug,
52: [ --with-debug specifies option -g to compile with debug info (default)
53: --without-debug omits the -g switch and creates smaller images on
54: machines where "strip" has problems with gcc style
55: debugging informations.],
56: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
57:
58: CFLAGS=$CFLAGS
59:
60: AC_PROG_CC
61:
62: if test "$GCC" = "yes"
63: then
64: echo "Fine, gcc is available"
65: else
66: cat <<'EOF'
67: Gforth requires GCC-2.0 or higher (it uses GNU C extensions).
68: It does not work with other C compilers. Please install the GNU C compiler,
69: and try again (or search for a binary distribution for your platform).
70: EOF
71: exit 1
72: fi
73:
74: AC_SUBST(CC)
75: AC_SUBST(DEBUGFLAG)
76:
77: dnl the following macro produces a warning with autoconf-2.1
78: AC_CHECK_SIZEOF(char *)
79: case "$ac_cv_sizeof_char_p" in
80: 2)
81: wordsize=16
82: ;;
83: 4)
84: wordsize=32
85: ;;
86: 8)
87: wordsize=64
88: ;;
89: esac
90:
91: AC_CHECK_SIZEOF(char)
92: AC_CHECK_SIZEOF(short)
93: AC_CHECK_SIZEOF(int)
94: AC_CHECK_SIZEOF(long)
95: AC_CHECK_SIZEOF(long long)
96:
97: ac_cv_int_type_cell=none
98: case "$ac_cv_sizeof_char_p" in
99: $ac_cv_sizeof_int)
100: ac_cv_int_type_cell=int
101: ;;
102: $ac_cv_sizeof_short)
103: ac_cv_int_type_cell=short
104: ;;
105: $ac_cv_sizeof_char)
106: ac_cv_int_type_cell=char
107: ;;
108: $ac_cv_sizeof_long)
109: ac_cv_int_type_cell=long
110: ;;
111: $ac_cv_sizeof_long_long)
112: ac_cv_int_type_cell="long long"
113: ;;
114: esac
115: if test "$ac_cv_int_type_cell" != int; then
116: echo "So, sizeof(pointer)!=sizeof(int); looks like a DOS C compiler to me."
117: echo "Since you don't have a proper C on this machine, that's one more reason"
118: echo "to use Forth;-)"
119: fi
120: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell)
121:
122: ac_cv_int_type_double_cell=none
123: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
124: $ac_cv_sizeof_short)
125: ac_cv_int_type_double_cell=short
126: ;;
127: $ac_cv_sizeof_int)
128: ac_cv_int_type_double_cell=int
129: ;;
130: $ac_cv_sizeof_long)
131: ac_cv_int_type_double_cell=long
132: ;;
133: $ac_cv_sizeof_long_long)
134: ac_cv_int_type_double_cell="long long"
135: ;;
136: esac
137: if test "$ac_cv_int_type_double_cell" = none; then
138: echo "Emulating double-cell arithmetic. This may be slow."
139: echo "If you find this unacceptable, ask the GCC maintainers to provide proper"
140: echo 'long longs for your machine (the GCC manual states that they \"are twice as'
141: echo "long as \`long int\'\")."
142: LIBOBJS="$LIBOBJS dblsub.o"
143: AC_DEFINE(BUGGY_LONG_LONG)
144: else
145: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell)
146: fi
147:
148: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
149: OLDLDFLAGS=$LDFLAGS
150: LDFLAGS="$LDFLAGS -export-dynamic"
151: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
152: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
153: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
154: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
155: AC_MSG_RESULT($ac_export_dynamic)
156:
157: #terminology is a bit unusual here: The host is the system on which
158: #gforth will run; the system on which configure will run is the `build'
159: AC_CANONICAL_HOST
160: case "$host_cpu" in
161: hppa*)
162: machine=hppa
163: $srcdir/mkinstalldirs arch/hppa
164: LIBOBJS="$LIBOBJS ../arch/hppa/cache.o"
165: LDFLAGS="$LDFLAGS -Xlinker -N"
166: LIBS="$LIBS -L/lib/pa1.1/"
167: if test "${enable_direct_threaded+set}" = ""
168: then
169: AC_DEFINE(DIRECT_THREADED)
170: fi
171: ;;
172: sparc*)
173: machine=sparc
174: ;;
175: i386)
176: machine=386
177: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
178: if test "${enable_direct_threaded+set}" = "" \
179: -a "${enable_indirect_threaded+set}" = ""
180: then
181: echo "Using direct threaded code on 386"
182: AC_DEFINE(DIRECT_THREADED)
183: fi
184: ;;
185: i486)
186: machine=386
187: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
188: if test "${enable_direct_threaded+set}" = "" \
189: -a "${enable_indirect_threaded+set}" = ""
190: then
191: echo "Using direct threaded code on 486"
192: AC_DEFINE(DIRECT_THREADED)
193: fi
194: ;;
195: i*86)
196: machine=386
197: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
198: CFLAGS_1="$CFLAGS"
199: CFLAGS="$CFLAGS -mpentium"
200: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
201: if test "${enable_direct_threaded+set}" = "" \
202: -a "${enable_indirect_threaded+set}" = ""
203: then
204: echo "Using indirect threaded code on IA32 CPUs with split L1 caches"
205: AC_DEFINE(INDIRECT_THREADED)
206: fi
207: ;;
208: ia64*)
209: machine=ia64
210: ;;
211: m68k)
212: machine=m68k
213: CFLAGS="$CFLAGS -fomit-frame-pointer"
214: if test "$host_os" = "nextstep3"
215: then
216: LIBOBJS="$LIBOBJS termios.o"
217: fi
218: ;;
219: mips*)
220: machine=mips
221: #link text and data segment into the same 256M region!
222: AC_MSG_CHECKING([whether the linker accepts -T])
223: OLDLDFLAGS=$LDFLAGS
224: LDFLAGS="$LDFLAGS -Xlinker -T -Xlinker 10000000"
225: AC_TRY_LINK(,,ac_link_mips_t=yes,ac_link_mips_t=no)
226: test $ac_link_mips_t = yes||LDFLAGS=$OLDLDFLAGS
227: AC_MSG_RESULT($ac_link_mips_t)
228: test $ac_link_mips_t = yes||(echo cannot link text and data into same 256M region, using indirect threading; AC_DEFINE(INDIRECT_THREADED))
229: AC_MSG_CHECKING([whether the linker accepts -D])
230: OLDLDFLAGS=$LDFLAGS
231: LDFLAGS="$LDFLAGS -Xlinker -D -Xlinker 10400000"
232: AC_TRY_LINK(,,ac_link_mips_d=yes,ac_link_mips_d=no)
233: test $ac_link_mips_d = yes||LDFLAGS=$OLDLDFLAGS
234: AC_MSG_RESULT($ac_link_mips_d)
235: ;;
236: alpha*)
237: machine=alpha
238: #full IEEE FP support for more uniformity across platforms:
239: CFLAGS="$CFLAGS -mieee"
240: ;;
241: power*|rs6000)
242: machine=power
243: $srcdir/mkinstalldirs arch/power
244: AC_CHECK_FUNC(_sync_cache_range,true,LIBOBJS="$LIBOBJS ../arch/power/_sync_cache_range.o")
245: #link text segment into first 32MB
246: AC_MSG_CHECKING([whether the linker accepts --script=arch/power/elf32ppc.x])
247: OLDLDFLAGS=$LDFLAGS
248: #the -L../$srcdir helps when $srcdir is relative
249: LDFLAGS="$LDFLAGS -L$srcdir -L../$srcdir -Xlinker --script=$srcdir/arch/power/elf32ppc.x"
250: AC_TRY_LINK(,,ac_link_script=yes,ac_link_script=no)
251: test $ac_link_script = yes||LDFLAGS=$OLDLDFLAGS
252: AC_MSG_RESULT($ac_link_script)
253: AC_MSG_CHECKING([whether the code is in the first 32MB])
254: AC_TRY_RUN([main(){label: exit(((unsigned long)&&label)>32000000UL);}],ac_code_under_32=yes,ac_code_under_32=no,ac_code_under_32=no)
255: AC_MSG_RESULT($ac_code_under_32)
256: test $ac_code_under_32 = yes||(AC_MSG_WARN([Using indirect threading]); AC_DEFINE(INDIRECT_THREADED))
257: ;;
258: *)
259: echo "No direct threading support for $host_cpu, using indirect threading."
260: echo "Using a generic machine description."
261: echo "I'll assume that C floats and doubles are represented by IEEE single and"
262: echo "double numbers. If this is not so, SF@ etc. will not work correctly."
263: echo "FLUSH-ICACHE will do nothing, so END-CODE may not work properly!"
264: machine=generic
265: esac
266: AC_SUBST(host)
267: AC_SUBST(ENGINE_FLAGS)
268:
269: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
270: AC_SUBST(asm_fs)
271:
272: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
273: AC_SUBST(disasm_fs)
274:
275: case "$host_os" in
276: *win32)
277: EXE=".exe"
278: ;;
279: *)
280: EXE=""
281: ;;
282: esac
283: AC_SUBST(EXE)
284:
285: dnl Now a little support for DOS/DJGCC
286: AC_SUBST(GFORTH_EXE)
287: GFORTH_EXE=""
288: AC_SUBST(GFORTHFAST_EXE)
289: GFORTHFAST_EXE=""
290: AC_SUBST(GFORTHDITC_EXE)
291: GFORTHDITC_EXE=""
292:
293: PATHSEP=":"
294: AC_SUBST(PATHSEP)
295: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP')
296:
297: AC_SUBST(FORTHSIZES)
298:
299: dnl copy commands for systems that don't have links
300: AC_SUBST(LINK_KERNL)
301: LINK_KERNL=""
302:
303: #if test $host_os=dos
304: #then
305: # echo Configuring for DOS!!!
306: # MAKE_EXE="coff2exe gforth"
307: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
308: #fi
309:
310: dnl the following macro produces a warning with autoconf-2.1
311: AC_C_BIGENDIAN
312: AC_SUBST(KERNEL)
313: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
314: if test $ac_cv_c_bigendian = yes; then
315: bytesex=b
316: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
317: else
318: bytesex=l
319: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
320: fi
321:
322: dnl Checks for programs.
323: AC_PROG_LN_S
324: dnl AM_PROG_INSTALL #performed by AM_INIT_AUTOMAKE
325:
326: dnl Checks for library functions
327: dnl This check is just for making later checks link with libm.
328: dnl using sin here is no good idea since it is built-into gcc and typechecked
329: AC_CHECK_LIB(m,asin)
330: AC_CHECK_LIB(dl,dlopen)
331: if test "$host_os" != "nextstep3"
332: then
333: AC_FUNC_MEMCMP
334: fi
335: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
336: AC_CHECK_FUNCS(dlopen sys_siglist getrusage)
337: AC_DECL_SYS_SIGLIST
338: AC_CHECK_FUNC(getopt_long,true,LIBOBJS="$LIBOBJS getopt.o getopt1.o")
339: AC_CHECK_FUNCS(rint expm1 log1p)
340: AC_REPLACE_FUNCS(ecvt)
341: dnl No check for select, because our replacement is no good under
342: dnl anything but DOS
343: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
344: AC_FUNC_FNMATCH
345: test $ac_cv_func_fnmatch_works = yes || LIBOBJS="$LIBOBJS fnmatch.o"
346: AC_CHECK_FUNCS(mmap sysconf getpagesize)
347: AM_PATH_LISPDIR
348:
349: kernel_fi=kernl${wordsize}${bytesex}.fi
350: AC_SUBST(kernel_fi)
351:
352: #this breaks bindists
353: #dnl replace srource directory by absolute value
354: #if test $srcdir = "."; then srcdir=`pwd`
355: #fi
356:
357: AC_SUBST(machine)
358: dnl AC_LINK_FILES(arch/$machine,arch/machine) #no longer needed
359: AC_OUTPUT([
360: Makefile
361: Makedist
362: gforthmi
363: engine/Makefile
364: doc/version.texi ],
365: echo timestamp > stamp-h
366: chmod +x gforthmi
367: test -d kernel||mkdir kernel)
368:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>