1: \ wiki forth
2:
3: \ Copyright (C) 2003,2004 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: require string.fs
22:
23: \ basic stuff
24:
25: : -scan ( addr u char -- addr' u' )
26: >r BEGIN dup WHILE 1- 2dup + c@ r@ = UNTIL THEN
27: rdrop ;
28: : -$split ( addr u char -- addr1 u1 addr2 u2 )
29: >r 2dup r@ -scan 2dup + c@ r> = negate over + >r
30: 2swap r> /string ;
31: : parse" ( -- addr u ) '" parse 2drop '" parse ;
32: : .' '' parse postpone SLiteral postpone type ; immediate
33: : s' '' parse postpone SLiteral ; immediate
34:
35: \ character recoding
36:
37: [IFDEF] maxascii $100 to maxascii 8-bit-io [THEN]
38: \ UTF-8 IO fails with .type:
39:
40: : .type ( addr u -- )
41: bounds ?DO I c@
42: case
43: '& of ." &" endof
44: '< of ." <" endof
45: dup emit
46: endcase
47: LOOP ;
48:
49: \ tag handling
50:
51: Variable indentlevel
52: Variable tag-option
53: Variable tag-class
54: s" " tag-option $!
55: s" " tag-class $!
56:
57: : tag ( addr u -- ) '< emit type
58: tag-class $@len IF .\" class=\"" tag-class $@ type '" emit THEN
59: tag-option $@ type
60: '> emit
61: s" " tag-option $! s" " tag-class $! ;
62: : tag/ ( addr u -- ) s" /" tag-option $+! tag ;
63: : /tag ( addr u -- ) '< emit '/ emit type '> emit ;
64: : tagged ( addr1 u1 addr2 u2 -- ) 2dup 2>r tag .type 2r> /tag ;
65:
66: : opt ( addr u opt u -- ) s" " tag-option $+!
67: tag-option $+! s' ="' tag-option $+! tag-option $+!
68: s' "' tag-option $+! ;
69: : n>string ( n -- addr u ) 0 <# #S #> ;
70: : xy>string ( x y -- ) swap 0 <# #S 'x hold 2drop 0 #S 's hold #> ;
71: : opt# ( n opt u -- ) rot n>string 2swap opt ;
72: : href= ( addr u -- ) s" href" opt ;
73: : id= ( addr u -- ) s" id" opt ;
74: : src= ( addr u -- ) s" src" opt ;
75: : alt= ( addr u -- ) s" alt" opt ;
76: : width= ( n -- ) s" width" opt# ;
77: : height= ( n -- ) s" height" opt# ;
78: : align= ( addr u -- ) s" align" opt ;
79: : class= ( addr u -- )
80: tag-class $@len IF s" " tag-class $+! THEN
81: tag-class $+! ;
82: : indent= ( -- )
83: indentlevel @ 0 <# #S 'p hold #> class= ;
84: : mailto: ( addr u -- ) s' href="mailto:' tag-option $+!
85: tag-option $+! s' "' tag-option $+! ;
86:
87: \ environment handling
88:
89: Variable end-sec
90: Variable oldenv
91: Variable envs 30 0 [DO] 0 , [LOOP]
92:
93: : env$ ( -- addr ) envs dup @ 1+ cells + ;
94: : env ( addr u -- ) env$ $! ;
95: : env? ( -- ) envs @ oldenv @
96: 2dup > IF env$ $@ tag THEN
97: 2dup < IF env$ cell+ $@ /tag env$ cell+ $off THEN
98: drop oldenv ! ;
99: : +env 1 envs +! ;
100: : -env end-sec @ envs @ 2 > or IF -1 envs +! env? THEN ;
101: : -envs envs @ 0 ?DO -env cr LOOP ;
102: : >env ( addr u -- ) +env env env? ;
103:
104: \ alignment
105:
106: Variable table-format
107: Variable table#
108: Create table-starts &10 0 [DO] 0 c, 0 c, [LOOP]
109: Variable taligned
110:
111: : >align ( c -- )
112: CASE
113: 'l OF s" left" class= ENDOF
114: 'r OF s" right" class= ENDOF
115: 'c OF s" center" class= ENDOF
116: '< OF s" left" class= ENDOF
117: '> OF s" right" class= ENDOF
118: '= OF s" center" class= ENDOF
119: '~ OF s" middle" class= ENDOF
120: ENDCASE ;
121:
122: : >talign ( c -- )
123: CASE
124: 'l OF s" left" align= ENDOF
125: 'r OF s" right" align= ENDOF
126: 'c OF s" center" align= ENDOF
127: '< OF s" left" align= ENDOF
128: '> OF s" right" align= ENDOF
129: '= OF s" center" align= ENDOF
130: ENDCASE taligned on ;
131:
132: : >border ( c -- )
133: case
134: '- of s" border0" class= endof
135: '+ of s" border1" class= endof
136: endcase ;
137:
138: \ image handling
139:
140: wordlist Constant img-sizes
141:
142: Create imgbuf $20 allot
143:
144: Create pngsig $89 c, $50 c, $4E c, $47 c, $0D c, $0A c, $1A c, $0A c,
145: Create jfif $FF c, $D8 c, $FF c, $E0 c, $00 c, $10 c, $4A c, $46 c,
146: $49 c, $46 c,
147:
148: : b@ ( addr -- x ) 0 swap 4 bounds ?DO 8 lshift I c@ + LOOP ;
149: : bw@ ( addr -- x ) 0 swap 2 bounds ?DO 8 lshift I c@ + LOOP ;
150:
151: : gif? ( -- flag )
152: s" GIF89a" imgbuf over str=
153: s" GIF87a" imgbuf over str= or ;
154: : gif-size ( -- w h )
155: imgbuf 8 + c@ imgbuf 9 + c@ 8 lshift +
156: imgbuf 6 + c@ imgbuf 7 + c@ 8 lshift + ;
157:
158: : png? ( -- flag )
159: pngsig 8 imgbuf over str= ;
160: : png-size ( -- w h )
161: imgbuf $14 + b@ imgbuf $10 + b@ ;
162:
163: : jpg? ( -- flag )
164: jfif 10 imgbuf over str= ;
165: : jpg-size ( fd -- w h ) >r
166: 2. BEGIN
167: 2dup r@ reposition-file throw
168: imgbuf $10 r@ read-file throw 0<>
169: imgbuf bw@ $FFC0 $FFD0 within 0= and WHILE
170: imgbuf 2 + bw@ 2 + 0 d+ REPEAT
171: 2drop imgbuf 5 + bw@ imgbuf 7 + bw@ rdrop ;
172:
173: : img-size ( fd -- w h ) >r
174: gif? IF gif-size rdrop EXIT THEN
175: jpg? IF r> jpg-size EXIT THEN
176: png? IF png-size rdrop EXIT THEN
177: 0 0 rdrop ;
178:
179: 3 set-precision
180:
181: : f.size ( r -- )
182: f$ dup >r 0<=
183: IF '0 emit
184: ELSE scratch r@ min type r@ precision - zeros THEN
185: '. emit r@ negate zeros
186: scratch r> 0 max /string 0 max -zeros type ;
187:
188: : size-does> ( -- ) DOES> ( -- )
189: ." img." dup body> >name .name
190: 2@ ." { width: "
191: s>d d>f 13.8e f/ f.size ." em; height: "
192: s>d d>f 13.8e f/ f.size ." em; }" cr ;
193:
194: : size-css ( file< > -- )
195: outfile-id >r
196: bl sword r/w create-file throw to outfile-id
197: img-sizes wordlist-id
198: BEGIN @ dup WHILE
199: dup name>int execute
200: REPEAT drop
201: outfile-id close-file throw
202: r> to outfile-id
203: dup 0< IF throw ELSE drop THEN ;
204:
205: : size-class ( x y addr u -- x y )
206: 2dup class=
207: 2dup img-sizes search-wordlist IF drop 2drop
208: ELSE
209: get-current >r img-sizes set-current
210: nextname Create 2dup , , size-does>
211: r> set-current
212: THEN ;
213:
214: : .img-size ( addr u -- )
215: r/o open-file IF drop EXIT THEN >r
216: imgbuf $20 r@ read-file throw drop
217: r@ img-size
218: r> close-file throw
219: 2dup or IF 2dup xy>string size-class THEN
220: ?dup IF width= THEN
221: ?dup IF height= THEN
222: ;
223:
224: \ link creation
225:
226: Variable link
227: Variable link-sig
228: Variable link-suffix
229: Variable iconpath
230: Variable icon-prefix
231: Variable icon-tmp
232:
233: Variable do-size
234: Variable do-icon
235: Variable do-expand
236:
237: Defer parse-line
238:
239: : .img ( addr u -- )
240: dup >r '@ -$split dup r> = IF 2swap 2drop
241: ELSE 2swap icon-tmp $! icon-prefix $@ icon-tmp $+! icon-tmp $+!
242: icon-tmp $@ THEN
243: dup >r '| -$split dup r> = IF 2swap THEN
244: dup IF 2swap alt= ELSE 2drop THEN
245: tag-class $@len >r over c@ >align tag-class $@len r> = 1+ /string
246: tag-class $@len >r over c@ >border tag-class $@len r> = 1+ /string
247: 2dup .img-size src= s" img" tag/ ;
248: : >img ( -- ) '{ parse type '} parse .img ;
249:
250: : alt-suffix ( -- )
251: link-suffix $@len 2 - link-suffix $!len
252: s" [" link-suffix 0 $ins
253: s" ]" link-suffix $+!
254: link-suffix $@ alt= ;
255:
256: : get-icon ( addr u -- ) iconpath @ IF 2drop EXIT THEN
257: link-suffix $! s" .*" link-suffix $+!
258: icon-prefix $@ open-dir throw >r
259: BEGIN
260: pad $100 r@ read-dir throw WHILE
261: pad swap 2dup link-suffix $@ filename-match
262: IF icon-prefix $@ iconpath $! s" /" iconpath $+! iconpath $+!
263: iconpath $@ 2dup .img-size src= '- >border
264: alt-suffix s" img" tag/ true
265: ELSE 2drop false THEN
266: UNTIL ELSE drop THEN
267: r> close-dir throw ;
268:
269: : link-icon? ( -- ) do-icon @ 0= ?EXIT
270: iconpath @ IF iconpath $off THEN
271: link $@ + 1- c@ '/ = IF s" index.html" ELSE link $@ THEN
272: '# $split 2drop
273: BEGIN '. $split 2swap 2drop dup WHILE
274: 2dup get-icon REPEAT 2drop ;
275:
276: : link-size? ( -- ) do-size @ 0= ?EXIT
277: link $@ r/o open-file IF drop EXIT THEN >r
278: r@ file-size throw $400 um/mod nip
279: dup $800 < IF ." (" 0 u.r ." k)"
280: ELSE $400 / ." (" 0 u.r ." M)" THEN
281: r> close-file throw ;
282:
283: : link-sig? ( -- )
284: link $@ link-sig $! s" .sig" link-sig $+!
285: link-sig $@ r/o open-file IF drop EXIT THEN
286: close-file throw
287: ." (" link-sig $@ href= s" a" tag
288: s" |-@/sig.gif" .img ." sig" s" /a" tag ." )" ;
289:
290: : link-warn? ( -- ) \ local links only
291: link $@ ': scan nip ?EXIT
292: link $@ '# $split 2drop r/o open-file nip IF
293: s" Dead Link '" stderr write-file throw
294: link $@ stderr write-file throw
295: s\" ' !!!\n" stderr write-file throw
296: THEN ;
297:
298: : link-options ( addr u -- addr' u' )
299: do-size off do-icon on do-expand off
300: over c@ '% = over 0> and IF do-size on 1 /string THEN
301: over c@ '\ = over 0> and IF do-icon off 1 /string THEN
302: over c@ '* = over 0> and IF do-expand on 1 /string THEN ;
303:
304: s" Gforth" environment? [IF] s" 0.5.0" str= [IF]
305: : parse-string ( c-addr u -- ) \ core,block
306: s" *evaluated string*" loadfilename>r
307: push-file #tib ! >tib !
308: >in off blk off loadfile off -1 loadline !
309: ['] parse-line catch
310: pop-file r>loadfilename throw ;
311: [ELSE]
312: : parse-string ( addr u -- )
313: evaluate-input cell new-tib #tib ! tib !
314: ['] parse-line catch pop-file throw ;
315: [THEN] [THEN]
316:
317: Variable expand-link
318: Variable expand-prefix
319: Variable expand-postfix
320:
321: : ?expand ( addr u -- ) expand-link $!
322: do-expand @ IF
323: expand-prefix $@ expand-link 0 $ins
324: expand-postfix $@ expand-link $+! THEN
325: expand-link $@ ;
326:
327: : .link ( addr u -- ) dup >r '| -$split dup r> = IF 2swap THEN
328: link-options link $!
329: link $@len 0= IF 2dup link $! ( s" .html" link $+! ) THEN
330: link $@ ?expand
331: href= s" a" tag link-icon?
332: parse-string s" a" /tag link-size? link-sig? link-warn? ;
333: : >link ( -- ) '[ parse type '] parse .link ;
334:
335: \ line handling
336:
337: : char? ( -- c ) >in @ char swap >in ! ;
338:
339: : parse-tag ( addr u char -- )
340: >r r@ parse .type
341: r> parse 2swap tagged ;
342:
343: : .text ( -- ) >in @ >r char drop
344: source r@ /string >in @ r> - nip .type ;
345:
346: Create do-words $100 0 [DO] ' .text , [LOOP]
347:
348: :noname '( emit 1 >in +! ; '( cells do-words + !
349:
350: : bind-char ( xt -- ) char cells do-words + ! ;
351:
352: : char>tag ( -- ) char >r
353: :noname bl sword postpone SLiteral r@ postpone Literal
354: postpone parse-tag postpone ; r> cells do-words + ! ;
355:
356: : >tag '\ parse type '\ parse tag ;
357:
358: char>tag * b
359: char>tag _ em
360: char>tag # code
361: :noname '~ parse .type '~ parse .type ; '~ cells do-words + !
362:
363: ' >link bind-char [
364: ' >img bind-char {
365: ' >tag bind-char \
366:
367: : do-word ( char -- ) cells do-words + perform ;
368:
369: : word? ( -- addr u ) >in @ >r bl sword r> >in ! ;
370:
371: wordlist Constant autoreplacements
372:
373: :noname ( -- )
374: BEGIN char? do-word source nip >in @ = UNTIL ; is parse-line
375:
376: : parse-line+ ( -- )
377: BEGIN
378: word? autoreplacements search-wordlist
379: IF execute bl sword 2drop
380: source >in @ 1- /string drop c@ bl = >in +!
381: ELSE char? do-word THEN
382: source nip >in @ = UNTIL ;
383:
384: : parse-to ( char -- ) >r
385: BEGIN
386: word? autoreplacements search-wordlist
387: IF execute bl sword 2drop
388: source >in @ 1- /string drop c@ bl = >in +! bl true
389: ELSE char? dup r@ <> THEN WHILE
390: do-word source nip >in @ = UNTIL ELSE drop THEN
391: r> parse type ;
392:
393: \ autoreplace
394:
395: : autoreplace ( <[string|url]> -- )
396: get-current autoreplacements set-current
397: Create set-current
398: here 0 , '[ parse 2drop '] parse rot $!
399: DOES> $@ .link ;
400:
401: \ paragraph handling
402:
403: : parse-par ( -- )
404: BEGIN
405: parse-line+ cr refill WHILE
406: source nip 0= UNTIL THEN ;
407:
408: : par ( addr u -- ) env?
409: 2dup tag parse-par /tag cr cr ;
410:
411: \ scan strings
412:
413: : get-rest ( addr -- ) 0 parse -trailing rot $! ;
414: Create $lf 1 c, #lf c,
415: : get-par ( addr -- ) >r s" " r@ $+!
416: BEGIN 0 parse 2dup s" ." str= 0= WHILE
417: r@ $@len IF $lf count r@ $+! THEN r@ $+!
418: refill 0= UNTIL ELSE 2drop THEN
419: rdrop ;
420:
421: \ toc handling
422:
423: Variable toc-link
424:
425: : >last ( addr link -- link' )
426: BEGIN dup @ WHILE @ REPEAT ! 0 ;
427:
428: Variable create-navs
429: Variable nav$
430: Variable nav-name
431: Variable nav-file
432: Create nav-buf 0 c,
433: : nav+ ( char -- ) nav-buf c! nav-buf 1 nav-file $+! ;
434:
435: : filenamize ( addr u -- )
436: bounds ?DO
437: I c@ dup 'A 'Z 1+ within IF bl + nav+
438: ELSE dup 'a 'z 1+ within IF nav+
439: ELSE dup '0 '9 1+ within IF nav+
440: ELSE dup bl = swap '- = or IF '- nav+
441: THEN THEN THEN THEN
442: LOOP ;
443: : >nav ( addr u -- addr' u' )
444: nav-name $! create-navs @ 0=
445: IF s" navigate/nav.scm" r/w create-file throw create-navs ! THEN
446: s' (script-fu-nav-file "' nav$ $! nav-name $@ nav$ $+!
447: s' " "./navigate/' nav$ $+! s" " nav-file $!
448: nav-name $@ filenamize
449: nav-file $@ nav$ $+! s' .jpg")' nav$ $+!
450: nav$ $@ create-navs @ write-line throw
451: s" [" nav$ $! nav-name $@ nav$ $+!
452: s" |-navigate/" nav$ $+! nav-file $@ nav$ $+! s" .jpg" nav$ $+!
453: nav$ $@ ;
454:
455: : toc, ( n -- ) , '| parse >nav here 0 , $! 0 parse here 0 , $! ;
456: : up-toc align here toc-link >last , 0 toc, ;
457: : top-toc align here toc-link >last , 1 toc, ;
458: : this-toc align here toc-link >last , 2 toc, ;
459: : sub-toc align here toc-link >last , 3 toc, ;
460: : new-toc toc-link off ;
461:
462: Variable toc-name
463: Variable toc-index
464: 6 Value /toc-line
465:
466: : .toc-entry ( toc flag -- )
467: swap cell+ dup @ swap cell+ dup cell+ $@ 2dup href= s" a" tag
468: '# scan 1 /string toc-name $@ compare >r
469: $@ .img swap
470: IF
471: case
472: 2 of s" ^]|-@/arrow_up.jpg" .img endof
473: 3 of
474: r@ 0= IF s" *]|-@/circle.jpg"
475: ELSE s" v]|-@/arrow_down.jpg" THEN .img endof
476: endcase
477: ELSE
478: case
479: 0 of s" ^]|-@/arrow_up.jpg" .img endof
480: 1 of s" >]|-@/arrow_right.jpg" .img endof
481: 2 of s" *]|-@/circle.jpg" .img endof
482: 3 of s" v]|-@/arrow_down.jpg" .img endof
483: endcase
484: THEN
485: s" a" /tag rdrop ." <!--" cr ." -->"
486: 1 toc-index +! toc-index @ /toc-line mod 0=
487: IF s" br" tag/ THEN ;
488:
489: : print-toc ( -- ) toc-index off cr s" menu" id= s" div" >env cr
490: 0 parse
491: dup 0= IF toc-name $! 0 ELSE
492: toc-name $! toc-name $@ id= s" " s" a" tagged 2
493: THEN >r
494: toc-link BEGIN @ dup WHILE
495: dup cell+ @ 3 = r@ 0= and IF rdrop 1 >r ( s" br" tag/ cr ) THEN
496: dup cell+ @ r@ >= IF dup r@ 2 = .toc-entry THEN
497: dup cell+ @ 2 = r@ 2 = and IF s" br" tag/ toc-index off THEN
498: REPEAT drop rdrop -env cr ;
499:
500: \ handle global tags
501:
502: : indent ( n -- )
503: indentlevel @ over
504: indentlevel !
505: 2dup < IF swap DO -env LOOP EXIT THEN
506: 2dup > IF DO s" div" >env LOOP EXIT THEN
507: 2dup = IF drop IF -env s" div" >env THEN THEN
508: ;
509: : +indent ( -- )
510: indentlevel @ IF -env indent= s" div" >env THEN
511: ;
512:
513: wordlist constant longtags
514:
515: Variable divs
516:
517: longtags set-current
518:
519: : --- 0 indent cr s" hr" tag/ cr ;
520: : * 1 indent s" h1" par +indent ;
521: : ** 1 indent s" h2" par +indent ;
522: : *** 2 indent s" h3" par +indent ;
523: : -- 0 indent cr print-toc ;
524: : && 0 parse id= ;
525: : - s" ul" env s" li" par ;
526: : + s" ol" env s" li" par ;
527: : ? s" dl" env s" dt" par ;
528: : : s" dl" env s" dd" par ;
529: : -<< s" ul" env env? s" li" >env ;
530: : +<< s" ol" env env? s" li" >env ;
531: : ?<< s" dl" env env? s" dt" >env ;
532: : :<< s" dl" env env? s" dd" >env ;
533: : p<< s" p" >env ;
534: : << +env ;
535: : <* s" center" class= ;
536: : <red s" #ff0000" s" color" opt s" font" >env ;
537: : red> -env ;
538: : >> -env ;
539: : *> ;
540: : :: interpret ;
541: : . end-sec on 0 indent ;
542: : :code s" pre" >env
543: BEGIN source >in @ /string type cr refill WHILE
544: source s" :endcode" str= UNTIL THEN
545: -env ;
546: : :code-file s" pre" >env
547: parse" slurp-file type -env ;
548: : \ postpone \ ;
549:
550: definitions
551:
552: : LT get-order longtags swap 1+ set-order
553: bl sword parser previous ; immediate
554:
555: \ Table
556:
557: : next-char ( -- char ) source drop >in @ + c@ ;
558: : next-table ( -- )
559: BEGIN
560: table-starts table# @ 2* + dup c@ dup
561: IF 1- over c! 1+ c@ 1+ ELSE swap 1+ c! 0 THEN
562: dup WHILE table# +! REPEAT drop
563: table-format $@ table# @ /string drop c@ taligned ! ;
564: : next>align ( -- )
565: next-char dup bl <> over '\ <> and
566: IF taligned ! 1 >in +! ELSE drop THEN ;
567:
568: : |tag ( addr u -- )
569: next-table
570: next-char '/ = IF 1 >in +!
571: next-char digit? IF
572: dup 1- table-starts table# @ 2* + c!
573: s" rowspan" opt# 1 >in +! THEN
574: next>align
575: THEN
576: next-char '\ = IF 1 >in +!
577: next-char digit? IF
578: dup 1- table-starts table# @ 2* + 1+ c!
579: dup 1- table# +!
580: s" colspan" opt# 1 >in +! THEN
581: next>align
582: THEN
583: taligned @ >talign >env
584: 1 table# +! ;
585: : |d table# @ 0> IF -env THEN s" td" |tag ;
586: : |h table# @ 0> IF -env THEN s" th" |tag ;
587: : |line s" tr" >env table# off ;
588: : line| 1 >in +! -env -env cr ;
589:
590: longtags set-current
591:
592: : <| ( -- ) table-starts &20 erase
593: s" table" class= s" div" >env
594: bl sword table-format $! bl sword
595: dup IF s" border" opt ELSE 2drop THEN
596: s" table" >env ;
597: : |> -env -env cr cr ;
598: : +| ( -- )
599: |line BEGIN |h '| parse-to next-char '+ = UNTIL line| ;
600: : -| ( -- )
601: |line BEGIN |d '| parse-to next-char '- = UNTIL line| ;
602: : =| ( -- )
603: |line |h '| parse-to
604: BEGIN |d '| parse-to next-char '= = UNTIL line| ;
605:
606: definitions
607:
608: \ parse a section
609:
610: : section-par ( -- ) >in off
611: bl sword longtags search-wordlist
612: IF execute
613: ELSE source nip IF >in off s" p" par THEN THEN ;
614: : parse-section ( -- ) end-sec off
615: BEGIN refill WHILE
616: section-par end-sec @ UNTIL THEN ;
617:
618: \ HTML head
619:
620: Variable css-file
621:
622: : .title ( addr u -- )
623: .' <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//en" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">' cr
624: s" html" >env s" head" >env cr
625: s" Content-Type" s" http-equiv" opt
626: s" text/xhtml; charset=iso-8859-1" s" content" opt
627: s" meta" tag/
628: css-file @ IF css-file $@len IF
629: s" StyleSheet" s" rel" opt
630: css-file $@ href=
631: s" text/css" s" type" opt s" link" tag/
632: THEN THEN
633: s" title" tagged cr
634: -env ;
635:
636: \ HTML trailer
637:
638: Variable public-key
639: Variable mail
640: Variable mail-name
641: Variable orig-date
642:
643: : .lastmod
644: ." Last modified: " time&date rot 0 u.r swap 1-
645: s" janfebmaraprmayjunjulaugsepoctnovdec" rot 3 * /string 3 min type
646: 0 u.r ;
647:
648: : .trailer
649: s" center" class= s" address" >env
650: orig-date @ IF ." Created " orig-date $@ type ." . " THEN
651: .lastmod
652: ." by "
653: s" Mail|@/mail.gif" .img mail $@ mailto: mail-name $@ s" a" tagged
654: public-key @ IF
655: public-key $@ href= s" a" tag
656: s" PGP key|@/gpg.asc.gif" .img s" a" /tag
657: THEN
658: -envs ;
659:
660: \ top word
661:
662: : maintainer ( -- )
663: '< sword -trailing mail-name $! '> sword mail $! ;
664: : pgp-key ( -- )
665: bl sword -trailing public-key $! ;
666: : created ( -- )
667: bl sword orig-date $! ;
668: : icons
669: bl sword icon-prefix $! ;
670: : expands '# sword expand-prefix $! bl sword expand-postfix $! ;
671:
672: icons icons
673:
674: Variable style$
675: : style> style$ @ 0= IF s" " style$ $! THEN style$ $@ tag-option $! ;
676: : >style tag-option $@ style$ $! s" " tag-option $! ;
677:
678: : style style> opt >style ;
679: : background ( -- ) parse" s" background" style ;
680: : text ( -- ) parse" s" text" style ;
681: warnings @ warnings off
682: : link ( -- ) parse" s" link" style ;
683: warnings !
684: : vlink ( -- ) parse" s" vlink" style ;
685: : marginheight ( -- ) parse" s" marginheight" style ;
686: : css ( -- ) parse" css-file $! ;
687:
688: : wf ( -- )
689: outfile-id >r
690: bl sword r/w create-file throw to outfile-id
691: parse" .title
692: +env style> s" body" env env?
693: ['] parse-section catch .trailer
694: outfile-id close-file throw
695: r> to outfile-id
696: dup 0< IF throw ELSE drop THEN ;
697:
698: : eval-par ( addr u -- )
699: s" wf-temp.wf" r/w create-file throw >r
700: r@ write-file r> close-file throw
701: push-file s" wf-temp.wf" r/o open-file throw loadfile !
702: parse-par parse-section
703: loadfile @ close-file swap 2dup or
704: pop-file drop throw throw
705: s" wf-temp.wf" delete-file throw ;
706:
707: \ simple text data base
708:
709: Variable last-entry
710: Variable field#
711:
712: : table: ( xt n -- ) Create 0 , ['] type , , , 1 field# !
713: DOES> 2 cells + 2@ >in @ >r longtags set-current
714: Create definitions swap , r> >in !
715: here last-entry !
716: dup 0 DO 0 , LOOP
717: 1 DO s" " last-entry @ I cells + $! LOOP
718: last-entry @ get-rest
719: DOES> dup cell+ swap perform ;
720:
721: : field: Create field# @ , ['] type , 1 field# +!
722: DOES> @ cells last-entry @ + get-rest ;
723: : par: Create field# @ , ['] eval-par , 1 field# +!
724: DOES> @ cells last-entry @ + get-par ;
725:
726: : >field-rest >body @ cells postpone Literal postpone + ;
727: : >field ' >field-rest ; immediate
728:
729: : db-line ( -- )
730: BEGIN
731: source >in @ /string nip WHILE
732: '% parse postpone SLiteral postpone type
733: '% parse dup IF
734: '| $split 2swap
735: sfind 0= abort" Field not found"
736: dup postpone r@ >field-rest postpone $@
737: over IF drop evaluate ELSE
738: nip nip >body cell+ @ compile,
739: THEN
740: ELSE 2drop postpone cr THEN
741: REPEAT ;
742:
743: : db-par ( -- ) LT postpone p<< postpone >r
744: BEGIN db-line refill WHILE next-char '. = UNTIL 1 >in +! THEN
745: postpone rdrop LT postpone >> ; immediate
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>