File:  [gforth] / gforth / wf.fs
Revision 1.35: download - view: text, annotated - select for diffs
Sun May 1 19:10:52 2005 UTC (18 years, 10 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Classes for headers

    1: \ wiki forth
    2: 
    3: \ Copyright (C) 2003,2004 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: require string.fs
   22: 
   23: \ basic stuff
   24: 
   25: : -scan ( addr u char -- addr' u' )
   26:   >r  BEGIN  dup  WHILE  1- 2dup + c@ r@ =  UNTIL  THEN
   27:   rdrop ;
   28: : -$split ( addr u char -- addr1 u1 addr2 u2 )
   29:   >r 2dup r@ -scan 2dup + c@ r> = negate over + >r
   30:   2swap r> /string ;
   31: : parse" ( -- addr u ) '" parse 2drop '" parse ;
   32: : .' '' parse postpone SLiteral postpone type ; immediate
   33: : s' '' parse postpone SLiteral ; immediate
   34: 
   35: \ character recoding
   36: 
   37: [IFDEF] maxascii $100 to maxascii 8-bit-io [THEN]
   38: \ UTF-8 IO fails with .type:
   39: 
   40: : .type ( addr u -- )
   41:     bounds ?DO  I c@
   42: 	case
   43: 	    '& of  ." &"  endof
   44: 	    '< of  ." &lt;"   endof
   45: 	    '¤ of  ." &euro;" endof
   46: 	    dup emit
   47: 	endcase
   48:     LOOP ;
   49: 
   50: \ tag handling
   51: 
   52: Variable indentlevel
   53: Variable tag-option
   54: Variable tag-class
   55: Variable default-class
   56: s" " tag-option $!
   57: s" " tag-class $!
   58: s" " default-class $!
   59: 
   60: : tag ( addr u -- ) '< emit type
   61:     tag-class $@len IF  .\"  class=\"" tag-class $@ type '" emit  THEN
   62:     tag-option $@ type
   63:     '> emit
   64:     s" " tag-option $! default-class $@ tag-class $! ;
   65: : tag/ ( addr u -- )  s"  /" tag-option $+! tag ;
   66: : /tag ( addr u -- ) '< emit '/ emit type '> emit ;
   67: : tagged ( addr1 u1 addr2 u2 -- )  2dup 2>r tag .type 2r> /tag ;
   68: 
   69: : opt ( addr u opt u -- )  s"  " tag-option $+!
   70:     tag-option $+! s' ="' tag-option $+! tag-option $+!
   71:     s' "' tag-option $+! ;
   72: : n>string ( n -- addr u )  0 <# #S #> ;
   73: : xy>string ( x y -- )  swap 0 <# #S 'x hold 2drop 0 #S 's hold #> ;
   74: : opt# ( n opt u -- )  rot n>string 2swap opt ;
   75: : href= ( addr u -- )  s" href" opt ;
   76: : id= ( addr u -- )  s" id" opt ;
   77: : src=  ( addr u -- )  s" src" opt ;
   78: : alt=  ( addr u -- )  s" alt" opt ;
   79: : width=  ( n -- )  s" width" opt# ;
   80: : height=  ( n -- )  s" height" opt# ;
   81: : align= ( addr u -- ) s" align" opt ;
   82: : class= ( addr u -- )
   83:     tag-class $@len IF  s"  " tag-class $+!  THEN
   84:     tag-class $+! ;
   85: : dclass= ( addr u -- )  2dup class=
   86:     default-class $! ;
   87: : indent= ( -- )
   88:     indentlevel @ 0 <# #S 'p hold #> class= ;
   89: : mailto: ( addr u -- ) s'  href="mailto:' tag-option $+!
   90:     tag-option $+! s' "' tag-option $+! ;
   91: 
   92: \ environment handling
   93: 
   94: Variable end-sec
   95: Variable oldenv
   96: Variable envs 30 0 [DO] 0 , [LOOP]
   97: 
   98: : env$ ( -- addr ) envs dup @ 1+ cells + ;
   99: : env ( addr u -- ) env$ $! ;
  100: : env? ( -- ) envs @ oldenv @ over oldenv !
  101:     2dup > IF  env$ $@ tag  THEN
  102:     2dup < IF  env$ cell+ $@ /tag  env$ cell+ $off  THEN
  103:     2drop ;
  104: : +env  1 envs +! ;
  105: : -env end-sec @ envs @ 1 > or  IF  -1 envs +! env?  THEN ;
  106: : -envs envs @ 0 ?DO  -env cr  LOOP ;
  107: : -tenvs envs @ 1 ?DO  -env cr  LOOP ;
  108: : >env ( addr u -- ) +env env env? ;
  109: 
  110: \ alignment
  111: 
  112: Variable table-format
  113: Variable table#
  114: Create table-starts &10 0 [DO] 0 c, 0 c, [LOOP]
  115: Variable taligned
  116: 
  117: : >align ( c -- )
  118:     CASE
  119: 	'l OF  s" left"      class=  ENDOF
  120: 	'r OF  s" right"     class=  ENDOF
  121: 	'c OF  s" center"    class=  ENDOF
  122: 	'< OF  s" left"      class=  ENDOF
  123: 	'> OF  s" right"     class=  ENDOF
  124: 	'= OF  s" center"    class=  ENDOF
  125: 	'~ OF  s" middle"    class=  ENDOF
  126:     ENDCASE ;
  127: 
  128: : >talign ( c -- )
  129:     CASE
  130: 	'l OF  s" left"   align=  ENDOF
  131: 	'r OF  s" right"  align=  ENDOF
  132: 	'c OF  s" center" align=  ENDOF
  133: 	'< OF  s" left"   align=  ENDOF
  134: 	'> OF  s" right"  align=  ENDOF
  135: 	'= OF  s" center" align=  ENDOF
  136:     ENDCASE  taligned on ;
  137: 
  138: : >border ( c -- )
  139:     case
  140: 	'- of  s" border0" class= endof
  141: 	'+ of  s" border1" class= endof
  142:     endcase ;
  143: 
  144: \ image handling
  145: 
  146: wordlist Constant img-sizes
  147: 
  148: Create imgbuf $20 allot
  149: 
  150: Create pngsig $89 c, $50 c, $4E c, $47 c, $0D c, $0A c, $1A c, $0A c,
  151: Create jfif   $FF c, $D8 c, $FF c, $E0 c, $00 c, $10 c, $4A c, $46 c,
  152:               $49 c, $46 c,
  153: 
  154: : b@ ( addr -- x )   0 swap 4 bounds ?DO  8 lshift I c@ +  LOOP ;
  155: : bw@ ( addr -- x )  0 swap 2 bounds ?DO  8 lshift I c@ +  LOOP ;
  156: 
  157: : gif? ( -- flag )
  158:     s" GIF89a" imgbuf over str=
  159:     s" GIF87a" imgbuf over str= or ;
  160: : gif-size ( -- w h )
  161:     imgbuf 8 + c@ imgbuf 9 + c@ 8 lshift +
  162:     imgbuf 6 + c@ imgbuf 7 + c@ 8 lshift + ;
  163: 
  164: : png? ( -- flag )
  165:     pngsig 8 imgbuf over str= ;
  166: : png-size ( -- w h )
  167:     imgbuf $14 + b@ imgbuf $10 + b@ ;
  168: 
  169: : jpg? ( -- flag )
  170:     jfif 10 imgbuf over str= ;
  171: : jpg-size ( fd -- w h )  >r
  172:     2.  BEGIN
  173: 	2dup r@ reposition-file throw
  174: 	imgbuf $10 r@ read-file throw 0<>
  175: 	imgbuf bw@ $FFC0 $FFD0 within 0= and  WHILE
  176: 	imgbuf 2 + bw@ 2 + 0 d+  REPEAT
  177:     2drop imgbuf 5 + bw@ imgbuf 7 + bw@  rdrop ;
  178: 
  179: : img-size ( fd -- w h )  >r
  180:     gif? IF  gif-size  rdrop EXIT  THEN
  181:     jpg? IF  r> jpg-size  EXIT  THEN
  182:     png? IF  png-size  rdrop EXIT  THEN
  183:     0 0 rdrop ;
  184: 
  185: 3 set-precision
  186: 
  187: : f.size  ( r -- )
  188:   f$ dup >r 0<=
  189:   IF    '0 emit
  190:   ELSE  scratch r@ min type  r@ precision - zeros  THEN
  191:   r@ negate zeros
  192:   scratch r> 0 max /string 0 max -zeros
  193:   dup IF  '. emit  THEN  type ;
  194: 
  195: : size-does> ( -- )  DOES> ( -- )
  196:     ." img." dup body> >name .name
  197:     2@ ." { width: "
  198:     s>d d>f 13.8e f/ f.size ." em; height: "
  199:     s>d d>f 13.8e f/ f.size ." em; }" cr ;
  200: 
  201: : size-css ( file< > -- )
  202:     outfile-id >r
  203:     bl sword r/w create-file throw to outfile-id
  204:     img-sizes wordlist-id
  205:     BEGIN  @ dup  WHILE
  206: 	    dup name>int execute
  207:     REPEAT  drop
  208:     outfile-id close-file throw
  209:     r> to outfile-id
  210:     dup 0< IF  throw  ELSE  drop  THEN ;
  211: 
  212: : size-class ( x y addr u -- x y )
  213:     2dup class=
  214:     2dup img-sizes search-wordlist  IF  drop 2drop
  215:     ELSE
  216: 	get-current >r img-sizes set-current
  217: 	nextname Create 2dup , , size-does>
  218: 	r> set-current
  219:     THEN ;
  220: 
  221: : .img-size ( addr u -- )
  222:     r/o open-file IF  drop  EXIT  THEN  >r
  223:     imgbuf $20 r@ read-file throw drop
  224:     r@ img-size
  225:     r> close-file throw
  226:     2dup or IF  2dup xy>string size-class  THEN  
  227:     ?dup IF  width=   THEN
  228:     ?dup IF  height=  THEN
  229: ;
  230: 
  231: \ link creation
  232: 
  233: Variable link
  234: Variable link-sig
  235: Variable link-suffix
  236: Variable iconpath
  237: Variable icon-prefix
  238: Variable icon-tmp
  239: 
  240: Variable do-size
  241: Variable do-icon
  242: Variable do-expand
  243: 
  244: Defer parse-line
  245: 
  246: : .img ( addr u -- )
  247:     dup >r '@ -$split  dup r> = IF  2swap 2drop
  248:     ELSE  2swap icon-tmp $! icon-prefix $@ icon-tmp $+! icon-tmp $+!
  249: 	icon-tmp $@  THEN
  250:     dup >r '| -$split  dup r> = IF  2swap  THEN 
  251:     dup IF  2swap alt=  ELSE  2drop  THEN
  252:     tag-class $@len >r over c@ >align  tag-class $@len r> = 1+ /string
  253:     tag-class $@len >r over c@ >border tag-class $@len r> = 1+ /string
  254:     2dup .img-size src= s" img" tag/ ;
  255: : >img ( -- )   '{ parse type '} parse .img ;
  256: 
  257: : alt-suffix ( -- )
  258:     link-suffix $@len 2 - link-suffix $!len
  259:     s" [" link-suffix 0 $ins
  260:     s" ]" link-suffix $+!
  261:     link-suffix $@ alt= ;
  262: 
  263: : get-icon ( addr u -- )  iconpath @ IF  2drop  EXIT  THEN
  264:     link-suffix $! s" .*" link-suffix $+!
  265:     icon-prefix $@ open-dir throw >r
  266:     BEGIN
  267: 	pad $100 r@ read-dir throw  WHILE
  268: 	pad swap 2dup link-suffix $@ filename-match
  269: 	IF  icon-prefix $@ iconpath $! s" /" iconpath $+! iconpath $+!
  270: 	    iconpath $@ 2dup .img-size src= '- >border
  271: 	    alt-suffix  s" img" tag/ true
  272: 	ELSE  2drop  false  THEN
  273:     UNTIL  ELSE  drop  THEN
  274:     r> close-dir throw ;
  275: 
  276: : link-icon? ( -- )  do-icon @ 0= ?EXIT
  277:     iconpath @  IF  iconpath $off  THEN
  278:     link $@ + 1- c@ '/ = IF  s" index.html"  ELSE  link $@  THEN
  279:     '# $split 2drop
  280:     BEGIN  '. $split 2swap 2drop dup  WHILE
  281: 	2dup get-icon  REPEAT  2drop ;
  282: 
  283: : link-size? ( -- )  do-size @ 0= ?EXIT
  284:     link $@ r/o open-file IF  drop  EXIT  THEN >r
  285:     r@ file-size throw $400 um/mod nip
  286:     dup $800 < IF  ."  (" 0 u.r ." k)"
  287: 	ELSE  $400 / ."  (" 0 u.r ." M)" THEN
  288:     r> close-file throw ;
  289: 
  290: : link-sig? ( -- )
  291:     link $@ link-sig $! s" .sig" link-sig $+!
  292:     link-sig $@ r/o open-file IF  drop  EXIT  THEN
  293:     close-file throw
  294:     ."  (" link-sig $@ href= s" a" tag
  295:     s" |-@/sig.gif" .img ." sig" s" /a" tag ." )" ;
  296: 
  297: : link-warn? ( -- ) \ local links only
  298:     link $@ ': scan nip ?EXIT
  299:     link $@ '# $split 2drop dup IF
  300: 	r/o open-file nip IF
  301: 	    s" Dead Link '" stderr write-file throw
  302: 	    link $@ stderr write-file throw
  303: 	    s\" ' !!!\n" stderr write-file throw
  304: 	THEN
  305:     ELSE  2drop  THEN ;
  306: 
  307: : link-options ( addr u -- addr' u' )
  308:     do-size off  do-icon on  do-expand off
  309:     over c@ '% = over 0> and IF  do-size on   1 /string  THEN
  310:     over c@ '\ = over 0> and IF  do-icon off  1 /string  THEN
  311:     over c@ '* = over 0> and IF  do-expand on 1 /string  THEN ;
  312: 
  313: s" Gforth" environment? [IF] s" 0.5.0" str= [IF] 
  314: : parse-string ( c-addr u -- ) \ core,block
  315:     s" *evaluated string*" loadfilename>r
  316:     push-file #tib ! >tib !
  317:     >in off blk off loadfile off -1 loadline !
  318:     ['] parse-line catch
  319:     pop-file r>loadfilename throw ;
  320: [ELSE]
  321: : parse-string ( addr u -- )
  322:     evaluate-input cell new-tib #tib ! tib !
  323:     ['] parse-line catch pop-file throw ;
  324: [THEN] [THEN]
  325: 
  326: Variable expand-link
  327: Variable expand-prefix
  328: Variable expand-postfix
  329: 
  330: : ?expand ( addr u -- )  expand-link $!
  331:     do-expand @ IF
  332: 	expand-prefix $@ expand-link 0 $ins
  333: 	expand-postfix $@ expand-link $+!  THEN
  334:     expand-link $@ ;
  335: 
  336: : .link ( addr u -- ) dup >r '| -$split  dup r> = IF  2swap  THEN 
  337:     link-options link $!
  338:     link $@len 0= IF  2dup link $! ( s" .html" link $+! ) THEN
  339:     link $@ ?expand
  340:     href= s" a" tag link-icon?
  341:     parse-string s" a" /tag link-size? link-sig? link-warn? ;
  342: : >link ( -- )  '[ parse type '] parse .link ;
  343: 
  344: \ line handling
  345: 
  346: : char? ( -- c )  >in @ char swap >in ! ;
  347: 
  348: : parse-tag ( addr u char -- )
  349:     >r r@ parse .type
  350:     r> parse 2swap tagged ;
  351: 
  352: : .text ( -- ) 	>in @ >r char drop
  353:     source r@ /string >in @ r> - nip .type ;
  354: 
  355: Create do-words  $100 0 [DO] ' .text , [LOOP]
  356: 
  357: :noname '( emit 1 >in +! ; '( cells do-words + !
  358: 
  359: : bind-char ( xt -- )  char cells do-words + ! ;
  360: 
  361: : char>tag ( -- ) char >r
  362: :noname bl sword postpone SLiteral r@ postpone Literal
  363:     postpone parse-tag postpone ; r> cells do-words + ! ;
  364: 
  365: : >tag '\ parse type '\ parse tag ;
  366: 
  367: char>tag * b
  368: char>tag _ em
  369: char>tag # code
  370: :noname  '~ parse .type '~ parse .type ; '~ cells do-words + !
  371: 
  372: ' >link bind-char [
  373: ' >img  bind-char {
  374: ' >tag  bind-char \
  375: 
  376: : do-word ( char -- )  cells do-words + perform ;
  377: 
  378: : word? ( -- addr u )  >in @ >r bl sword r> >in ! ;
  379: 
  380: wordlist Constant autoreplacements
  381: 
  382: :noname ( -- )
  383:     BEGIN char? do-word source nip >in @ = UNTIL ; is parse-line
  384: 
  385: : parse-line+ ( -- )
  386:     BEGIN
  387: 	word? autoreplacements search-wordlist
  388: 	IF    execute  bl sword 2drop
  389: 	    source >in @ 1- /string drop c@ bl = >in +!
  390: 	ELSE  char? do-word  THEN
  391: 	source nip >in @ = UNTIL ;
  392: 
  393: : parse-to ( char -- ) >r
  394:     BEGIN
  395: 	word? autoreplacements search-wordlist
  396: 	IF    execute  bl sword 2drop
  397: 	    source >in @ 1- /string drop c@ bl = >in +! bl true
  398: 	ELSE  char? dup r@ <>  THEN  WHILE
  399: 	do-word source nip >in @ = UNTIL  ELSE  drop  THEN
  400:     r> parse type ;
  401: 
  402: \ autoreplace
  403: 
  404: : autoreplace ( <[string|url]> -- )
  405:     get-current autoreplacements set-current
  406:     Create set-current
  407:     here 0 , '[ parse 2drop '] parse rot $!
  408:     DOES> $@ .link ;
  409:     
  410: \ paragraph handling
  411: 
  412: : parse-par ( -- )
  413:     BEGIN
  414: 	parse-line+ cr refill  WHILE
  415: 	source nip 0= UNTIL  THEN ;
  416: 
  417: : par ( addr u -- ) env?
  418:     2dup tag parse-par /tag cr cr ;
  419: 
  420: \ scan strings
  421: 
  422: : get-rest ( addr -- ) 0 parse -trailing rot $! ;
  423: Create $lf 1 c, #lf c,
  424: : get-par ( addr -- )  >r  s" " r@ $+!
  425:     BEGIN  0 parse 2dup s" ." str= 0=  WHILE
  426: 	r@ $@len IF  $lf count r@ $+!  THEN  r@ $+!
  427: 	refill 0= UNTIL  ELSE  2drop  THEN
  428:     rdrop ;
  429: 
  430: \ toc handling
  431: 
  432: Variable toc-link
  433: 
  434: : >last ( addr link -- link' )
  435:     BEGIN  dup @  WHILE  @  REPEAT  ! 0 ;
  436: 
  437: Variable create-navs
  438: Variable nav$
  439: Variable nav-name
  440: Variable nav-file
  441: Create nav-buf 0 c,
  442: : nav+ ( char -- )  nav-buf c! nav-buf 1 nav-file $+! ;
  443: 
  444: : filenamize ( addr u -- )
  445:     bounds ?DO
  446: 	I c@  dup 'A 'Z 1+ within IF  bl + nav+
  447: 	ELSE  dup 'a 'z 1+ within IF  nav+
  448: 	ELSE  dup '0 '9 1+ within IF  nav+
  449: 	ELSE  dup  bl = swap '- = or IF  '- nav+
  450: 	THEN  THEN  THEN  THEN
  451:     LOOP ;
  452: : >nav ( addr u -- addr' u' )
  453:     nav-name $!  create-navs @ 0=
  454:     IF  s" navigate/nav.scm" r/w create-file throw create-navs !  THEN
  455:     s' (script-fu-nav-file "' nav$ $! nav-name $@ nav$ $+!
  456:     s' " "./navigate/' nav$ $+!  s" " nav-file $!
  457:     nav-name $@ filenamize
  458:     nav-file $@ nav$ $+! s' .jpg")' nav$ $+!
  459:     nav$ $@ create-navs @ write-line throw
  460:     s" [" nav$ $! nav-name $@ nav$ $+!
  461:     s" |-navigate/" nav$ $+! nav-file $@ nav$ $+! s" .jpg" nav$ $+!
  462:     nav$ $@ ;
  463: 
  464: : toc, ( n -- ) , '| parse >nav here 0 , $! 0 parse here 0 , $! ;
  465: : up-toc   align here toc-link >last , 0 toc, ;
  466: : top-toc  align here toc-link >last , 1 toc, ;
  467: : this-toc align here toc-link >last , 2 toc, ;
  468: : sub-toc  align here toc-link >last , 3 toc, ;
  469: : new-toc  toc-link off ;
  470: 
  471: Variable toc-name
  472: Variable toc-index
  473: 6 Value /toc-line
  474: 
  475: : .toc-entry ( toc flag -- )
  476:     swap cell+ dup @ swap cell+ dup cell+ $@ 2dup href= s" a" tag
  477:     '# scan 1 /string toc-name $@ compare >r
  478:     $@ .img swap
  479:     IF
  480: 	case
  481: 	    2 of  s" ^]|-@/arrow_up.jpg" .img  endof
  482: 	    3 of
  483: 		r@ 0= IF s" *]|-@/circle.jpg"
  484: 		    ELSE s" v]|-@/arrow_down.jpg"  THEN  .img  endof
  485: 	endcase
  486:     ELSE
  487: 	case
  488: 	    0 of  s" ^]|-@/arrow_up.jpg" .img  endof
  489: 	    1 of  s" >]|-@/arrow_right.jpg" .img  endof
  490: 	    2 of  s" *]|-@/circle.jpg" .img  endof
  491: 	    3 of  s" v]|-@/arrow_down.jpg" .img  endof
  492: 	endcase
  493:     THEN
  494:     s" a" /tag rdrop ." <!--" cr ." -->"
  495:     1 toc-index +! toc-index @ /toc-line mod 0=
  496:     IF  s" br" tag/ THEN ;
  497: 
  498: : print-toc ( -- ) toc-index off cr s" menu" class= s" div" >env cr
  499:     0 parse
  500:     dup 0= IF  toc-name $! 0  ELSE
  501: 	toc-name $! toc-name $@ id= s" " s" a" tagged  2
  502:     THEN  >r
  503:     toc-link  BEGIN  @ dup  WHILE
  504: 	dup cell+ @ 3 = r@ 0= and IF  rdrop 1 >r ( s" br" tag/ cr )  THEN
  505: 	dup cell+ @ r@ >= IF  dup r@ 2 = .toc-entry  THEN
  506: 	dup cell+ @ 2 = r@ 2 = and IF  s" br" tag/ toc-index off THEN
  507:     REPEAT  drop rdrop -env cr ;
  508: 
  509: \ handle global tags
  510: 
  511: : indent ( n -- )
  512:     indentlevel @ over
  513:     indentlevel !
  514:     2dup < IF swap DO  -env   LOOP  EXIT THEN
  515:     2dup > IF      DO   s" div" >env  LOOP EXIT THEN
  516:     2dup = IF drop IF  -env  s" div" >env  THEN THEN
  517: ;
  518: : +indent ( -- )
  519:     indentlevel @ IF  -env indent= s" div" >env  THEN
  520: ;
  521: 
  522: wordlist constant longtags
  523: 
  524: Variable divs
  525: 
  526: longtags set-current
  527: 
  528: : --- 0 indent cr s" hr" tag/ cr ;
  529: : *   1 indent s" h1" dclass= s" h1" par +indent s" " dclass= ;
  530: : **  1 indent s" h2" dclass= s" h2" par +indent s" " dclass= ;
  531: : *** 2 indent s" h3" dclass= s" h3" par +indent s" " dclass= ;
  532: : --  0 indent cr print-toc ;
  533: : &&  0 parse id= ;
  534: : -   s" ul" env s" li" par ;
  535: : +   s" ol" env s" li" par ;
  536: : ?   s" dl" env s" dt" par ;
  537: : :   s" dl" env s" dd" par ;
  538: : -<< s" ul" env env? s" li" >env ;
  539: : +<< s" ol" env env? s" li" >env ;
  540: \ : ?<< s" dl" env env? s" dt" >env ; \ not allowed
  541: : :<< s" dl" env env? s" dd" >env ;
  542: : p<< s" p" >env ;
  543: : <<  +env ;
  544: : <*  s" center" class= ;
  545: : <red  s" p" >env s" #ff0000" s" color" opt s" font" >env parse-par ;
  546: : red> -env -env ;
  547: : >>  -env ;
  548: : *> ;
  549: : ::  interpret ;
  550: : .   end-sec on 0 indent ;
  551: : :code s" pre" >env
  552:     BEGIN  source >in @ /string .type cr refill  WHILE
  553: 	source s" :endcode" str= UNTIL  THEN
  554:     -env ;
  555: : :code-file s" pre" >env
  556:     parse" slurp-file type -env ;
  557: : \   postpone \ ;
  558: 
  559: definitions
  560: 
  561: : LT  get-order longtags swap 1+ set-order
  562:     bl sword parser previous ; immediate
  563: 
  564: \ Table
  565: 
  566: : next-char ( -- char )  source drop >in @ + c@ ;
  567: : next-table ( -- )
  568:     BEGIN
  569: 	table-starts table# @ 2* + dup c@ dup
  570: 	IF    1- over c! 1+ c@ 1+  ELSE  swap 1+ c! 0  THEN
  571: 	dup WHILE  table# +!  REPEAT  drop
  572:     table-format $@ table# @ /string drop c@ taligned ! ;
  573: : next>align ( -- )
  574:     next-char dup bl <> over '\ <> and
  575:     IF  taligned ! 1 >in +!  ELSE  drop  THEN ;
  576: 
  577: : |tag ( addr u -- )
  578:     next-table
  579:     next-char '/ = IF  1 >in +!
  580: 	next-char digit?  IF
  581: 	    dup 1- table-starts table# @ 2* + c!
  582: 	    s" rowspan" opt# 1 >in +!  THEN
  583: 	next>align
  584:     THEN
  585:     next-char '\ = IF  1 >in +!
  586: 	next-char digit?  IF
  587: 	    dup 1- table-starts table# @ 2* + 1+ c!
  588: 	    dup 1- table# +!
  589: 	    s" colspan" opt# 1 >in +!  THEN
  590: 	next>align
  591:     THEN
  592:     taligned @ >talign >env
  593:     1 table# +! ;
  594: : |d  table# @ 0> IF  -env  THEN  s" td" |tag ;
  595: : |h  table# @ 0> IF  -env  THEN  s" th" |tag ;
  596: : |line  s" tr" >env table# off ;
  597: : line|  1 >in +! -env -env cr ;
  598: 
  599: longtags set-current
  600: 
  601: : <| ( -- )  table-starts &20 erase
  602:     s" table" class= s" div" >env
  603:     bl sword table-format $! bl sword
  604:     dup IF  s" border" opt  ELSE  2drop  THEN
  605:     s" table" >env ;
  606: : |> -env -env cr cr ;
  607: : +| ( -- )
  608:     |line  BEGIN  |h '| parse-to next-char '+ =  UNTIL line| ;
  609: : -| ( -- )
  610:     |line  BEGIN  |d '| parse-to next-char '- =  UNTIL line| ;
  611: : =| ( -- )
  612:     |line  |h '| parse-to
  613:            BEGIN  |d '| parse-to next-char '= =  UNTIL line| ;
  614: 
  615: definitions
  616: 
  617: \ parse a section
  618: 
  619: : section-par ( -- )  >in off
  620:     bl sword longtags search-wordlist
  621:     IF    execute
  622:     ELSE  source nip IF  >in off s" p" par  THEN  THEN ;
  623: : parse-section ( -- )  end-sec off
  624:     BEGIN  refill  WHILE
  625: 	section-par end-sec @  UNTIL  THEN  end-sec off ;
  626: 
  627: \ HTML head
  628: 
  629: Variable css-file
  630: Variable content
  631: Variable lang
  632: 
  633: : lang@  ( -- addr u )
  634:     lang @ IF  lang $@  ELSE  s" en"  THEN ;
  635: : .css ( -- )
  636:     css-file @ IF  css-file $@len IF
  637: 	    s" StyleSheet" s" rel" opt
  638: 	    css-file $@ href=
  639: 	    s" text/css" s" type" opt s" link" tag/ cr
  640: 	THEN  THEN ;
  641: : .title ( addr u -- )  1 envs ! oldenv off
  642:     .' <!DOCTYPE html' cr
  643:     .'   PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"' cr
  644:     .'   "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">' cr
  645:     s" http://www.w3.org/1999/xhtml" s" xmlns" opt
  646:     lang@ s" xml:lang" opt lang@ s" lang" opt
  647:     s" html" >env cr s" head" >env cr
  648:     s" Content-Type" s" http-equiv" opt
  649:     content $@ s" content" opt
  650:     s" meta" tag/ cr .css
  651:     s" title" tagged cr
  652:     -env ;
  653: 
  654: \ HTML trailer
  655: 
  656: Variable public-key
  657: Variable mail
  658: Variable mail-name
  659: Variable orig-date
  660: 
  661: : .lastmod
  662:     ." Last modified: " time&date rot 0 u.r swap 1-
  663:     s" janfebmaraprmayjunjulaugsepoctnovdec" rot 3 * /string 3 min type
  664:     0 u.r ;
  665: 
  666: : .trailer
  667:     s" center" class= s" address" >env
  668:     orig-date @ IF  ." Created " orig-date $@ type ." . "  THEN
  669:     .lastmod
  670:  ."  by "
  671:     s" Mail|@/mail.gif" .img mail $@ mailto: mail-name $@ s" a" tagged
  672:     public-key @ IF
  673: 	public-key $@ href=  s" a" tag
  674: 	s" PGP key|@/gpg.asc.gif" .img s" a" /tag
  675:     THEN
  676:     -envs ;
  677: 
  678: \ top word
  679: 
  680: : maintainer ( -- )
  681:     '< sword -trailing mail-name $! '> sword mail $! ;
  682: : pgp-key ( -- )
  683:     bl sword -trailing public-key $! ;
  684: : charset ( -- )  s" text/xhtml; charset=" content $!
  685:     bl sword -trailing content $+! ;
  686: 
  687: charset iso-8859-1
  688: 
  689: : created ( -- )
  690:     bl sword orig-date $! ;
  691: : icons
  692:     bl sword icon-prefix $! ;
  693: : lang
  694:     bl sword lang $! ;
  695: : expands '# sword expand-prefix $! bl sword expand-postfix $! ;
  696: 
  697: icons icons
  698: 
  699: Variable style$
  700: : style> style$ @ 0= IF  s" " style$ $!  THEN  style$ $@ tag-option $! ;
  701: : >style tag-option $@ style$ $! s" " tag-option $! ;
  702: 
  703: : style  style> opt >style ;
  704: : background ( -- )  parse" s" background" style ;
  705: : text ( -- )  parse" s" text" style ;
  706:     warnings @ warnings off
  707: : link ( -- )  parse" s" link" style ;
  708:     warnings !
  709: : vlink ( -- ) parse" s" vlink" style ;
  710: : marginheight ( -- ) parse" s" marginheight" style ;
  711: : css ( -- ) parse" css-file $! ;
  712: 
  713: : wf ( -- )
  714:     outfile-id >r
  715:     bl sword r/w create-file throw to outfile-id
  716:     parse" .title
  717:     +env style> s" body" env env?
  718:     ['] parse-section catch .trailer
  719:     outfile-id close-file throw
  720:     r> to outfile-id
  721:     dup 0< IF  throw  ELSE  drop  THEN ;
  722: 
  723: : eval-par ( addr u -- )
  724:   s" wf-temp.wf" r/w create-file throw >r
  725:   r@ write-file r> close-file throw
  726:   push-file s" wf-temp.wf" r/o open-file throw loadfile !
  727:   parse-par -env parse-section
  728:   loadfile @ close-file swap 2dup or
  729:   pop-file  drop throw throw
  730:   s" wf-temp.wf" delete-file throw ;
  731: 
  732: \ simple text data base
  733: 
  734: Variable last-entry
  735: Variable field#
  736: 
  737: : table: ( xt n -- )  Create 0 , ['] type , , ,  1 field# !
  738:     DOES> 2 cells + 2@ >in @ >r longtags set-current
  739:     Create definitions swap , r> >in !
  740:     here last-entry !
  741:     dup 0 DO  0 ,  LOOP
  742:     1 DO  s" " last-entry @ I cells + $!  LOOP
  743:     last-entry @ get-rest
  744:     DOES> dup cell+ swap perform ;
  745: 
  746: : field:  Create field# @ , ['] type , 1 field# +!
  747: DOES> @ cells last-entry @ + get-rest ;
  748: : par:  Create field# @ , ['] eval-par , 1 field# +!
  749: DOES> @ cells last-entry @ + get-par ;
  750: 
  751: : >field-rest >body @ cells postpone Literal postpone + ;
  752: : >field ' >field-rest ; immediate
  753: 
  754: : db-line ( -- )
  755:     BEGIN
  756: 	source >in @ /string nip  WHILE
  757: 	    '% parse  postpone SLiteral postpone type
  758: 	    '% parse dup IF
  759: 		'| $split 2swap
  760: 		sfind 0= abort" Field not found"
  761: 		dup postpone r@ >field-rest  postpone $@
  762: 		over IF  drop evaluate  ELSE
  763: 		    nip nip >body cell+ @ compile,
  764: 		THEN
  765: 	    ELSE  2drop  postpone cr  THEN
  766:     REPEAT ;
  767: 
  768: : db-par ( -- )  LT postpone p<< postpone >r
  769:     BEGIN  db-line refill  WHILE  next-char '. = UNTIL  1 >in +!  THEN
  770:     postpone rdrop ( LT postpone >> ) ; immediate

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>