Return to configure.in CVS log

Up to [gforth] / gforth

documentation changes
Updates in Makefile.in to reflect newer autoconf usage
Distribution and installation of libcc stuff
libcc header files are now found automatically
Disabled vmgen installation

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.9-20070604],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="June 02, 2007"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: 	AC_HELP_STRING([--enable-force-reg],
   38: 		        [ Use explicit register declarations if they appear in
   39: 			  the machine.h file. This can cause a good speedup,
   40: 			  but also incorrect code with some gcc versions on
   41: 			  some processors (default disabled).]),
   42: 	,enable_force_reg=no)
   43: test "$enable_force_reg" = "no"||
   44:   AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
   45: 
   46: AC_ARG_ENABLE(force-ll,
   47: 	AC_HELP_STRING([--enable-force-ll],
   48: 		       [  Use explicit long long declarations if they appear in
   49: 			  the machine.h file. This can cause a good speedup,
   50: 			  but also incorrect code with some gcc versions on
   51: 			  some processors (default disabled).]),
   52: 	,enable_force_ll=no)
   53: test "$enable_force_ll" = "no"||
   54:   AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
   55: 
   56: AC_ARG_ENABLE(force-cdiv,
   57: 	AC_HELP_STRING([--enable-force-cdiv],
   58: 		       [  Use the native C division - symmetric - instead of
   59: 		          floored division (default disabled).]),
   60: 	,enable_force_cdiv=no)
   61: test "$enable_force_cdiv" = "no"||
   62:   AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
   63: 
   64: AC_SUBST(PROFEXES)
   65: AC_SUBST(PROFOBJS)
   66: AC_ARG_ENABLE(prof,
   67: 	AC_HELP_STRING([--enable-prof],
   68: 			[ Build gforth-prof, which outputs frequently occuring
   69:                           sequences of primitives.]),
   70: 	,enable_prof=no)
   71: if test "$enable_prof" = "no"; then
   72:   PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
   73: fi
   74: 
   75: AC_ARG_WITH(debug,
   76: [  --with-debug		  specifies option -g to compile with debug info
   77:   --without-debug	  omits the -g switch and creates smaller images on
   78: 			  machines where "strip" has problems with gcc style
   79: 			  debugging informations.],
   80: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   81: 
   82: dnl PEEPHOLE="yes"
   83: dnl AC_ARG_WITH(peephole,
   84: dnl [  --with-peephole	Enable peephole optimization (default)
   85: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   86: dnl 			but slower images.],
   87: dnl PEEPHOLE="$withval")
   88: 
   89: GCC_LD="\$(GCC)"
   90: EC_MODE="false"
   91: EC=""
   92: engine2="engine2.o"
   93: engine_fast2="engine-fast2.o"
   94: no_dynamic=""
   95: image_i=""
   96: signals_o="io.o signals.o"
   97: 
   98: AC_ARG_WITH(ec,
   99: 	AC_HELP_STRING([--with-ec=<arch>],
  100: 			[  Build gforth for systems without OS.]),
  101: [if test "$withval" = "no"; then
  102:   echo "defining hosted system"
  103: else
  104:   echo "defining standalone system (${withval})"
  105:   AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
  106:   EC_MODE="true"
  107:   EC="-ec"
  108:   engine2=""
  109:   engine_fast2=""
  110:   no_dynamic="-DNO_DYNAMIC"
  111:   image_i="image.i"
  112:   if test "$withval" != "yes"; then
  113:     signals_o="io-${withval}.o"
  114:   else
  115:     signals_o="io.o"
  116:   fi
  117:   GCC_PATH=$(which $CC)
  118:   LIB_PATH=${GCC_PATH%/*/*}
  119:   GCC_LD="\$(LD)"
  120:   platform=${withval}
  121: fi])
  122: 
  123: #variables mentioned in INSTALL
  124: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
  125: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
  126: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
  127: AC_ARG_VAR(GCC_PR15242_WORKAROUND, [Force the enabling (1) or disabling (0) of a workaround for a gcc-3.x performance bug (default unset: use workaround for gcc-3.x)])
  128: 
  129: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
  130: AC_ARG_VAR(ac_cv_sizeof_void_p, [sizeof(void *)])
  131: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
  132: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
  133: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
  134: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
  135: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
  136: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
  137: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
  138: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
  139: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
  140: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
  141: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
  142: AC_ARG_VAR(asmcomment, [assembler comment start string])
  143: AC_ARG_VAR(arm_cacheflush, [file containing ARM cacheflush function (without .c)])
  144: 
  145: #set up feature test macros, so the tests get them right:
  146: # turn on all POSIX, SUSv3, and GNU features if available
  147: AC_GNU_SOURCE
  148: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
  149: 
  150: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
  151: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
  152: dnl but not for _XOPEN_SOURCE)
  153: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
  154: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
  155: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
  156: # turn on large file support with 64-bit off_t where available
  157: AC_SYS_LARGEFILE
  158: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
  159: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  160: 
  161: #currently we force direct threading this way.  Eventually we should
  162: #setup in the arch and engine files right
  163: 
  164: AC_PROG_CC
  165: 
  166: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  167: 
  168: AC_SUBST(CC)
  169: AC_SUBST(GCC_LD)
  170: AC_SUBST(DEBUGFLAG)
  171: AC_SUBST(EC)
  172: AC_SUBST(EC_MODE)
  173: AC_SUBST(engine2)
  174: AC_SUBST(engine_fast2)
  175: AC_SUBST(no_dynamic)
  176: AC_SUBST(image_i)
  177: AC_SUBST(signals_o)
  178: 
  179: #this is used to disable some (not generally essential) part of the
  180: #Makefile that some makes don't grok.  It would be better to test for
  181: #this specific Makefile feature than the make version.
  182: AC_MSG_CHECKING(make type)
  183: make_type=`make -n -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
  184: GNUMAKE='#'
  185: test "$make_type" = "GNU Make" && GNUMAKE=''
  186: AC_MSG_RESULT($make_type)
  187: AC_SUBST(GNUMAKE)
  188: 
  189: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  190: OLDLDFLAGS=$LDFLAGS
  191: LDFLAGS="$LDFLAGS -export-dynamic"
  192: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  193: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  194: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  195: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  196: AC_MSG_RESULT($ac_export_dynamic)
  197: 
  198: #terminology is a bit unusual here: The host is the system on which
  199: #gforth will run; the system on which configure will run is the `build'
  200: AC_CANONICAL_HOST
  201: case "$host_cpu" in
  202: 	arm*)
  203: 		machine=arm
  204: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  205: 		if test x$platform = xnxt; then
  206: 		   CFLAGS="$CFLAGS -mthumb -mthumb-interwork"
  207: 		fi
  208: 		if test -z $arm_cacheflush; then
  209: 		    no_dynamic_default=1
  210:                     arm_cacheflush=arch/arm/cacheflush0
  211: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  212: 		fi
  213:                 AC_LIBSOURCES([../arch/arm/cacheflush0, ../arch/arm/cacheflush1, ../arch/arm/cacheflush2])
  214:                 AC_LIBOBJ(../$arm_cacheflush)
  215:                 #longer skipcodes lead to problems on ARM, and it uses
  216:                 #only 4-byte alignment anyway
  217: 		test "$skipcode" || skipcode="nop"
  218: 		;;
  219: 	hppa*)
  220: 		machine=hppa
  221: 		$srcdir/mkinstalldirs arch/hppa
  222: 		AC_LIBOBJ(../arch/hppa/cache)
  223: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  224: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  225: 		LIBS="$LIBS -L/lib/pa1.1/"
  226: 		;;
  227: 	sparc*)
  228: 		machine=sparc
  229: 		;;
  230: 	i386)
  231: 		machine=386
  232: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  233: 		;;
  234: 	i486)
  235: 		machine=386
  236: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  237: 		;;
  238: 	i*86)
  239: 		machine=386
  240: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  241: 		CFLAGS_1="$CFLAGS"
  242: 		CFLAGS="$CFLAGS -march=pentium"
  243: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  244: 		;;
  245: 	x86_64)
  246: 		machine=amd64
  247: 		;;
  248: 	ia64*)
  249: 		machine=ia64
  250: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  251: 		test "$skipcode" || skipcode="nop.i 0"
  252: 		#".skip 16" passes the test below,
  253: 		# but gives an assembler error in engine
  254: 		;;
  255:         m68k)
  256: 		machine=m68k
  257: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  258: 		if test "$host_os" = "nextstep3"
  259: 		then
  260: 			AC_LIBOBJ(termios)
  261: 		fi
  262: 		;;
  263: 	mips*)
  264: 		machine=mips
  265: 		#dynamic native code has the following problems on MIPS:
  266: 		#
  267: 		#1) J/JAL seems relocatable, but is are only
  268: 		#relocatable within a 256MB-segment.  While we try to
  269: 		#get the linker to arrange this, there is no guarantee
  270: 		#that this will succeed (and if the user uses a lot of
  271: 		#memory, it is likely to fail).
  272: 		#
  273: 		#2) The way we generate dynamic native code may
  274: 		#violate MIPS architectural restrictions (in
  275: 		#particular, the delay slots of LW, MFLO, etc.)
  276: 		#
  277: 		#Therefore we disable dynamic native code by default:
  278: 		if test -z $no_dynamic_default; then
  279: 		    no_dynamic_default=1
  280: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  281: 		fi
  282: 		;;
  283: 	alpha*)
  284: 		machine=alpha
  285: 		#full IEEE FP support for more uniformity across platforms:
  286: 		CFLAGS="$CFLAGS -mieee"
  287: 		;;
  288: 	power*|rs6000)
  289: 		machine=power
  290: 		$srcdir/mkinstalldirs arch/power
  291: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  292: 		#long long is broken on (at least) gcc-2.95.* for PPC
  293: 		test x$ac_cv_sizeof_long_long = x && 
  294: 		($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
  295: 		ac_cv_sizeof_long_long=0
  296: 		;;
  297: 	*)
  298: 		AC_MSG_WARN([Using a generic machine description])
  299: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  300: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  301: 		machine=generic
  302: 		#I-cache flushing would be needed for dynamic code generation
  303: 		if test -z $no_dynamic_default; then
  304: 		    no_dynamic_default=1
  305: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  306: 		fi
  307: esac
  308: AC_SUBST(host)
  309: 
  310: MAKEINC=""
  311: 
  312: echo "Check for arch/$machine/$platform/gforth.ld ($EC_MODE)"
  313: if test x$EC_MODE = xtrue
  314: then
  315: 	echo "Check for arch/$machine/$platform/gforth.ld"
  316: 	if test -f arch/$machine/$platform/gforth.ld
  317: 	then
  318: 		LDFLAGS="-T ../arch/$machine/$platform/gforth.ld -Map \$@.map -cref --gc-sections $LDFLAGS"
  319: 		if test x$platform = xnxt; then
  320: 			LIBS="$LIB_PATH/lib/gcc/arm-elf/$($CC --version | grep GCC | cut -d' ' -f3)/interwork/libgcc.a $LIB_PATH/arm-elf/lib/interwork/libc.a $LIBS"
  321: 		fi
  322: 	fi
  323: 	if test -f arch/$machine/$platform/make.inc
  324: 	then
  325: 		MAKEINC="include ../arch/$machine/$platform/make.inc"
  326: 	fi
  327: fi
  328: AC_SUBST(MAKEINC)
  329: 
  330: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
  331: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
  332: 		   [number of registers in the default stack cache state for gforth-fast and gforth-native])
  333: 
  334: test x$GCC_PR15242_WORKAROUND = x ||
  335: AC_DEFINE_UNQUOTED(GCC_PR15242_WORKAROUND, $GCC_PR15242_WORKAROUND,
  336:                    [force (1) or forbid (0) use of a workaround for a gcc performance bug])
  337: 
  338: dnl AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
  339: dnl generation on gccs affected by PR15242])
  340: 
  341: 
  342: if test "${enable_force_ll+set}" = set; then
  343:    ac_includes_default="$ac_includes_default
  344: #include \"arch/generic/128bit.h\""
  345: fi
  346: 
  347: dnl the following macro produces a warning with autoconf-2.1
  348: AC_CHECK_SIZEOF(char *)
  349: case "$ac_cv_sizeof_char_p" in
  350:   2)
  351:     wordsize=16
  352:     ;;
  353:   4)
  354:     wordsize=32
  355:     ;;
  356:   8)
  357:     wordsize=64
  358:     ;;
  359: esac
  360: 
  361: AC_CHECK_SIZEOF(void *)
  362: case "$ac_cv_sizeof_void_p" in
  363:   2)
  364:     vwordsize=16
  365:     ;;
  366:   4)
  367:     vwordsize=32
  368:     ;;
  369:   8)
  370:     vwordsize=64
  371:     ;;
  372: esac
  373: 
  374: AC_CHECK_SIZEOF(char)
  375: AC_CHECK_SIZEOF(short)
  376: AC_CHECK_SIZEOF(int)
  377: AC_CHECK_SIZEOF(long)
  378: AC_CHECK_SIZEOF(long long)
  379: AC_CHECK_SIZEOF(intptr_t)
  380: AC_CHECK_SIZEOF(int128_t)
  381: AC_CHECK_SIZEOF(uint128_t)
  382: 
  383: AC_MSG_CHECKING([for a C type for cells])
  384: ac_cv_int_type_cell=none
  385: case "$ac_cv_sizeof_char_p" in
  386:   $ac_cv_sizeof_int)
  387:     ac_cv_int_type_cell=int
  388:     ;;
  389:   $ac_cv_sizeof_short)
  390:     ac_cv_int_type_cell=short
  391:     ;;
  392:   $ac_cv_sizeof_char)
  393:     ac_cv_int_type_cell=char
  394:     ;;
  395:   $ac_cv_sizeof_long)
  396:     ac_cv_int_type_cell=long
  397:     ;;
  398:   $ac_cv_sizeof_long_long)
  399:     ac_cv_int_type_cell="long long"
  400:     ;;
  401:   $ac_cv_sizeof_intptr_t)
  402:     ac_cv_int_type_cell="intptr_t"
  403:     ;;
  404:   $ac_cv_sizeof_int128_t)
  405:     ac_cv_int_type_cell="int128_t"
  406:     ;;
  407: esac
  408: AC_MSG_RESULT($ac_cv_int_type_cell)
  409: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  410: 
  411: AC_MSG_CHECKING([for a C type for wydes])
  412: ac_cv_wyde_type_cell=none
  413: case 2 in
  414:   $ac_cv_sizeof_int)
  415:     ac_cv_wyde_type_cell=int
  416:     ;;
  417:   $ac_cv_sizeof_short)
  418:     ac_cv_wyde_type_cell=short
  419:     ;;
  420:   $ac_cv_sizeof_char)
  421:     ac_cv_wyde_type_cell=char
  422:     ;;
  423:   $ac_cv_sizeof_long)
  424:     ac_cv_wyde_type_cell=long
  425:     ;;
  426:   $ac_cv_sizeof_long_long)
  427:     ac_cv_wyde_type_cell="long long"
  428:     ;;
  429:   $ac_cv_sizeof_intptr_t)
  430:     ac_cv_wyde_type_cell="intptr_t"
  431:     ;;
  432:   $ac_cv_sizeof_int128_t)
  433:     ac_cv_wyde_type_cell="int128_t"
  434:     ;;
  435: esac
  436: AC_MSG_RESULT($ac_cv_wyde_type_cell)
  437: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
  438: 
  439: AC_MSG_CHECKING([for a C type for tetrabytes])
  440: ac_cv_tetrabyte_type_cell=none
  441: case 4 in
  442:   $ac_cv_sizeof_int)
  443:     ac_cv_tetrabyte_type_cell=int
  444:     ;;
  445:   $ac_cv_sizeof_short)
  446:     ac_cv_tetrabyte_type_cell=short
  447:     ;;
  448:   $ac_cv_sizeof_char)
  449:     ac_cv_tetrabyte_type_cell=char
  450:     ;;
  451:   $ac_cv_sizeof_long)
  452:     ac_cv_tetrabyte_type_cell=long
  453:     ;;
  454:   $ac_cv_sizeof_long_long)
  455:     ac_cv_tetrabyte_type_cell="long long"
  456:     ;;
  457:   $ac_cv_sizeof_intptr_t)
  458:     ac_cv_tetrabyte_type_cell="intptr_t"
  459:     ;;
  460:   $ac_cv_sizeof_int128_t)
  461:     ac_cv_tetrabyte_type_cell="int128_t"
  462:     ;;
  463: esac
  464: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
  465: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
  466: 
  467: AC_MSG_CHECKING([for a C type for double-cells])
  468: ac_cv_int_type_double_cell=none
  469: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  470:   $ac_cv_sizeof_short)
  471:     ac_cv_int_type_double_cell=short
  472:     ;;
  473:   $ac_cv_sizeof_int)
  474:     ac_cv_int_type_double_cell=int
  475:     ;;
  476:   $ac_cv_sizeof_long)
  477:     ac_cv_int_type_double_cell=long
  478:     ;;
  479:   $ac_cv_sizeof_long_long)
  480:     ac_cv_int_type_double_cell="long long"
  481:     ;;
  482:   $ac_cv_sizeof_intptr_t)
  483:     ac_cv_int_type_double_cell="intptr_t"
  484:     ;;
  485:   $ac_cv_sizeof_int128_t)
  486:     ac_cv_int_type_double_cell="int128_t"
  487:     ;;
  488: esac
  489: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  490: 
  491: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  492: ac_cv_int_type_double_ucell=none
  493: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  494:   $ac_cv_sizeof_short)
  495:     ac_cv_int_type_double_ucell="unsigned short"
  496:     ;;
  497:   $ac_cv_sizeof_int)
  498:     ac_cv_int_type_double_ucell="unsigned int"
  499:     ;;
  500:   $ac_cv_sizeof_long)
  501:     ac_cv_int_type_double_ucell="unsigned long"
  502:     ;;
  503:   $ac_cv_sizeof_long_long)
  504:     ac_cv_int_type_double_ucell="unsigned long long"
  505:     ;;
  506:   $ac_cv_sizeof_intptr_t)
  507:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  508:     ;;
  509:   $ac_cv_sizeof_uint128_t)
  510:     ac_cv_int_type_double_ucell="uint128_t"
  511:     ;;
  512: esac
  513: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  514: 
  515: if test "$ac_cv_int_type_double_cell" = none || \
  516:    test "$ac_cv_int_type_double_ucell" = none
  517: then
  518: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  519: 	AC_LIBOBJ(dblsub)
  520: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  521: else
  522: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  523: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  524: fi
  525: 
  526: AC_TYPE_OFF_T
  527: AC_CHECK_SIZEOF(off_t)
  528: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  529: ac_small_off_t=$?
  530: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  531: 
  532: ENGINE_FLAGS=
  533: AC_SUBST(ENGINE_FLAGS)
  534: 
  535: # Try if GCC understands -fno-gcse
  536: 
  537: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  538: CFLAGS_1="$CFLAGS"
  539: CFLAGS="$CFLAGS -fno-gcse"
  540: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  541: CFLAGS="$CFLAGS_1"
  542: AC_MSG_RESULT($ac_nogcse)
  543: 
  544: # Try if GCC understands -fno-strict-aliasing
  545: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  546: CFLAGS_1="$CFLAGS"
  547: CFLAGS="$CFLAGS -fno-strict-aliasing"
  548: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  549: CFLAGS="$CFLAGS_1"
  550: AC_MSG_RESULT($ac_nostrictaliasing)
  551: 
  552: # Try if GCC understands -fno-crossjumping
  553: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  554: CFLAGS_1="$CFLAGS"
  555: CFLAGS="$CFLAGS -fno-crossjumping"
  556: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  557: CFLAGS="$CFLAGS_1"
  558: AC_MSG_RESULT($ac_nocrossjumping)
  559: 
  560: # Try if GCC understands -fno-reorder-blocks
  561: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  562: CFLAGS_1="$CFLAGS"
  563: CFLAGS="$CFLAGS -fno-reorder-blocks"
  564: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  565: CFLAGS="$CFLAGS_1"
  566: AC_MSG_RESULT($ac_noreorder_blocks)
  567: 
  568: # Try if GCC understands __attribute__((unused))
  569: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  570: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  571: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  572: AC_MSG_RESULT($MAYBE_UNUSED)
  573: 
  574: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  575: AC_SUBST(asm_fs)
  576: 
  577: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  578: AC_SUBST(disasm_fs)
  579: 
  580: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  581: 
  582: case "$host_os" in
  583: 	*win32*)
  584: 		# !!!FIXME!!! problems with cygwin and ';' as path separator
  585: 		DIRSEP="\\\\"
  586: 		PATHSEP=";"
  587: 		#we want the builtins of command.com/cmd.exe and its
  588: 		# handling of .com files.
  589: 		#$COMSPEC contains the name of the Windows shell;
  590: 		# the ./ is there, because the bash does not recognize
  591: 		# absolute DOS filenames
  592: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  593: 		;;
  594: 	*darwin*)
  595: 		#Darwin uses some funny preprocessor by default; eliminate it:
  596: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  597: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  598: 		DIRSEP="/"
  599: 		PATHSEP=":"
  600: 		DEFAULTSYSTEMPREFIX=""
  601: 		;;
  602: 	*)
  603: 		DIRSEP="/"
  604: 		PATHSEP=":"
  605: 		DEFAULTSYSTEMPREFIX=""
  606: 		;;
  607: esac
  608: AC_SUBST(DIRSEP)
  609: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  610: AC_SUBST(PATHSEP)
  611: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  612: AC_SUBST(DEFAULTSYSTEMPREFIX)
  613: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  614: 
  615: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
  616: #This magic incantation  seems to be completely undocumented.
  617: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t],[true])
  618: 
  619: dnl Now a little support for DOS/DJGCC
  620: AC_SUBST(GFORTH_EXE)
  621: GFORTH_EXE=""
  622: AC_SUBST(GFORTHFAST_EXE)
  623: GFORTHFAST_EXE=""
  624: AC_SUBST(GFORTHITC_EXE)
  625: GFORTHITC_EXE=""
  626: AC_SUBST(GFORTHDITC_EXE)
  627: GFORTHDITC_EXE=""
  628: 
  629: AC_SUBST(FORTHSIZES)
  630: 
  631: dnl if test "$PEEPHOLE" = "yes"
  632: dnl then
  633: dnl    PEEPHOLEFLAG="true"
  634: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  635: dnl else
  636: dnl    PEEPHOLEFLAG="false"
  637: dnl fi
  638: PEEPHOLEFLAG="true"
  639: AC_SUBST(PEEPHOLEFLAG)
  640: 
  641: dnl copy commands for systems that don't have links
  642: AC_SUBST(LINK_KERNL)
  643: LINK_KERNL=""
  644: 
  645: #if test $host_os=dos
  646: #then
  647: #  echo Configuring for DOS!!!
  648: #  MAKE_EXE="coff2exe gforth"
  649: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  650: #fi
  651: 
  652: dnl the following macro produces a warning with autoconf-2.1
  653: AC_C_BIGENDIAN
  654: AC_SUBST(KERNEL)
  655: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  656: if test $ac_cv_c_bigendian = yes; then
  657:   bytesex=b
  658:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  659: else
  660:   bytesex=l
  661:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  662: fi
  663: 
  664: #check how to do asm(".skip 16")
  665: #echo "CFLAGS=$CFLAGS"
  666: #echo "ac_link=$ac_link"
  667: AC_MSG_CHECKING([if and how we can waste code space])
  668: if test -z "$skipcode"; then
  669:     skipcode=no
  670:     CFLAGS_1="$CFLAGS"
  671:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  672:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  673:     do
  674: 	AC_TRY_RUN(
  675: [int foo(int,int,int);
  676: main()
  677: {
  678:   exit(foo(0,0,0)!=16);
  679: }
  680: int foo(int x, int y, int z)
  681: {
  682:   static void *labels[]={&&label1, &&label2};
  683:   if (x) {
  684:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  685:   label1:
  686:     asm("$i"); /* or ".space 16" or somesuch */
  687:   label2: ;
  688:   }
  689:   {
  690:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  691:   return labels[1]-labels[0];
  692:   }
  693: }]
  694: 	,skipcode=$i; break
  695: 	,,)
  696:     done
  697:     CFLAGS=$CFLAGS_1
  698: fi
  699: AC_MSG_RESULT($skipcode)
  700: if test "$skipcode" = no
  701: then 
  702:     if test -z $no_dynamic_default; then
  703: 	no_dynamic_default=1
  704: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  705:     fi
  706:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  707: else
  708:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  709: fi
  710: 
  711: AC_MSG_CHECKING([if and how we can do comments in asm statements])
  712: #the point here is to get asm statements that look different to
  713: #gcc's "optimizer"
  714: if test -z "$asmcomment"; then
  715:     asmcomment=no
  716:     CFLAGS_1="$CFLAGS"
  717:     CFLAGS="$CFLAGS $ENGINE_FLAGS"
  718:     for i in '"# "' '"! "' '"; "'; do
  719: 	AC_TRY_COMPILE(,[asm($i"fluffystunk");],asmcomment=$i; break,)
  720:     done
  721:     CFLAGS=$CFLAGS_1
  722: fi
  723: AC_MSG_RESULT($asmcomment)
  724: if test "$asmcomment" != no
  725: then 
  726:     AC_DEFINE_UNQUOTED(ASMCOMMENT,$asmcomment,[assembler comment start string])
  727: fi
  728: 
  729: test "$no_dynamic_default" || no_dynamic_default=0
  730: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  731: 
  732: dnl Checks for programs.
  733: AC_PROG_LN_S
  734: AC_PROG_INSTALL
  735: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
  736: 
  737: dnl Checks for library functions
  738: dnl This check is just for making later checks link with libm.
  739: dnl using sin here is no good idea since it is built-into gcc and typechecked
  740: AC_CHECK_LIB(m,asin)
  741: AC_CHECK_LIB(dl,dlopen)
  742: dnl check for libffi 2.x
  743: AC_CHECK_LIB(ffi,ffi_call)
  744: if test $ac_cv_lib_ffi_ffi_call = yes
  745: then
  746: LIBFFIFLAG="true"
  747: FFCALLFLAG="false"
  748: OLDCALLFLAG="false"
  749: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
  750: else
  751: dnl check for ffcall libraries
  752: dnl unfortunately, these four calls are separated out into a library each.
  753: AC_CHECK_LIB(avcall,__builtin_avcall)
  754: AC_CHECK_LIB(callback,__vacall_r)
  755: AC_CHECK_LIB(vacall,vacall)
  756: AC_CHECK_LIB(trampoline,alloc_trampoline)
  757: LIBFFIFLAG="false"
  758: FFCALLFLAG="false"
  759: OLDCALLFLAG="true"
  760: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  761: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  762: fi
  763: AC_SUBST(LIBFFIFLAG)
  764: AC_SUBST(FFCALLFLAG)
  765: AC_SUBST(OLDCALLFLAG)
  766: if test "$host_os" != "nextstep3"
  767: then
  768: 	AC_FUNC_MEMCMP
  769: fi
  770: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  771: AC_FUNC_FSEEKO
  772: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage nanosleep)
  773: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  774: AC_DECL_SYS_SIGLIST
  775: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  776: AC_CHECK_FUNCS(expm1 log1p)
  777: AC_REPLACE_FUNCS(rint ecvt)
  778: dnl No check for select, because our replacement is no good under
  779: dnl anything but DOS
  780: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  781: AC_FUNC_FNMATCH
  782: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  783: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  784: AM_PATH_LISPDIR
  785: 
  786: kernel_fi=kernl${vwordsize}${bytesex}.fi
  787: include_fi=kernl${wordsize}${bytesex}${EC}.fi
  788: AC_SUBST(kernel_fi)
  789: AC_SUBST(include_fi)
  790: 
  791: #this breaks bindists
  792: #dnl replace srource directory by absolute value
  793: #if test $srcdir = "."; then srcdir=`pwd` 
  794: #fi
  795: 
  796: echo "version=$PACKAGE_VERSION"
  797: 
  798: AC_SUBST(machine)
  799: AC_CONFIG_FILES([
  800: Makefile
  801: Makedist
  802: gforthmi
  803: vmgen
  804: machpc.fs
  805: envos.fs
  806: engine/Makefile
  807: engine/libcc.h
  808: doc/version.texi
  809: build-ec ])
  810: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  811: chmod +x gforthmi
  812: chmod +x vmgen
  813: chmod +x build-ec
  814: test -d kernel||mkdir kernel
  815: $srcdir/mkinstalldirs include/gforth/$PACKAGE_VERSION
  816: ln -s ../../../engine/config.h ../../../engine/libcc.h include/gforth/$PACKAGE_VERSION]],[[PACKAGE_VERSION=$PACKAGE_VERSION]])
  817: AC_OUTPUT
  818: