1: \ assertions
2:
3: \ Copyright (C) 1995,1996,1997 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20:
21: require source.fs
22:
23: variable assert-level ( -- a-addr ) \ gforth
24: \G all assertions above this level are turned off
25: 1 assert-level !
26:
27: : assertn ( n -- ) \ gforth assert-n
28: \ this is internal (it is not immediate)
29: assert-level @ >
30: if
31: POSTPONE (
32: then ;
33:
34: : assert0( ( -- ) \ gforth assert-zero
35: \G important assertions that should always be turned on
36: 0 assertn ; immediate
37: : assert1( ( -- ) \ gforth assert-one
38: \G normal assertions; turned on by default
39: 1 assertn ; immediate
40: : assert2( ( -- ) \ gforth assert-two
41: \G debugging assertions
42: 2 assertn ; immediate
43: : assert3( ( -- ) \ gforth assert-three
44: \G slow assertions that you may not want to turn on in normal debugging;
45: \G you would turn them on mainly for thorough checking
46: 3 assertn ; immediate
47: : assert( ( -- ) \ gforth
48: \G equivalent to assert1(
49: POSTPONE assert1( ; immediate
50:
51: : (endassert) ( flag -- ) \ gforth-internal
52: \ inline argument sourcepos
53: if
54: r> sourcepos %size + >r EXIT
55: else
56: r> print-sourcepos ." : failed assertion"
57: true abort" assertion failed" \ !! or use a new throw code?
58: then ;
59:
60: : ) ( -- ) \ gforth close-paren
61: \G end an assertion
62: POSTPONE (endassert) sourcepos, ; immediate
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>