1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004,2005,2006 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20060527],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="April 09, 2006"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(gcc-pr15242-workaround,
57: AC_HELP_STRING([--disable-gcc-pr15242-workaround],[Disables
58: dynamic code generation on some versions of gcc
59: (slowdown~2 on Athlon) and causes slower building
60: of gforth (but gforth speedups) on others.
61: (default enabled)]),
62: ,enable_gcc_pr15242_workaround=yes)
63: test "$enable_gcc_pr15242_workaround" = "no"||
64: AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
65: generation on gccs affected by PR15242])
66:
67: AC_ARG_ENABLE(force-cdiv,
68: AC_HELP_STRING([--enable-force-cdiv],
69: [ Use the native C division - symmetric - instead of
70: floored division (default disabled).]),
71: ,enable_force_cdiv=no)
72: test "$enable_force_cdiv" = "no"||
73: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
74:
75: AC_SUBST(PROFEXES)
76: AC_SUBST(PROFOBJS)
77: AC_ARG_ENABLE(prof,
78: AC_HELP_STRING([--enable-prof],
79: [ Build gforth-prof, which outputs frequently occuring
80: sequences of primitives.]),
81: ,enable_prof=no)
82: if test "$enable_prof" = "no"; then
83: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
84: fi
85:
86: AC_ARG_WITH(debug,
87: [ --with-debug specifies option -g to compile with debug info
88: --without-debug omits the -g switch and creates smaller images on
89: machines where "strip" has problems with gcc style
90: debugging informations.],
91: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
92:
93: dnl PEEPHOLE="yes"
94: dnl AC_ARG_WITH(peephole,
95: dnl [ --with-peephole Enable peephole optimization (default)
96: dnl --without-peephole disables peephole optimization. Creates smaller,
97: dnl but slower images.],
98: dnl PEEPHOLE="$withval")
99:
100: AC_ARG_ENABLE(ec,
101: AC_HELP_STRING([--enable-ec],
102: [ Build gforth for systems without OS.]),
103: ,enable_ec=no)
104: if test "$enable_ec" = "yes"; then
105: echo "defining standalone system"
106: AC_DEFINE(STANDALONE,,[Define if you want a Gforth without OS])
107: EC_MODE="true"
108: else
109: echo "defining hosted system"
110: EC_MODE="false"
111: fi
112:
113: #variables mentioned in INSTALL
114: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
115: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
116: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
117: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
118: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
119: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
120: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
121: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
122: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
123: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
124: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
125: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
126: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
127: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
128: AC_ARG_VAR(skipcode, [assembly code for skipping 16 bytes of code])
129:
130: #set up feature test macros, so the tests get them right:
131: # turn on all POSIX, SUSv3, and GNU features if available
132: AC_GNU_SOURCE
133: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
134:
135: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
136: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
137: dnl but not for _XOPEN_SOURCE)
138: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
139: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
140: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
141: # turn on large file support with 64-bit off_t where available
142: AC_SYS_LARGEFILE
143: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
144: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
145:
146: #currently we force direct threading this way. Eventually we should
147: #setup in the arch and engine files right
148:
149: AC_PROG_CC
150:
151: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
152:
153: AC_SUBST(CC)
154: AC_SUBST(DEBUGFLAG)
155: AC_SUBST(EC_MODE)
156:
157: AC_MSG_CHECKING(make type)
158: make_type=`make -v 2>&1|grep 'ake'|sed 's/ake .*/ake/'`
159:
160: GNUMAKE='#'
161: test "$make_type" = "GNU Make" && GNUMAKE=''
162:
163: AC_MSG_RESULT($make_type)
164:
165: AC_SUBST(GNUMAKE)
166:
167: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
168: OLDLDFLAGS=$LDFLAGS
169: LDFLAGS="$LDFLAGS -export-dynamic"
170: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
171: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
172: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
173: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
174: AC_MSG_RESULT($ac_export_dynamic)
175:
176: #terminology is a bit unusual here: The host is the system on which
177: #gforth will run; the system on which configure will run is the `build'
178: AC_CANONICAL_HOST
179: case "$host_cpu" in
180: arm*)
181: machine=arm
182: CFLAGS="$CFLAGS -fomit-frame-pointer"
183: if test -z $no_dynamic_default; then
184: no_dynamic_default=1
185: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
186: fi
187: ;;
188: hppa*)
189: machine=hppa
190: $srcdir/mkinstalldirs arch/hppa
191: AC_LIBOBJ(../arch/hppa/cache)
192: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
193: LDFLAGS="$LDFLAGS -Xlinker -N"
194: LIBS="$LIBS -L/lib/pa1.1/"
195: ;;
196: sparc*)
197: machine=sparc
198: ;;
199: i386)
200: machine=386
201: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
202: ;;
203: i486)
204: machine=386
205: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
206: ;;
207: i*86)
208: machine=386
209: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
210: CFLAGS_1="$CFLAGS"
211: CFLAGS="$CFLAGS -march=pentium"
212: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
213: ;;
214: x86_64)
215: machine=amd64
216: ;;
217: ia64*)
218: machine=ia64
219: AC_LIBOBJ(../arch/ia64/flush_icache_block)
220: test "$skipcode" || skipcode="nop.i 0"
221: #".skip 16" passes the test below,
222: # but gives an assembler error in engine
223: ;;
224: m68k)
225: machine=m68k
226: CFLAGS="$CFLAGS -fomit-frame-pointer"
227: if test "$host_os" = "nextstep3"
228: then
229: AC_LIBOBJ(termios)
230: fi
231: ;;
232: mips*)
233: machine=mips
234: #dynamic native code has the following problems on MIPS:
235: #
236: #1) J/JAL seems relocatable, but is are only
237: #relocatable within a 256MB-segment. While we try to
238: #get the linker to arrange this, there is no guarantee
239: #that this will succeed (and if the user uses a lot of
240: #memory, it is likely to fail).
241: #
242: #2) The way we generate dynamic native code may
243: #violate MIPS architectural restrictions (in
244: #particular, the delay slots of LW, MFLO, etc.)
245: #
246: #Therefore we disable dynamic native code by default:
247: if test -z $no_dynamic_default; then
248: no_dynamic_default=1
249: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
250: fi
251: ;;
252: alpha*)
253: machine=alpha
254: #full IEEE FP support for more uniformity across platforms:
255: CFLAGS="$CFLAGS -mieee"
256: ;;
257: power*|rs6000)
258: machine=power
259: $srcdir/mkinstalldirs arch/power
260: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
261: #long long is broken on (at least) gcc-2.95.* for PPC
262: test x$ac_cv_sizeof_long_long = x &&
263: ($CC -v 2>&1 |grep -q 'gcc version 2.95') &&
264: ac_cv_sizeof_long_long=0
265: ;;
266: *)
267: AC_MSG_WARN([Using a generic machine description])
268: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
269: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
270: machine=generic
271: #I-cache flushing would be needed for dynamic code generation
272: if test -z $no_dynamic_default; then
273: no_dynamic_default=1
274: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
275: fi
276: esac
277: AC_SUBST(host)
278:
279: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
280: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
281: [number of registers in the default stack cache state for gforth-fast and gforth-native])
282:
283: if test "${enable_force_ll+set}" = set; then
284: ac_includes_default="$ac_includes_default
285: #include \"arch/generic/128bit.h\""
286: fi
287:
288: dnl the following macro produces a warning with autoconf-2.1
289: AC_CHECK_SIZEOF(char *)
290: case "$ac_cv_sizeof_char_p" in
291: 2)
292: wordsize=16
293: ;;
294: 4)
295: wordsize=32
296: ;;
297: 8)
298: wordsize=64
299: ;;
300: esac
301:
302: AC_CHECK_SIZEOF(char)
303: AC_CHECK_SIZEOF(short)
304: AC_CHECK_SIZEOF(int)
305: AC_CHECK_SIZEOF(long)
306: AC_CHECK_SIZEOF(long long)
307: AC_CHECK_SIZEOF(intptr_t)
308: AC_CHECK_SIZEOF(int128_t)
309: AC_CHECK_SIZEOF(uint128_t)
310:
311: AC_MSG_CHECKING([for a C type for cells])
312: ac_cv_int_type_cell=none
313: case "$ac_cv_sizeof_char_p" in
314: $ac_cv_sizeof_int)
315: ac_cv_int_type_cell=int
316: ;;
317: $ac_cv_sizeof_short)
318: ac_cv_int_type_cell=short
319: ;;
320: $ac_cv_sizeof_char)
321: ac_cv_int_type_cell=char
322: ;;
323: $ac_cv_sizeof_long)
324: ac_cv_int_type_cell=long
325: ;;
326: $ac_cv_sizeof_long_long)
327: ac_cv_int_type_cell="long long"
328: ;;
329: $ac_cv_sizeof_intptr_t)
330: ac_cv_int_type_cell="intptr_t"
331: ;;
332: $ac_cv_sizeof_int128_t)
333: ac_cv_int_type_cell="int128_t"
334: ;;
335: esac
336: AC_MSG_RESULT($ac_cv_int_type_cell)
337: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
338:
339: AC_MSG_CHECKING([for a C type for wydes])
340: ac_cv_wyde_type_cell=none
341: case 2 in
342: $ac_cv_sizeof_int)
343: ac_cv_wyde_type_cell=int
344: ;;
345: $ac_cv_sizeof_short)
346: ac_cv_wyde_type_cell=short
347: ;;
348: $ac_cv_sizeof_char)
349: ac_cv_wyde_type_cell=char
350: ;;
351: $ac_cv_sizeof_long)
352: ac_cv_wyde_type_cell=long
353: ;;
354: $ac_cv_sizeof_long_long)
355: ac_cv_wyde_type_cell="long long"
356: ;;
357: $ac_cv_sizeof_intptr_t)
358: ac_cv_wyde_type_cell="intptr_t"
359: ;;
360: $ac_cv_sizeof_int128_t)
361: ac_cv_wyde_type_cell="int128_t"
362: ;;
363: esac
364: AC_MSG_RESULT($ac_cv_wyde_type_cell)
365: AC_DEFINE_UNQUOTED(WYDE_TYPE,$ac_cv_wyde_type_cell,[an integer type that is 2 bytes long])
366:
367: AC_MSG_CHECKING([for a C type for tetrabytes])
368: ac_cv_tetrabyte_type_cell=none
369: case 4 in
370: $ac_cv_sizeof_int)
371: ac_cv_tetrabyte_type_cell=int
372: ;;
373: $ac_cv_sizeof_short)
374: ac_cv_tetrabyte_type_cell=short
375: ;;
376: $ac_cv_sizeof_char)
377: ac_cv_tetrabyte_type_cell=char
378: ;;
379: $ac_cv_sizeof_long)
380: ac_cv_tetrabyte_type_cell=long
381: ;;
382: $ac_cv_sizeof_long_long)
383: ac_cv_tetrabyte_type_cell="long long"
384: ;;
385: $ac_cv_sizeof_intptr_t)
386: ac_cv_tetrabyte_type_cell="intptr_t"
387: ;;
388: $ac_cv_sizeof_int128_t)
389: ac_cv_tetrabyte_type_cell="int128_t"
390: ;;
391: esac
392: AC_MSG_RESULT($ac_cv_tetrabyte_type_cell)
393: AC_DEFINE_UNQUOTED(TETRABYTE_TYPE,$ac_cv_tetrabyte_type_cell,[an integer type that is 4 bytes long])
394:
395: AC_MSG_CHECKING([for a C type for double-cells])
396: ac_cv_int_type_double_cell=none
397: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
398: $ac_cv_sizeof_short)
399: ac_cv_int_type_double_cell=short
400: ;;
401: $ac_cv_sizeof_int)
402: ac_cv_int_type_double_cell=int
403: ;;
404: $ac_cv_sizeof_long)
405: ac_cv_int_type_double_cell=long
406: ;;
407: $ac_cv_sizeof_long_long)
408: ac_cv_int_type_double_cell="long long"
409: ;;
410: $ac_cv_sizeof_intptr_t)
411: ac_cv_int_type_double_cell="intptr_t"
412: ;;
413: $ac_cv_sizeof_int128_t)
414: ac_cv_int_type_double_cell="int128_t"
415: ;;
416: esac
417: AC_MSG_RESULT($ac_cv_int_type_double_cell)
418:
419: AC_MSG_CHECKING([for a C type for unsigned double-cells])
420: ac_cv_int_type_double_ucell=none
421: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
422: $ac_cv_sizeof_short)
423: ac_cv_int_type_double_ucell="unsigned short"
424: ;;
425: $ac_cv_sizeof_int)
426: ac_cv_int_type_double_ucell="unsigned int"
427: ;;
428: $ac_cv_sizeof_long)
429: ac_cv_int_type_double_ucell="unsigned long"
430: ;;
431: $ac_cv_sizeof_long_long)
432: ac_cv_int_type_double_ucell="unsigned long long"
433: ;;
434: $ac_cv_sizeof_intptr_t)
435: ac_cv_int_type_double_ucell="unsigned intptr_t"
436: ;;
437: $ac_cv_sizeof_uint128_t)
438: ac_cv_int_type_double_ucell="uint128_t"
439: ;;
440: esac
441: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
442:
443: if test "$ac_cv_int_type_double_cell" = none || \
444: test "$ac_cv_int_type_double_ucell" = none
445: then
446: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
447: AC_LIBOBJ(dblsub)
448: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
449: else
450: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
451: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
452: fi
453:
454: AC_TYPE_OFF_T
455: AC_CHECK_SIZEOF(off_t)
456: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
457: ac_small_off_t=$?
458: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
459:
460: ENGINE_FLAGS=
461: AC_SUBST(ENGINE_FLAGS)
462:
463: # Try if GCC understands -fno-gcse
464:
465: AC_MSG_CHECKING([if $CC understands -fno-gcse])
466: CFLAGS_1="$CFLAGS"
467: CFLAGS="$CFLAGS -fno-gcse"
468: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
469: CFLAGS="$CFLAGS_1"
470: AC_MSG_RESULT($ac_nogcse)
471:
472: # Try if GCC understands -fno-strict-aliasing
473: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
474: CFLAGS_1="$CFLAGS"
475: CFLAGS="$CFLAGS -fno-strict-aliasing"
476: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
477: CFLAGS="$CFLAGS_1"
478: AC_MSG_RESULT($ac_nostrictaliasing)
479:
480: # Try if GCC understands -fno-crossjumping
481: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
482: CFLAGS_1="$CFLAGS"
483: CFLAGS="$CFLAGS -fno-crossjumping"
484: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
485: CFLAGS="$CFLAGS_1"
486: AC_MSG_RESULT($ac_nocrossjumping)
487:
488: # Try if GCC understands -fno-reorder-blocks
489: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
490: CFLAGS_1="$CFLAGS"
491: CFLAGS="$CFLAGS -fno-reorder-blocks"
492: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
493: CFLAGS="$CFLAGS_1"
494: AC_MSG_RESULT($ac_noreorder_blocks)
495:
496: # Try if GCC understands __attribute__((unused))
497: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
498: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
499: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
500: AC_MSG_RESULT($MAYBE_UNUSED)
501:
502: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
503: AC_SUBST(asm_fs)
504:
505: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
506: AC_SUBST(disasm_fs)
507:
508: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
509:
510: case "$host_os" in
511: *win32*)
512: # !!!FIXME!!! problems with cygwin and ';' as path separator
513: DIRSEP="\\\\"
514: PATHSEP=";"
515: #we want the builtins of command.com/cmd.exe and its
516: # handling of .com files.
517: #$COMSPEC contains the name of the Windows shell;
518: # the ./ is there, because the bash does not recognize
519: # absolute DOS filenames
520: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
521: ;;
522: *darwin*)
523: #Darwin uses some funny preprocessor by default; eliminate it:
524: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
525: CFLAGS="$CFLAGS -no-cpp-precomp"
526: DIRSEP="/"
527: PATHSEP=":"
528: DEFAULTSYSTEMPREFIX=""
529: ;;
530: *)
531: DIRSEP="/"
532: PATHSEP=":"
533: DEFAULTSYSTEMPREFIX=""
534: ;;
535: esac
536: AC_SUBST(DIRSEP)
537: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
538: AC_SUBST(PATHSEP)
539: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
540: AC_SUBST(DEFAULTSYSTEMPREFIX)
541: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
542:
543: #work around SELinux brain damage (from Andrew Haley <12t8f3jakb74g2c@news.supernews.com>)
544: AC_CHECK_PROG([MASSAGE_EXE],[chcon],[chcon -t unconfined_execmem_exec_t $@])
545:
546: dnl Now a little support for DOS/DJGCC
547: AC_SUBST(GFORTH_EXE)
548: GFORTH_EXE=$MASSAGE_EXE
549: AC_SUBST(GFORTHFAST_EXE)
550: GFORTHFAST_EXE=$MASSAGE_EXE
551: AC_SUBST(GFORTHITC_EXE)
552: GFORTHITC_EXE=""
553: AC_SUBST(GFORTHDITC_EXE)
554: GFORTHDITC_EXE=""
555:
556: AC_SUBST(FORTHSIZES)
557:
558: dnl if test "$PEEPHOLE" = "yes"
559: dnl then
560: dnl PEEPHOLEFLAG="true"
561: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
562: dnl else
563: dnl PEEPHOLEFLAG="false"
564: dnl fi
565: PEEPHOLEFLAG="true"
566: AC_SUBST(PEEPHOLEFLAG)
567:
568: dnl copy commands for systems that don't have links
569: AC_SUBST(LINK_KERNL)
570: LINK_KERNL=""
571:
572: #if test $host_os=dos
573: #then
574: # echo Configuring for DOS!!!
575: # MAKE_EXE="coff2exe gforth"
576: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
577: #fi
578:
579: dnl the following macro produces a warning with autoconf-2.1
580: AC_C_BIGENDIAN
581: AC_SUBST(KERNEL)
582: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
583: if test $ac_cv_c_bigendian = yes; then
584: bytesex=b
585: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
586: else
587: bytesex=l
588: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
589: fi
590:
591: #check how to do asm(".skip 16")
592: #echo "CFLAGS=$CFLAGS"
593: #echo "ac_link=$ac_link"
594: AC_MSG_CHECKING([if and how we can waste code space])
595: if test -z "$skipcode"; then
596: skipcode=no
597: CFLAGS_1="$CFLAGS"
598: CFLAGS="$CFLAGS $ENGINE_FLAGS"
599: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
600: do
601: AC_TRY_RUN(
602: [int foo(int,int,int);
603: main()
604: {
605: exit(foo(0,0,0)!=16);
606: }
607: int foo(int x, int y, int z)
608: {
609: static void *labels[]={&&label1, &&label2};
610: if (x) {
611: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
612: label1:
613: asm("$i"); /* or ".space 16" or somesuch */
614: label2: ;
615: }
616: {
617: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
618: return labels[1]-labels[0];
619: }
620: }]
621: ,skipcode=$i; break
622: ,,)
623: done
624: CFLAGS=$CFLAGS_1
625: fi
626: AC_MSG_RESULT($skipcode)
627: if test "$skipcode" = no
628: then
629: if test -z $no_dynamic_default; then
630: no_dynamic_default=1
631: AC_MSG_WARN(Disabling default dynamic native code generation)
632: fi
633: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
634: else
635: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
636: fi
637:
638: test "$no_dynamic_default" || no_dynamic_default=0
639: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
640:
641: dnl Checks for programs.
642: AC_PROG_LN_S
643: AC_PROG_INSTALL
644: AC_CHECK_PROGS(TEXI2DVI,texi2dvi4a2ps texi2dvi)
645:
646: dnl Checks for library functions
647: dnl This check is just for making later checks link with libm.
648: dnl using sin here is no good idea since it is built-into gcc and typechecked
649: AC_CHECK_LIB(m,asin)
650: AC_CHECK_LIB(dl,dlopen)
651: dnl check for libffi 2.x
652: AC_CHECK_LIB(ffi,ffi_call)
653: if test $ac_cv_lib_ffi_ffi_call = yes
654: then
655: LIBFFIFLAG="true"
656: FFCALLFLAG="false"
657: OLDCALLFLAG="false"
658: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
659: else
660: dnl check for ffcall libraries
661: dnl unfortunately, these four calls are separated out into a library each.
662: AC_CHECK_LIB(avcall,__builtin_avcall)
663: AC_CHECK_LIB(callback,__vacall_r)
664: AC_CHECK_LIB(vacall,vacall)
665: AC_CHECK_LIB(trampoline,alloc_trampoline)
666: LIBFFIFLAG="false"
667: FFCALLFLAG="false"
668: OLDCALLFLAG="true"
669: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
670: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
671: fi
672: AC_SUBST(LIBFFIFLAG)
673: AC_SUBST(FFCALLFLAG)
674: AC_SUBST(OLDCALLFLAG)
675: if test "$host_os" != "nextstep3"
676: then
677: AC_FUNC_MEMCMP
678: fi
679: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
680: AC_FUNC_FSEEKO
681: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
682: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
683: AC_DECL_SYS_SIGLIST
684: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
685: AC_CHECK_FUNCS(expm1 log1p)
686: AC_REPLACE_FUNCS(rint ecvt)
687: dnl No check for select, because our replacement is no good under
688: dnl anything but DOS
689: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
690: AC_FUNC_FNMATCH
691: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
692: AC_CHECK_FUNCS(mmap sysconf getpagesize)
693: AM_PATH_LISPDIR
694:
695: kernel_fi=kernl${wordsize}${bytesex}.fi
696: AC_SUBST(kernel_fi)
697:
698: #this breaks bindists
699: #dnl replace srource directory by absolute value
700: #if test $srcdir = "."; then srcdir=`pwd`
701: #fi
702:
703: AC_SUBST(machine)
704: AC_CONFIG_FILES([
705: Makefile
706: Makedist
707: gforthmi
708: vmgen
709: machpc.fs
710: envos.fs
711: engine/Makefile
712: doc/version.texi
713: build-ec ])
714: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
715: chmod +x gforthmi
716: chmod +x vmgen
717: chmod +x build-ec
718: test -d kernel||mkdir kernel]],[[]])
719: AC_OUTPUT
720:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>