1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation, either version 3
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program. If not, see http://www.gnu.org/licenses/.
19:
20:
21: dnl We use some automake macros here,
22: dnl but don't use automake for creating Makefile.in
23: AC_INIT([gforth],[0.6.9-20080430],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
24: AC_PREREQ(2.54)
25: #snapshots have numbers major.minor.release-YYYYMMDD
26: #note that lexicographic ordering must be heeded.
27: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
28: UPDATED="February 23, 2008"
29: AC_SUBST(UPDATED)
30: AC_CONFIG_HEADERS(engine/config.h)
31:
32: #ltdl stuff:
33: AC_CONFIG_MACRO_DIR([libltdl/m4])
34: LT_CONFIG_LTDL_DIR([libltdl])
35: LT_INIT([dlopen])
36: LTDL_INIT([subproject],[convenience])
37: AC_CONFIG_AUX_DIR([libltdl/config])
38:
39: # check for ltdl features we need
40: # The lt_dladvise_init symbol was added with libtool-2.2
41: if test "x$with_included_ltdl" != "xyes"; then
42: save_CFLAGS="$CFLAGS"
43: save_LDFLAGS="$LDFLAGS"
44: CFLAGS="$CFLAGS $LTDLINCL"
45: LDFLAGS="$LDFLAGS $LIBLTDL"
46: AC_CHECK_LIB([ltdl], [lt_dladvise_init],
47: [],
48: [AC_MSG_ERROR([libltdl-2.2 or later needed; configure with --with-included-ltdl])])
49: LDFLAGS="$save_LDFLAGS"
50: CFLAGS="$save_CFLAGS"
51: fi
52:
53: #how to link with libltdl
54: if test "x$with_included_ltdl" = "xyes"; then
55: #hard-code it (hopefully portable); the official way is to use automake :-(
56: LTDL_LDLIBS='-L$(top_builddir)/libltdl/.libs -lltdlc'
57: else
58: LTDL_LDLIBS='$(LIBLTDL)'
59: fi
60: AC_SUBST(LTDL_LDLIBS)
61:
62: #suppress the "-g -O2" default
63: test "$CFLAGS" || CFLAGS=-O2
64:
65: AC_ARG_ENABLE(force-cdiv,
66: AC_HELP_STRING([--enable-force-cdiv],
67: [ Use the native C division - symmetric - instead of
68: floored division (default disabled).]),
69: ,enable_force_cdiv=no)
70: test "$enable_force_cdiv" = "no"||
71: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
72:
73: AC_SUBST(PROFEXES)
74: AC_SUBST(PROFOBJS)
75: AC_ARG_ENABLE(prof,
76: AC_HELP_STRING([--enable-prof],
77: [ Build gforth-prof, which outputs frequently occuring
78: sequences of primitives.]),
79: ,enable_prof=no)
80: if test "$enable_prof" != "no"; then
81: PROFEXES='gforth-prof$(OPT)$(EXE)'; PROFOBJS='engine-prof$(OPT).o main-prof$(OPT).o profile$(OPT).o'
82: fi
83:
84: AC_ARG_WITH(debug,
85: [ --with-debug specifies option -g to compile with debug info
86: --without-debug omits the -g switch and creates smaller images on
87: machines where "strip" has problems with gcc style
88: debugging informations.],
89: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
90:
91: GCC_LD="\$(GCC)"
92: EC_MODE="false"
93: EC=""
94: engine2='engine2$(OPT).o'
95: engine_fast2='engine-fast2$(OPT).o'
96: no_dynamic=""
97: image_i=""
98: signals_o="io.o signals.o"
99:
100: AC_ARG_WITH(ec,
101: AC_HELP_STRING([--with-ec=<arch>],
102: [ Build gforth for systems without OS.]),
103: [if test "$withval" = "no"; then
104: echo "defining hosted system"
105: else
106: echo "defining standalone system (${withval})"
107: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
108: EC_MODE="true"
109: EC="-ec"
110: engine2=""
111: engine_fast2=""
112: no_dynamic="-DNO_DYNAMIC"
113: image_i="image.i"
114: if test "$withval" != "yes"; then
115: signals_o="io-${withval}.o"
116: else
117: signals_o="io.o"
118: fi
119: GCC_PATH=$(which $CC)
120: LIB_PATH=${GCC_PATH%/*/*}
121: GCC_LD="\$(LD)"
122: platform=${withval}
123: fi])
124:
125: #variables mentioned in INSTALL
126: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
127: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
128: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
129: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
130: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
131:
132: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
133: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
134: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
135: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
136: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
137: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
138: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
139: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
140: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
141: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
142: AC_ARG_VAR(condbranch_opt, [enable (1) or disable (0) using two dispatches for conditional branches])
143: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
144: AC_ARG_VAR(asmcomment, [assembler comment start string])
145: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
146:
147: #set up feature test macros, so the tests get them right:
148: # turn on all POSIX, SUSv3, and GNU features if available
149: AC_GNU_SOURCE
150: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
151:
152: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
153: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
154: dnl but not for _XOPEN_SOURCE)
155: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
156: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
157: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
158: # turn on large file support with 64-bit off_t where available
159: AC_SYS_LARGEFILE
160: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
161: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
162:
163: #currently we force direct threading this way. Eventually we should
164: #setup in the arch and engine files right
165:
166: AC_PROG_CC
167:
168: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
169:
170: AC_MSG_CHECKING([whether to use two dispatches per conditional branch])
171: test x$condbranch_opt = x &&
172: if ($CC -v 2>&1 |grep -q 'gcc version 3'); then
173: condbranch_opt=0
174: else
175: condbranch_opt=1
176: fi
177: AC_MSG_RESULT($condbranch_opt)
178: AC_SUBST(condbranch_opt)
179:
180: AC_SUBST(CC)
181: AC_SUBST(GCC_LD)
182: AC_SUBST(DEBUGFLAG)
183: AC_SUBST(EC)
184: AC_SUBST(EC_MODE)
185: AC_SUBST(engine2)
186: AC_SUBST(engine_fast2)
187: AC_SUBST(no_dynamic)
188: AC_SUBST(image_i)
189: AC_SUBST(signals_o)
190:
191: #this is used to disable some (not generally essential) part of the
192: #Makefile that some makes don't grok. It would be better to test for
193: #this specific Makefile feature than the make version.
194: AC_MSG_CHECKING(make type)
195: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
196: GNUMAKE='#'
197: test "$make_type" = "GNU Make" && GNUMAKE=''
198: AC_MSG_RESULT($make_type)
199: AC_SUBST(GNUMAKE)
200:
201: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
202: OLDLDFLAGS=$LDFLAGS
203: LDFLAGS="$LDFLAGS -export-dynamic"
204: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
205: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
206: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
207: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
208: AC_MSG_RESULT($ac_export_dynamic)
209:
210: #terminology is a bit unusual here: The host is the system on which
211: #gforth will run; the system on which configure will run is the `build'
212: AC_CANONICAL_HOST
213: case "$host_cpu" in
214: arm*)
215: machine=arm
216: CFLAGS="$CFLAGS -fomit-frame-pointer"
217: if test x$platform = xnxt; then
218: CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
219: fi
220: if test -z $arm_cacheflush; then
221: case "$host_os" in
222: *linux*)
223: arm_cacheflush=arch/arm/cacheflush-linux
224: ;;
225: *)
226: no_dynamic_default=1
227: arm_cacheflush=arch/arm/cacheflush0
228: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
229: ;;
230: esac
231: fi
232: AC_LIBSOURCES([../arch/arm/cacheflush0, dnl
233: ../arch/arm/cacheflush-linux])
234: AC_LIBOBJ(../$arm_cacheflush)
235: #longer skipcodes lead to problems on ARM, and it uses
236: #only 4-byte alignment anyway
237: test "$skipcode" || skipcode="nop"
238: ;;
239: hppa*)
240: machine=hppa
241: $srcdir/mkinstalldirs arch/hppa
242: AC_LIBOBJ(../arch/hppa/cache)
243: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
244: LDFLAGS="$LDFLAGS -Xlinker -N"
245: LIBS="$LIBS -L/lib/pa1.1/"
246: ;;
247: sparc*)
248: machine=sparc
249: ;;
250: i386)
251: machine=386
252: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
253: ;;
254: i486)
255: machine=386
256: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -m486"
257: ;;
258: i*86)
259: machine=386
260: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
261: CFLAGS_1="$CFLAGS"
262: CFLAGS="$CFLAGS -march=pentium"
263: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
264: ;;
265: x86_64)
266: case $CC
267: in
268: *-m32*)
269: machine=386
270: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr"
271: CFLAGS_1="$CFLAGS"
272: CFLAGS="$CFLAGS -march=athlon64"
273: ;;
274: *)
275: machine=amd64
276: ;;
277: esac
278: ;;
279: ia64*)
280: machine=ia64
281: AC_LIBOBJ(../arch/ia64/flush_icache_block)
282: test "$skipcode" || skipcode="nop.i 0"
283: #".skip 16" passes the test below,
284: # but gives an assembler error in engine
285: ;;
286: m68k)
287: machine=m68k
288: CFLAGS="$CFLAGS -fomit-frame-pointer"
289: if test "$host_os" = "nextstep3"
290: then
291: AC_LIBOBJ(termios)
292: fi
293: ;;
294: mips*)
295: machine=mips
296: #dynamic native code has the following problems on MIPS:
297: #
298: #1) J/JAL seems relocatable, but is are only
299: #relocatable within a 256MB-segment. While we try to
300: #get the linker to arrange this, there is no guarantee
301: #that this will succeed (and if the user uses a lot of
302: #memory, it is likely to fail).
303: #
304: #2) The way we generate dynamic native code may
305: #violate MIPS architectural restrictions (in
306: #particular, the delay slots of LW, MFLO, etc.)
307: #
308: #Therefore we disable dynamic native code by default:
309: if test -z $no_dynamic_default; then
310: no_dynamic_default=1
311: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
312: fi
313: ;;
314: alpha*)
315: machine=alpha
316: #full IEEE FP support for more uniformity across platforms:
317: CFLAGS="$CFLAGS -mieee"
318: ;;
319: power*|rs6000)
320: machine=power
321: $srcdir/mkinstalldirs arch/power
322: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
323: #long long is broken on (at least) gcc-2.95.* for PPC
324: test x$ac_cv_sizeof_long_long = x &&
325: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
326: ac_cv_sizeof_long_long=0
327: #The only architecture with enough callee-saved registers
328: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=3
329: #or use 2, hardly slower at run-time and starts up faster
330: ;;
331: *)
332: AC_MSG_WARN([Using a generic machine description])
333: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
334: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
335: machine=generic
336: #I-cache flushing would be needed for dynamic code generation
337: if test -z $no_dynamic_default; then
338: no_dynamic_default=1
339: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
340: fi
341: esac
342: AC_SUBST(host)
343:
344: MAKEINC=""
345:
346: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
347: if test x$EC_MODE = xtrue
348: then
349: echo "Check for arch/$machine/$platform/gforth.ld"
350: if test -f arch/$machine/$platform/gforth.ld
351: then
352: LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
353: if test x$platform = xnxt; then
354: LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
355: fi
356: fi
357: if test -f arch/$machine/$platform/make.inc
358: then
359: MAKEINC="include ../arch/$machine/$platform/make.inc"
360: fi
361: fi
362: AC_SUBST(MAKEINC)
363:
364: AC_ARG_VAR(STACK_CACHE_REGS, [number of registers in the maximum stack cache state for gforth-fast and gforth-native (default platform-dependent).])
365:
366: test x$STACK_CACHE_REGS = x && STACK_CACHE_REGS=1
367: AC_DEFINE_UNQUOTED(STACK_CACHE_REGS, $STACK_CACHE_REGS,
368: [number of registers in the maximum stack cache state for gforth-fast and gforth-native])
369: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
370: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
371: [number of registers in the default stack cache state for gforth-fast and gforth-native])
372:
373: test x$GCC_PR15242_WORKAROUND = x ||
374: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
375: [force (1) or forbid (0) use of a workaround for a gcc performance bug])
376:
377: dnl the following macro produces a warning with autoconf-2.1
378: AC_CHECK_SIZEOF(char *)
379: case "$ac_cv_sizeof_char_p" in
380: 2)
381: wordsize=16
382: ;;
383: 4)
384: wordsize=32
385: ;;
386: 8)
387: wordsize=64
388: ;;
389: esac
390:
391: AC_CHECK_SIZEOF(void *)
392: case "$ac_cv_sizeof_void_p" in
393: 2)
394: vwordsize=16
395: ;;
396: 4)
397: vwordsize=32
398: ;;
399: 8)
400: vwordsize=64
401: ;;
402: esac
403:
404: AC_CHECK_SIZEOF(char)
405: AC_CHECK_SIZEOF(short)
406: AC_CHECK_SIZEOF(int)
407: AC_CHECK_SIZEOF(long)
408: AC_CHECK_SIZEOF(long long)
409: AC_CHECK_SIZEOF(intptr_t)
410: AC_CHECK_SIZEOF(int128_t)
411: AC_CHECK_SIZEOF(uint128_t)
412:
413: AC_MSG_CHECKING([for a C type for cells])
414: ac_cv_int_type_cell=none
415: case "$ac_cv_sizeof_char_p" in
416: $ac_cv_sizeof_int)
417: ac_cv_int_type_cell=int
418: ;;
419: $ac_cv_sizeof_short)
420: ac_cv_int_type_cell=short
421: ;;
422: $ac_cv_sizeof_char)
423: ac_cv_int_type_cell=char
424: ;;
425: $ac_cv_sizeof_long)
426: ac_cv_int_type_cell=long
427: ;;
428: $ac_cv_sizeof_long_long)
429: ac_cv_int_type_cell="long long"
430: ;;
431: $ac_cv_sizeof_intptr_t)
432: ac_cv_int_type_cell="intptr_t"
433: ;;
434: esac
435: AC_MSG_RESULT($ac_cv_int_type_cell)
436: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
437:
438: AC_MSG_CHECKING([for a C type for wydes])
439: ac_cv_wyde_type_cell=none
440: case 2 in
441: $ac_cv_sizeof_int)
442: ac_cv_wyde_type_cell=int
443: ;;
444: $ac_cv_sizeof_short)
445: ac_cv_wyde_type_cell=short
446: ;;
447: $ac_cv_sizeof_char)
448: ac_cv_wyde_type_cell=char
449: ;;
450: $ac_cv_sizeof_long)
451: ac_cv_wyde_type_cell=long
452: ;;
453: $ac_cv_sizeof_long_long)
454: ac_cv_wyde_type_cell="long long"
455: ;;
456: $ac_cv_sizeof_intptr_t)
457: ac_cv_wyde_type_cell="intptr_t"
458: ;;
459: esac
460: AC_MSG_RESULT($ac_cv_wyde_type_cell)
461: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
462:
463: AC_MSG_CHECKING([for a C type for tetrabytes])
464: ac_cv_tetrabyte_type_cell=none
465: case 4 in
466: $ac_cv_sizeof_int)
467: ac_cv_tetrabyte_type_cell=int
468: ;;
469: $ac_cv_sizeof_short)
470: ac_cv_tetrabyte_type_cell=short
471: ;;
472: $ac_cv_sizeof_char)
473: ac_cv_tetrabyte_type_cell=char
474: ;;
475: $ac_cv_sizeof_long)
476: ac_cv_tetrabyte_type_cell=long
477: ;;
478: $ac_cv_sizeof_long_long)
479: ac_cv_tetrabyte_type_cell="long long"
480: ;;
481: $ac_cv_sizeof_intptr_t)
482: ac_cv_tetrabyte_type_cell="intptr_t"
483: ;;
484: esac
485: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
486: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
487:
488: AC_MSG_CHECKING([for a C type for double-cells])
489: ac_cv_int_type_double_cell=none
490: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
491: $ac_cv_sizeof_short)
492: ac_cv_int_type_double_cell=short
493: ;;
494: $ac_cv_sizeof_int)
495: ac_cv_int_type_double_cell=int
496: ;;
497: $ac_cv_sizeof_long)
498: ac_cv_int_type_double_cell=long
499: ;;
500: $ac_cv_sizeof_long_long)
501: ac_cv_int_type_double_cell="long long"
502: ;;
503: $ac_cv_sizeof_intptr_t)
504: ac_cv_int_type_double_cell="intptr_t"
505: ;;
506: $ac_cv_sizeof_int128_t)
507: ac_cv_int_type_double_cell="int128_t"
508: ;;
509: esac
510: AC_MSG_RESULT($ac_cv_int_type_double_cell)
511:
512: AC_MSG_CHECKING([for a C type for unsigned double-cells])
513: ac_cv_int_type_double_ucell=none
514: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
515: $ac_cv_sizeof_short)
516: ac_cv_int_type_double_ucell="unsigned short"
517: ;;
518: $ac_cv_sizeof_int)
519: ac_cv_int_type_double_ucell="unsigned int"
520: ;;
521: $ac_cv_sizeof_long)
522: ac_cv_int_type_double_ucell="unsigned long"
523: ;;
524: $ac_cv_sizeof_long_long)
525: ac_cv_int_type_double_ucell="unsigned long long"
526: ;;
527: $ac_cv_sizeof_intptr_t)
528: ac_cv_int_type_double_ucell="unsigned intptr_t"
529: ;;
530: $ac_cv_sizeof_uint128_t)
531: ac_cv_int_type_double_ucell="uint128_t"
532: ;;
533: esac
534: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
535:
536: if test "$ac_cv_int_type_double_cell" != none && \
537: test "$ac_cv_int_type_double_ucell" != none
538: then
539: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
540: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
541: OPTS=-ll
542: else
543: if test "$ac_cv_sizeof_char_p" = 8; then
544: OPTS="-ll -noll"
545: else
546: OPTS=-noll
547: fi
548: fi
549:
550: if grep -q FORCE_REG arch/$machine/machine.h; then
551: OPTS=`for i in $OPTS; do echo -n "$i-reg "; done`$OPTS
552: else
553: AC_DEFINE_UNQUOTED(FORCE_REG_UNNECESSARY,,[defined if the platform does not need FORCE_REG])
554: fi
555: AC_SUBST(OPTS)
556:
557: AC_TYPE_OFF_T
558: AC_CHECK_SIZEOF(off_t)
559: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
560: ac_small_off_t=$?
561: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
562:
563: ENGINE_FLAGS=
564: AC_SUBST(ENGINE_FLAGS)
565:
566: # Try if GCC understands -fno-gcse
567:
568: AC_MSG_CHECKING([if $CC understands -fno-gcse])
569: CFLAGS_1="$CFLAGS"
570: CFLAGS="$CFLAGS -fno-gcse"
571: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
572: CFLAGS="$CFLAGS_1"
573: AC_MSG_RESULT($ac_nogcse)
574:
575: # Try if GCC understands -fno-strict-aliasing
576: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
577: CFLAGS_1="$CFLAGS"
578: CFLAGS="$CFLAGS -fno-strict-aliasing"
579: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
580: CFLAGS="$CFLAGS_1"
581: AC_MSG_RESULT($ac_nostrictaliasing)
582:
583: # Try if GCC understands -fno-crossjumping
584: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
585: CFLAGS_1="$CFLAGS"
586: CFLAGS="$CFLAGS -fno-crossjumping"
587: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
588: CFLAGS="$CFLAGS_1"
589: AC_MSG_RESULT($ac_nocrossjumping)
590:
591: # Try if GCC understands -fno-reorder-blocks
592: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
593: CFLAGS_1="$CFLAGS"
594: CFLAGS="$CFLAGS -fno-reorder-blocks"
595: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
596: CFLAGS="$CFLAGS_1"
597: AC_MSG_RESULT($ac_noreorder_blocks)
598:
599: # Try if GCC understands -falign-labels=1
600: AC_MSG_CHECKING([if $CC understands -falign-labels=1])
601: CFLAGS_1="$CFLAGS"
602: CFLAGS="$CFLAGS -falign-labels=1"
603: AC_TRY_COMPILE(,,ac_align_labels=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-labels=1",ac_align_labels=no)
604: CFLAGS="$CFLAGS_1"
605: AC_MSG_RESULT($ac_align_labels)
606:
607: # Try if GCC understands -falign-loops=1
608: AC_MSG_CHECKING([if $CC understands -falign-loops=1])
609: CFLAGS_1="$CFLAGS"
610: CFLAGS="$CFLAGS -falign-loops=1"
611: AC_TRY_COMPILE(,,ac_align_loops=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-loops=1",ac_align_loops=no)
612: CFLAGS="$CFLAGS_1"
613: AC_MSG_RESULT($ac_align_loops)
614:
615: # Try if GCC understands -falign-jumps=1
616: AC_MSG_CHECKING([if $CC understands -falign-jumps=1])
617: CFLAGS_1="$CFLAGS"
618: CFLAGS="$CFLAGS -falign-jumps=1"
619: AC_TRY_COMPILE(,,ac_align_jumps=yes;ENGINE_FLAGS="$ENGINE_FLAGS -falign-jumps=1",ac_align_jumps=no)
620: CFLAGS="$CFLAGS_1"
621: AC_MSG_RESULT($ac_align_jumps)
622:
623: # Try if GCC understands __attribute__((unused))
624: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
625: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
626: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
627: AC_MSG_RESULT($MAYBE_UNUSED)
628:
629: #try if m4 understands -s
630: AC_MSG_CHECKING([how to invoke m4])
631: if m4 -s /dev/null >/dev/null 2>&1; then
632: M4="m4 -s"
633: else
634: M4=m4
635: fi
636: AC_SUBST(M4)
637: AC_DEFINE_UNQUOTED(M4,"$M4",[How to invoke m4])
638: AC_MSG_RESULT($M4)
639:
640: # Find installed Gforth
641: AC_MSG_CHECKING([for gforth])
642: GFORTH="`cd / && which gforth 2>/dev/null`"
643: if test -z "$GFORTH"; then
644: PREFORTH='echo "You need to configure with a gforth in \$PATH to build this part" && false'
645: else
646: PREFORTH="$GFORTH -i `cd / && gforth --debug -e bye 2>&1 |grep "Opened image file: "|sed 's/Opened image file: //'`" ;
647: fi
648: AC_SUBST(PREFORTH)
649: AC_DEFINE_UNQUOTED(PREFORTH,"$PREFORTH",[How to invoke the pre-installed gforth])
650: AC_MSG_RESULT($PREFORTH)
651:
652: #echo "machine='$machine'"
653:
654: dnl AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
655: AC_CHECK_FILE($srcdir/arch/$machine/asm.fs,[asm_fs=arch/$machine/asm.fs],)
656: AC_SUBST(asm_fs)
657:
658: dnl AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
659: AC_CHECK_FILE($srcdir/arch/$machine/disasm.fs,[disasm_fs=arch/$machine/disasm.fs],)
660: AC_SUBST(disasm_fs)
661:
662: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
663:
664: case "$host_os" in
665: *win32*)
666: # !!!FIXME!!! problems with cygwin and ';' as path separator
667: DIRSEP="\\\\"
668: PATHSEP=";"
669: #we want the builtins of command.com/cmd.exe and its
670: # handling of .com files.
671: #$COMSPEC contains the name of the Windows shell;
672: # the ./ is there, because the bash does not recognize
673: # absolute DOS filenames
674: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
675: ;;
676: *darwin*)
677: #Darwin uses some funny preprocessor by default; eliminate it:
678: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
679: CFLAGS="$CFLAGS -no-cpp-precomp"
680: DIRSEP="/"
681: PATHSEP=":"
682: DEFAULTSYSTEMPREFIX=""
683: ;;
684: *)
685: DIRSEP="/"
686: PATHSEP=":"
687: DEFAULTSYSTEMPREFIX=""
688: ;;
689: esac
690: AC_SUBST(DIRSEP)
691: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
692: AC_SUBST(PATHSEP)
693: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
694: AC_SUBST(DEFAULTSYSTEMPREFIX)
695: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
696:
697: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
698: #This magic incantation seems to be completely undocumented.
699: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
700:
701: dnl Now a little support for DOS/DJGCC
702: AC_SUBST(GFORTH_EXE)
703: GFORTH_EXE="true"
704: AC_SUBST(GFORTHFAST_EXE)
705: GFORTHFAST_EXE="true"
706: AC_SUBST(GFORTHITC_EXE)
707: GFORTHITC_EXE="true"
708: AC_SUBST(GFORTHDITC_EXE)
709: GFORTHDITC_EXE="true"
710:
711: AC_SUBST(FORTHSIZES)
712:
713: dnl if test "$PEEPHOLE" = "yes"
714: dnl then
715: dnl PEEPHOLEFLAG="true"
716: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
717: dnl else
718: dnl PEEPHOLEFLAG="false"
719: dnl fi
720: PEEPHOLEFLAG="true"
721: AC_SUBST(PEEPHOLEFLAG)
722:
723: dnl copy commands for systems that don't have links
724: AC_SUBST(LINK_KERNL)
725: LINK_KERNL=""
726:
727: #if test $host_os=dos
728: #then
729: # echo Configuring for DOS!!!
730: # MAKE_EXE="coff2exe gforth"
731: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
732: #fi
733:
734: dnl the following macro produces a warning with autoconf-2.1
735: AC_C_BIGENDIAN
736: AC_SUBST(KERNEL)
737: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
738: if test $ac_cv_c_bigendian = yes; then
739: bytesex=b
740: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
741: else
742: bytesex=l
743: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
744: fi
745:
746: #check how to do asm(".skip 16")
747: #echo "CFLAGS=$CFLAGS"
748: #echo "ac_link=$ac_link"
749: AC_MSG_CHECKING([if and how we can waste code space])
750: if test -z "$skipcode"; then
751: skipcode=no
752: CFLAGS_1="$CFLAGS"
753: CFLAGS="$CFLAGS $ENGINE_FLAGS"
754: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
755: do
756: AC_TRY_RUN(
757: [int foo(int,int,int);
758: main()
759: {
760: exit(foo(0,0,0)!=16);
761: }
762: int foo(int x, int y, int z)
763: {
764: static void *labels[]={&&label1, &&label2};
765: if (x) {
766: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
767: label1:
768: asm("$i"); /* or ".space 16" or somesuch */
769: label2: ;
770: }
771: {
772: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
773: return labels[1]-labels[0];
774: }
775: }]
776: ,skipcode=$i; break
777: ,,)
778: done
779: CFLAGS=$CFLAGS_1
780: fi
781: AC_MSG_RESULT($skipcode)
782: if test "$skipcode" = no
783: then
784: if test -z $no_dynamic_default; then
785: no_dynamic_default=1
786: AC_MSG_WARN(Disabling default dynamic native code generation)
787: fi
788: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
789: else
790: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
791: fi
792:
793: AC_MSG_CHECKING([if and how we can do comments in asm statements])
794: #the point here is to get asm statements that look different to
795: #gcc's "optimizer"
796: if test -z "$asmcomment"; then
797: asmcomment=no
798: CFLAGS_1="$CFLAGS"
799: CFLAGS="$CFLAGS $ENGINE_FLAGS"
800: for i in '"# "' '"! "' '"; "'; do
801: AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
802: done
803: CFLAGS=$CFLAGS_1
804: fi
805: AC_MSG_RESULT($asmcomment)
806: if test "$asmcomment" != no
807: then
808: AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
809: fi
810:
811: test "$no_dynamic_default" || no_dynamic_default=0
812: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
813:
814: dnl Checks for programs.
815: AC_PROG_LN_S
816: AC_PROG_INSTALL
817: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
818:
819: dnl MacOS X has a libtool that does something else
820: AC_CHECK_PROGS(GNU_LIBTOOL,glibtool libtool)
821:
822: dnl Checks for library functions
823: dnl This check is just for making later checks link with libm.
824: dnl using sin here is no good idea since it is built-into gcc and typechecked
825: AC_CHECK_LIB(m,asin)
826: AC_CHECK_LIB(dl,dlopen)
827: dnl check for libffi 2.x
828: AC_CHECK_LIB(ffi,ffi_call)
829: if test $ac_cv_lib_ffi_ffi_call = yes
830: then
831: LIBFFIFLAG="true"
832: FFCALLFLAG="false"
833: OLDCALLFLAG="false"
834: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
835: else
836: dnl check for ffcall libraries
837: dnl unfortunately, these four calls are separated out into a library each.
838: AC_CHECK_LIB(avcall,__builtin_avcall)
839: AC_CHECK_LIB(callback,__vacall_r)
840: AC_CHECK_LIB(vacall,vacall)
841: AC_CHECK_LIB(trampoline,alloc_trampoline)
842: LIBFFIFLAG="false"
843: FFCALLFLAG="false"
844: OLDCALLFLAG="true"
845: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
846: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
847: fi
848: AC_SUBST(LIBFFIFLAG)
849: AC_SUBST(FFCALLFLAG)
850: AC_SUBST(OLDCALLFLAG)
851: if test "$host_os" != "nextstep3"
852: then
853: AC_FUNC_MEMCMP
854: fi
855: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
856: AC_FUNC_FSEEKO
857: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
858: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
859: AC_DECL_SYS_SIGLIST
860: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
861: AC_CHECK_FUNCS(expm1 log1p)
862: AC_REPLACE_FUNCS(rint ecvt)
863: dnl No check for select, because our replacement is no good under
864: dnl anything but DOS
865: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
866: AC_FUNC_FNMATCH
867: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
868: AC_CHECK_FUNCS(mmap sysconf getpagesize)
869: AM_PATH_LISPDIR
870:
871: kernel_fi=kernl${vwordsize}${bytesex}.fi
872: include_fi=kernl${wordsize}${bytesex}${EC}.fi
873: AC_SUBST(kernel_fi)
874: AC_SUBST(include_fi)
875:
876: #this breaks bindists
877: #dnl replace srource directory by absolute value
878: #if test $srcdir = "."; then srcdir=`pwd`
879: #fi
880:
881: AC_SUBST(machine)
882: AC_CONFIG_FILES([
883: Makefile
884: Makedist
885: gforthmi
886: vmgen
887: machpc.fs
888: envos.fs
889: preforth
890: engine/Makefile
891: engine/libcc.h
892: doc/version.texi
893: build-ec ])
894: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
895: chmod +x gforthmi
896: chmod +x vmgen
897: chmod +x build-ec
898: chmod +x preforth
899: test -d kernel||mkdir kernel
900: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
901: ln -sf ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
902: AC_OUTPUT
903:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>