[gforth] / gforth / mini-oof.fs

gforth: gforth/mini-oof.fs

File: [gforth] / gforth / mini-oof.fs (download)
Revision: 1.7, Wed Aug 23 21:03:51 2000 UTC (12 years, 9 months ago) by anton
Branch: MAIN
CVS Tags: v0-7-0, v0-5-0, v0-6-2, v0-6-0, v0-6-1
Changes since 1.6: +4 -4 lines

Documentation changes
renamed general push-order to >order, objects push-order to class>order,
        drop-order to class-previous

\ Mini-OOF                                                 12apr98py
: method ( m v "name" -- m' v ) Create  over , swap cell+ swap
  DOES> ( ... o -- ... ) @ over @ + @ execute ;
: var ( m v size "name" -- m v' ) Create  over , +
  DOES> ( o -- addr ) @ + ;
: class ( class -- class methods vars ) dup 2@ ;
: end-class  ( class methods vars "name" -- )
  Create  here >r , dup , 2 cells ?DO ['] noop , 1 cells +LOOP
  cell+ dup cell+ r> rot @ 2 cells /string move ;
: defines ( xt class "name" -- ) ' >body @ + ! ;
: new ( class -- o )  here over @ allot swap over ! ;
: :: ( class "name" -- ) ' >body @ + @ compile, ;
Create object  1 cells , 2 cells ,

CVS Admin

gforth: gforth/mini-oof.fs

ViewCVS and CVS Help