1: \ A less simple implementation of the blocks wordset.
2:
3: \ Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: \ A more efficient implementation would use mmap on OSs that
23: \ provide it and many buffers on OSs that do not provide mmap.
24:
25: \ Now, the replacement algorithm is "direct mapped"; change to LRU
26: \ if too slow. Using more buffers helps, too.
27:
28: \ I think I avoid the assumption 1 char = 1 here, but I have not tested this
29:
30: \ 1024 constant chars/block \ mandated by the standard
31:
32: require struct.fs
33:
34: struct
35: cell% field buffer-block \ the block number
36: cell% field buffer-fid \ the block's fid
37: cell% field buffer-dirty \ the block dirty flag
38: char% chars/block * field block-buffer \ the data
39: cell% 0 * field next-buffer
40: end-struct buffer-struct
41:
42: Variable block-buffers
43: Variable last-block
44:
45: $20 Value buffers
46:
47: User block-fid
48: User block-offset ( -- addr ) \ gforth
49: \G User variable containing the number of the first block (default
50: \G since 0.5.0: 0). Block files created with Gforth versions before
51: \G 0.5.0 have the offset 1. If you use these files you can: @code{1
52: \G offset !}; or add 1 to every block number used; or prepend 1024
53: \G characters to the file.
54: 0 block-offset ! \ store 1 here fore 0.4.0 compatibility
55:
56: ' block-offset alias offset \ !! eliminate this?
57:
58: : block-cold ( -- )
59: block-fid off last-block off
60: buffer-struct buffers * %alloc dup block-buffers ! ( addr )
61: buffer-struct %size buffers * erase ;
62:
63: ' block-cold INIT8 chained
64:
65: block-cold
66:
67: Defer flush-blocks ( -- ) \ gforth
68:
69: : open-blocks ( c-addr u -- ) \ gforth
70: \g Use the file, whose name is given by @i{c-addr u}, as the blocks file.
71: 2dup open-fpath-file 0<>
72: if
73: r/w bin create-file throw
74: else
75: rot close-file throw 2dup file-status throw bin open-file throw
76: >r 2drop r>
77: then
78: block-fid @ IF flush-blocks block-fid @ close-file throw THEN
79: block-fid ! ;
80:
81: : use ( "file" -- ) \ gforth
82: \g Use @i{file} as the blocks file.
83: name open-blocks ;
84:
85: \ the file is opened as binary file, since it either will contain text
86: \ without newlines or binary data
87: : get-block-fid ( -- wfileid ) \ gforth
88: \G Return the file-id of the current blocks file. If no blocks
89: \G file has been opened, use @file{blocks.fb} as the default
90: \G blocks file.
91: block-fid @ 0=
92: if
93: s" blocks.fb" open-blocks
94: then
95: block-fid @ ;
96:
97: : block-position ( u -- ) \ block
98: \G Position the block file to the start of block @i{u}.
99: offset @ - chars/block chars um* get-block-fid reposition-file throw ;
100:
101: : update ( -- ) \ block
102: \G Mark the state of the current block buffer as assigned-dirty.
103: last-block @ ?dup IF buffer-dirty on THEN ;
104:
105: : save-buffer ( buffer -- ) \ gforth
106: >r
107: r@ buffer-dirty @ r@ buffer-block @ 0<> and
108: if
109: r@ buffer-block @ block-position
110: r@ block-buffer chars/block r@ buffer-fid @ write-file throw
111: buffer-fid @ flush-file throw
112: r@ buffer-dirty off
113: endif
114: rdrop ;
115:
116: : empty-buffer ( buffer -- ) \ gforth
117: buffer-block off ;
118:
119: : save-buffers ( -- ) \ block
120: \G Transfer the contents of each @code{update}d block buffer to
121: \G mass storage, then mark all block buffers as assigned-clean.
122: block-buffers @
123: buffers 0 ?DO dup save-buffer next-buffer LOOP drop ;
124:
125: : empty-buffers ( -- ) \ block-ext
126: \G Mark all block buffers as unassigned; if any had been marked as
127: \G assigned-dirty (by @code{update}), the changes to those blocks
128: \G will be lost.
129: block-buffers @
130: buffers 0 ?DO dup empty-buffer next-buffer LOOP drop ;
131:
132: : flush ( -- ) \ block
133: \G Perform the functions of @code{save-buffers} then
134: \G @code{empty-buffers}.
135: save-buffers
136: empty-buffers ;
137:
138: ' flush IS flush-blocks
139:
140: : get-buffer ( u -- a-addr ) \ gforth
141: 0 buffers um/mod drop buffer-struct %size * block-buffers @ + ;
142:
143: : block ( u -- a-addr ) \ gforthman- block
144: \G If a block buffer is assigned for block @i{u}, return its
145: \G start address, @i{a-addr}. Otherwise, assign a block buffer
146: \G for block @i{u} (if the assigned block buffer has been
147: \G @code{update}d, transfer the contents to mass storage), read
148: \G the block into the block buffer and return its start address,
149: \G @i{a-addr}.
150: dup offset @ u< -35 and throw
151: dup get-buffer >r
152: dup r@ buffer-block @ <>
153: r@ buffer-fid @ block-fid @ <> or
154: if
155: r@ save-buffer
156: dup block-position
157: r@ block-buffer chars/block get-block-fid read-file throw
158: \ clear the rest of the buffer if the file is too short
159: r@ block-buffer over chars + chars/block rot chars - blank
160: r@ buffer-block !
161: get-block-fid r@ buffer-fid !
162: else
163: drop
164: then
165: r> dup last-block ! block-buffer ;
166:
167: : buffer ( u -- a-addr ) \ block
168: \G If a block buffer is assigned for block @i{u}, return its
169: \G start address, @i{a-addr}. Otherwise, assign a block buffer
170: \G for block @i{u} (if the assigned block buffer has been
171: \G @code{update}d, transfer the contents to mass storage) and
172: \G return its start address, @i{a-addr}. The subtle difference
173: \G between @code{buffer} and @code{block} mean that you should
174: \G only use @code{buffer} if you don't care about the previous
175: \G contents of block @i{u}. In Gforth, this simply calls
176: \G @code{block}.
177: \ reading in the block is unnecessary, but simpler
178: block ;
179:
180: User scr ( -- a-addr ) \ block-ext s-c-r
181: \G @code{User} variable -- @i{a-addr} is the address of a cell containing
182: \G the block number of the block most recently processed by
183: \G @code{list}.
184: 0 scr !
185:
186: \ nac31Mar1999 moved "scr @" to list to make the stack comment correct
187: : updated? ( n -- f ) \ gforth
188: \G Return true if @code{updated} has been used to mark block @i{n}
189: \G as assigned-dirty.
190: buffer
191: [ 0 buffer-dirty 0 block-buffer - ] Literal + @ ;
192:
193: : list ( u -- ) \ block-ext
194: \G Display block @i{u}. In Gforth, the block is displayed as 16
195: \G numbered lines, each of 64 characters.
196: \ calling block again and again looks inefficient but is necessary
197: \ in a multitasking environment
198: dup scr !
199: ." Screen " u.
200: scr @ updated? 0= IF ." not " THEN ." modified " cr
201: 16 0
202: ?do
203: i 2 .r space scr @ block i 64 * chars + 64 type cr
204: loop ;
205:
206: [IFDEF] current-input
207: :noname 2 <> -12 and throw >in ! blk ! ;
208: \ restore-input
209: :noname blk @ >in @ 2 ; \ save-input
210: :noname 2 ; \ source-id "*a block*"
211: :noname 1 blk +! 1 loadline +! true ; \ refill
212: :noname blk @ block chars/block ; \ source
213:
214: Create block-input A, A, A, A, A,
215:
216: : load ( i*x n -- j*x ) \ block
217: \G Save the current input source specification. Store @i{n} in
218: \G @code{BLK}, set @code{>IN} to 0 and interpret. When the parse
219: \G area is exhausted, restore the input source specification.
220: block-input 0 new-tib dup loadline ! blk ! 2 loadfilename# !
221: ['] interpret catch pop-file throw ;
222: [ELSE]
223: : (source) ( -- c-addr u )
224: blk @ ?dup
225: IF block chars/block
226: ELSE tib #tib @
227: THEN ;
228:
229: ' (source) IS source ( -- c-addr u ) \ core
230: \G @i{c-addr} is the address of the input buffer and @i{u} is the
231: \G number of characters in it.
232:
233: : load ( i*x n -- j*x ) \ block
234: \G Save the current input source specification. Store @i{n} in
235: \G @code{BLK}, set @code{>IN} to 0 and interpret. When the parse
236: \G area is exhausted, restore the input source specification.
237: loadfilename# @ >r
238: 2 loadfilename# ! \ "*a block*"
239: push-file
240: dup loadline ! blk ! >in off ['] interpret catch
241: pop-file
242: r> loadfilename# !
243: throw ;
244: [THEN]
245:
246: : thru ( i*x n1 n2 -- j*x ) \ block-ext
247: \G @code{load} the blocks @i{n1} through @i{n2} in sequence.
248: 1+ swap ?DO I load LOOP ;
249:
250: : +load ( i*x n -- j*x ) \ gforth
251: \G Used within a block to load the block specified as the
252: \G current block + @i{n}.
253: blk @ + load ;
254:
255: : +thru ( i*x n1 n2 -- j*x ) \ gforth
256: \G Used within a block to load the range of blocks specified as the
257: \G current block + @i{n1} thru the current block + @i{n2}.
258: 1+ swap ?DO I +load LOOP ;
259:
260: : --> ( -- ) \ gforthman- gforth chain
261: \G If this symbol is encountered whilst loading block @i{n},
262: \G discard the remainder of the block and load block @i{n+1}. Used
263: \G for chaining multiple blocks together as a single loadable
264: \G unit. Not recommended, because it destroys the independence of
265: \G loading. Use @code{thru} (which is standard) or @code{+thru}
266: \G instead.
267: refill drop ; immediate
268:
269: : block-included ( a-addr u -- ) \ gforth
270: \G Use within a block that is to be processed by @code{load}. Save
271: \G the current blocks file specification, open the blocks file
272: \G specified by @i{a-addr u} and @code{load} block 1 from that
273: \G file (which may in turn chain or load other blocks). Finally,
274: \G close the blocks file and restore the original blocks file.
275: block-fid @ >r block-fid off open-blocks
276: 1 load block-fid @ close-file throw flush
277: r> block-fid ! ;
278:
279: \ thrown out because it may provide unpleasant surprises - anton
280: \ : include ( "name" -- )
281: \ name 2dup dup 3 - /string s" .fb" compare
282: \ 0= IF block-included ELSE included THEN ;
283:
284: get-current environment-wordlist set-current
285: true constant block
286: true constant block-ext
287: set-current
288:
289: : bye ( -- ) \ tools-ext
290: \G Return control to the host operating system (if any).
291: ['] flush catch drop bye ;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>