1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20060527],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="April 09, 2006"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(force-cdiv,
57: AC_HELP_STRING([--enable-force-cdiv],
58: [ Use the native C division - symmetric - instead of
59: floored division (default disabled).]),
60: ,enable_force_cdiv=no)
61: test "$enable_force_cdiv" = "no"||
62: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
63:
64: AC_SUBST(PROFEXES)
65: AC_SUBST(PROFOBJS)
66: AC_ARG_ENABLE(prof,
67: AC_HELP_STRING([--enable-prof],
68: [ Build gforth-prof, which outputs frequently occuring
69: sequences of primitives.]),
70: ,enable_prof=no)
71: if test "$enable_prof" = "no"; then
72: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
73: fi
74:
75: AC_ARG_WITH(debug,
76: [ --with-debug specifies option -g to compile with debug info
77: --without-debug omits the -g switch and creates smaller images on
78: machines where "strip" has problems with gcc style
79: debugging informations.],
80: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
81:
82: dnl PEEPHOLE="yes"
83: dnl AC_ARG_WITH(peephole,
84: dnl [ --with-peephole Enable peephole optimization (default)
85: dnl --without-peephole disables peephole optimization. Creates smaller,
86: dnl but slower images.],
87: dnl PEEPHOLE="$withval")
88:
89: AC_ARG_ENABLE(ec,
90: AC_HELP_STRING([--enable-ec],
91: [ Build gforth for systems without OS.]),
92: ,enable_ec=no)
93: if test "$enable_ec" = "yes"; then
94: echo "defining standalone system"
95: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
96: EC_MODE="true"
97: EC="-ec"
98: engine2=""
99: engine_fast2=""
100: no_dynamic="-DNO_DYNAMIC"
101: image_i="image.i"
102: else
103: echo "defining hosted system"
104: EC_MODE="false"
105: EC=""
106: engine2="engine2.o"
107: engine_fast2="engine-fast2.o"
108: no_dynamic=""
109: image_i=""
110: fi
111:
112: #variables mentioned in INSTALL
113: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
114: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
115: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
116: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
117:
118: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
119: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
120: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
121: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
122: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
123: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
124: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
125: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
126: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
127: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
128: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
129: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
130: AC_ARG_VAR(asmcomment, [assembler comment start string])
131: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
132:
133: #set up feature test macros, so the tests get them right:
134: # turn on all POSIX, SUSv3, and GNU features if available
135: AC_GNU_SOURCE
136: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
137:
138: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
139: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
140: dnl but not for _XOPEN_SOURCE)
141: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
142: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
143: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
144: # turn on large file support with 64-bit off_t where available
145: AC_SYS_LARGEFILE
146: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
147: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
148:
149: #currently we force direct threading this way. Eventually we should
150: #setup in the arch and engine files right
151:
152: AC_PROG_CC
153:
154: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
155:
156: AC_SUBST(CC)
157: AC_SUBST(DEBUGFLAG)
158: AC_SUBST(EC)
159: AC_SUBST(EC_MODE)
160: AC_SUBST(engine2)
161: AC_SUBST(engine_fast2)
162: AC_SUBST(no_dynamic)
163: AC_SUBST(image_i)
164:
165: #this is used to disable some (not generally essential) part of the
166: #Makefile that some makes don't grok. It would be better to test for
167: #this specific Makefile feature than the make version.
168: AC_MSG_CHECKING(make type)
169: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
170: GNUMAKE='#'
171: test "$make_type" = "GNU Make" && GNUMAKE=''
172: AC_MSG_RESULT($make_type)
173: AC_SUBST(GNUMAKE)
174:
175: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
176: OLDLDFLAGS=$LDFLAGS
177: LDFLAGS="$LDFLAGS -export-dynamic"
178: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
179: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
180: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
181: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
182: AC_MSG_RESULT($ac_export_dynamic)
183:
184: #terminology is a bit unusual here: The host is the system on which
185: #gforth will run; the system on which configure will run is the `build'
186: AC_CANONICAL_HOST
187: case "$host_cpu" in
188: arm*)
189: machine=arm
190: CFLAGS="$CFLAGS -fomit-frame-pointer"
191: if test -z $arm_cacheflush; then
192: no_dynamic_default=1
193: arm_cacheflush=arch/arm/cacheflush0
194: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
195: fi
196: AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
197: AC_LIBOBJ(../$arm_cacheflush)
198: #longer skipcodes lead to problems on ARM, and it uses
199: #only 4-byte alignment anyway
200: test "$skipcode" || skipcode="nop"
201: ;;
202: hppa*)
203: machine=hppa
204: $srcdir/mkinstalldirs arch/hppa
205: AC_LIBOBJ(../arch/hppa/cache)
206: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
207: LDFLAGS="$LDFLAGS -Xlinker -N"
208: LIBS="$LIBS -L/lib/pa1.1/"
209: ;;
210: sparc*)
211: machine=sparc
212: ;;
213: i386)
214: machine=386
215: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
216: ;;
217: i486)
218: machine=386
219: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
220: ;;
221: i*86)
222: machine=386
223: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
224: CFLAGS_1="$CFLAGS"
225: CFLAGS="$CFLAGS -march=pentium"
226: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
227: ;;
228: x86_64)
229: machine=amd64
230: ;;
231: ia64*)
232: machine=ia64
233: AC_LIBOBJ(../arch/ia64/flush_icache_block)
234: test "$skipcode" || skipcode="nop.i 0"
235: #".skip 16" passes the test below,
236: # but gives an assembler error in engine
237: ;;
238: m68k)
239: machine=m68k
240: CFLAGS="$CFLAGS -fomit-frame-pointer"
241: if test "$host_os" = "nextstep3"
242: then
243: AC_LIBOBJ(termios)
244: fi
245: ;;
246: mips*)
247: machine=mips
248: #dynamic native code has the following problems on MIPS:
249: #
250: #1) J/JAL seems relocatable, but is are only
251: #relocatable within a 256MB-segment. While we try to
252: #get the linker to arrange this, there is no guarantee
253: #that this will succeed (and if the user uses a lot of
254: #memory, it is likely to fail).
255: #
256: #2) The way we generate dynamic native code may
257: #violate MIPS architectural restrictions (in
258: #particular, the delay slots of LW, MFLO, etc.)
259: #
260: #Therefore we disable dynamic native code by default:
261: if test -z $no_dynamic_default; then
262: no_dynamic_default=1
263: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
264: fi
265: ;;
266: alpha*)
267: machine=alpha
268: #full IEEE FP support for more uniformity across platforms:
269: CFLAGS="$CFLAGS -mieee"
270: ;;
271: power*|rs6000)
272: machine=power
273: $srcdir/mkinstalldirs arch/power
274: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
275: #long long is broken on (at least) gcc-2.95.* for PPC
276: test x$ac_cv_sizeof_long_long = x &&
277: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
278: ac_cv_sizeof_long_long=0
279: ;;
280: *)
281: AC_MSG_WARN([Using a generic machine description])
282: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
283: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
284: machine=generic
285: #I-cache flushing would be needed for dynamic code generation
286: if test -z $no_dynamic_default; then
287: no_dynamic_default=1
288: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
289: fi
290: esac
291: AC_SUBST(host)
292:
293: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
294: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
295: [number of registers in the default stack cache state for gforth-fast and gforth-native])
296:
297: test x$GCC_PR15242_WORKAROUND = x ||
298: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
299: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
300:
301: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
302: dnl generation on gccs affected by PR15242])
303:
304:
305: if test "${enable_force_ll+set}" = set; then
306: ac_includes_default="$ac_includes_default
307: #include \"arch/generic/128bit.h\""
308: fi
309:
310: dnl the following macro produces a warning with autoconf-2.1
311: AC_CHECK_SIZEOF(char *)
312: case "$ac_cv_sizeof_char_p" in
313: 2)
314: wordsize=16
315: ;;
316: 4)
317: wordsize=32
318: ;;
319: 8)
320: wordsize=64
321: ;;
322: esac
323:
324: AC_CHECK_SIZEOF(char)
325: AC_CHECK_SIZEOF(short)
326: AC_CHECK_SIZEOF(int)
327: AC_CHECK_SIZEOF(long)
328: AC_CHECK_SIZEOF(long long)
329: AC_CHECK_SIZEOF(intptr_t)
330: AC_CHECK_SIZEOF(int128_t)
331: AC_CHECK_SIZEOF(uint128_t)
332:
333: AC_MSG_CHECKING([for a C type for cells])
334: ac_cv_int_type_cell=none
335: case "$ac_cv_sizeof_char_p" in
336: $ac_cv_sizeof_int)
337: ac_cv_int_type_cell=int
338: ;;
339: $ac_cv_sizeof_short)
340: ac_cv_int_type_cell=short
341: ;;
342: $ac_cv_sizeof_char)
343: ac_cv_int_type_cell=char
344: ;;
345: $ac_cv_sizeof_long)
346: ac_cv_int_type_cell=long
347: ;;
348: $ac_cv_sizeof_long_long)
349: ac_cv_int_type_cell="long long"
350: ;;
351: $ac_cv_sizeof_intptr_t)
352: ac_cv_int_type_cell="intptr_t"
353: ;;
354: $ac_cv_sizeof_int128_t)
355: ac_cv_int_type_cell="int128_t"
356: ;;
357: esac
358: AC_MSG_RESULT($ac_cv_int_type_cell)
359: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
360:
361: AC_MSG_CHECKING([for a C type for wydes])
362: ac_cv_wyde_type_cell=none
363: case 2 in
364: $ac_cv_sizeof_int)
365: ac_cv_wyde_type_cell=int
366: ;;
367: $ac_cv_sizeof_short)
368: ac_cv_wyde_type_cell=short
369: ;;
370: $ac_cv_sizeof_char)
371: ac_cv_wyde_type_cell=char
372: ;;
373: $ac_cv_sizeof_long)
374: ac_cv_wyde_type_cell=long
375: ;;
376: $ac_cv_sizeof_long_long)
377: ac_cv_wyde_type_cell="long long"
378: ;;
379: $ac_cv_sizeof_intptr_t)
380: ac_cv_wyde_type_cell="intptr_t"
381: ;;
382: $ac_cv_sizeof_int128_t)
383: ac_cv_wyde_type_cell="int128_t"
384: ;;
385: esac
386: AC_MSG_RESULT($ac_cv_wyde_type_cell)
387: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
388:
389: AC_MSG_CHECKING([for a C type for tetrabytes])
390: ac_cv_tetrabyte_type_cell=none
391: case 4 in
392: $ac_cv_sizeof_int)
393: ac_cv_tetrabyte_type_cell=int
394: ;;
395: $ac_cv_sizeof_short)
396: ac_cv_tetrabyte_type_cell=short
397: ;;
398: $ac_cv_sizeof_char)
399: ac_cv_tetrabyte_type_cell=char
400: ;;
401: $ac_cv_sizeof_long)
402: ac_cv_tetrabyte_type_cell=long
403: ;;
404: $ac_cv_sizeof_long_long)
405: ac_cv_tetrabyte_type_cell="long long"
406: ;;
407: $ac_cv_sizeof_intptr_t)
408: ac_cv_tetrabyte_type_cell="intptr_t"
409: ;;
410: $ac_cv_sizeof_int128_t)
411: ac_cv_tetrabyte_type_cell="int128_t"
412: ;;
413: esac
414: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
415: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
416:
417: AC_MSG_CHECKING([for a C type for double-cells])
418: ac_cv_int_type_double_cell=none
419: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
420: $ac_cv_sizeof_short)
421: ac_cv_int_type_double_cell=short
422: ;;
423: $ac_cv_sizeof_int)
424: ac_cv_int_type_double_cell=int
425: ;;
426: $ac_cv_sizeof_long)
427: ac_cv_int_type_double_cell=long
428: ;;
429: $ac_cv_sizeof_long_long)
430: ac_cv_int_type_double_cell="long long"
431: ;;
432: $ac_cv_sizeof_intptr_t)
433: ac_cv_int_type_double_cell="intptr_t"
434: ;;
435: $ac_cv_sizeof_int128_t)
436: ac_cv_int_type_double_cell="int128_t"
437: ;;
438: esac
439: AC_MSG_RESULT($ac_cv_int_type_double_cell)
440:
441: AC_MSG_CHECKING([for a C type for unsigned double-cells])
442: ac_cv_int_type_double_ucell=none
443: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
444: $ac_cv_sizeof_short)
445: ac_cv_int_type_double_ucell="unsigned short"
446: ;;
447: $ac_cv_sizeof_int)
448: ac_cv_int_type_double_ucell="unsigned int"
449: ;;
450: $ac_cv_sizeof_long)
451: ac_cv_int_type_double_ucell="unsigned long"
452: ;;
453: $ac_cv_sizeof_long_long)
454: ac_cv_int_type_double_ucell="unsigned long long"
455: ;;
456: $ac_cv_sizeof_intptr_t)
457: ac_cv_int_type_double_ucell="unsigned intptr_t"
458: ;;
459: $ac_cv_sizeof_uint128_t)
460: ac_cv_int_type_double_ucell="uint128_t"
461: ;;
462: esac
463: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
464:
465: if test "$ac_cv_int_type_double_cell" = none || \
466: test "$ac_cv_int_type_double_ucell" = none
467: then
468: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
469: AC_LIBOBJ(dblsub)
470: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
471: else
472: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
473: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
474: fi
475:
476: AC_TYPE_OFF_T
477: AC_CHECK_SIZEOF(off_t)
478: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
479: ac_small_off_t=$?
480: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
481:
482: ENGINE_FLAGS=
483: AC_SUBST(ENGINE_FLAGS)
484:
485: # Try if GCC understands -fno-gcse
486:
487: AC_MSG_CHECKING([if $CC understands -fno-gcse])
488: CFLAGS_1="$CFLAGS"
489: CFLAGS="$CFLAGS -fno-gcse"
490: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
491: CFLAGS="$CFLAGS_1"
492: AC_MSG_RESULT($ac_nogcse)
493:
494: # Try if GCC understands -fno-strict-aliasing
495: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
496: CFLAGS_1="$CFLAGS"
497: CFLAGS="$CFLAGS -fno-strict-aliasing"
498: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
499: CFLAGS="$CFLAGS_1"
500: AC_MSG_RESULT($ac_nostrictaliasing)
501:
502: # Try if GCC understands -fno-crossjumping
503: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
504: CFLAGS_1="$CFLAGS"
505: CFLAGS="$CFLAGS -fno-crossjumping"
506: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
507: CFLAGS="$CFLAGS_1"
508: AC_MSG_RESULT($ac_nocrossjumping)
509:
510: # Try if GCC understands -fno-reorder-blocks
511: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
512: CFLAGS_1="$CFLAGS"
513: CFLAGS="$CFLAGS -fno-reorder-blocks"
514: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
515: CFLAGS="$CFLAGS_1"
516: AC_MSG_RESULT($ac_noreorder_blocks)
517:
518: # Try if GCC understands __attribute__((unused))
519: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
520: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
521: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
522: AC_MSG_RESULT($MAYBE_UNUSED)
523:
524: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
525: AC_SUBST(asm_fs)
526:
527: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
528: AC_SUBST(disasm_fs)
529:
530: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
531:
532: case "$host_os" in
533: *win32*)
534: # !!!FIXME!!! problems with cygwin and ';' as path separator
535: DIRSEP="\\\\"
536: PATHSEP=";"
537: #we want the builtins of command.com/cmd.exe and its
538: # handling of .com files.
539: #$COMSPEC contains the name of the Windows shell;
540: # the ./ is there, because the bash does not recognize
541: # absolute DOS filenames
542: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
543: ;;
544: *darwin*)
545: #Darwin uses some funny preprocessor by default; eliminate it:
546: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
547: CFLAGS="$CFLAGS -no-cpp-precomp"
548: DIRSEP="/"
549: PATHSEP=":"
550: DEFAULTSYSTEMPREFIX=""
551: ;;
552: *)
553: DIRSEP="/"
554: PATHSEP=":"
555: DEFAULTSYSTEMPREFIX=""
556: ;;
557: esac
558: AC_SUBST(DIRSEP)
559: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
560: AC_SUBST(PATHSEP)
561: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
562: AC_SUBST(DEFAULTSYSTEMPREFIX)
563: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
564:
565: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
566: #This magic incantation seems to be completely undocumented.
567: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
568:
569: dnl Now a little support for DOS/DJGCC
570: AC_SUBST(GFORTH_EXE)
571: GFORTH_EXE=""
572: AC_SUBST(GFORTHFAST_EXE)
573: GFORTHFAST_EXE=""
574: AC_SUBST(GFORTHITC_EXE)
575: GFORTHITC_EXE=""
576: AC_SUBST(GFORTHDITC_EXE)
577: GFORTHDITC_EXE=""
578:
579: AC_SUBST(FORTHSIZES)
580:
581: dnl if test "$PEEPHOLE" = "yes"
582: dnl then
583: dnl PEEPHOLEFLAG="true"
584: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
585: dnl else
586: dnl PEEPHOLEFLAG="false"
587: dnl fi
588: PEEPHOLEFLAG="true"
589: AC_SUBST(PEEPHOLEFLAG)
590:
591: dnl copy commands for systems that don't have links
592: AC_SUBST(LINK_KERNL)
593: LINK_KERNL=""
594:
595: #if test $host_os=dos
596: #then
597: # echo Configuring for DOS!!!
598: # MAKE_EXE="coff2exe gforth"
599: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
600: #fi
601:
602: dnl the following macro produces a warning with autoconf-2.1
603: AC_C_BIGENDIAN
604: AC_SUBST(KERNEL)
605: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
606: if test $ac_cv_c_bigendian = yes; then
607: bytesex=b
608: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
609: else
610: bytesex=l
611: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
612: fi
613:
614: #check how to do asm(".skip 16")
615: #echo "CFLAGS=$CFLAGS"
616: #echo "ac_link=$ac_link"
617: AC_MSG_CHECKING([if and how we can waste code space])
618: if test -z "$skipcode"; then
619: skipcode=no
620: CFLAGS_1="$CFLAGS"
621: CFLAGS="$CFLAGS $ENGINE_FLAGS"
622: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
623: do
624: AC_TRY_RUN(
625: [int foo(int,int,int);
626: main()
627: {
628: exit(foo(0,0,0)!=16);
629: }
630: int foo(int x, int y, int z)
631: {
632: static void *labels[]={&&label1, &&label2};
633: if (x) {
634: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
635: label1:
636: asm("$i"); /* or ".space 16" or somesuch */
637: label2: ;
638: }
639: {
640: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
641: return labels[1]-labels[0];
642: }
643: }]
644: ,skipcode=$i; break
645: ,,)
646: done
647: CFLAGS=$CFLAGS_1
648: fi
649: AC_MSG_RESULT($skipcode)
650: if test "$skipcode" = no
651: then
652: if test -z $no_dynamic_default; then
653: no_dynamic_default=1
654: AC_MSG_WARN(Disabling default dynamic native code generation)
655: fi
656: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
657: else
658: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
659: fi
660:
661: AC_MSG_CHECKING([if and how we can do comments in asm statements])
662: #the point here is to get asm statements that look different to
663: #gcc's "optimizer"
664: if test -z "$asmcomment"; then
665: asmcomment=no
666: CFLAGS_1="$CFLAGS"
667: CFLAGS="$CFLAGS $ENGINE_FLAGS"
668: for i in '"# "' '"! "' '"; "'; do
669: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
670: done
671: CFLAGS=$CFLAGS_1
672: fi
673: AC_MSG_RESULT($asmcomment)
674: if test "$asmcomment" != no
675: then
676: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
677: fi
678:
679: test "$no_dynamic_default" || no_dynamic_default=0
680: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
681:
682: dnl Checks for programs.
683: AC_PROG_LN_S
684: AC_PROG_INSTALL
685: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
686:
687: dnl Checks for library functions
688: dnl This check is just for making later checks link with libm.
689: dnl using sin here is no good idea since it is built-into gcc and typechecked
690: AC_CHECK_LIB(m,asin)
691: AC_CHECK_LIB(dl,dlopen)
692: dnl check for libffi 2.x
693: AC_CHECK_LIB(ffi,ffi_call)
694: if test $ac_cv_lib_ffi_ffi_call = yes
695: then
696: LIBFFIFLAG="true"
697: FFCALLFLAG="false"
698: OLDCALLFLAG="false"
699: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
700: else
701: dnl check for ffcall libraries
702: dnl unfortunately, these four calls are separated out into a library each.
703: AC_CHECK_LIB(avcall,__builtin_avcall)
704: AC_CHECK_LIB(callback,__vacall_r)
705: AC_CHECK_LIB(vacall,vacall)
706: AC_CHECK_LIB(trampoline,alloc_trampoline)
707: LIBFFIFLAG="false"
708: FFCALLFLAG="false"
709: OLDCALLFLAG="true"
710: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
711: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
712: fi
713: AC_SUBST(LIBFFIFLAG)
714: AC_SUBST(FFCALLFLAG)
715: AC_SUBST(OLDCALLFLAG)
716: if test "$host_os" != "nextstep3"
717: then
718: AC_FUNC_MEMCMP
719: fi
720: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
721: AC_FUNC_FSEEKO
722: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
723: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
724: AC_DECL_SYS_SIGLIST
725: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
726: AC_CHECK_FUNCS(expm1 log1p)
727: AC_REPLACE_FUNCS(rint ecvt)
728: dnl No check for select, because our replacement is no good under
729: dnl anything but DOS
730: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
731: AC_FUNC_FNMATCH
732: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
733: AC_CHECK_FUNCS(mmap sysconf getpagesize)
734: AM_PATH_LISPDIR
735:
736: kernel_fi=kernl${wordsize}${bytesex}.fi
737: include_fi=kernl${wordsize}${bytesex}${EC}.fi
738: AC_SUBST(kernel_fi)
739: AC_SUBST(include_fi)
740:
741: #this breaks bindists
742: #dnl replace srource directory by absolute value
743: #if test $srcdir = "."; then srcdir=`pwd`
744: #fi
745:
746: AC_SUBST(machine)
747: AC_CONFIG_FILES([
748: Makefile
749: Makedist
750: gforthmi
751: vmgen
752: machpc.fs
753: envos.fs
754: engine/Makefile
755: doc/version.texi
756: build-ec ])
757: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
758: chmod +x gforthmi
759: chmod +x vmgen
760: chmod +x build-ec
761: test -d kernel||mkdir kernel]],[[]])
762: AC_OUTPUT
763:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>