1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20030910],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="September 10, 2003"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: AC_HELP_STRING([--enable-force-reg],
38: [ Use explicit register declarations if they appear in
39: the machine.h file. This can cause a good speedup,
40: but also incorrect code with some gcc versions on
41: some processors (default disabled).]),
42: ,enable_force_reg=no)
43: test "$enable_force_reg" = "no"||
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)])
45:
46: AC_ARG_ENABLE(force-ll,
47: AC_HELP_STRING([--enable-force-ll],
48: [ Use explicit long long declarations if they appear in
49: the machine.h file. This can cause a good speedup,
50: but also incorrect code with some gcc versions on
51: some processors (default disabled).]),
52: ,enable_force_ll=no)
53: test "$enable_force_ll" = "no"||
54: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)])
55:
56: AC_ARG_ENABLE(gcc-pr15242-workaround,
57: AC_HELP_STRING([--disable-gcc-pr15242-workaround],[Disables
58: dynamic code generation on some versions of gcc
59: (slowdown~2 on Athlon) and causes slower building
60: of gforth (but gforth speedups) on others.
61: (default enabled)]),
62: ,enable_gcc_pr15242_workaround=yes)
63: test "$enable_gcc_pr15242_workaround" = "no"||
64: AC_DEFINE(GCC_PR15242_WORKAROUND,,[Define if you want to get dynamic code
65: generation on gccs affected by PR15242])
66:
67: AC_ARG_ENABLE(force-cdiv,
68: AC_HELP_STRING([--enable-force-cdiv],
69: [ Use the native C division - symmetric - instead of
70: floored division (default disabled).]),
71: ,enable_force_cdiv=no)
72: test "$enable_force_cdiv" = "no"||
73: AC_DEFINE(FORCE_CDIV,,[Define if you want to use explicit symmetric division for better performance])
74:
75: AC_SUBST(PROFEXES)
76: AC_SUBST(PROFOBJS)
77: AC_ARG_ENABLE(prof,
78: AC_HELP_STRING([--enable-prof],
79: [ Build gforth-prof, which outputs frequently occuring
80: sequences of primitives.]),
81: ,enable_prof=no)
82: if test "$enable_prof" = "no"; then
83: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o"
84: fi
85:
86: AC_ARG_WITH(debug,
87: [ --with-debug specifies option -g to compile with debug info
88: --without-debug omits the -g switch and creates smaller images on
89: machines where "strip" has problems with gcc style
90: debugging informations.],
91: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
92:
93: dnl PEEPHOLE="yes"
94: dnl AC_ARG_WITH(peephole,
95: dnl [ --with-peephole Enable peephole optimization (default)
96: dnl --without-peephole disables peephole optimization. Creates smaller,
97: dnl but slower images.],
98: dnl PEEPHOLE="$withval")
99:
100: #variables mentioned in INSTALL
101: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
102: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
103: AC_ARG_VAR(STACK_CACHE_DEFAULT_FAST, [number of registers in the default stack cache state for gforth-fast and gforth-native (default 1).])
104: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
105: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
106: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
107: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
108: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
109: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
110: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
111: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
112: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
113: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
114: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
115: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
116:
117: #set up feature test macros, so the tests get them right:
118: # turn on all POSIX, SUSv3, and GNU features if available
119: AC_GNU_SOURCE
120: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
121:
122: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
123: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
124: dnl but not for _XOPEN_SOURCE)
125: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
126: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
127: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
128: # turn on large file support with 64-bit off_t where available
129: AC_SYS_LARGEFILE
130: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
131: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
132:
133: #currently we force direct threading this way. Eventually we should
134: #setup in the arch and engine files right
135:
136: AC_PROG_CC
137:
138: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
139:
140: AC_SUBST(CC)
141: AC_SUBST(DEBUGFLAG)
142:
143: AC_MSG_CHECKING(make type)
144: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
145:
146: GNUMAKE='#'
147: test "$make_type" = "GNU Make" && GNUMAKE=''
148:
149: AC_MSG_RESULT($make_type)
150:
151: AC_SUBST(GNUMAKE)
152:
153: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
154: OLDLDFLAGS=$LDFLAGS
155: LDFLAGS="$LDFLAGS -export-dynamic"
156: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
157: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
158: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
159: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
160: AC_MSG_RESULT($ac_export_dynamic)
161:
162: #terminology is a bit unusual here: The host is the system on which
163: #gforth will run; the system on which configure will run is the `build'
164: AC_CANONICAL_HOST
165: case "$host_cpu" in
166: arm*)
167: machine=arm
168: CFLAGS="$CFLAGS -fomit-frame-pointer"
169: if test -z $no_dynamic_default; then
170: no_dynamic_default=1
171: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
172: fi
173: ;;
174: hppa*)
175: machine=hppa
176: $srcdir/mkinstalldirs arch/hppa
177: AC_LIBOBJ(../arch/hppa/cache)
178: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
179: LDFLAGS="$LDFLAGS -Xlinker -N"
180: LIBS="$LIBS -L/lib/pa1.1/"
181: ;;
182: sparc*)
183: machine=sparc
184: ;;
185: i386)
186: machine=386
187: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
188: ;;
189: i486)
190: machine=386
191: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
192: ;;
193: i*86)
194: machine=386
195: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
196: CFLAGS_1="$CFLAGS"
197: CFLAGS="$CFLAGS -march=pentium"
198: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
199: ;;
200: x86_64)
201: machine=amd64
202: ;;
203: ia64*)
204: machine=ia64
205: AC_LIBOBJ(../arch/ia64/flush_icache_block)
206: test "$skipcode" || skipcode="nop.i 0"
207: #".skip 16" passes the test below,
208: # but gives an assembler error in engine
209: ;;
210: m68k)
211: machine=m68k
212: CFLAGS="$CFLAGS -fomit-frame-pointer"
213: if test "$host_os" = "nextstep3"
214: then
215: AC_LIBOBJ(termios)
216: fi
217: ;;
218: mips*)
219: machine=mips
220: #dynamic native code has the following problems on MIPS:
221: #
222: #1) J/JAL seems relocatable, but is are only
223: #relocatable within a 256MB-segment. While we try to
224: #get the linker to arrange this, there is no guarantee
225: #that this will succeed (and if the user uses a lot of
226: #memory, it is likely to fail).
227: #
228: #2) The way we generate dynamic native code may
229: #violate MIPS architectural restrictions (in
230: #particular, the delay slots of LW, MFLO, etc.)
231: #
232: #Therefore we disable dynamic native code by default:
233: if test -z $no_dynamic_default; then
234: no_dynamic_default=1
235: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
236: fi
237: ;;
238: alpha*)
239: machine=alpha
240: #full IEEE FP support for more uniformity across platforms:
241: CFLAGS="$CFLAGS -mieee"
242: ;;
243: power*|rs6000)
244: machine=power
245: $srcdir/mkinstalldirs arch/power
246: AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
247: #long long is broken on (at least) gcc-2.95.* for PPC
248: test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
249: ;;
250: *)
251: AC_MSG_WARN([Using a generic machine description])
252: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
253: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
254: machine=generic
255: #I-cache flushing would be needed for dynamic code generation
256: if test -z $no_dynamic_default; then
257: no_dynamic_default=1
258: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
259: fi
260: esac
261: AC_SUBST(host)
262:
263: test x$STACK_CACHE_DEFAULT_FAST = x && STACK_CACHE_DEFAULT_FAST=1
264: AC_DEFINE_UNQUOTED(STACK_CACHE_DEFAULT_FAST, $STACK_CACHE_DEFAULT_FAST,
265: [number of registers in the default stack cache state for gforth-fast and gforth-native])
266:
267: if test "${enable_force_ll+set}" = set; then
268: ac_includes_default="$ac_includes_default
269: #include \"arch/generic/128bit.h\""
270: fi
271:
272: dnl the following macro produces a warning with autoconf-2.1
273: AC_CHECK_SIZEOF(char *)
274: case "$ac_cv_sizeof_char_p" in
275: 2)
276: wordsize=16
277: ;;
278: 4)
279: wordsize=32
280: ;;
281: 8)
282: wordsize=64
283: ;;
284: esac
285:
286: AC_CHECK_SIZEOF(char)
287: AC_CHECK_SIZEOF(short)
288: AC_CHECK_SIZEOF(int)
289: AC_CHECK_SIZEOF(long)
290: AC_CHECK_SIZEOF(long long)
291: AC_CHECK_SIZEOF(intptr_t)
292: AC_CHECK_SIZEOF(int128_t)
293: AC_CHECK_SIZEOF(uint128_t)
294:
295: AC_MSG_CHECKING([for a C type for cells])
296: ac_cv_int_type_cell=none
297: case "$ac_cv_sizeof_char_p" in
298: $ac_cv_sizeof_int)
299: ac_cv_int_type_cell=int
300: ;;
301: $ac_cv_sizeof_short)
302: ac_cv_int_type_cell=short
303: ;;
304: $ac_cv_sizeof_char)
305: ac_cv_int_type_cell=char
306: ;;
307: $ac_cv_sizeof_long)
308: ac_cv_int_type_cell=long
309: ;;
310: $ac_cv_sizeof_long_long)
311: ac_cv_int_type_cell="long long"
312: ;;
313: $ac_cv_sizeof_intptr_t)
314: ac_cv_int_type_cell="intptr_t"
315: ;;
316: $ac_cv_sizeof_int128_t)
317: ac_cv_int_type_cell="int128_t"
318: ;;
319: esac
320: AC_MSG_RESULT($ac_cv_int_type_cell)
321: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
322:
323: AC_MSG_CHECKING([for a C type for double-cells])
324: ac_cv_int_type_double_cell=none
325: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
326: $ac_cv_sizeof_short)
327: ac_cv_int_type_double_cell=short
328: ;;
329: $ac_cv_sizeof_int)
330: ac_cv_int_type_double_cell=int
331: ;;
332: $ac_cv_sizeof_long)
333: ac_cv_int_type_double_cell=long
334: ;;
335: $ac_cv_sizeof_long_long)
336: ac_cv_int_type_double_cell="long long"
337: ;;
338: $ac_cv_sizeof_intptr_t)
339: ac_cv_int_type_double_cell="intptr_t"
340: ;;
341: $ac_cv_sizeof_int128_t)
342: ac_cv_int_type_double_cell="int128_t"
343: ;;
344: esac
345: AC_MSG_RESULT($ac_cv_int_type_double_cell)
346:
347: AC_MSG_CHECKING([for a C type for unsigned double-cells])
348: ac_cv_int_type_double_ucell=none
349: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
350: $ac_cv_sizeof_short)
351: ac_cv_int_type_double_ucell="unsigned short"
352: ;;
353: $ac_cv_sizeof_int)
354: ac_cv_int_type_double_ucell="unsigned int"
355: ;;
356: $ac_cv_sizeof_long)
357: ac_cv_int_type_double_ucell="unsigned long"
358: ;;
359: $ac_cv_sizeof_long_long)
360: ac_cv_int_type_double_ucell="unsigned long long"
361: ;;
362: $ac_cv_sizeof_intptr_t)
363: ac_cv_int_type_double_ucell="unsigned intptr_t"
364: ;;
365: $ac_cv_sizeof_uint128_t)
366: ac_cv_int_type_double_ucell="uint128_t"
367: ;;
368: esac
369: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
370:
371: if test "$ac_cv_int_type_double_cell" = none || \
372: test "$ac_cv_int_type_double_ucell" = none
373: then
374: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
375: AC_LIBOBJ(dblsub)
376: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
377: else
378: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
379: AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
380: fi
381:
382: AC_TYPE_OFF_T
383: AC_CHECK_SIZEOF(off_t)
384: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
385: ac_small_off_t=$?
386: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
387:
388: ENGINE_FLAGS=
389: AC_SUBST(ENGINE_FLAGS)
390:
391: # Try if GCC understands -fno-gcse
392:
393: AC_MSG_CHECKING([if $CC understands -fno-gcse])
394: CFLAGS_1="$CFLAGS"
395: CFLAGS="$CFLAGS -fno-gcse"
396: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
397: CFLAGS="$CFLAGS_1"
398: AC_MSG_RESULT($ac_nogcse)
399:
400: # Try if GCC understands -fno-strict-aliasing
401: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
402: CFLAGS_1="$CFLAGS"
403: CFLAGS="$CFLAGS -fno-strict-aliasing"
404: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
405: CFLAGS="$CFLAGS_1"
406: AC_MSG_RESULT($ac_nostrictaliasing)
407:
408: # Try if GCC understands -fno-crossjumping
409: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
410: CFLAGS_1="$CFLAGS"
411: CFLAGS="$CFLAGS -fno-crossjumping"
412: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
413: CFLAGS="$CFLAGS_1"
414: AC_MSG_RESULT($ac_nocrossjumping)
415:
416: # Try if GCC understands -fno-reorder-blocks
417: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
418: CFLAGS_1="$CFLAGS"
419: CFLAGS="$CFLAGS -fno-reorder-blocks"
420: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
421: CFLAGS="$CFLAGS_1"
422: AC_MSG_RESULT($ac_noreorder_blocks)
423:
424: # Try if GCC understands __attribute__((unused))
425: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
426: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
427: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
428: AC_MSG_RESULT($MAYBE_UNUSED)
429:
430: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
431: AC_SUBST(asm_fs)
432:
433: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
434: AC_SUBST(disasm_fs)
435:
436: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
437:
438: case "$host_os" in
439: *win32|cygwin)
440: DIRSEP="\\\\"
441: PATHSEP=";"
442: #we want the builtins of command.com/cmd.exe and its
443: # handling of .com files.
444: #$COMSPEC contains the name of the Windows shell;
445: # the ./ is there, because the bash does not recognize
446: # absolute DOS filenames
447: DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
448: ;;
449: *darwin*)
450: #Darwin uses some funny preprocessor by default; eliminate it:
451: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
452: CFLAGS="$CFLAGS -no-cpp-precomp"
453: DIRSEP="/"
454: PATHSEP=":"
455: DEFAULTSYSTEMPREFIX=""
456: ;;
457: *)
458: DIRSEP="/"
459: PATHSEP=":"
460: DEFAULTSYSTEMPREFIX=""
461: ;;
462: esac
463: AC_SUBST(DIRSEP)
464: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
465: AC_SUBST(PATHSEP)
466: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
467: AC_SUBST(DEFAULTSYSTEMPREFIX)
468: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
469:
470: dnl Now a little support for DOS/DJGCC
471: AC_SUBST(GFORTH_EXE)
472: GFORTH_EXE=""
473: AC_SUBST(GFORTHFAST_EXE)
474: GFORTHFAST_EXE=""
475: AC_SUBST(GFORTHITC_EXE)
476: GFORTHITC_EXE=""
477: AC_SUBST(GFORTHDITC_EXE)
478: GFORTHDITC_EXE=""
479:
480: AC_SUBST(FORTHSIZES)
481:
482: dnl if test "$PEEPHOLE" = "yes"
483: dnl then
484: dnl PEEPHOLEFLAG="true"
485: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
486: dnl else
487: dnl PEEPHOLEFLAG="false"
488: dnl fi
489: PEEPHOLEFLAG="true"
490: AC_SUBST(PEEPHOLEFLAG)
491:
492: dnl copy commands for systems that don't have links
493: AC_SUBST(LINK_KERNL)
494: LINK_KERNL=""
495:
496: #if test $host_os=dos
497: #then
498: # echo Configuring for DOS!!!
499: # MAKE_EXE="coff2exe gforth"
500: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
501: #fi
502:
503: dnl the following macro produces a warning with autoconf-2.1
504: AC_C_BIGENDIAN
505: AC_SUBST(KERNEL)
506: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
507: if test $ac_cv_c_bigendian = yes; then
508: bytesex=b
509: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
510: else
511: bytesex=l
512: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
513: fi
514:
515: #check how to do asm(".skip 16")
516: echo "CFLAGS=$CFLAGS"
517: echo "ac_link=$ac_link"
518: AC_MSG_CHECKING([if and how we can waste code space])
519: if test -z "$skipcode"; then
520: skipcode=no
521: CFLAGS_1="$CFLAGS"
522: CFLAGS="$CFLAGS $ENGINE_FLAGS"
523: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
524: do
525: AC_TRY_RUN(
526: [int foo(int,int,int);
527: main()
528: {
529: exit(foo(0,0,0)!=16);
530: }
531: int foo(int x, int y, int z)
532: {
533: static void *labels[]={&&label1, &&label2};
534: if (x) {
535: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
536: label1:
537: asm("$i"); /* or ".space 16" or somesuch */
538: label2: ;
539: }
540: {
541: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
542: return labels[1]-labels[0];
543: }
544: }]
545: ,skipcode=$i; break
546: ,,)
547: done
548: CFLAGS=$CFLAGS_1
549: fi
550: AC_MSG_RESULT($skipcode)
551: if test "$skipcode" = no
552: then
553: if test -z $no_dynamic_default; then
554: no_dynamic_default=1
555: AC_MSG_WARN(Disabling default dynamic native code generation)
556: fi
557: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
558: else
559: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
560: fi
561:
562: test "$no_dynamic_default" || no_dynamic_default=0
563: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
564:
565: dnl Checks for programs.
566: AC_PROG_LN_S
567: AC_PROG_INSTALL
568:
569: dnl Checks for library functions
570: dnl This check is just for making later checks link with libm.
571: dnl using sin here is no good idea since it is built-into gcc and typechecked
572: AC_CHECK_LIB(m,asin)
573: AC_CHECK_LIB(dl,dlopen)
574: dnl check for libffi 2.x
575: AC_CHECK_LIB(ffi,ffi_call)
576: if test $ac_cv_lib_ffi_ffi_call = yes
577: then
578: LIBFFIFLAG="true"
579: FFCALLFLAG="false"
580: OLDCALLFLAG="false"
581: AC_DEFINE(HAS_LIBFFI,,[define this if you want to use the ffcall interface with libffi 2.0])
582: else
583: dnl check for ffcall libraries
584: dnl unfortunately, these four calls are separated out into a library each.
585: AC_CHECK_LIB(avcall,__builtin_avcall)
586: AC_CHECK_LIB(callback,__vacall_r)
587: AC_CHECK_LIB(vacall,vacall)
588: AC_CHECK_LIB(trampoline,alloc_trampoline)
589: LIBFFIFLAG="false"
590: FFCALLFLAG="false"
591: OLDCALLFLAG="true"
592: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
593: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
594: fi
595: AC_SUBST(LIBFFIFLAG)
596: AC_SUBST(FFCALLFLAG)
597: AC_SUBST(OLDCALLFLAG)
598: if test "$host_os" != "nextstep3"
599: then
600: AC_FUNC_MEMCMP
601: fi
602: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
603: AC_FUNC_FSEEKO
604: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
605: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
606: AC_DECL_SYS_SIGLIST
607: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
608: AC_CHECK_FUNCS(expm1 log1p)
609: AC_REPLACE_FUNCS(rint ecvt)
610: dnl No check for select, because our replacement is no good under
611: dnl anything but DOS
612: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
613: AC_FUNC_FNMATCH
614: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
615: AC_CHECK_FUNCS(mmap sysconf getpagesize)
616: AM_PATH_LISPDIR
617:
618: kernel_fi=kernl${wordsize}${bytesex}.fi
619: AC_SUBST(kernel_fi)
620:
621: #this breaks bindists
622: #dnl replace srource directory by absolute value
623: #if test $srcdir = "."; then srcdir=`pwd`
624: #fi
625:
626: AC_SUBST(machine)
627: AC_CONFIG_FILES([
628: Makefile
629: Makedist
630: gforthmi
631: vmgen
632: machpc.fs
633: engine/Makefile
634: doc/version.texi ])
635: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
636: chmod +x gforthmi
637: chmod +x vmgen
638: test -d kernel||mkdir kernel]],[[]])
639: AC_OUTPUT
640:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>